* ses.el (macroexp): add require for this package, so that function
[emacs.git] / lisp / emacs-lisp / benchmark.el
1 ;;; benchmark.el --- support for benchmarking code
2
3 ;; Copyright (C) 2003-2014 Free Software Foundation, Inc.
4
5 ;; Author: Dave Love  <fx@gnu.org>
6 ;; Keywords: lisp, extensions
7
8 ;; This file is part of GNU Emacs.
9
10 ;; GNU Emacs is free software: you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation, either version 3 of the License, or
13 ;; (at your option) any later version.
14
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
22
23 ;;; Commentary:
24
25 ;; Utilities for timing the execution of forms, including the time
26 ;; taken for GC.  Note that prior to timing code you may want to
27 ;; ensure things like:  there has just been a GC, the relevant code is
28 ;; already loaded (so that there's no overhead from autoloading etc.),
29 ;; and the code is compiled if appropriate (but see
30 ;; `benchmark-run-compiled').
31
32 ;;; Code:
33
34 (defmacro benchmark-elapse (&rest forms)
35   "Return the time in seconds elapsed for execution of FORMS."
36   (let ((t1 (make-symbol "t1"))
37         (t2 (make-symbol "t2")))
38     `(let (,t1 ,t2)
39        (setq ,t1 (current-time))
40        ,@forms
41        (setq ,t2 (current-time))
42        (float-time (time-subtract ,t2 ,t1)))))
43
44 (put 'benchmark-elapse 'edebug-form-spec t)
45 (put 'benchmark-elapse 'lisp-indent-function 0)
46
47 ;;;###autoload
48 (defmacro benchmark-run (&optional repetitions &rest forms)
49   "Time execution of FORMS.
50 If REPETITIONS is supplied as a number, run forms that many times,
51 accounting for the overhead of the resulting loop.  Otherwise run
52 FORMS once.
53 Return a list of the total elapsed time for execution, the number of
54 garbage collections that ran, and the time taken by garbage collection.
55 See also `benchmark-run-compiled'."
56   (declare (indent 1) (debug t))
57   (unless (natnump repetitions)
58     (setq forms (cons repetitions forms)
59           repetitions 1))
60   (let ((i (make-symbol "i"))
61         (gcs (make-symbol "gcs"))
62         (gc (make-symbol "gc")))
63     `(let ((,gc gc-elapsed)
64            (,gcs gcs-done))
65        (list ,(if (> repetitions 1)
66                   ;; Take account of the loop overhead.
67                   `(- (benchmark-elapse (dotimes (,i ,repetitions)
68                                           ,@forms))
69                       (benchmark-elapse (dotimes (,i ,repetitions))))
70                 `(benchmark-elapse ,@forms))
71              (- gcs-done ,gcs)
72              (- gc-elapsed ,gc)))))
73
74 ;;;###autoload
75 (defmacro benchmark-run-compiled (&optional repetitions &rest forms)
76   "Time execution of compiled version of FORMS.
77 This is like `benchmark-run', but what is timed is a funcall of the
78 byte code obtained by wrapping FORMS in a `lambda' and compiling the
79 result.  The overhead of the `lambda's is accounted for."
80   (declare (indent 1) (debug t))
81   (unless (natnump repetitions)
82     (setq forms (cons repetitions forms)
83           repetitions 1))
84   (let ((i (make-symbol "i"))
85         (gcs (make-symbol "gcs"))
86         (gc (make-symbol "gc"))
87         (code (byte-compile `(lambda () ,@forms)))
88         (lambda-code (byte-compile `(lambda ()))))
89     `(let ((,gc gc-elapsed)
90            (,gcs gcs-done))
91        (list ,(if (> repetitions 1)
92                   ;; Take account of the loop overhead.
93                   `(- (benchmark-elapse (dotimes (,i ,repetitions)
94                                           (funcall ,code)))
95                       (benchmark-elapse (dotimes (,i ,repetitions)
96                                           (funcall ,lambda-code))))
97                 `(benchmark-elapse (funcall ,code)))
98              (- gcs-done ,gcs) (- gc-elapsed ,gc)))))
99
100 ;;;###autoload
101 (defun benchmark (repetitions form)
102   "Print the time taken for REPETITIONS executions of FORM.
103 Interactively, REPETITIONS is taken from the prefix arg.
104 For non-interactive use see also `benchmark-run' and
105 `benchmark-run-compiled'."
106   (interactive "p\nxForm: ")
107   (let ((result (eval `(benchmark-run ,repetitions ,form))))
108     (if (zerop (nth 1 result))
109         (message "Elapsed time: %fs" (car result))
110       (message "Elapsed time: %fs (%fs in %d GCs)" (car result)
111                (nth 2 result) (nth 1 result)))))
112
113 (provide 'benchmark)
114
115 ;;; benchmark.el ends here