elisp/geiser-guile.el

   1 ;; geiser-guile.el -- guile's implementation of the geiser protocols
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Mar 08, 2009 23:03
  11
  12 \f
  13
  14 (require 'geiser-connection)
  15 (require 'geiser-syntax)
  16 (require 'geiser-custom)
  17 (require 'geiser-base)
  18 (require 'geiser-eval)
  19 (require 'geiser-edit)
  20 (require 'geiser-log)
  21 (require 'geiser)
  22
  23 (require 'compile)
  24 (require 'info-look)
  25
  26 (eval-when-compile (require 'cl))
  27
  28 \f
  29 ;;; Customization:
  30
  31 (defgroup geiser-guile nil
  32   "Customization for Geiser's Guile flavour."
  33   :group 'geiser)
  34
  35 (geiser-custom--defcustom geiser-guile-binary
  36   (cond ((eq system-type 'windows-nt) "guile.exe")
  37         ((eq system-type 'darwin) "guile")
  38         (t "guile"))
  39   "Name to use to call the Guile executable when starting a REPL."
  40   :type '(choice string (repeat string))
  41   :group 'geiser-guile)
  42
  43 (geiser-custom--defcustom geiser-guile-load-path nil
  44   "A list of paths to be added to Guile's load path when it's
  45 started."
  46   :type '(repeat file)
  47   :group 'geiser-guile)
  48
  49 (geiser-custom--defcustom geiser-guile-init-file "~/.guile-geiser"
  50   "Initialization file with user code for the Guile REPL.
  51 If all you want is to load ~/.guile, set
  52 `geiser-guile-load-init-file-p' instead."
  53   :type 'string
  54   :group 'geiser-guile)
  55
  56 (geiser-custom--defcustom geiser-guile-load-init-file-p nil
  57   "Whether to load ~/.guile when starting Guile.
  58 Note that, due to peculiarities in the way Guile loads its init
  59 file, using `geiser-guile-init-file' is not equivalent to setting
  60 this variable to t."
  61   :type 'boolean
  62   :group 'geiser-guile)
  63
  64 (geiser-custom--defcustom geiser-guile-debug-show-bt-p nil
  65   "Whether to autmatically show a full backtrace when entering the debugger.
  66 If `nil', only the last frame is shown."
  67   :type 'boolean
  68   :group 'geiser-guile)
  69
  70 (geiser-custom--defcustom geiser-guile-jump-on-debug-p nil
  71   "Whether to autmatically jump to error when entering the debugger.
  72 If `t', Geiser will use `next-error' to jump to the error's location."
  73   :type 'boolean
  74   :group 'geiser-guile)
  75
  76 (geiser-custom--defcustom geiser-guile-show-debug-help-p t
  77   "Whether to show brief help in the echo area when entering the debugger."
  78   :type 'boolean
  79   :group 'geiser-guile)
  80
  81 (geiser-custom--defcustom geiser-guile-warning-level 'medium
  82   "Verbosity of the warnings reported by Guile.
  83
  84 You can either choose one of the predefined warning sets, or
  85 provide a list of symbols identifying the ones you want. Possible
  86 choices are arity-mismatch, unbound-variable, unused-variable and
  87 unused-toplevel. Unrecognised symbols are ignored.
  88
  89 The predefined levels are:
  90
  91   - Medium: arity-mismatch, unbound-variable, format
  92   - High: arity-mismatch, unbound-variable, unused-variable, format
  93   - None: no warnings
  94
  95 Changes to the value of this variable will automatically take
  96 effect on new REPLs. For existing ones, use the command
  97 \\[geiser-guile-update-warning-level]."
  98   :type '(choice (const :tag "Medium (arity and unbound vars)" medium)
  99                  (const :tag "High (also unused vars)" high)
 100                  (const :tag "No warnings" none)
 101                  (repeat :tag "Custom" symbol))
 102   :group 'geiser-guile)
 103
 104 (geiser-custom--defcustom geiser-guile-extra-keywords nil
 105   "Extra keywords highlighted in Guile scheme buffers."
 106   :type '(repeat string)
 107   :group 'geiser-guile)
 108
 109 (geiser-custom--defcustom geiser-guile-case-sensitive-p t
 110   "Non-nil means keyword highlighting is case-sensitive."
 111   :type 'boolean
 112   :group 'geiser-guile)
 113
 114 (geiser-custom--defcustom geiser-guile-manual-lookup-other-window-p nil
 115   "Non-nil means pop up the Info buffer in another window."
 116   :type 'boolean
 117   :group 'geiser-guile)
 118
 119 (geiser-custom--defcustom geiser-guile-manual-lookup-nodes
 120                           '("Guile" "guile-2.0")
 121   "List of info nodes that, when present, are used for manual lookups"
 122   :type '(repeat string)
 123   :group 'geiser-guile)
 124
 125 \f
 126 ;;; REPL support:
 127
 128 (defun geiser-guile--binary ()
 129   (if (listp geiser-guile-binary)
 130       (car geiser-guile-binary)
 131     geiser-guile-binary))
 132
 133 (defun geiser-guile--parameters ()
 134   "Return a list with all parameters needed to start Guile.
 135 This function uses `geiser-guile-init-file' if it exists."
 136   (let ((init-file (and (stringp geiser-guile-init-file)
 137                         (expand-file-name geiser-guile-init-file)))
 138         (q-flags (and (not geiser-guile-load-init-file-p) '("-q"))))
 139   `(,@(and (listp geiser-guile-binary) (cdr geiser-guile-binary))
 140     ,@q-flags "-L" ,(expand-file-name "guile/" geiser-scheme-dir)
 141     ,@(apply 'append (mapcar (lambda (p) (list "-L" p))
 142                              geiser-guile-load-path))
 143     ,@(and init-file (file-readable-p init-file) (list "-l" init-file)))))
 144
 145 ;;(defconst geiser-guile--prompt-regexp "^[^() \n]+@([^)]*?)> ")
 146 (defconst geiser-guile--prompt-regexp "[^@()]+@([^)]*?)> ")
 147 (defconst geiser-guile--debugger-prompt-regexp
 148   "[^@()]+@([^)]*?) \\[[0-9]+\\]> ")
 149
 150 \f
 151 ;;; Evaluation support:
 152 (defsubst geiser-guile--linearize-args (args)
 153   (mapconcat 'identity args " "))
 154
 155 (defun geiser-guile--geiser-procedure (proc &rest args)
 156   (case proc
 157     ((eval compile) (format ",geiser-eval %s %s%s"
 158                             (or (car args) "#f")
 159                             (geiser-guile--linearize-args (cdr args))
 160                             (if (cddr args) "" " ()")))
 161     ((load-file compile-file) (format ",geiser-load-file %s" (car args)))
 162     ((no-values) ",geiser-no-values")
 163     (t (format "ge:%s (%s)" proc (geiser-guile--linearize-args args)))))
 164
 165 (defconst geiser-guile--module-re
 166   "(define-module +\\(([^)]+)\\)")
 167
 168 (defconst geiser-guile--library-re
 169   "(library +\\(([^)]+)\\)")
 170
 171 (defun geiser-guile--get-module (&optional module)
 172   (cond ((null module)
 173          (save-excursion
 174            (ignore-errors
 175              (while (not (zerop (geiser-syntax--nesting-level)))
 176                (backward-up-list)))
 177            (if (or (re-search-backward geiser-guile--module-re nil t)
 178                    (looking-at geiser-guile--library-re)
 179                    (re-search-forward geiser-guile--module-re nil t))
 180                (geiser-guile--get-module (match-string-no-properties 1))
 181              :f)))
 182         ((listp module) module)
 183         ((stringp module)
 184          (condition-case nil
 185              (car (geiser-syntax--read-from-string module))
 186            (error :f)))
 187         (t :f)))
 188
 189 (defun geiser-guile--module-cmd (module fmt &optional def)
 190   (when module
 191     (let* ((module (geiser-guile--get-module module))
 192            (module (cond ((or (null module) (eq module :f)) def)
 193                          (t (format "%s" module)))))
 194       (and module (format fmt module)))))
 195
 196 (defun geiser-guile--import-command (module)
 197   (geiser-guile--module-cmd module ",use %s"))
 198
 199 (defun geiser-guile--enter-command (module)
 200   (geiser-guile--module-cmd module ",m %s" "(guile-user)"))
 201
 202
 203 (defun geiser-guile--exit-command () ",q")
 204
 205 (defun geiser-guile--symbol-begin (module)
 206   (if module
 207       (max (save-excursion (beginning-of-line) (point))
 208            (save-excursion (skip-syntax-backward "^(>") (1- (point))))
 209     (save-excursion (skip-syntax-backward "^-()>") (point))))
 210
 211 \f
 212 ;;; Error display
 213
 214 (defun geiser-guile--enter-debugger ()
 215   (let ((bt-cmd (format ",geiser-newline\n,error-message\n,%s\n"
 216                         (if geiser-guile-debug-show-bt-p "bt" "fr"))))
 217     (compilation-forget-errors)
 218     (goto-char (point-max))
 219     (geiser-repl--prepare-send)
 220     (comint-send-string nil bt-cmd)
 221     (when geiser-guile-show-debug-help-p
 222       (message "Debug REPL. Enter ,q to quit, ,h for help."))
 223     (when geiser-guile-jump-on-debug-p
 224       (accept-process-output (get-buffer-process (current-buffer))
 225                              0.2 nil t)
 226       (ignore-errors (next-error)))))
 227
 228 (defun geiser-guile--display-error (module key msg)
 229   (newline)
 230   (when (stringp msg)
 231     (save-excursion (insert msg))
 232     (geiser-edit--buttonize-files))
 233   (and (not key) msg (not (zerop (length msg)))))
 234
 235 \f
 236 ;;; Trying to ascertain whether a buffer is Guile Scheme:
 237
 238 (defconst geiser-guile--guess-re
 239   (format "\\(%s\\|#! *.+\\(/\\| \\)guile\\( *\\\\\\)?\\)"
 240           geiser-guile--module-re))
 241
 242 (defun geiser-guile--guess ()
 243   (save-excursion
 244     (goto-char (point-min))
 245     (re-search-forward geiser-guile--guess-re nil t)))
 246
 247 \f
 248 ;;; Keywords and syntax
 249
 250 (defun geiser-guile--keywords ()
 251   (when geiser-guile-extra-keywords
 252     `((,(format "[[(]%s\\>" (regexp-opt geiser-guile-extra-keywords 1))
 253        . 1))))
 254
 255 (geiser-syntax--scheme-indent
 256  (c-declare 0)
 257  (c-lambda 2)
 258  (lambda* 1)
 259  (pmatch defun)
 260  (sigaction 1)
 261  (with-fluid* 1)
 262  (with-fluids 1)
 263  (with-fluids* 1)
 264  (with-method 1))
 265
 266
 267 \f
 268 ;;; Compilation shell regexps
 269
 270 (defconst geiser-guile--path-rx "^In \\([^:\n ]+\\):\n")
 271
 272 (defconst geiser-guile--rel-path-rx "^In +\\([^/\n :]+\\):\n")
 273
 274 (defvar geiser-guile--file-cache (make-hash-table :test 'equal))
 275
 276 (defun geiser-guile--resolve-file (file)
 277   (when (and (stringp file)
 278              (not (member file '("socket" "stdin" "unknown file"))))
 279     (if (file-name-absolute-p file) file
 280       (or (gethash file geiser-guile--file-cache)
 281           (puthash file
 282                    (geiser-eval--send/result `(:eval (:ge find-file ,file)))
 283                    geiser-guile--file-cache)))))
 284
 285 (defun geiser-guile--resolve-file-x ()
 286   (let ((f (geiser-guile--resolve-file (match-string-no-properties 1))))
 287     (and (stringp f) (list f))))
 288
 289 \f
 290 ;;; REPL startup
 291
 292 (defun geiser-guile-update-warning-level ()
 293   "Update the warning level used by the REPL.
 294 The new level is set using the value of `geiser-guile-warning-level'."
 295   (interactive)
 296   (let ((code `(:eval (:ge set-warnings ',geiser-guile-warning-level)
 297                       (geiser evaluation))))
 298     (geiser-eval--send/result code)))
 299
 300 (defun connect-to-guile ()
 301   "Start a Guile REPL connected to a remote process.
 302
 303 Start the external Guile process with the flag --listen to make
 304 it spawn a server thread."
 305   (interactive)
 306   (geiser-connect 'guile))
 307
 308 (defun geiser-guile--set-geiser-load-path ()
 309   (let* ((path (expand-file-name "guile/" geiser-scheme-dir))
 310          (witness "geiser/emacs.scm")
 311          (code `(begin (if (not (%search-load-path ,witness))
 312                            (set! %load-path (cons ,path %load-path)))
 313                        'done)))
 314     (geiser-eval--send/wait code)))
 315
 316 (defun geiser-guile--startup (remote)
 317   (set (make-local-variable 'compilation-error-regexp-alist)
 318        `((,geiser-guile--path-rx geiser-guile--resolve-file-x)
 319          ("^  +\\([0-9]+\\):\\([0-9]+\\)" nil 1 2)))
 320   (compilation-setup t)
 321   (font-lock-add-keywords nil `((,geiser-guile--path-rx
 322                                  1 compilation-error-face)))
 323   (let ((geiser-log-verbose-p t))
 324     (when remote (geiser-guile--set-geiser-load-path))
 325     (geiser-eval--send/wait ",use (geiser emacs)\n'done")
 326     (mapcar (lambda (dir)
 327               (let ((dir (expand-file-name dir)))
 328                 (geiser-eval--send/wait `(:eval (:ge add-to-load-path ,dir)))))
 329             geiser-guile-load-path)
 330     (geiser-guile-update-warning-level)))
 331
 332 \f
 333 ;;; Manual lookup
 334
 335 (defun geiser-guile--info-spec (&optional nodes)
 336   (let* ((nrx "^[       ]+-+ [^:]+:[    ]*")
 337          (drx "\\b")
 338          (res (when (Info-find-file "r5rs" t)
 339                 `(("(r5rs)Index" nil ,nrx ,drx)))))
 340     (dolist (node (or nodes geiser-guile-manual-lookup-nodes) res)
 341       (when (Info-find-file node t)
 342         (mapc (lambda (idx)
 343                 (add-to-list 'res
 344                              (list (format "(%s)%s" node idx) nil nrx drx)))
 345               '("Variable Index" "Procedure Index" "R5RS Index"))))))
 346
 347
 348 (info-lookup-add-help :topic 'symbol :mode 'geiser-guile-mode
 349                       :ignore-case nil
 350                       :regexp "[^()`',\"        \n]+"
 351                       :doc-spec (geiser-guile--info-spec))
 352
 353 (defun guile--manual-look-up (id mod)
 354   (let ((info-lookup-other-window-flag
 355          geiser-guile-manual-lookup-other-window-p))
 356     (info-lookup-symbol id 'geiser-guile-mode))
 357   (when geiser-guile-manual-lookup-other-window-p
 358     (switch-to-buffer-other-window "*info*"))
 359   (search-forward (format "%s" id) nil t))
 360
 361
 362 \f
 363 ;;; Implementation definition:
 364
 365 (define-geiser-implementation guile
 366   (binary geiser-guile--binary)
 367   (arglist geiser-guile--parameters)
 368   (repl-startup geiser-guile--startup)
 369   (prompt-regexp geiser-guile--prompt-regexp)
 370   (debugger-prompt-regexp geiser-guile--debugger-prompt-regexp)
 371   (enter-debugger geiser-guile--enter-debugger)
 372   (marshall-procedure geiser-guile--geiser-procedure)
 373   (find-module geiser-guile--get-module)
 374   (enter-command geiser-guile--enter-command)
 375   (exit-command geiser-guile--exit-command)
 376   (import-command geiser-guile--import-command)
 377   (find-symbol-begin geiser-guile--symbol-begin)
 378   (display-error geiser-guile--display-error)
 379   (external-help guile--manual-look-up)
 380   (check-buffer geiser-guile--guess)
 381   (keywords geiser-guile--keywords)
 382   (case-sensitive geiser-guile-case-sensitive-p))
 383
 384 (geiser-impl--add-to-alist 'regexp "\\.scm$" 'guile t)
 385
 386 \f
 387 (provide 'geiser-guile)