net-news/liferea/liferea-1.5.2b.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="1"
   6
   7 WANT_AUTOMAKE=1.7
   8 WANT_AUTOCONF=latest
   9 inherit gnome2 eutils
  10
  11 DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo/etc feeds"
  12 HOMEPAGE="http://liferea.sourceforge.net/"
  13 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  14 LICENSE="GPL-2"
  15
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
  18 IUSE="avahi dbus gtkhtml gnutls libnotify lua networkmanager webkit xulrunner"
  19
  20 RDEPEND="xulrunner? ( net-libs/xulrunner:1.8 )
  21                  webkit? ( net-libs/webkitgtk )
  22                  !amd64? ( gtkhtml? ( gnome-extra/gtkhtml:2 ) )
  23                  >=x11-libs/gtk+-2.8:2
  24                  x11-libs/pango
  25                  gnome-base/gconf:2
  26                  >=dev-libs/libxml2-2.6.27:2
  27                  >=dev-libs/libxslt-1.1.19
  28                  >=dev-db/sqlite-3.3:3
  29                  dev-libs/glib:2
  30                  gnome-base/libglade:2.0
  31                  avahi? ( net-dns/avahi )
  32                  dbus? ( >=dev-libs/dbus-glib-0.71 )
  33                  gnutls? ( net-libs/gnutls )
  34                  libnotify? ( >=x11-libs/libnotify-0.3.2 )
  35                  lua? ( >=dev-lang/lua-5.1 )
  36                  networkmanager? ( net-misc/networkmanager )"
  37
  38 DEPEND="${RDEPEND}
  39                 dev-util/pkgconfig
  40                 >=dev-util/intltool-0.35"
  41
  42 DOCS="AUTHORS ChangeLog NEWS README"
  43
  44 pkg_setup() {
  45         # Backends are now mutually exclusive.
  46         # we prefer xulrunner over firefox over seamonkey over gtkhtml
  47         if ! ( use xulrunner || use webkit || use gtkhtml ); then
  48                 ewarn "You must choose at least one backend for liferea to work."
  49                 ewarn "Choices are: xulrunner, webkit, gtkhtml."
  50                 die "You must enable one of the backends"
  51         fi
  52
  53         G2CONF="${G2CONF} \
  54                 --disable-gecko \
  55                 $(use_enable xulrunner) \
  56                 $(use_enable webkit) \
  57                 $(use_enable gtkhtml gtkhtml2) \
  58                 $(use_enable avahi) \
  59                 $(use_enable dbus) \
  60                 $(use_enable gnutls) \
  61                 $(use_enable libnotify) \
  62                 $(use_enable lua) \
  63                 $(use_enable networkmanager nm)"
  64 }
  65
  66 src_install() {
  67         gnome2_src_install
  68         rm -f "${D}"/usr/bin/${PN}
  69         mv "${D}"/usr/bin/${PN}-bin "${D}"/usr/bin/${PN}
  70 }