dired: Revert buffer when DIRNAME is a cons
[emacs.git] / lisp / xml.el
blob88dc70bc413661ac9cb741cedd8afbe097a59861
1 ;;; xml.el --- XML parser -*- lexical-binding: t -*-
3 ;; Copyright (C) 2000-2017 Free Software Foundation, Inc.
5 ;; Author: Emmanuel Briot <briot@gnat.com>
6 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
7 ;; Keywords: xml, data
9 ;; This file is part of GNU Emacs.
11 ;; GNU Emacs is free software: you can redistribute it and/or modify
12 ;; it under the terms of the GNU General Public License as published by
13 ;; the Free Software Foundation, either version 3 of the License, or
14 ;; (at your option) any later version.
16 ;; GNU Emacs is distributed in the hope that it will be useful,
17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 ;; GNU General Public License for more details.
21 ;; You should have received a copy of the GNU General Public License
22 ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
24 ;;; Commentary:
26 ;; This file contains a somewhat incomplete non-validating XML parser. It
27 ;; parses a file, and returns a list that can be used internally by
28 ;; any other Lisp libraries.
30 ;;; FILE FORMAT
32 ;; The document type declaration may either be ignored or (optionally)
33 ;; parsed, but currently the parsing will only accept element
34 ;; declarations. The XML file is assumed to be well-formed. In case
35 ;; of error, the parsing stops and the XML file is shown where the
36 ;; parsing stopped.
38 ;; It also knows how to ignore comments and processing instructions.
40 ;; The XML file should have the following format:
41 ;; <node1 attr1="name1" attr2="name2" ...>value
42 ;; <node2 attr3="name3" attr4="name4">value2</node2>
43 ;; <node3 attr5="name5" attr6="name6">value3</node3>
44 ;; </node1>
45 ;; Of course, the name of the nodes and attributes can be anything. There can
46 ;; be any number of attributes (or none), as well as any number of children
47 ;; below the nodes.
49 ;; There can be only top level node, but with any number of children below.
51 ;;; LIST FORMAT
53 ;; The functions `xml-parse-file', `xml-parse-region' and
54 ;; `xml-parse-tag' return a list with the following format:
56 ;; xml-list ::= (node node ...)
57 ;; node ::= (qname attribute-list . child_node_list)
58 ;; child_node_list ::= child_node child_node ...
59 ;; child_node ::= node | string
60 ;; qname ::= (:namespace-uri . "name") | "name"
61 ;; attribute_list ::= ((qname . "value") (qname . "value") ...)
62 ;; | nil
63 ;; string ::= "..."
65 ;; Some macros are provided to ease the parsing of this list.
66 ;; Whitespace is preserved. Fixme: There should be a tree-walker that
67 ;; can remove it.
69 ;; TODO:
70 ;; * xml:base, xml:space support
71 ;; * more complete DOCTYPE parsing
72 ;; * pi support
74 ;;; Code:
76 ;; Note that buffer-substring and match-string were formerly used in
77 ;; several places, because the -no-properties variants remove
78 ;; composition info. However, after some discussion on emacs-devel,
79 ;; the consensus was that the speed of the -no-properties variants was
80 ;; a worthwhile tradeoff especially since we're usually parsing files
81 ;; instead of hand-crafted XML.
83 ;;; Macros to parse the list
85 (defconst xml-undefined-entity "?"
86 "What to substitute for undefined entities")
88 (defconst xml-default-ns '(("" . "")
89 ("xml" . "http://www.w3.org/XML/1998/namespace")
90 ("xmlns" . "http://www.w3.org/2000/xmlns/"))
91 "Alist mapping default XML namespaces to their URIs.")
93 (defvar xml-entity-alist
94 '(("lt" . "&#60;")
95 ("gt" . ">")
96 ("apos" . "'")
97 ("quot" . "\"")
98 ("amp" . "&#38;"))
99 "Alist mapping XML entities to their replacement text.")
101 (defvar xml-entity-expansion-limit 20000
102 "The maximum size of entity reference expansions.
103 If the size of the buffer increases by this many characters while
104 expanding entity references in a segment of character data, the
105 XML parser signals an error. Setting this to nil removes the
106 limit (making the parser vulnerable to XML bombs).")
108 (defvar xml-parameter-entity-alist nil
109 "Alist of defined XML parametric entities.")
111 (defvar xml-sub-parser nil
112 "Non-nil when the XML parser is parsing an XML fragment.")
114 (defvar xml-validating-parser nil
115 "Set to non-nil to get validity checking.")
117 (defsubst xml-node-name (node)
118 "Return the tag associated with NODE.
119 Without namespace-aware parsing, the tag is a symbol.
121 With namespace-aware parsing, the tag is a cons of a string
122 representing the uri of the namespace with the local name of the
123 tag. For example,
125 <foo>
127 would be represented by
129 (\"\" . \"foo\").
131 If you'd just like a plain symbol instead, use `symbol-qnames' in
132 the PARSE-NS argument."
134 (car node))
136 (defsubst xml-node-attributes (node)
137 "Return the list of attributes of NODE.
138 The list can be nil."
139 (nth 1 node))
141 (defsubst xml-node-children (node)
142 "Return the list of children of NODE.
143 This is a list of nodes, and it can be nil."
144 (cddr node))
146 (defun xml-get-children (node child-name)
147 "Return the children of NODE whose tag is CHILD-NAME.
148 CHILD-NAME should match the value returned by `xml-node-name'."
149 (let ((match ()))
150 (dolist (child (xml-node-children node))
151 (if (and (listp child)
152 (equal (xml-node-name child) child-name))
153 (push child match)))
154 (nreverse match)))
156 (defun xml-get-attribute-or-nil (node attribute)
157 "Get from NODE the value of ATTRIBUTE.
158 Return nil if the attribute was not found.
160 See also `xml-get-attribute'."
161 (cdr (assoc attribute (xml-node-attributes node))))
163 (defsubst xml-get-attribute (node attribute)
164 "Get from NODE the value of ATTRIBUTE.
165 An empty string is returned if the attribute was not found.
167 See also `xml-get-attribute-or-nil'."
168 (or (xml-get-attribute-or-nil node attribute) ""))
170 ;;; Regular expressions for XML components
172 ;; The following regexps are used as subexpressions in regexps that
173 ;; are `eval-when-compile'd for efficiency, so they must be defined at
174 ;; compile time.
175 (eval-and-compile
177 ;; [4] NameStartChar
178 ;; See the definition of word syntax in `xml-syntax-table'.
179 (defconst xml-name-start-char-re (concat "[[:word:]:_]"))
181 ;; [4a] NameChar ::= NameStartChar | "-" | "." | [0-9] | #xB7
182 ;; | [#x0300-#x036F] | [#x203F-#x2040]
183 (defconst xml-name-char-re (concat "[-0-9.[:word:]:_·̀-ͯ‿-⁀]"))
185 ;; [5] Name ::= NameStartChar (NameChar)*
186 (defconst xml-name-re (concat xml-name-start-char-re xml-name-char-re "*"))
188 ;; [6] Names ::= Name (#x20 Name)*
189 (defconst xml-names-re (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
191 ;; [7] Nmtoken ::= (NameChar)+
192 (defconst xml-nmtoken-re (concat xml-name-char-re "+"))
194 ;; [8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
195 (defconst xml-nmtokens-re (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
197 ;; [66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
198 (defconst xml-char-ref-re "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
200 ;; [68] EntityRef ::= '&' Name ';'
201 (defconst xml-entity-ref (concat "&" xml-name-re ";"))
203 (defconst xml-entity-or-char-ref-re (concat "&\\(?:#\\(x\\)?\\([0-9a-fA-F]+\\)\\|\\("
204 xml-name-re "\\)\\);"))
206 ;; [69] PEReference ::= '%' Name ';'
207 (defconst xml-pe-reference-re (concat "%\\(" xml-name-re "\\);"))
209 ;; [67] Reference ::= EntityRef | CharRef
210 (defconst xml-reference-re (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
212 ;; [10] AttValue ::= '"' ([^<&"] | Reference)* '"'
213 ;; | "'" ([^<&'] | Reference)* "'"
214 (defconst xml-att-value-re (concat "\\(?:\"\\(?:[^&\"]\\|"
215 xml-reference-re "\\)*\"\\|"
216 "'\\(?:[^&']\\|" xml-reference-re
217 "\\)*'\\)"))
219 ;; [56] TokenizedType ::= 'ID'
220 ;; [VC: ID] [VC: One ID / Element Type] [VC: ID Attribute Default]
221 ;; | 'IDREF' [VC: IDREF]
222 ;; | 'IDREFS' [VC: IDREF]
223 ;; | 'ENTITY' [VC: Entity Name]
224 ;; | 'ENTITIES' [VC: Entity Name]
225 ;; | 'NMTOKEN' [VC: Name Token]
226 ;; | 'NMTOKENS' [VC: Name Token]
227 (defconst xml-tokenized-type-re (concat "\\(?:ID\\|IDREF\\|IDREFS\\|ENTITY\\|"
228 "ENTITIES\\|NMTOKEN\\|NMTOKENS\\)"))
230 ;; [58] NotationType ::= 'NOTATION' S '(' S? Name (S? '|' S? Name)* S? ')'
231 (defconst xml-notation-type-re
232 (concat "\\(?:NOTATION\\s-+(\\s-*" xml-name-re
233 "\\(?:\\s-*|\\s-*" xml-name-re "\\)*\\s-*)\\)"))
235 ;; [59] Enumeration ::= '(' S? Nmtoken (S? '|' S? Nmtoken)* S? ')'
236 ;; [VC: Enumeration] [VC: No Duplicate Tokens]
237 (defconst xml-enumeration-re (concat "\\(?:(\\s-*" xml-nmtoken-re
238 "\\(?:\\s-*|\\s-*" xml-nmtoken-re
239 "\\)*\\s-+)\\)"))
241 ;; [57] EnumeratedType ::= NotationType | Enumeration
242 (defconst xml-enumerated-type-re (concat "\\(?:" xml-notation-type-re
243 "\\|" xml-enumeration-re "\\)"))
245 ;; [54] AttType ::= StringType | TokenizedType | EnumeratedType
246 ;; [55] StringType ::= 'CDATA'
247 (defconst xml-att-type-re (concat "\\(?:CDATA\\|" xml-tokenized-type-re
248 "\\|" xml-notation-type-re
249 "\\|" xml-enumerated-type-re "\\)"))
251 ;; [60] DefaultDecl ::= '#REQUIRED' | '#IMPLIED' | (('#FIXED' S)? AttValue)
252 (defconst xml-default-decl-re (concat "\\(?:#REQUIRED\\|#IMPLIED\\|"
253 "\\(?:#FIXED\\s-+\\)*"
254 xml-att-value-re "\\)"))
256 ;; [53] AttDef ::= S Name S AttType S DefaultDecl
257 (defconst xml-att-def-re (concat "\\(?:\\s-*" xml-name-re
258 "\\s-*" xml-att-type-re
259 "\\s-*" xml-default-decl-re "\\)"))
261 ;; [9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
262 ;; | "'" ([^%&'] | PEReference | Reference)* "'"
263 (defconst xml-entity-value-re (concat "\\(?:\"\\(?:[^%&\"]\\|"
264 xml-pe-reference-re
265 "\\|" xml-reference-re
266 "\\)*\"\\|'\\(?:[^%&']\\|"
267 xml-pe-reference-re "\\|"
268 xml-reference-re "\\)*'\\)"))
269 ) ; End of `eval-when-compile'
272 ;; [75] ExternalID ::= 'SYSTEM' S SystemLiteral
273 ;; | 'PUBLIC' S PubidLiteral S SystemLiteral
274 ;; [76] NDataDecl ::= S 'NDATA' S
275 ;; [73] EntityDef ::= EntityValue| (ExternalID NDataDecl?)
276 ;; [71] GEDecl ::= '<!ENTITY' S Name S EntityDef S? '>'
277 ;; [74] PEDef ::= EntityValue | ExternalID
278 ;; [72] PEDecl ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
279 ;; [70] EntityDecl ::= GEDecl | PEDecl
281 ;; Note that this is setup so that we can do whitespace-skipping with
282 ;; `(skip-syntax-forward " ")', inter alia. Previously this was slow
283 ;; compared with `re-search-forward', but that has been fixed.
285 (defvar xml-syntax-table
286 ;; By default, characters have symbol syntax.
287 (let ((table (make-char-table 'syntax-table '(3))))
288 ;; The XML space chars [3], and nothing else, have space syntax.
289 (dolist (c '(?\s ?\t ?\r ?\n))
290 (modify-syntax-entry c " " table))
291 ;; The characters in NameStartChar [4], aside from ':' and '_',
292 ;; have word syntax. This is used by `xml-name-start-char-re'.
293 (modify-syntax-entry '(?A . ?Z) "w" table)
294 (modify-syntax-entry '(?a . ?z) "w" table)
295 (modify-syntax-entry '(#xC0 . #xD6) "w" table)
296 (modify-syntax-entry '(#xD8 . #XF6) "w" table)
297 (modify-syntax-entry '(#xF8 . #X2FF) "w" table)
298 (modify-syntax-entry '(#x370 . #X37D) "w" table)
299 (modify-syntax-entry '(#x37F . #x1FFF) "w" table)
300 (modify-syntax-entry '(#x200C . #x200D) "w" table)
301 (modify-syntax-entry '(#x2070 . #x218F) "w" table)
302 (modify-syntax-entry '(#x2C00 . #x2FEF) "w" table)
303 (modify-syntax-entry '(#x3001 . #xD7FF) "w" table)
304 (modify-syntax-entry '(#xF900 . #xFDCF) "w" table)
305 (modify-syntax-entry '(#xFDF0 . #xFFFD) "w" table)
306 (modify-syntax-entry '(#x10000 . #xEFFFF) "w" table)
307 table)
308 "Syntax table used by the XML parser.
309 In this syntax table, the XML space characters [ \\t\\r\\n], and
310 only those characters, have whitespace syntax.")
312 ;;; Entry points:
314 ;;;###autoload
315 (defun xml-parse-file (file &optional parse-dtd parse-ns)
316 "Parse the well-formed XML file FILE.
317 Return the top node with all its children.
318 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
320 If PARSE-NS is non-nil, then QNAMES are expanded. By default,
321 the variable `xml-default-ns' is the mapping from namespaces to
322 URIs, and expanded names will be returned as a cons
324 (\"namespace:\" . \"foo\").
326 If PARSE-NS is an alist, it will be used as the mapping from
327 namespace to URIs instead.
329 If it is the symbol `symbol-qnames', expanded names will be
330 returned as a plain symbol `namespace:foo' instead of a cons.
332 Both features can be combined by providing a cons cell
334 (symbol-qnames . ALIST)."
335 (with-temp-buffer
336 (insert-file-contents file)
337 (xml--parse-buffer parse-dtd parse-ns)))
339 ;;;###autoload
340 (defun xml-parse-region (&optional beg end buffer parse-dtd parse-ns)
341 "Parse the region from BEG to END in BUFFER.
342 Return the XML parse tree, or raise an error if the region does
343 not contain well-formed XML.
345 If BEG is nil, it defaults to `point-min'.
346 If END is nil, it defaults to `point-max'.
347 If BUFFER is nil, it defaults to the current buffer.
348 If PARSE-DTD is non-nil, parse the DTD and return it as the first
349 element of the list.
350 If PARSE-NS is non-nil, then QNAMES are expanded. By default,
351 the variable `xml-default-ns' is the mapping from namespaces to
352 URIs, and expanded names will be returned as a cons
354 (\"namespace:\" . \"foo\").
356 If PARSE-NS is an alist, it will be used as the mapping from
357 namespace to URIs instead.
359 If it is the symbol `symbol-qnames', expanded names will be
360 returned as a plain symbol `namespace:foo' instead of a cons.
362 Both features can be combined by providing a cons cell
364 (symbol-qnames . ALIST)."
365 ;; Use fixed syntax table to ensure regexp char classes and syntax
366 ;; specs DTRT.
367 (unless buffer
368 (setq buffer (current-buffer)))
369 (with-temp-buffer
370 (insert-buffer-substring-no-properties buffer beg end)
371 (xml--parse-buffer parse-dtd parse-ns)))
373 ;; XML [5]
375 ;; Fixme: This needs re-writing to deal with the XML grammar properly, i.e.
376 ;; document ::= prolog element Misc*
377 ;; prolog ::= XMLDecl? Misc* (doctypedecl Misc*)?
379 (defun xml--parse-buffer (parse-dtd parse-ns)
380 (with-syntax-table xml-syntax-table
381 (let ((case-fold-search nil) ; XML is case-sensitive.
382 ;; Prevent entity definitions from changing the defaults
383 (xml-entity-alist xml-entity-alist)
384 (xml-parameter-entity-alist xml-parameter-entity-alist)
385 xml result dtd)
386 (goto-char (point-min))
387 (while (not (eobp))
388 (if (search-forward "<" nil t)
389 (progn
390 (forward-char -1)
391 (setq result (xml-parse-tag-1 parse-dtd parse-ns))
392 (cond
393 ((null result)
394 ;; Not looking at an xml start tag.
395 (unless (eobp)
396 (forward-char 1)))
397 ((and xml (not xml-sub-parser))
398 ;; Translation of rule [1] of XML specifications
399 (error "XML: (Not Well-Formed) Only one root tag allowed"))
400 ((and (listp (car result))
401 parse-dtd)
402 (setq dtd (car result))
403 (if (cdr result) ; possible leading comment
404 (push (cdr result) xml)))
406 (push result xml))))
407 (goto-char (point-max))))
408 (if parse-dtd
409 (cons dtd (nreverse xml))
410 (nreverse xml)))))
412 (defun xml-maybe-do-ns (name default xml-ns)
413 "Perform any namespace expansion.
414 NAME is the name to perform the expansion on.
415 DEFAULT is the default namespace. XML-NS is a cons of namespace
416 names to uris. When namespace-aware parsing is off, then XML-NS
417 is nil.
419 During namespace-aware parsing, any name without a namespace is
420 put into the namespace identified by DEFAULT. nil is used to
421 specify that the name shouldn't be given a namespace.
422 Expanded names will by default be returned as a cons. If you
423 would like to get plain symbols instead, provide a cons cell
425 (symbol-qnames . ALIST)
427 in the XML-NS argument."
428 (if (consp xml-ns)
429 (let* ((symbol-qnames (eq (car-safe xml-ns) 'symbol-qnames))
430 (nsp (string-match ":" name))
431 (lname (if nsp (substring name (match-end 0)) name))
432 (prefix (if nsp (substring name 0 (match-beginning 0)) default))
433 (special (and (string-equal lname "xmlns") (not prefix)))
434 ;; Setting default to nil will insure that there is not
435 ;; matching cons in xml-ns. In which case we
436 (ns (or (cdr (assoc (if special "xmlns" prefix)
437 (if symbol-qnames (cdr xml-ns) xml-ns)))
438 "")))
439 (if (and symbol-qnames
440 (not special)
441 (not (string= prefix "xmlns")))
442 (intern (concat ns lname))
443 (cons ns (if special "" lname))))
444 (intern name)))
446 (defun xml-parse-tag (&optional parse-dtd parse-ns)
447 "Parse the tag at point.
448 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
449 returned as the first element in the list.
450 If PARSE-NS is non-nil, expand QNAMES; for further details, see
451 `xml-parse-region'.
453 Return one of:
454 - a list : the matching node
455 - nil : the point is not looking at a tag.
456 - a pair : the first element is the DTD, the second is the node."
457 (let* ((case-fold-search nil)
458 ;; Prevent entity definitions from changing the defaults
459 (xml-entity-alist xml-entity-alist)
460 (xml-parameter-entity-alist xml-parameter-entity-alist)
461 (buf (current-buffer))
462 (pos (point)))
463 (with-temp-buffer
464 (with-syntax-table xml-syntax-table
465 (insert-buffer-substring-no-properties buf pos)
466 (goto-char (point-min))
467 (xml-parse-tag-1 parse-dtd parse-ns)))))
469 (defun xml-parse-tag-1 (&optional parse-dtd parse-ns)
470 "Like `xml-parse-tag', but possibly modify the buffer while working."
471 (let* ((xml-validating-parser (or parse-dtd xml-validating-parser))
472 (xml-ns
473 (cond ((eq parse-ns 'symbol-qnames)
474 (cons 'symbol-qnames xml-default-ns))
475 ((or (consp (car-safe parse-ns))
476 (and (eq (car-safe parse-ns) 'symbol-qnames)
477 (listp (cdr parse-ns))))
478 parse-ns)
479 (parse-ns
480 xml-default-ns))))
481 (cond
482 ;; Processing instructions, like <?xml version="1.0"?>.
483 ((looking-at-p "<\\?")
484 (search-forward "?>")
485 (skip-syntax-forward " ")
486 (xml-parse-tag-1 parse-dtd xml-ns))
487 ;; Character data (CDATA) sections, in which no tag should be interpreted
488 ((looking-at "<!\\[CDATA\\[")
489 (let ((pos (match-end 0)))
490 (unless (search-forward "]]>" nil t)
491 (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
492 (concat
493 (buffer-substring-no-properties pos (match-beginning 0))
494 (xml-parse-string))))
495 ;; DTD for the document
496 ((looking-at-p "<!DOCTYPE[ \t\n\r]")
497 (let ((dtd (xml-parse-dtd parse-ns)))
498 (skip-syntax-forward " ")
499 (if xml-validating-parser
500 (cons dtd (xml-parse-tag-1 nil xml-ns))
501 (xml-parse-tag-1 nil xml-ns))))
502 ;; skip comments
503 ((looking-at-p "<!--")
504 (search-forward "-->")
505 ;; FIXME: This loses the skipped-over spaces.
506 (skip-syntax-forward " ")
507 (unless (eobp)
508 (let ((xml-sub-parser t))
509 (xml-parse-tag-1 parse-dtd xml-ns))))
510 ;; end tag
511 ((looking-at-p "</")
512 '())
513 ;; opening tag
514 ((looking-at (eval-when-compile (concat "<\\(" xml-name-re "\\)")))
515 (goto-char (match-end 1))
516 ;; Parse this node
517 (let* ((node-name (match-string-no-properties 1))
518 ;; Parse the attribute list.
519 (attrs (xml-parse-attlist xml-ns))
520 children)
521 ;; add the xmlns:* attrs to our cache
522 (when (consp xml-ns)
523 (dolist (attr attrs)
524 (when (and (consp (car attr))
525 (equal "http://www.w3.org/2000/xmlns/"
526 (caar attr)))
527 (push (cons (cdar attr) (cdr attr))
528 (if (symbolp (car xml-ns))
529 (cdr xml-ns)
530 xml-ns)))))
531 (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
532 (cond
533 ;; is this an empty element ?
534 ((looking-at-p "/>")
535 (forward-char 2)
536 (nreverse children))
537 ;; is this a valid start tag ?
538 ((eq (char-after) ?>)
539 (forward-char 1)
540 ;; Now check that we have the right end-tag.
541 (let ((end (concat "</" node-name "\\s-*>")))
542 (while (not (looking-at end))
543 (cond
544 ((eobp)
545 (error "XML: (Not Well-Formed) End of document while reading element `%s'"
546 node-name))
547 ((looking-at-p "</")
548 (forward-char 2)
549 (error "XML: (Not Well-Formed) Invalid end tag `%s' (expecting `%s')"
550 (let ((pos (point)))
551 (buffer-substring pos (if (re-search-forward "\\s-*>" nil t)
552 (match-beginning 0)
553 (point-max))))
554 node-name))
555 ;; Read a sub-element and push it onto CHILDREN.
556 ((= (char-after) ?<)
557 (let ((tag (xml-parse-tag-1 nil xml-ns)))
558 (when tag
559 (push tag children))))
560 ;; Read some character data.
562 (let ((expansion (xml-parse-string)))
563 (push (if (stringp (car children))
564 ;; If two strings were separated by a
565 ;; comment, concat them.
566 (concat (pop children) expansion)
567 expansion)
568 children)))))
569 ;; Move point past the end-tag.
570 (goto-char (match-end 0))
571 (nreverse children)))
572 ;; Otherwise this was an invalid start tag (expected ">" not found.)
574 (error "XML: (Well-Formed) Couldn't parse tag: %s"
575 (buffer-substring-no-properties (- (point) 10) (+ (point) 1)))))))
577 ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
579 (unless xml-sub-parser ; Usually, we error out.
580 (error "XML: (Well-Formed) Invalid character"))
581 ;; However, if we're parsing incrementally, then we need to deal
582 ;; with stray CDATA.
583 (let ((s (xml-parse-string)))
584 (when (zerop (length s))
585 ;; We haven't consumed any input! We must throw an error in
586 ;; order to prevent looping forever.
587 (error "XML: (Not Well-Formed) Could not parse: %s"
588 (buffer-substring-no-properties
589 (point) (min (+ (point) 10) (point-max)))))
590 s)))))
592 (defun xml-parse-string ()
593 "Parse character data at point, and return it as a string.
594 Leave point at the start of the next thing to parse. This
595 function can modify the buffer by expanding entity and character
596 references."
597 (let ((start (point))
598 ;; Keep track of the size of the rest of the buffer:
599 (old-remaining-size (- (buffer-size) (point)))
600 ref val)
601 (while (and (not (eobp))
602 (not (looking-at-p "<")))
603 ;; Find the next < or & character.
604 (skip-chars-forward "^<&")
605 (when (eq (char-after) ?&)
606 ;; If we find an entity or character reference, expand it.
607 (unless (looking-at xml-entity-or-char-ref-re)
608 (error "XML: (Not Well-Formed) Invalid entity reference"))
609 ;; For a character reference, the next entity or character
610 ;; reference must be after the replacement. [4.6] "Numerical
611 ;; character references are expanded immediately when
612 ;; recognized and MUST be treated as character data."
613 (if (setq ref (match-string 2))
614 (progn ; Numeric char reference
615 (setq val (save-match-data
616 (decode-char 'ucs (string-to-number
617 ref (if (match-string 1) 16)))))
618 (and (null val)
619 xml-validating-parser
620 (error "XML: (Validity) Invalid character reference `%s'"
621 (match-string 0)))
622 (replace-match (if val (string val) xml-undefined-entity) t t))
623 ;; For an entity reference, search again from the start of
624 ;; the replaced text, since the replacement can contain
625 ;; entity or character references, or markup.
626 (setq ref (match-string 3)
627 val (assoc ref xml-entity-alist))
628 (and (null val)
629 xml-validating-parser
630 (error "XML: (Validity) Undefined entity `%s'" ref))
631 (replace-match (or (cdr val) xml-undefined-entity) t t)
632 (goto-char (match-beginning 0)))
633 ;; Check for XML bombs.
634 (and xml-entity-expansion-limit
635 (> (- (buffer-size) (point))
636 (+ old-remaining-size xml-entity-expansion-limit))
637 (error "XML: Entity reference expansion \
638 surpassed `xml-entity-expansion-limit'"))))
639 ;; [2.11] Clean up line breaks.
640 (let ((end-marker (point-marker)))
641 (goto-char start)
642 (while (re-search-forward "\r\n?" end-marker t)
643 (replace-match "\n" t t))
644 (goto-char end-marker)
645 (buffer-substring start (point)))))
647 (defun xml-parse-attlist (&optional xml-ns)
648 "Return the attribute-list after point.
649 Leave point at the first non-blank character after the tag."
650 (let ((attlist ())
651 end-pos name)
652 (skip-syntax-forward " ")
653 (while (looking-at (eval-when-compile
654 (concat "\\(" xml-name-re "\\)\\s-*=\\s-*")))
655 (setq end-pos (match-end 0))
656 (setq name (xml-maybe-do-ns (match-string-no-properties 1) nil xml-ns))
657 (goto-char end-pos)
659 ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
661 ;; Do we have a string between quotes (or double-quotes),
662 ;; or a simple word ?
663 (if (looking-at "\"\\([^\"]*\\)\"")
664 (setq end-pos (match-end 0))
665 (if (looking-at "'\\([^']*\\)'")
666 (setq end-pos (match-end 0))
667 (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
669 ;; Each attribute must be unique within a given element
670 (if (assoc name attlist)
671 (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
673 ;; Multiple whitespace characters should be replaced with a single one
674 ;; in the attributes
675 (let ((string (match-string-no-properties 1)))
676 (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
677 (let ((expansion (xml-substitute-special string)))
678 (unless (stringp expansion)
679 ;; We say this is the constraint. It is actually that
680 ;; neither external entities nor "<" can be in an
681 ;; attribute value.
682 (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
683 (push (cons name expansion) attlist)))
685 (goto-char end-pos)
686 (skip-syntax-forward " "))
687 (nreverse attlist)))
689 ;;; DTD (document type declaration)
691 ;; The following functions know how to skip or parse the DTD of a
692 ;; document. FIXME: it fails at least if the DTD contains conditional
693 ;; sections.
695 (defun xml-skip-dtd ()
696 "Skip the DTD at point.
697 This follows the rule [28] in the XML specifications."
698 (let ((xml-validating-parser nil))
699 (xml-parse-dtd)))
701 (defun xml-parse-dtd (&optional _parse-ns)
702 "Parse the DTD at point."
703 (forward-char (eval-when-compile (length "<!DOCTYPE")))
704 (skip-syntax-forward " ")
705 (if (and (looking-at-p ">")
706 xml-validating-parser)
707 (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
709 ;; Get the name of the document
710 (looking-at xml-name-re)
711 (let ((dtd (list (match-string-no-properties 0) 'dtd))
712 (xml-parameter-entity-alist xml-parameter-entity-alist)
713 next-parameter-entity)
714 (goto-char (match-end 0))
715 (skip-syntax-forward " ")
717 ;; External subset (XML [75])
718 (cond ((looking-at "PUBLIC\\s-+")
719 (goto-char (match-end 0))
720 (unless (or (re-search-forward
721 "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
722 nil t)
723 (re-search-forward
724 "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
725 nil t))
726 (error "XML: Missing Public ID"))
727 (let ((pubid (match-string-no-properties 1)))
728 (skip-syntax-forward " ")
729 (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
730 (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
731 (error "XML: Missing System ID"))
732 (push (list pubid (match-string-no-properties 1) 'public) dtd)))
733 ((looking-at "SYSTEM\\s-+")
734 (goto-char (match-end 0))
735 (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
736 (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
737 (error "XML: Missing System ID"))
738 (push (list (match-string-no-properties 1) 'system) dtd)))
739 (skip-syntax-forward " ")
741 (if (eq (char-after) ?>)
743 ;; No internal subset
744 (forward-char)
746 ;; Internal subset (XML [28b])
747 (unless (eq (char-after) ?\[)
748 (error "XML: Bad DTD"))
749 (forward-char)
751 ;; [2.8]: "markup declarations may be made up in whole or in
752 ;; part of the replacement text of parameter entities."
754 ;; Since parameter entities are valid only within the DTD, we
755 ;; first search for the position of the next possible parameter
756 ;; entity. Then, search for the next DTD element; if it ends
757 ;; before the next parameter entity, expand the parameter entity
758 ;; and try again.
759 (setq next-parameter-entity
760 (save-excursion
761 (if (re-search-forward xml-pe-reference-re nil t)
762 (match-beginning 0))))
764 ;; Parse the rest of the DTD
765 ;; Fixme: Deal with NOTATION, PIs.
766 (while (not (looking-at-p "\\s-*\\]"))
767 (skip-syntax-forward " ")
768 (cond
769 ((eobp)
770 (error "XML: (Well-Formed) End of document while reading DTD"))
771 ;; Element declaration [45]:
772 ((and (looking-at (eval-when-compile
773 (concat "<!ELEMENT\\s-+\\(" xml-name-re
774 "\\)\\s-+\\([^>]+\\)>")))
775 (or (null next-parameter-entity)
776 (<= (match-end 0) next-parameter-entity)))
777 (let ((element (match-string-no-properties 1))
778 (type (match-string-no-properties 2))
779 (end-pos (match-end 0)))
780 ;; Translation of rule [46] of XML specifications
781 (cond
782 ((string-match-p "\\`EMPTY\\s-*\\'" type) ; empty declaration
783 (setq type 'empty))
784 ((string-match-p "\\`ANY\\s-*$" type) ; any type of contents
785 (setq type 'any))
786 ((string-match "\\`(\\(.*\\))\\s-*\\'" type) ; children ([47])
787 (setq type (xml-parse-elem-type
788 (match-string-no-properties 1 type))))
789 ((string-match-p "^%[^;]+;[ \t\n\r]*\\'" type) ; substitution
790 nil)
791 (xml-validating-parser
792 (error "XML: (Validity) Invalid element type in the DTD")))
794 ;; rule [45]: the element declaration must be unique
795 (and (assoc element dtd)
796 xml-validating-parser
797 (error "XML: (Validity) DTD element declarations must be unique (<%s>)"
798 element))
800 ;; Store the element in the DTD
801 (push (list element type) dtd)
802 (goto-char end-pos)))
804 ;; Attribute-list declaration [52] (currently unsupported):
805 ((and (looking-at (eval-when-compile
806 (concat "<!ATTLIST[ \t\n\r]*\\(" xml-name-re
807 "\\)[ \t\n\r]*\\(" xml-att-def-re
808 "\\)*[ \t\n\r]*>")))
809 (or (null next-parameter-entity)
810 (<= (match-end 0) next-parameter-entity)))
811 (goto-char (match-end 0)))
813 ;; Comments (skip to end, ignoring parameter entity):
814 ((looking-at-p "<!--")
815 (search-forward "-->")
816 (and next-parameter-entity
817 (> (point) next-parameter-entity)
818 (setq next-parameter-entity
819 (save-excursion
820 (if (re-search-forward xml-pe-reference-re nil t)
821 (match-beginning 0))))))
823 ;; Internal entity declarations:
824 ((and (looking-at (eval-when-compile
825 (concat "<!ENTITY[ \t\n\r]+\\(%[ \t\n\r]+\\)?\\("
826 xml-name-re "\\)[ \t\n\r]*\\("
827 xml-entity-value-re "\\)[ \t\n\r]*>")))
828 (or (null next-parameter-entity)
829 (<= (match-end 0) next-parameter-entity)))
830 (let* ((name (prog1 (match-string-no-properties 2)
831 (goto-char (match-end 0))))
832 (alist (if (match-string 1)
833 'xml-parameter-entity-alist
834 'xml-entity-alist))
835 ;; Retrieve the deplacement text:
836 (value (xml--entity-replacement-text
837 ;; Entity value, sans quotation marks:
838 (substring (match-string-no-properties 3) 1 -1))))
839 ;; If the same entity is declared more than once, the
840 ;; first declaration is binding.
841 (unless (assoc name (symbol-value alist))
842 (set alist (cons (cons name value) (symbol-value alist))))))
844 ;; External entity declarations (currently unsupported):
845 ((and (or (looking-at (eval-when-compile
846 (concat "<!ENTITY[ \t\n\r]+\\(%[ \t\n\r]+\\)?\\("
847 xml-name-re "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
848 "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>")))
849 (looking-at (eval-when-compile
850 (concat "<!ENTITY[ \t\n\r]+\\(%[ \t\n\r]+\\)?\\("
851 xml-name-re "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
852 "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
853 "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
854 "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
855 "[ \t\n\r]*>"))))
856 (or (null next-parameter-entity)
857 (<= (match-end 0) next-parameter-entity)))
858 (goto-char (match-end 0)))
860 ;; If a parameter entity is in the way, expand it.
861 (next-parameter-entity
862 (save-excursion
863 (goto-char next-parameter-entity)
864 (unless (looking-at xml-pe-reference-re)
865 (error "XML: Internal error"))
866 (let* ((entity (match-string 1))
867 (elt (assoc entity xml-parameter-entity-alist)))
868 (if elt
869 (progn
870 (replace-match (cdr elt) t t)
871 ;; The replacement can itself be a parameter entity.
872 (goto-char next-parameter-entity))
873 (goto-char (match-end 0))))
874 (setq next-parameter-entity
875 (if (re-search-forward xml-pe-reference-re nil t)
876 (match-beginning 0)))))
878 ;; Anything else is garbage (ignored if not validating).
879 (xml-validating-parser
880 (error "XML: (Validity) Invalid DTD item"))
882 (skip-chars-forward "^]"))))
884 (if (looking-at "\\s-*]>")
885 (goto-char (match-end 0))))
886 (nreverse dtd)))
888 (defun xml--entity-replacement-text (string)
889 "Return the replacement text for the entity value STRING.
890 The replacement text is obtained by replacing character
891 references and parameter-entity references."
892 (let ((ref-re (eval-when-compile
893 (concat "\\(?:&#\\([0-9]+\\)\\|&#x\\([0-9a-fA-F]+\\)\\|%\\("
894 xml-name-re "\\)\\);")))
895 children)
896 (while (string-match ref-re string)
897 (push (substring string 0 (match-beginning 0)) children)
898 (let ((remainder (substring string (match-end 0)))
899 ref val)
900 (cond ((setq ref (match-string 1 string))
901 ;; Decimal character reference
902 (setq val (decode-char 'ucs (string-to-number ref)))
903 (if val (push (string val) children)))
904 ;; Hexadecimal character reference
905 ((setq ref (match-string 2 string))
906 (setq val (decode-char 'ucs (string-to-number ref 16)))
907 (if val (push (string val) children)))
908 ;; Parameter entity reference
909 ((setq ref (match-string 3 string))
910 (setq val (assoc ref xml-parameter-entity-alist))
911 (and (null val)
912 xml-validating-parser
913 (error "XML: (Validity) Undefined parameter entity `%s'" ref))
914 (push (or (cdr val) xml-undefined-entity) children)))
915 (setq string remainder)))
916 (mapconcat 'identity (nreverse (cons string children)) "")))
918 (defun xml-parse-elem-type (string)
919 "Convert element type STRING into a Lisp structure."
921 (let (elem modifier)
922 (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
923 (progn
924 (setq elem (match-string-no-properties 1 string)
925 modifier (match-string-no-properties 2 string))
926 (if (string-match-p "|" elem)
927 (setq elem (cons 'choice
928 (mapcar 'xml-parse-elem-type
929 (split-string elem "|"))))
930 (if (string-match-p "," elem)
931 (setq elem (cons 'seq
932 (mapcar 'xml-parse-elem-type
933 (split-string elem ",")))))))
934 (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
935 (setq elem (match-string-no-properties 1 string)
936 modifier (match-string-no-properties 2 string))))
938 (if (and (stringp elem) (string= elem "#PCDATA"))
939 (setq elem 'pcdata))
941 (cond
942 ((string= modifier "+")
943 (list '+ elem))
944 ((string= modifier "*")
945 (list '* elem))
946 ((string= modifier "?")
947 (list '\? elem))
949 elem))))
951 ;;; Substituting special XML sequences
953 (defun xml-substitute-special (string)
954 "Return STRING, after substituting entity and character references.
955 STRING is assumed to occur in an XML attribute value."
956 (let ((strlen (length string))
957 children)
958 (while (string-match xml-entity-or-char-ref-re string)
959 (push (substring string 0 (match-beginning 0)) children)
960 (let* ((remainder (substring string (match-end 0)))
961 (is-hex (match-string 1 string)) ; Is it a hex numeric reference?
962 (ref (match-string 2 string))) ; Numeric part of reference
963 (if ref
964 ;; [4.6] Character references are included as
965 ;; character data.
966 (let ((val (decode-char 'ucs (string-to-number ref (if is-hex 16)))))
967 (push (cond (val (string val))
968 (xml-validating-parser
969 (error "XML: (Validity) Undefined character `x%s'" ref))
970 (t xml-undefined-entity))
971 children)
972 (setq string remainder
973 strlen (length string)))
974 ;; [4.4.5] Entity references are "included in literal".
975 ;; Note that we don't need do anything special to treat
976 ;; quotes as normal data characters.
977 (setq ref (match-string 3 string)) ; entity name
978 (let ((val (or (cdr (assoc ref xml-entity-alist))
979 (if xml-validating-parser
980 (error "XML: (Validity) Undefined entity `%s'" ref)
981 xml-undefined-entity))))
982 (setq string (concat val remainder)))
983 (and xml-entity-expansion-limit
984 (> (length string) (+ strlen xml-entity-expansion-limit))
985 (error "XML: Passed `xml-entity-expansion-limit' while expanding `&%s;'"
986 ref)))))
987 (mapconcat 'identity (nreverse (cons string children)) "")))
989 (defun xml-substitute-numeric-entities (string)
990 "Substitute SGML numeric entities by their respective utf characters.
991 This function replaces numeric entities in the input STRING and
992 returns the modified string. For example \"&#42;\" gets replaced
993 by \"*\"."
994 (if (and string (stringp string))
995 (let ((start 0))
996 (while (string-match "&#\\([0-9]+\\);" string start)
997 (ignore-errors
998 (setq string (replace-match
999 (string (read (substring string
1000 (match-beginning 1)
1001 (match-end 1))))
1002 nil nil string)))
1003 (setq start (1+ (match-beginning 0))))
1004 string)
1005 nil))
1007 ;;; Printing a parse tree (mainly for debugging).
1009 (defun xml-debug-print (xml &optional indent-string)
1010 "Outputs the XML in the current buffer.
1011 XML can be a tree or a list of nodes.
1012 The first line is indented with the optional INDENT-STRING."
1013 (setq indent-string (or indent-string ""))
1014 (dolist (node xml)
1015 (xml-debug-print-internal node indent-string)))
1017 (defalias 'xml-print 'xml-debug-print)
1019 (defun xml-escape-string (string)
1020 "Convert STRING into a string containing valid XML character data.
1021 Replace occurrences of &<>\\='\" in STRING with their default XML
1022 entity references (e.g., replace each & with &amp;).
1024 XML character data must not contain & or < characters, nor the >
1025 character under some circumstances. The XML spec does not impose
1026 restriction on \" or \\=', but we just substitute for these too
1027 \(as is permitted by the spec)."
1028 (with-temp-buffer
1029 (insert string)
1030 (dolist (substitution '(("&" . "&amp;")
1031 ("<" . "&lt;")
1032 (">" . "&gt;")
1033 ("'" . "&apos;")
1034 ("\"" . "&quot;")))
1035 (goto-char (point-min))
1036 (while (search-forward (car substitution) nil t)
1037 (replace-match (cdr substitution) t t nil)))
1038 (buffer-string)))
1040 (defun xml-debug-print-internal (xml indent-string)
1041 "Outputs the XML tree in the current buffer.
1042 The first line is indented with INDENT-STRING."
1043 (let ((tree xml)
1044 attlist)
1045 (insert indent-string ?< (symbol-name (xml-node-name tree)))
1047 ;; output the attribute list
1048 (setq attlist (xml-node-attributes tree))
1049 (while attlist
1050 (insert ?\ (symbol-name (caar attlist)) "=\""
1051 (xml-escape-string (cdar attlist)) ?\")
1052 (setq attlist (cdr attlist)))
1054 (setq tree (xml-node-children tree))
1056 (if (null tree)
1057 (insert ?/ ?>)
1058 (insert ?>)
1060 ;; output the children
1061 (dolist (node tree)
1062 (cond
1063 ((listp node)
1064 (insert ?\n)
1065 (xml-debug-print-internal node (concat indent-string " ")))
1066 ((stringp node)
1067 (insert (xml-escape-string node)))
1069 (error "Invalid XML tree"))))
1071 (when (not (and (null (cdr tree))
1072 (stringp (car tree))))
1073 (insert ?\n indent-string))
1074 (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
1076 (provide 'xml)
1078 ;;; xml.el ends here