Fixes: debbugs:19269
[emacs.git] / lisp / autoinsert.el
1 ;;; autoinsert.el --- automatic mode-dependent insertion of text into new files
2
3 ;; Copyright (C) 1985-1987, 1994-1995, 1998, 2000-2014 Free Software
4 ;; Foundation, Inc.
5
6 ;; Author: Charlie Martin <crm@cs.duke.edu>
7 ;; Adapted-By: Daniel Pfeiffer <occitan@esperanto.org>
8 ;; Keywords: convenience
9 ;; Maintainer: emacs-devel@gnu.org
10
11 ;; This file is part of GNU Emacs.
12
13 ;; GNU Emacs is free software: you can redistribute it and/or modify
14 ;; it under the terms of the GNU General Public License as published by
15 ;; the Free Software Foundation, either version 3 of the License, or
16 ;; (at your option) any later version.
17
18 ;; GNU Emacs is distributed in the hope that it will be useful,
19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
21 ;; GNU General Public License for more details.
22
23 ;; You should have received a copy of the GNU General Public License
24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
25
26 ;;; Commentary:
27
28 ;;  The following defines an association list for text to be
29 ;;  automatically inserted when a new file is created, and a function
30 ;;  which automatically inserts these files; the idea is to insert
31 ;;  default text much as the mode is automatically set using
32 ;;  auto-mode-alist.
33 ;;
34 ;;  To use:
35 ;;     (add-hook 'find-file-hook 'auto-insert)
36 ;;     setq auto-insert-directory to an appropriate slash-terminated value
37 ;;
38 ;;  You can also customize the variable `auto-insert-mode' to load the
39 ;;  package.  Alternatively, add the following to your init file:
40 ;;  (auto-insert-mode 1)
41 ;;
42 ;;  Author:  Charlie Martin
43 ;;           Department of Computer Science and
44 ;;           National Biomedical Simulation Resource
45 ;;           Box 3709
46 ;;           Duke University Medical Center
47 ;;           Durham, NC 27710
48 ;;            (crm@cs.duke.edu,mcnc!duke!crm)
49
50 ;;; Code:
51
52 (defgroup auto-insert nil
53   "Automatic mode-dependent insertion of text into new files."
54   :prefix "auto-insert-"
55   :group 'files
56   :group 'convenience
57   :link '(custom-manual "(autotype) Autoinserting"))
58
59
60 (defcustom auto-insert 'not-modified
61   "Controls automatic insertion into newly found empty files.
62 Possible values:
63         nil     do nothing
64         t       insert if possible
65         other   insert if possible, but mark as unmodified.
66 Insertion is possible when something appropriate is found in
67 `auto-insert-alist'.  When the insertion is marked as unmodified, you can
68 save it with  \\[write-file] RET.
69 This variable is used when the function `auto-insert' is called, e.g.
70 when you do (add-hook 'find-file-hook 'auto-insert).
71 With \\[auto-insert], this is always treated as if it were t."
72   :type '(choice (const :tag "Insert if possible" t)
73                  (const :tag "Do nothing" nil)
74                  (other :tag "insert if possible, mark as unmodified."
75                         not-modified))
76   :group 'auto-insert)
77
78 (defcustom auto-insert-query 'function
79   "Non-nil means ask user before auto-inserting.
80 When this is `function', only ask when called non-interactively."
81   :type '(choice (const :tag "Don't ask" nil)
82                  (const :tag "Ask if called non-interactively" function)
83                  (other :tag "Ask" t))
84   :group 'auto-insert)
85
86 (defcustom auto-insert-prompt "Perform %s auto-insertion? "
87   "Prompt to use when querying whether to auto-insert.
88 If this contains a %s, that will be replaced by the matching rule."
89   :type 'string
90   :group 'auto-insert)
91
92
93 (defcustom auto-insert-alist
94   '((("\\.\\([Hh]\\|hh\\|hpp\\|hxx\\|h\\+\\+\\)\\'" . "C / C++ header")
95      (replace-regexp-in-string
96       "[^A-Z0-9]" "_"
97       (replace-regexp-in-string
98        "\\+" "P"
99        (upcase (file-name-nondirectory buffer-file-name))))
100      "#ifndef " str \n
101      "#define " str "\n\n"
102      _ "\n\n#endif")
103
104     (("\\.\\([Cc]\\|cc\\|cpp\\|cxx\\|c\\+\\+\\)\\'" . "C / C++ program")
105      nil
106      "#include \""
107      (let ((stem (file-name-sans-extension buffer-file-name))
108            ret)
109        (dolist (ext '("H" "h" "hh" "hpp" "hxx" "h++") ret)
110          (when (file-exists-p (concat stem "." ext))
111            (setq ret (file-name-nondirectory (concat stem "." ext))))))
112      & ?\" | -10)
113
114     (("[Mm]akefile\\'" . "Makefile") . "makefile.inc")
115
116     (html-mode . (lambda () (sgml-tag "html")))
117
118     (plain-tex-mode . "tex-insert.tex")
119     (bibtex-mode . "tex-insert.tex")
120     (latex-mode
121      ;; should try to offer completing read for these
122      "options, RET: "
123      "\\documentclass[" str & ?\] | -1
124      ?{ (read-string "class: ") "}\n"
125      ("package, %s: "
126       "\\usepackage[" (read-string "options, RET: ") & ?\] | -1 ?{ str "}\n")
127      _ "\n\\begin{document}\n" _
128      "\n\\end{document}")
129
130     (("/bin/.*[^/]\\'" . "Shell-Script mode magic number") .
131      (lambda ()
132        (if (eq major-mode (default-value 'major-mode))
133            (sh-mode))))
134
135     (ada-mode . ada-header)
136
137     (("\\.[1-9]\\'" . "Man page skeleton")
138      "Short description: "
139      ".\\\" Copyright (C), " (format-time-string "%Y") "  "
140      (getenv "ORGANIZATION") | (progn user-full-name)
141      "
142 .\\\" You may distribute this file under the terms of the GNU Free
143 .\\\" Documentation License.
144 .TH " (file-name-base)
145      " " (file-name-extension (buffer-file-name))
146      " " (format-time-string "%Y-%m-%d ")
147      "\n.SH NAME\n"
148      (file-name-base)
149      " \\- " str
150      "\n.SH SYNOPSIS
151 .B " (file-name-base)
152      "\n"
153      _
154      "
155 .SH DESCRIPTION
156 .SH OPTIONS
157 .SH FILES
158 .SH \"SEE ALSO\"
159 .SH BUGS
160 .SH AUTHOR
161 " (user-full-name)
162      '(if (search-backward "&" (line-beginning-position) t)
163           (replace-match (capitalize (user-login-name)) t t))
164      '(end-of-line 1) " <" (progn user-mail-address) ">\n")
165
166     (("\\.el\\'" . "Emacs Lisp header")
167      "Short description: "
168      ";;; " (file-name-nondirectory (buffer-file-name)) " --- " str
169      (make-string (max 2 (- 80 (current-column) 27)) ?\s)
170      "-*- lexical-binding: t; -*-" '(setq lexical-binding t)
171      "
172
173 ;; Copyright (C) " (format-time-string "%Y") "  "
174  (getenv "ORGANIZATION") | (progn user-full-name) "
175
176 ;; Author: " (user-full-name)
177 '(if (search-backward "&" (line-beginning-position) t)
178      (replace-match (capitalize (user-login-name)) t t))
179 '(end-of-line 1) " <" (progn user-mail-address) ">
180 ;; Keywords: "
181  '(require 'finder)
182  ;;'(setq v1 (apply 'vector (mapcar 'car finder-known-keywords)))
183  '(setq v1 (mapcar (lambda (x) (list (symbol-name (car x))))
184                    finder-known-keywords)
185         v2 (mapconcat (lambda (x) (format "%12s:  %s" (car x) (cdr x)))
186            finder-known-keywords
187            "\n"))
188  ((let ((minibuffer-help-form v2))
189     (completing-read "Keyword, C-h: " v1 nil t))
190     str ", ") & -2 "
191
192 \;; This program is free software; you can redistribute it and/or modify
193 \;; it under the terms of the GNU General Public License as published by
194 \;; the Free Software Foundation, either version 3 of the License, or
195 \;; (at your option) any later version.
196
197 \;; This program is distributed in the hope that it will be useful,
198 \;; but WITHOUT ANY WARRANTY; without even the implied warranty of
199 \;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
200 \;; GNU General Public License for more details.
201
202 \;; You should have received a copy of the GNU General Public License
203 \;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
204
205 \;;; Commentary:
206
207 \;; " _ "
208
209 \;;; Code:
210
211
212
213 \(provide '"
214        (file-name-base)
215        ")
216 \;;; " (file-name-nondirectory (buffer-file-name)) " ends here\n")
217     (("\\.texi\\(nfo\\)?\\'" . "Texinfo file skeleton")
218      "Title: "
219      "\\input texinfo   @c -*-texinfo-*-
220 @c %**start of header
221 @setfilename "
222      (file-name-base) ".info\n"
223       "@settitle " str "
224 @c %**end of header
225 @copying\n"
226       (setq short-description (read-string "Short description: "))
227       ".\n\n"
228       "Copyright @copyright{} " (format-time-string "%Y") "  "
229       (getenv "ORGANIZATION") | (progn user-full-name) "
230
231 @quotation
232 Permission is granted to copy, distribute and/or modify this document
233 under the terms of the GNU Free Documentation License, Version 1.3
234 or any later version published by the Free Software Foundation;
235 with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts.
236 A copy of the license is included in the section entitled ``GNU
237 Free Documentation License''.
238
239 A copy of the license is also available from the Free Software
240 Foundation Web site at @url{http://www.gnu.org/licenses/fdl.html}.
241
242 @end quotation
243
244 The document was typeset with
245 @uref{http://www.texinfo.org/, GNU Texinfo}.
246
247 @end copying
248
249 @titlepage
250 @title " str "
251 @subtitle " short-description "
252 @author " (getenv "ORGANIZATION") | (progn user-full-name)
253      " <" (progn user-mail-address) ">
254 @page
255 @vskip 0pt plus 1filll
256 @insertcopying
257 @end titlepage
258
259 @c Output the table of the contents at the beginning.
260 @contents
261
262 @ifnottex
263 @node Top
264 @top " str "
265
266 @insertcopying
267 @end ifnottex
268
269 @c Generate the nodes for this menu with `C-c C-u C-m'.
270 @menu
271 @end menu
272
273 @c Update all node entries with `C-c C-u C-n'.
274 @c Insert new nodes with `C-c C-c n'.
275 @node Chapter One
276 @chapter Chapter One
277
278 " _ "
279
280 @node Copying This Manual
281 @appendix Copying This Manual
282
283 @menu
284 * GNU Free Documentation License::  License for copying this manual.
285 @end menu
286
287 @c Get fdl.texi from http://www.gnu.org/licenses/fdl.html
288 @include fdl.texi
289
290 @node Index
291 @unnumbered Index
292
293 @printindex cp
294
295 @bye
296
297 @c " (file-name-nondirectory (buffer-file-name)) " ends here\n"))
298   "A list specifying text to insert by default into a new file.
299 Elements look like (CONDITION . ACTION) or ((CONDITION . DESCRIPTION) . ACTION).
300 CONDITION may be a regexp that must match the new file's name, or it may be
301 a symbol that must match the major mode for this element to apply.
302 Only the first matching element is effective.
303 Optional DESCRIPTION is a string for filling `auto-insert-prompt'.
304 ACTION may be a skeleton to insert (see `skeleton-insert'), an absolute
305 file-name or one relative to `auto-insert-directory' or a function to call.
306 ACTION may also be a vector containing several successive single actions as
307 described above, e.g. [\"header.insert\" date-and-author-update]."
308   :type 'sexp
309   :version "25.1"
310   :group 'auto-insert)
311
312
313 ;; Establish a default value for auto-insert-directory
314 (defcustom auto-insert-directory "~/insert/"
315   "Directory from which auto-inserted files are taken.
316 The value must be an absolute directory name;
317 thus, on a GNU or Unix system, it must end in a slash."
318   :type 'directory
319   :group 'auto-insert)
320
321
322 ;;;###autoload
323 (defun auto-insert ()
324   "Insert default contents into new files if variable `auto-insert' is non-nil.
325 Matches the visited file name against the elements of `auto-insert-alist'."
326   (interactive)
327   (and (not buffer-read-only)
328        (or (eq this-command 'auto-insert)
329            (and auto-insert
330                 (bobp) (eobp)))
331        (let ((alist auto-insert-alist)
332              case-fold-search cond desc action)
333          (goto-char 1)
334          ;; find first matching alist entry
335          (while alist
336            (if (atom (setq cond (car (car alist))))
337                (setq desc cond)
338              (setq desc (cdr cond)
339                    cond (car cond)))
340            (if (if (symbolp cond)
341                    (eq cond major-mode)
342                  (and buffer-file-name
343                       (string-match cond buffer-file-name)))
344                (setq action (cdr (car alist))
345                      alist nil)
346              (setq alist (cdr alist))))
347
348          ;; Now, if we found something, do it
349          (and action
350               (or (not (stringp action))
351                   (file-readable-p (expand-file-name
352                                     action auto-insert-directory)))
353               (or (not auto-insert-query)
354                   (if (eq auto-insert-query 'function)
355                       (eq this-command 'auto-insert))
356                   (y-or-n-p (format auto-insert-prompt desc)))
357               (mapc
358                (lambda (action)
359                  (if (stringp action)
360                      (if (file-readable-p
361                           (setq action (expand-file-name
362                                         action auto-insert-directory)))
363                          (insert-file-contents action))
364                    (save-window-excursion
365                      ;; make buffer visible before skeleton or function
366                      ;; which might ask the user for something
367                      (switch-to-buffer (current-buffer))
368                      (if (and (consp action)
369                               (not (eq (car action) 'lambda)))
370                          (skeleton-insert action)
371                        (funcall action)))))
372                (if (vectorp action)
373                    action
374                  (vector action))))
375          (and (buffer-modified-p)
376               (not (eq this-command 'auto-insert))
377               (set-buffer-modified-p (eq auto-insert t)))))
378   ;; Return nil so that it could be used in
379   ;; `find-file-not-found-hooks', though that's probably inadvisable.
380   nil)
381
382
383 ;;;###autoload
384 (defun define-auto-insert (condition action &optional after)
385   "Associate CONDITION with (additional) ACTION in `auto-insert-alist'.
386 Optional AFTER means to insert action after all existing actions for CONDITION,
387 or if CONDITION had no actions, after all other CONDITIONs."
388   (let ((elt (assoc condition auto-insert-alist)))
389     (if elt
390         (setcdr elt
391                 (if (vectorp (cdr elt))
392                     (vconcat (if after (cdr elt))
393                              (if (vectorp action) action (vector action))
394                              (if after () (cdr elt)))
395                   (if after
396                       (vector (cdr elt) action)
397                     (vector action (cdr elt)))))
398       (if after
399           (nconc auto-insert-alist (list (cons condition action)))
400         (push (cons condition action) auto-insert-alist)))))
401
402 ;;;###autoload
403 (define-minor-mode auto-insert-mode
404   "Toggle Auto-insert mode, a global minor mode.
405 With a prefix argument ARG, enable Auto-insert mode if ARG is
406 positive, and disable it otherwise.  If called from Lisp, enable
407 the mode if ARG is omitted or nil.
408
409 When Auto-insert mode is enabled, when new files are created you can
410 insert a template for the file depending on the mode of the buffer."
411   :global t :group 'auto-insert
412   (if auto-insert-mode
413       (add-hook 'find-file-hook 'auto-insert)
414     (remove-hook 'find-file-hook 'auto-insert)))
415
416 (provide 'autoinsert)
417
418 ;;; autoinsert.el ends here