Don't overflow if computing approximate percentage
[emacs.git] / lisp / calendar / holidays.el
blob8085c1cf119131337c054358d7aa5931016c0e0a
1 ;;; holidays.el --- holiday functions for the calendar package
3 ;; Copyright (C) 1989-1990, 1992-1994, 1997, 2001-2015 Free Software
4 ;; Foundation, Inc.
6 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
8 ;; Keywords: holidays, calendar
9 ;; Package: calendar
11 ;; This file is part of GNU Emacs.
13 ;; GNU Emacs is free software: you can redistribute it and/or modify
14 ;; it under the terms of the GNU General Public License as published by
15 ;; the Free Software Foundation, either version 3 of the License, or
16 ;; (at your option) any later version.
18 ;; GNU Emacs is distributed in the hope that it will be useful,
19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
21 ;; GNU General Public License for more details.
23 ;; You should have received a copy of the GNU General Public License
24 ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
26 ;;; Commentary:
28 ;; See calendar.el.
30 ;;; Code:
32 (require 'calendar)
33 (load "hol-loaddefs" nil t)
35 (defgroup holidays nil
36 "Holidays support in calendar."
37 :group 'calendar
38 :prefix "holidays-"
39 :group 'local)
41 ;; The various holiday variables are autoloaded because people
42 ;; are used to using them to set calendar-holidays without having to
43 ;; explicitly load this file.
45 ;;;###autoload
46 (defcustom holiday-general-holidays
47 (mapcar 'purecopy
48 '((holiday-fixed 1 1 "New Year's Day")
49 (holiday-float 1 1 3 "Martin Luther King Day")
50 (holiday-fixed 2 2 "Groundhog Day")
51 (holiday-fixed 2 14 "Valentine's Day")
52 (holiday-float 2 1 3 "President's Day")
53 (holiday-fixed 3 17 "St. Patrick's Day")
54 (holiday-fixed 4 1 "April Fools' Day")
55 (holiday-float 5 0 2 "Mother's Day")
56 (holiday-float 5 1 -1 "Memorial Day")
57 (holiday-fixed 6 14 "Flag Day")
58 (holiday-float 6 0 3 "Father's Day")
59 (holiday-fixed 7 4 "Independence Day")
60 (holiday-float 9 1 1 "Labor Day")
61 (holiday-float 10 1 2 "Columbus Day")
62 (holiday-fixed 10 31 "Halloween")
63 (holiday-fixed 11 11 "Veteran's Day")
64 (holiday-float 11 4 4 "Thanksgiving")))
65 "General holidays. Default value is for the United States.
66 See the documentation for `calendar-holidays' for details."
67 :type 'sexp
68 :group 'holidays)
69 ;;;###autoload
70 (put 'holiday-general-holidays 'risky-local-variable t)
72 ;;;###autoload
73 (defcustom holiday-oriental-holidays
74 (mapcar 'purecopy
75 '((holiday-chinese-new-year)
76 (if calendar-chinese-all-holidays-flag
77 (append
78 (holiday-chinese 1 15 "Lantern Festival")
79 (holiday-chinese-qingming)
80 (holiday-chinese 5 5 "Dragon Boat Festival")
81 (holiday-chinese 7 7 "Double Seventh Festival")
82 (holiday-chinese 8 15 "Mid-Autumn Festival")
83 (holiday-chinese 9 9 "Double Ninth Festival")
84 (holiday-chinese-winter-solstice)
85 ))))
86 "Oriental holidays.
87 See the documentation for `calendar-holidays' for details."
88 :version "23.1" ; added more holidays
89 :type 'sexp
90 :group 'holidays)
91 ;;;###autoload
92 (put 'holiday-oriental-holidays 'risky-local-variable t)
94 ;;;###autoload
95 (defcustom holiday-local-holidays nil
96 "Local holidays.
97 See the documentation for `calendar-holidays' for details."
98 :type 'sexp
99 :group 'holidays)
100 ;;;###autoload
101 (put 'holiday-local-holidays 'risky-local-variable t)
103 ;;;###autoload
104 (defcustom holiday-other-holidays nil
105 "User defined holidays.
106 See the documentation for `calendar-holidays' for details."
107 :type 'sexp
108 :group 'holidays)
109 ;;;###autoload
110 (put 'holiday-other-holidays 'risky-local-variable t)
112 ;;;###autoload
113 (defcustom holiday-hebrew-holidays
114 (mapcar 'purecopy
115 '((holiday-hebrew-passover)
116 (holiday-hebrew-rosh-hashanah)
117 (holiday-hebrew-hanukkah)
118 (if calendar-hebrew-all-holidays-flag
119 (append
120 (holiday-hebrew-tisha-b-av)
121 (holiday-hebrew-misc)))))
122 "Jewish holidays.
123 See the documentation for `calendar-holidays' for details."
124 :type 'sexp
125 :version "23.1" ; removed dependency on hebrew-holidays-N
126 :group 'holidays)
127 ;;;###autoload
128 (put 'holiday-hebrew-holidays 'risky-local-variable t)
130 ;;;###autoload
131 (defcustom holiday-christian-holidays
132 (mapcar 'purecopy
133 '((holiday-easter-etc) ; respects calendar-christian-all-holidays-flag
134 (holiday-fixed 12 25 "Christmas")
135 (if calendar-christian-all-holidays-flag
136 (append
137 (holiday-fixed 1 6 "Epiphany")
138 (holiday-julian 12 25 "Christmas (Julian calendar)")
139 (holiday-greek-orthodox-easter)
140 (holiday-fixed 8 15 "Assumption")
141 (holiday-advent 0 "Advent")))))
142 "Christian holidays.
143 See the documentation for `calendar-holidays' for details."
144 :type 'sexp
145 :group 'holidays)
146 ;;;###autoload
147 (put 'holiday-christian-holidays 'risky-local-variable t)
149 ;;;###autoload
150 (defcustom holiday-islamic-holidays
151 (mapcar 'purecopy
152 '((holiday-islamic-new-year)
153 (holiday-islamic 9 1 "Ramadan Begins")
154 (if calendar-islamic-all-holidays-flag
155 (append
156 (holiday-islamic 1 10 "Ashura")
157 (holiday-islamic 3 12 "Mulad-al-Nabi")
158 (holiday-islamic 7 26 "Shab-e-Mi'raj")
159 (holiday-islamic 8 15 "Shab-e-Bara't")
160 (holiday-islamic 9 27 "Shab-e Qadr")
161 (holiday-islamic 10 1 "Id-al-Fitr")
162 (holiday-islamic 12 10 "Id-al-Adha")))))
163 "Islamic holidays.
164 See the documentation for `calendar-holidays' for details."
165 :type 'sexp
166 :group 'holidays)
167 ;;;###autoload
168 (put 'holiday-islamic-holidays 'risky-local-variable t)
170 ;;;###autoload
171 (defcustom holiday-bahai-holidays
172 (mapcar 'purecopy
173 '((holiday-bahai-new-year)
174 (holiday-bahai-ridvan) ; respects calendar-bahai-all-holidays-flag
175 (holiday-fixed 5 23 "Declaration of the Báb")
176 (holiday-fixed 5 29 "Ascension of Bahá'u'lláh")
177 (holiday-fixed 7 9 "Martyrdom of the Báb")
178 (holiday-fixed 10 20 "Birth of the Báb")
179 (holiday-fixed 11 12 "Birth of Bahá'u'lláh")
180 (if calendar-bahai-all-holidays-flag
181 (append
182 (holiday-fixed 11 26 "Day of the Covenant")
183 (holiday-fixed 11 28 "Ascension of `Abdu'l-Bahá")))))
184 "Bahá'í holidays.
185 See the documentation for `calendar-holidays' for details."
186 :type 'sexp
187 :group 'holidays)
188 ;;;###autoload
189 (put 'holiday-bahai-holidays 'risky-local-variable t)
191 ;;;###autoload
192 (defcustom holiday-solar-holidays
193 (mapcar 'purecopy
194 '((solar-equinoxes-solstices)
195 (holiday-sexp calendar-daylight-savings-starts
196 (format "Daylight Saving Time Begins %s"
197 (solar-time-string
198 (/ calendar-daylight-savings-starts-time (float 60))
199 calendar-standard-time-zone-name)))
200 (holiday-sexp calendar-daylight-savings-ends
201 (format "Daylight Saving Time Ends %s"
202 (solar-time-string
203 (/ calendar-daylight-savings-ends-time (float 60))
204 calendar-daylight-time-zone-name)))))
205 "Sun-related holidays.
206 See the documentation for `calendar-holidays' for details."
207 :type 'sexp
208 :group 'holidays)
209 ;;;###autoload
210 (put 'holiday-solar-holidays 'risky-local-variable t)
212 ;; This one should not be autoloaded, else .emacs changes of
213 ;; holiday-general-holidays etc have no effect.
214 ;; FIXME should have some :set-after.
215 (defcustom calendar-holidays
216 (append holiday-general-holidays holiday-local-holidays
217 holiday-other-holidays holiday-christian-holidays
218 holiday-hebrew-holidays holiday-islamic-holidays
219 holiday-bahai-holidays holiday-oriental-holidays
220 holiday-solar-holidays)
221 "List of notable days for the command \\[holidays].
223 Additional holidays are easy to add to the list, just put them in the
224 list `holiday-other-holidays' in your init file. Similarly, by setting
225 any of `holiday-general-holidays', `holiday-local-holidays',
226 `holiday-christian-holidays', `holiday-hebrew-holidays',
227 `holiday-islamic-holidays', `holiday-bahai-holidays',
228 `holiday-oriental-holidays', or `holiday-solar-holidays' to nil in your
229 init file, you can eliminate unwanted categories of holidays.
231 The aforementioned variables control the holiday choices offered
232 by the function `holiday-list' when it is called interactively.
234 They also initialize the default value of `calendar-holidays',
235 which is the default list of holidays used by the function
236 `holiday-list' in the non-interactive case. Note that these
237 variables have no effect on `calendar-holidays' after it has been
238 set (e.g. after the calendar is loaded). In that case, customize
239 `calendar-holidays' directly.
241 The intention is that (in the US) `holiday-local-holidays' be set in
242 site-init.el and `holiday-other-holidays' be set by the user.
244 Entries on the list are expressions that return (possibly empty) lists of
245 items of the form ((month day year) string) of a holiday in the
246 three-month period centered around `displayed-month' of `displayed-year'.
247 Several basic functions are provided for this purpose:
249 (holiday-fixed MONTH DAY STRING) is a fixed date on the Gregorian calendar
250 (holiday-float MONTH DAYNAME K STRING &optional DAY) is the Kth DAYNAME
251 (0 for Sunday, etc.) after/before Gregorian
252 MONTH DAY. K<0 means count back from the end
253 of the month. Optional DAY defaults to 1 if
254 K>0, and MONTH's last day otherwise.
255 (holiday-hebrew MONTH DAY STRING) a fixed date on the Hebrew calendar
256 (holiday-islamic MONTH DAY STRING) a fixed date on the Islamic calendar
257 (holiday-bahai MONTH DAY STRING) a fixed date on the Bahá'í calendar
258 (holiday-julian MONTH DAY STRING) a fixed date on the Julian calendar
259 (holiday-sexp SEXP STRING) SEXP is a Gregorian-date-valued expression
260 in the variable `year'; if it evaluates to
261 a visible date, that's the holiday; if it
262 evaluates to nil, there's no holiday. STRING
263 is an expression in the variable `date'.
265 For example, to add Bastille Day, celebrated in France on July 14, add
267 (holiday-fixed 7 14 \"Bastille Day\")
269 to the list. To add Hurricane Supplication Day, celebrated in the Virgin
270 Islands on the fourth Monday in August, add
272 (holiday-float 8 1 4 \"Hurricane Supplication Day\")
274 to the list (the last Monday would be specified with `-1' instead of `4').
275 To add the last day of Hanukkah to the list, use
277 (holiday-hebrew 10 2 \"Last day of Hanukkah\")
279 since the Hebrew months are numbered with 1 starting from Nisan.
280 To add the Islamic feast celebrating Mohammed's birthday, use
282 (holiday-islamic 3 12 \"Mohammed's Birthday\")
284 since the Islamic months are numbered from 1 starting with Muharram.
285 To add an entry for the Bahá'í festival of Ridvan, use
287 (holiday-bahai 2 13 \"Festival of Ridvan\")
289 since the Bahá'í months are numbered from 1 starting with Bahá.
290 To add Thomas Jefferson's birthday, April 2, 1743 (Julian), use
292 (holiday-julian 4 2 \"Jefferson's Birthday\")
294 To include a holiday conditionally, use the sexp form or a conditional. For
295 example, to include American presidential elections, which occur on the first
296 Tuesday after the first Monday in November of years divisible by 4, add
298 (holiday-sexp
299 '(if (zerop (% year 4))
300 (calendar-gregorian-from-absolute
301 (1+ (calendar-dayname-on-or-before
302 1 (+ 6 (calendar-absolute-from-gregorian
303 (list 11 1 year)))))))
304 \"US Presidential Election\")
306 or
308 (if (zerop (% displayed-year 4))
309 (holiday-fixed 11
310 (calendar-extract-day
311 (calendar-gregorian-from-absolute
312 (1+ (calendar-dayname-on-or-before
313 1 (+ 6 (calendar-absolute-from-gregorian
314 (list 11 1 displayed-year)))))))
315 \"US Presidential Election\"))
317 to the list. To include the phases of the moon, add
319 (lunar-phases)
321 to the holiday list, where `lunar-phases' is an Emacs-Lisp function that
322 you've written to return a (possibly empty) list of the relevant VISIBLE dates
323 with descriptive strings such as
325 (((2 6 1989) \"New Moon\") ((2 12 1989) \"First Quarter Moon\") ... )."
326 :type 'sexp
327 :group 'holidays)
328 ;;;###autoload
329 (put 'calendar-holidays 'risky-local-variable t)
331 ;;; End of user options.
334 ;; FIXME name that makes sense
335 ;;;###diary-autoload
336 (defun calendar-holiday-list ()
337 "Form the list of holidays that occur on dates in the calendar window.
338 The holidays are those in the list `calendar-holidays'."
339 (let (res h err)
340 (sort
341 (dolist (p calendar-holidays res)
342 (if (setq h (if calendar-debug-sexp
343 (let ((debug-on-error t))
344 (eval p))
345 (condition-case err
346 (eval p)
347 (error
348 (display-warning
349 :error
350 (format "Bad holiday list item: %s\nError: %s\n"
351 p err))
352 nil))))
353 (setq res (append h res))))
354 'calendar-date-compare)))
356 (defvar displayed-month) ; from calendar-generate
357 (defvar displayed-year)
359 ;; FIXME name that makes sense
360 ;;;###cal-autoload
361 (defun calendar-list-holidays (&optional event)
362 "Create a buffer containing the holidays for the current calendar window.
363 The holidays are those in the list `calendar-notable-days'.
364 Returns non-nil if any holidays are found.
365 If EVENT is non-nil, it's an event indicating the buffer position to
366 use instead of point."
367 (interactive (list last-nonmenu-event))
368 ;; If called from a menu, with the calendar window not selected.
369 (with-current-buffer
370 (if event (window-buffer (posn-window (event-start event)))
371 (current-buffer))
372 (message "Looking up holidays...")
373 (let ((holiday-list (calendar-holiday-list))
374 (m1 displayed-month)
375 (y1 displayed-year)
376 (m2 displayed-month)
377 (y2 displayed-year))
378 (if (not holiday-list)
379 (message "Looking up holidays...none found")
380 (calendar-in-read-only-buffer holiday-buffer
381 (calendar-increment-month m1 y1 -1)
382 (calendar-increment-month m2 y2 1)
383 (calendar-set-mode-line
384 (if (= y1 y2)
385 (format "Notable Dates from %s to %s, %d%%-"
386 (calendar-month-name m1) (calendar-month-name m2) y2)
387 (format "Notable Dates from %s, %d to %s, %d%%-"
388 (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
389 (insert
390 (mapconcat
391 (lambda (x) (concat (calendar-date-string (car x))
392 ": " (cadr x)))
393 holiday-list "\n")))
394 (message "Looking up holidays...done"))
395 holiday-list)))
397 ;;;###autoload
398 (defun holidays (&optional arg)
399 "Display the holidays for last month, this month, and next month.
400 If called with an optional prefix argument ARG, prompts for month and year.
401 This function is suitable for execution in a init file."
402 (interactive "P")
403 (save-excursion
404 (let* ((completion-ignore-case t)
405 (date (if arg (calendar-read-date t)
406 (calendar-current-date)))
407 (displayed-month (calendar-extract-month date))
408 (displayed-year (calendar-extract-year date)))
409 (calendar-list-holidays))))
411 ;; rms: "Emacs commands to display a list of something generally start
412 ;; with `list-'. Please make `list-holidays' the principal name."
413 ;;;###autoload
414 (defun list-holidays (y1 &optional y2 l label)
415 "Display holidays for years Y1 to Y2 (inclusive).
416 Y2 defaults to Y1. The optional list of holidays L defaults to
417 `calendar-holidays'. If you want to control what holidays are
418 displayed, use a different list. For example,
420 (list-holidays 2006 2006
421 (append holiday-general-holidays holiday-local-holidays))
423 will display holidays for the year 2006 defined in the two
424 mentioned lists, and nothing else.
426 When called interactively, this command offers a choice of
427 holidays, based on the variables `holiday-solar-holidays' etc. See the
428 documentation of `calendar-holidays' for a list of the variables
429 that control the choices, as well as a description of the format
430 of a holiday list.
432 The optional LABEL is used to label the buffer created."
433 (interactive
434 (let* ((start-year (calendar-read
435 "Starting year of holidays (>0): "
436 (lambda (x) (> x 0))
437 (number-to-string (calendar-extract-year
438 (calendar-current-date)))))
439 (end-year (calendar-read
440 (format "Ending year (inclusive) of holidays (>=%s): "
441 start-year)
442 (lambda (x) (>= x start-year))
443 (number-to-string start-year)))
444 (completion-ignore-case t)
445 (lists
446 (list
447 (cons "All" calendar-holidays)
448 (cons "Equinoxes/Solstices"
449 (list (list 'solar-equinoxes-solstices)))
450 (if holiday-general-holidays
451 (cons "General" holiday-general-holidays))
452 (if holiday-local-holidays
453 (cons "Local" holiday-local-holidays))
454 (if holiday-other-holidays
455 (cons "Other" holiday-other-holidays))
456 (if holiday-christian-holidays
457 (cons "Christian" holiday-christian-holidays))
458 (if holiday-hebrew-holidays
459 (cons "Hebrew" holiday-hebrew-holidays))
460 (if holiday-islamic-holidays
461 (cons "Islamic" holiday-islamic-holidays))
462 (if holiday-bahai-holidays
463 (cons "Bahá'í" holiday-bahai-holidays))
464 (if holiday-oriental-holidays
465 (cons "Oriental" holiday-oriental-holidays))
466 (if holiday-solar-holidays
467 (cons "Solar" holiday-solar-holidays))
468 (cons "Ask" nil)))
469 (choice (capitalize
470 (completing-read "List (TAB for choices): " lists nil t)))
471 (which (if (string-equal choice "Ask")
472 (eval (read-variable "Enter list name: "))
473 (cdr (assoc choice lists))))
474 (name (if (string-equal choice "Equinoxes/Solstices")
475 choice
476 (if (member choice '("Ask" ""))
477 "Holidays"
478 (format "%s Holidays" choice)))))
479 (list start-year end-year which name)))
480 (unless y2 (setq y2 y1))
481 (message "Computing holidays...")
482 (let ((calendar-holidays (or l calendar-holidays))
483 (title (or label "Holidays"))
484 (s (calendar-absolute-from-gregorian (list 2 1 y1)))
485 (e (calendar-absolute-from-gregorian (list 11 1 y2)))
486 (displayed-month 2)
487 (displayed-year y1)
488 holiday-list)
489 (while (<= s e)
490 (setq holiday-list (append holiday-list (calendar-holiday-list)))
491 (calendar-increment-month displayed-month displayed-year 3)
492 (setq s (calendar-absolute-from-gregorian
493 (list displayed-month 1 displayed-year))))
494 (save-excursion
495 (calendar-in-read-only-buffer holiday-buffer
496 (calendar-set-mode-line
497 (if (= y1 y2)
498 (format "%s for %s" title y1)
499 (format "%s for %s-%s" title y1 y2)))
500 (insert
501 (mapconcat
502 (lambda (x) (concat (calendar-date-string (car x))
503 ": " (cadr x)))
504 holiday-list "\n")))
505 (message "Computing holidays...done"))))
507 ;;;###autoload
508 (defalias 'holiday-list 'list-holidays)
510 ;;;###diary-autoload
511 (defun calendar-check-holidays (date)
512 "Check the list of holidays for any that occur on DATE.
513 DATE is a list (month day year). This function considers the
514 holidays from the list `calendar-holidays', and returns a list of
515 strings describing those holidays that apply on DATE, or nil if none do."
516 (let ((displayed-month (calendar-extract-month date))
517 (displayed-year (calendar-extract-year date))
518 holiday-list)
519 (dolist (h (calendar-holiday-list) holiday-list)
520 (if (calendar-date-equal date (car h))
521 (setq holiday-list (append holiday-list (cdr h)))))))
524 ;; Formerly cal-tex-list-holidays.
525 (defun holiday-in-range (d1 d2)
526 "Generate a list of all holidays in range from absolute date D1 to D2."
527 (let* ((start (calendar-gregorian-from-absolute d1))
528 (displayed-month (calendar-extract-month start))
529 (displayed-year (calendar-extract-year start))
530 (end (calendar-gregorian-from-absolute d2))
531 (end-month (calendar-extract-month end))
532 (end-year (calendar-extract-year end))
533 (number-of-intervals
534 (1+ (/ (calendar-interval displayed-month displayed-year
535 end-month end-year)
536 3)))
537 holidays in-range a)
538 (calendar-increment-month displayed-month displayed-year 1)
539 (dotimes (_idummy number-of-intervals)
540 (setq holidays (append holidays (calendar-holiday-list)))
541 (calendar-increment-month displayed-month displayed-year 3))
542 (dolist (hol holidays)
543 (and (car hol)
544 (setq a (calendar-absolute-from-gregorian (car hol)))
545 (and (<= d1 a) (<= a d2))
546 (setq in-range (append (list hol) in-range))))
547 in-range))
550 (declare-function x-popup-menu "menu.c" (position menu))
552 ;;;###cal-autoload
553 (defun calendar-cursor-holidays (&optional date event)
554 "Find holidays for the date specified by the cursor in the calendar window.
555 Optional DATE is a list (month day year) to use instead of the
556 cursor position. EVENT specifies a buffer position to use for a date."
557 (interactive (list nil last-nonmenu-event))
558 (message "Checking holidays...")
559 (or date (setq date (calendar-cursor-to-date t event)))
560 (let ((date-string (calendar-date-string date))
561 (holiday-list (calendar-check-holidays date))
562 selection msg)
563 (if (mouse-event-p event)
564 (and (setq selection (cal-menu-x-popup-menu event
565 (format "Holidays for %s" date-string)
566 (if holiday-list
567 (mapcar 'list holiday-list)
568 '("None"))))
569 (call-interactively selection))
570 (if (not holiday-list)
571 (message "No holidays known for %s" date-string)
572 (if (<= (length (setq msg
573 (format "%s: %s" date-string
574 (mapconcat 'identity holiday-list "; "))))
575 (frame-width))
576 (message "%s" msg)
577 (calendar-in-read-only-buffer holiday-buffer
578 (calendar-set-mode-line date-string)
579 (insert (mapconcat 'identity holiday-list "\n")))
580 (message "Checking holidays...done"))))))
582 ;; FIXME move to calendar?
583 ;;;###cal-autoload
584 (defun calendar-mark-holidays (&optional event)
585 "Mark notable days in the calendar window.
586 If EVENT is non-nil, it's an event indicating the buffer position to
587 use instead of point."
588 (interactive (list last-nonmenu-event))
589 ;; If called from a menu, with the calendar window not selected.
590 (with-current-buffer
591 (if event (window-buffer (posn-window (event-start event)))
592 (current-buffer))
593 (setq calendar-mark-holidays-flag t)
594 (message "Marking holidays...")
595 (dolist (holiday (calendar-holiday-list))
596 (calendar-mark-visible-date (car holiday) calendar-holiday-marker))
597 (message "Marking holidays...done")))
599 ;; Below are the functions that calculate the dates of holidays; these
600 ;; are eval'ed in the function calendar-holiday-list. If you
601 ;; write other such functions, be sure to imitate the style used below.
602 ;; Remember that each function must return a list of items of the form
603 ;; ((month day year) string) of VISIBLE dates in the calendar window.
605 (defun holiday-fixed (month day string)
606 "Holiday on MONTH, DAY (Gregorian) called STRING.
607 If MONTH, DAY is visible, the value returned is the list (((MONTH DAY year)
608 STRING)). Returns nil if it is not visible in the current calendar window."
609 ;; This determines whether a given month is visible in the calendar.
610 ;; cf calendar-date-is-visible-p (which also checks the year part).
611 ;; The day is irrelevant since only full months are displayed.
612 ;; Since the calendar displays three months at a time, month N
613 ;; is visible if displayed-month = N-1, N, N+1.
614 ;; In particular, November is visible if d-m = 10, 11, 12.
615 ;; This is useful, because we can do a one-sided test:
616 ;; November is visible if d-m > 9. (Similarly, February is visible if
617 ;; d-m < 4.)
618 ;; To determine if December is visible, we can shift the calendar
619 ;; back a month and ask if November is visible; to determine if
620 ;; October is visible, we can shift it forward a month and ask if
621 ;; November is visible; etc.
622 (let ((m displayed-month)
623 (y displayed-year))
624 (calendar-increment-month m y (- 11 month))
625 (if (> m 9) ; Is November visible?
626 (list (list (list month day y) string)))))
628 (defun holiday-float (month dayname n string &optional day)
629 "Holiday called STRING on the Nth DAYNAME after/before MONTH DAY.
630 DAYNAME=0 means Sunday, DAYNAME=1 means Monday, and so on.
631 If N>0, use the Nth DAYNAME after MONTH DAY.
632 If N<0, use the Nth DAYNAME before MONTH DAY.
633 DAY defaults to 1 if N>0, and MONTH's last day otherwise.
634 If the holiday is visible in the calendar window, returns a
635 list (((month day year) STRING)). Otherwise returns nil."
636 ;; This is messy because the holiday may be visible, while the date
637 ;; on which it is based is not. For example, the first Monday after
638 ;; December 30 may be visible when January is not. For large values
639 ;; of |n| the problem is more grotesque. If we didn't have to worry
640 ;; about such cases, we could just use the original version of this
641 ;; function:
642 ;; (let ((m displayed-month)
643 ;; (y displayed-year))
644 ;; (calendar-increment-month m y (- 11 month))
645 ;; (if (> m 9); month in year y is visible
646 ;; (list (list (calendar-nth-named-day n dayname month y day) string)))))
647 (let* ((m1 displayed-month)
648 (y1 displayed-year)
649 (m2 displayed-month)
650 (y2 displayed-year)
651 (d1 (progn ; first possible base date for holiday
652 (calendar-increment-month m1 y1 -1)
653 (+ (calendar-nth-named-absday 1 dayname m1 y1)
654 (* -7 n)
655 (if (> n 0) 1 -7))))
656 (d2 ; last possible base date for holiday
657 (progn
658 (calendar-increment-month m2 y2 1)
659 (+ (calendar-nth-named-absday -1 dayname m2 y2)
660 (* -7 n)
661 (if (> n 0) 7 -1))))
662 (y1 (calendar-extract-year (calendar-gregorian-from-absolute d1)))
663 (y2 (calendar-extract-year (calendar-gregorian-from-absolute d2)))
664 (y ; year of base date
665 (if (or (= y1 y2) (> month 9))
666 y1
667 y2))
668 (d ; day of base date
669 (or day (if (> n 0)
671 (calendar-last-day-of-month month y))))
672 (date ; base date for holiday
673 (calendar-absolute-from-gregorian (list month d y))))
674 (and (<= d1 date) (<= date d2)
675 (list (list (calendar-nth-named-day n dayname month y d)
676 string)))))
678 (defun holiday-filter-visible-calendar (hlist)
679 "Filter list of holidays HLIST, and return only the visible ones.
680 HLIST is a list of elements of the form (DATE) TEXT."
681 (delq nil (mapcar (lambda (p)
682 (and (car p) (calendar-date-is-visible-p (car p)) p))
683 hlist)))
685 (defun holiday-sexp (sexp string)
686 "Sexp holiday for dates in the calendar window.
687 SEXP is an expression in variable `year' that is evaluated to
688 give `date'. STRING is an expression in `date' that evaluates to
689 the holiday description of `date'. If `date' is visible in the
690 calendar window, the holiday STRING is on that date. If date is
691 nil, or if the date is not visible, there is no holiday."
692 (let ((m displayed-month)
693 (y displayed-year)
694 year date)
695 (calendar-increment-month m y -1)
696 (holiday-filter-visible-calendar
697 (list
698 (progn
699 (setq year y
700 date (eval sexp))
701 (list date (if date (eval string))))
702 (progn
703 (setq year (1+ y)
704 date (eval sexp))
705 (list date (if date (eval string))))))))
708 (defun holiday-advent (&optional n string)
709 "Date of Nth day after advent (named STRING), if visible in calendar window.
710 Negative values of N are interpreted as days before advent.
711 STRING is used purely for display purposes. The return value has
712 the form ((MONTH DAY YEAR) STRING), where the date is that of the
713 Nth day before or after advent.
715 For backwards compatibility, if this function is called with no
716 arguments, then it returns the value appropriate for advent itself."
717 ;; Backwards compatibility layer.
718 (if (not n)
719 (holiday-advent 0 "Advent")
720 (let* ((year displayed-year)
721 (month displayed-month)
722 (advent (progn
723 (calendar-increment-month month year -1)
724 (calendar-gregorian-from-absolute
725 (+ n
726 (calendar-dayname-on-or-before
728 (calendar-absolute-from-gregorian
729 (list 12 3 year))))))))
730 (if (calendar-date-is-visible-p advent)
731 (list (list advent string))))))
733 (defun holiday-easter-etc (&optional n string)
734 "Date of Nth day after Easter (named STRING), if visible in calendar window.
735 Negative values of N are interpreted as days before Easter.
736 STRING is used purely for display purposes. The return value has
737 the form ((MONTH DAY YEAR) STRING), where the date is that of the
738 Nth day before or after Easter.
740 For backwards compatibility, if this function is called with no
741 arguments, then it returns a list of \"standard\" Easter-related
742 holidays (with more entries if `calendar-christian-all-holidays-flag'
743 is non-nil)."
744 ;; Backwards compatibility layer.
745 (if (not n)
746 (apply 'append
747 (mapcar (lambda (e)
748 (apply 'holiday-easter-etc e))
749 ;; The combined list is not in order.
750 (append
751 (if calendar-christian-all-holidays-flag
752 '((-63 "Septuagesima Sunday")
753 (-56 "Sexagesima Sunday")
754 (-49 "Shrove Sunday")
755 (-48 "Shrove Monday")
756 (-47 "Shrove Tuesday")
757 (-14 "Passion Sunday")
758 (-7 "Palm Sunday")
759 (-3 "Maundy Thursday")
760 (35 "Rogation Sunday")
761 (39 "Ascension Day")
762 (49 "Pentecost (Whitsunday)")
763 (50 "Whitmonday")
764 (56 "Trinity Sunday")
765 (60 "Corpus Christi")))
766 '((-46 "Ash Wednesday")
767 (-2 "Good Friday")
768 (0 "Easter Sunday")))))
769 (let* ((century (1+ (/ displayed-year 100)))
770 (shifted-epact ; age of moon for April 5...
771 (% (+ 14 (* 11 (% displayed-year 19)) ; ...by Nicaean rule
772 (- ; ...corrected for the Gregorian century rule
773 (/ (* 3 century) 4))
774 (/ ; ...corrected for Metonic cycle inaccuracy
775 (+ 5 (* 8 century)) 25)
776 (* 30 century)) ; keeps value positive
777 30))
778 (adjusted-epact ; adjust for 29.5 day month
779 (if (or (zerop shifted-epact)
780 (and (= shifted-epact 1) (< 10 (% displayed-year 19))))
781 (1+ shifted-epact)
782 shifted-epact))
783 (paschal-moon ; day after the full moon on or after March 21
784 (- (calendar-absolute-from-gregorian (list 4 19 displayed-year))
785 adjusted-epact))
786 (abs-easter (calendar-dayname-on-or-before 0 (+ paschal-moon 7)))
787 (greg (calendar-gregorian-from-absolute (+ abs-easter n))))
788 (if (calendar-date-is-visible-p greg)
789 (list (list greg string))))))
791 ;; Prior call to calendar-julian-from-absolute will autoload cal-julian.
792 (declare-function calendar-julian-to-absolute "cal-julian" (date))
794 (defun holiday-greek-orthodox-easter ()
795 "Date of Easter according to the rule of the Council of Nicaea."
796 (let* ((m displayed-month)
797 (y displayed-year)
798 (julian-year (progn
799 (calendar-increment-month m y 1)
800 (calendar-extract-year
801 (calendar-julian-from-absolute
802 (calendar-absolute-from-gregorian
803 (list m (calendar-last-day-of-month m y) y))))))
804 (shifted-epact ; age of moon for April 5
805 (% (+ 14
806 (* 11 (% julian-year 19)))
807 30))
808 (paschal-moon ; day after full moon on or after March 21
809 (- (calendar-julian-to-absolute (list 4 19 julian-year))
810 shifted-epact))
811 (nicaean-easter ; Sunday following the Paschal moon
812 (calendar-gregorian-from-absolute
813 (calendar-dayname-on-or-before 0 (+ paschal-moon 7)))))
814 (if (calendar-date-is-visible-p nicaean-easter)
815 (list (list nicaean-easter "Pascha (Greek Orthodox Easter)")))))
817 (provide 'holidays)
819 ;; Local Variables:
820 ;; coding: utf-8
821 ;; End:
823 ;;; holidays.el ends here