src/dispnew.c (adjust_decode_mode_spec_buffer): Use 'int' instead of 'ssize_t'.
[emacs.git] / lisp / misc.el
1 ;;; misc.el --- some nonstandard editing and utility commands for Emacs
2
3 ;; Copyright (C) 1989, 2001-2014 Free Software Foundation, Inc.
4
5 ;; Maintainer: emacs-devel@gnu.org
6 ;; Keywords: convenience
7 ;; Package: emacs
8
9 ;; This file is part of GNU Emacs.
10
11 ;; GNU Emacs is free software: you can redistribute it and/or modify
12 ;; it under the terms of the GNU General Public License as published by
13 ;; the Free Software Foundation, either version 3 of the License, or
14 ;; (at your option) any later version.
15
16 ;; GNU Emacs is distributed in the hope that it will be useful,
17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 ;; GNU General Public License for more details.
20
21 ;; You should have received a copy of the GNU General Public License
22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23
24 ;;; Commentary:
25
26 ;;; Code:
27
28 (eval-when-compile
29   (require 'tabulated-list))
30
31 (defun copy-from-above-command (&optional arg)
32   "Copy characters from previous nonblank line, starting just above point.
33 Copy ARG characters, but not past the end of that line.
34 If no argument given, copy the entire rest of the line.
35 The characters copied are inserted in the buffer before point."
36   (interactive "P")
37   (let ((cc (current-column))
38         n
39         (string ""))
40     (save-excursion
41       (beginning-of-line)
42       (backward-char 1)
43       (skip-chars-backward "\ \t\n")
44       (move-to-column cc)
45       ;; Default is enough to copy the whole rest of the line.
46       (setq n (if arg (prefix-numeric-value arg) (point-max)))
47       ;; If current column winds up in middle of a tab,
48       ;; copy appropriate number of "virtual" space chars.
49       (if (< cc (current-column))
50           (if (= (preceding-char) ?\t)
51               (progn
52                 (setq string (make-string (min n (- (current-column) cc)) ?\s))
53                 (setq n (- n (min n (- (current-column) cc)))))
54             ;; In middle of ctl char => copy that whole char.
55             (backward-char 1)))
56       (setq string (concat string
57                            (buffer-substring
58                             (point)
59                             (min (line-end-position)
60                                  (+ n (point)))))))
61     (insert string)))
62
63 ;; Variation of `zap-to-char'.
64
65 (defun zap-up-to-char (arg char)
66   "Kill up to, but not including ARGth occurrence of CHAR.
67 Case is ignored if `case-fold-search' is non-nil in the current buffer.
68 Goes backward if ARG is negative; error if CHAR not found.
69 Ignores CHAR at point."
70   (interactive "p\ncZap up to char: ")
71   (let ((direction (if (>= arg 0) 1 -1)))
72     (kill-region (point)
73                  (progn
74                    (forward-char direction)
75                    (unwind-protect
76                        (search-forward (char-to-string char) nil nil arg)
77                      (backward-char direction))
78                    (point)))))
79
80 ;; These were added with an eye to making possible a more CCA-compatible
81 ;; command set; but that turned out not to be interesting.
82
83 (defun mark-beginning-of-buffer ()
84   "Set mark at the beginning of the buffer."
85   (interactive)
86   (push-mark (point-min)))
87
88 (defun mark-end-of-buffer ()
89   "Set mark at the end of the buffer."
90   (interactive)
91   (push-mark (point-max)))
92
93 (defun upcase-char (arg)
94   "Uppercasify ARG chars starting from point.  Point doesn't move."
95   (interactive "p")
96   (save-excursion
97     (upcase-region (point) (progn (forward-char arg) (point)))))
98
99 (defun forward-to-word (arg)
100   "Move forward until encountering the beginning of a word.
101 With argument, do this that many times."
102   (interactive "^p")
103   (or (re-search-forward (if (> arg 0) "\\W\\b" "\\b\\W") nil t arg)
104       (goto-char (if (> arg 0) (point-max) (point-min)))))
105
106 (defun backward-to-word (arg)
107   "Move backward until encountering the end of a word.
108 With argument, do this that many times."
109   (interactive "^p")
110   (forward-to-word (- arg)))
111
112 ;;;###autoload
113 (defun butterfly ()
114   "Use butterflies to flip the desired bit on the drive platter.
115 Open hands and let the delicate wings flap once.  The disturbance
116 ripples outward, changing the flow of the eddy currents in the
117 upper atmosphere.  These cause momentary pockets of higher-pressure
118 air to form, which act as lenses that deflect incoming cosmic rays,
119 focusing them to strike the drive platter and flip the desired bit.
120 You can type `M-x butterfly C-M-c' to run it.  This is a permuted
121 variation of `C-x M-c M-butterfly' from url `http://xkcd.com/378/'."
122   (interactive)
123   (if (yes-or-no-p "Do you really want to unleash the powers of the butterfly? ")
124       (progn
125         (switch-to-buffer (get-buffer-create "*butterfly*"))
126         (erase-buffer)
127         (sit-for 0)
128         (animate-string "Amazing physics going on..."
129                         (/ (window-height) 2) (- (/ (window-width) 2) 12))
130         (sit-for (* 5 (/ (abs (random)) (float most-positive-fixnum))))
131         (message "Successfully flipped one bit!"))
132     (message "Well, then go to xkcd.com!")
133     (browse-url "http://xkcd.com/378/")))
134
135 ;; A command to list dynamically loaded libraries.  This useful in
136 ;; environments where dynamic-library-alist is used, i.e., Windows
137
138 (defvar list-dynamic-libraries--loaded-only-p)
139 (make-variable-buffer-local 'list-dynamic-libraries--loaded-only-p)
140
141 (defun list-dynamic-libraries--loaded (from)
142   "Compute the \"Loaded from\" column.
143 Internal use only."
144   (if from
145       (let ((name (car from))
146             (path (or (cdr from) "<unknown>")))
147         ;; This is a roundabout way to change the tooltip without
148         ;; having to replace the default printer function
149         (propertize name
150                     'display (propertize name
151                                          'help-echo (concat "Loaded from: " path))))
152     ""))
153
154 (defun list-dynamic-libraries--refresh ()
155   "Recompute the list of dynamic libraries.
156 Internal use only."
157   (setq tabulated-list-format  ; recomputed because column widths can change
158         (let ((max-id-len 0) (max-name-len 0))
159           (dolist (lib dynamic-library-alist)
160             (let ((id-len (length (symbol-name (car lib))))
161                   (name-len (apply 'max (mapcar 'length (cdr lib)))))
162               (when (> id-len max-id-len) (setq max-id-len id-len))
163               (when (> name-len max-name-len) (setq max-name-len name-len))))
164           (vector (list "Library" (1+ max-id-len) t)
165                   (list "Loaded from" (1+ max-name-len) t)
166                   (list "Candidate names" 0 t))))
167   (tabulated-list-init-header)
168   (setq tabulated-list-entries nil)
169   (dolist (lib dynamic-library-alist)
170     (let* ((id (car lib))
171            (from (get id :loaded-from)))
172       (when (or from
173                 (not list-dynamic-libraries--loaded-only-p))
174         (push (list id (vector (symbol-name id)
175                                (list-dynamic-libraries--loaded from)
176                                (mapconcat 'identity (cdr lib) ", ")))
177               tabulated-list-entries)))))
178
179 ;;;###autoload
180 (defun list-dynamic-libraries (&optional loaded-only-p buffer)
181   "Display a list of all dynamic libraries known to Emacs.
182 \(These are the libraries listed in `dynamic-library-alist'.)
183 If optional argument LOADED-ONLY-P (interactively, prefix arg)
184 is non-nil, only libraries already loaded are listed.
185 Optional argument BUFFER specifies a buffer to use, instead of
186 \"*Dynamic Libraries*\".
187 The return value is always nil."
188   (interactive "P")
189   (unless (bufferp buffer)
190     (setq buffer (get-buffer-create "*Dynamic Libraries*")))
191   (with-current-buffer buffer
192     (tabulated-list-mode)
193     (setq tabulated-list-sort-key (cons "Library" nil))
194     (add-hook 'tabulated-list-revert-hook 'list-dynamic-libraries--refresh nil t)
195     (setq list-dynamic-libraries--loaded-only-p loaded-only-p)
196     (list-dynamic-libraries--refresh)
197     (tabulated-list-print))
198   (display-buffer buffer)
199   nil)
200
201 (provide 'misc)
202
203 ;;; misc.el ends here