lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   7 ;; Keywords: xml, data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  27 ;; parses a file, and returns a list that can be used internally by
  28 ;; any other Lisp libraries.
  29
  30 ;;; FILE FORMAT
  31
  32 ;; The document type declaration may either be ignored or (optionally)
  33 ;; parsed, but currently the parsing will only accept element
  34 ;; declarations.  The XML file is assumed to be well-formed.  In case
  35 ;; of error, the parsing stops and the XML file is shown where the
  36 ;; parsing stopped.
  37 ;;
  38 ;; It also knows how to ignore comments and processing instructions.
  39 ;;
  40 ;; The XML file should have the following format:
  41 ;;    <node1 attr1="name1" attr2="name2" ...>value
  42 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  43 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  44 ;;    </node1>
  45 ;; Of course, the name of the nodes and attributes can be anything.  There can
  46 ;; be any number of attributes (or none), as well as any number of children
  47 ;; below the nodes.
  48 ;;
  49 ;; There can be only top level node, but with any number of children below.
  50
  51 ;;; LIST FORMAT
  52
  53 ;; The functions `xml-parse-file', `xml-parse-region' and
  54 ;; `xml-parse-tag' return a list with the following format:
  55 ;;
  56 ;;    xml-list   ::= (node node ...)
  57 ;;    node       ::= (qname attribute-list . child_node_list)
  58 ;;    child_node_list ::= child_node child_node ...
  59 ;;    child_node ::= node | string
  60 ;;    qname      ::= (:namespace-uri . "name") | "name"
  61 ;;    attribute_list ::= ((qname . "value") (qname . "value") ...)
  62 ;;                       | nil
  63 ;;    string     ::= "..."
  64 ;;
  65 ;; Some macros are provided to ease the parsing of this list.
  66 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  67 ;; can remove it.
  68
  69 ;; TODO:
  70 ;;  * xml:base, xml:space support
  71 ;;  * more complete DOCTYPE parsing
  72 ;;  * pi support
  73
  74 ;;; Code:
  75
  76 ;; Note that buffer-substring and match-string were formerly used in
  77 ;; several places, because the -no-properties variants remove
  78 ;; composition info.  However, after some discussion on emacs-devel,
  79 ;; the consensus was that the speed of the -no-properties variants was
  80 ;; a worthwhile tradeoff especially since we're usually parsing files
  81 ;; instead of hand-crafted XML.
  82
  83 ;;*******************************************************************
  84 ;;**
  85 ;;**  Macros to parse the list
  86 ;;**
  87 ;;*******************************************************************
  88
  89 (defconst xml-undefined-entity "?"
  90   "What to substitute for undefined entities")
  91
  92 (defvar xml-entity-alist
  93   '(("lt"   . "<")
  94     ("gt"   . ">")
  95     ("apos" . "'")
  96     ("quot" . "\"")
  97     ("amp"  . "&"))
  98   "The defined entities.  Entities are added to this when the DTD is parsed.")
  99
 100 (defvar xml-sub-parser nil
 101   "Dynamically set this to a non-nil value if you want to parse an XML fragment.")
 102
 103 (defvar xml-validating-parser nil
 104   "Set to non-nil to get validity checking.")
 105
 106 (defsubst xml-node-name (node)
 107   "Return the tag associated with NODE.
 108 Without namespace-aware parsing, the tag is a symbol.
 109
 110 With namespace-aware parsing, the tag is a cons of a string
 111 representing the uri of the namespace with the local name of the
 112 tag.  For example,
 113
 114     <foo>
 115
 116 would be represented by
 117
 118     '(\"\" . \"foo\")."
 119
 120   (car node))
 121
 122 (defsubst xml-node-attributes (node)
 123   "Return the list of attributes of NODE.
 124 The list can be nil."
 125   (nth 1 node))
 126
 127 (defsubst xml-node-children (node)
 128   "Return the list of children of NODE.
 129 This is a list of nodes, and it can be nil."
 130   (cddr node))
 131
 132 (defun xml-get-children (node child-name)
 133   "Return the children of NODE whose tag is CHILD-NAME.
 134 CHILD-NAME should match the value returned by `xml-node-name'."
 135   (let ((match ()))
 136     (dolist (child (xml-node-children node))
 137       (if (and (listp child)
 138                (equal (xml-node-name child) child-name))
 139           (push child match)))
 140     (nreverse match)))
 141
 142 (defun xml-get-attribute-or-nil (node attribute)
 143   "Get from NODE the value of ATTRIBUTE.
 144 Return nil if the attribute was not found.
 145
 146 See also `xml-get-attribute'."
 147   (cdr (assoc attribute (xml-node-attributes node))))
 148
 149 (defsubst xml-get-attribute (node attribute)
 150   "Get from NODE the value of ATTRIBUTE.
 151 An empty string is returned if the attribute was not found.
 152
 153 See also `xml-get-attribute-or-nil'."
 154   (or (xml-get-attribute-or-nil node attribute) ""))
 155
 156 ;;*******************************************************************
 157 ;;**
 158 ;;**  Creating the list
 159 ;;**
 160 ;;*******************************************************************
 161
 162 ;;;###autoload
 163 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 164   "Parse the well-formed XML file FILE.
 165 If FILE is already visited, use its buffer and don't kill it.
 166 Returns the top node with all its children.
 167 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 168 If PARSE-NS is non-nil, then QNAMES are expanded."
 169   (if (get-file-buffer file)
 170       (with-current-buffer (get-file-buffer file)
 171         (save-excursion
 172           (xml-parse-region (point-min)
 173                             (point-max)
 174                             (current-buffer)
 175                             parse-dtd parse-ns)))
 176     (with-temp-buffer
 177       (insert-file-contents file)
 178       (xml-parse-region (point-min)
 179                         (point-max)
 180                         (current-buffer)
 181                         parse-dtd parse-ns))))
 182
 183
 184 (defvar xml-name-re)
 185 (defvar xml-entity-value-re)
 186 (defvar xml-att-def-re)
 187 (let* ((start-chars (concat "[:alpha:]:_"))
 188        (name-chars  (concat "-[:digit:]." start-chars))
 189        ;;[3]    S          ::=          (#x20 | #x9 | #xD | #xA)+
 190        (whitespace  "[ \t\n\r]"))
 191   ;;[4] NameStartChar ::= ":" | [A-Z] | "_" | [a-z] | [#xC0-#xD6]
 192   ;;                      | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF]
 193   ;;                      | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF]
 194   ;;                      | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]
 195   (defvar xml-name-start-char-re (concat "[" start-chars "]"))
 196   ;;[4a] NameChar       ::= NameStartChar | "-" | "." | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]
 197   (defvar xml-name-char-re       (concat "[" name-chars  "]"))
 198   ;;[5] Name     ::= NameStartChar (NameChar)*
 199   (defvar xml-name-re            (concat xml-name-start-char-re xml-name-char-re "*"))
 200   ;;[6] Names    ::= Name (#x20 Name)*
 201   (defvar xml-names-re           (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
 202   ;;[7] Nmtoken ::= (NameChar)+
 203   (defvar xml-nmtoken-re         (concat xml-name-char-re "+"))
 204   ;;[8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
 205   (defvar xml-nmtokens-re        (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
 206   ;;[66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
 207   (defvar xml-char-ref-re        "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
 208   ;;[68] EntityRef   ::= '&' Name ';'
 209   (defvar xml-entity-ref         (concat "&" xml-name-re ";"))
 210   ;;[69] PEReference ::= '%' Name ';'
 211   (defvar xml-pe-reference-re    (concat "%" xml-name-re ";"))
 212   ;;[67] Reference   ::= EntityRef | CharRef
 213   (defvar xml-reference-re       (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
 214   ;;[10]        AttValue           ::=          '"' ([^<&"] | Reference)* '"' |  "'" ([^<&'] | Reference)* "'"
 215   (defvar xml-att-value-re    (concat "\\(?:\"\\(?:[^&\"]\\|" xml-reference-re "\\)*\"\\|"
 216                                       "'\\(?:[^&']\\|" xml-reference-re "\\)*'\\)"))
 217   ;;[56]        TokenizedType      ::=          'ID'       [VC: ID] [VC: One ID per Element Type] [VC: ID Attribute Default]
 218   ;;                                            | 'IDREF'    [VC: IDREF]
 219   ;;                                                  | 'IDREFS'   [VC: IDREF]
 220   ;;                                            | 'ENTITY'   [VC: Entity Name]
 221   ;;                                            | 'ENTITIES' [VC: Entity Name]
 222   ;;                                            | 'NMTOKEN'  [VC: Name Token]
 223   ;;                                            | 'NMTOKENS' [VC: Name Token]
 224   (defvar xml-tokenized-type-re "\\(?:ID\\|IDREF\\|IDREFS\\|ENTITY\\|ENTITIES\\|NMTOKEN\\|NMTOKENS\\)")
 225   ;;[58]        NotationType       ::=          'NOTATION' S '(' S? Name (S? '|' S? Name)* S? ')'
 226   (defvar xml-notation-type-re (concat "\\(?:NOTATION" whitespace "(" whitespace "*" xml-name-re
 227                                        "\\(?:" whitespace "*|" whitespace "*" xml-name-re "\\)*" whitespace "*)\\)"))
 228   ;;[59]        Enumeration        ::=          '(' S? Nmtoken (S? '|' S? Nmtoken)* S? ')'      [VC: Enumeration] [VC: No Duplicate Tokens]
 229   (defvar xml-enumeration-re (concat "\\(?:(" whitespace "*" xml-nmtoken-re
 230                                      "\\(?:" whitespace "*|" whitespace "*" xml-nmtoken-re "\\)*"
 231                                      whitespace ")\\)"))
 232   ;;[57]        EnumeratedType     ::=          NotationType | Enumeration
 233   (defvar xml-enumerated-type-re (concat "\\(?:" xml-notation-type-re "\\|" xml-enumeration-re "\\)"))
 234   ;;[54]        AttType    ::=          StringType | TokenizedType | EnumeratedType
 235   ;;[55]        StringType         ::=          'CDATA'
 236   (defvar xml-att-type-re (concat "\\(?:CDATA\\|" xml-tokenized-type-re "\\|" xml-notation-type-re"\\|" xml-enumerated-type-re "\\)"))
 237   ;;[60]        DefaultDecl        ::=          '#REQUIRED' | '#IMPLIED' | (('#FIXED' S)? AttValue)
 238   (defvar xml-default-decl-re (concat "\\(?:#REQUIRED\\|#IMPLIED\\|\\(?:#FIXED" whitespace "\\)*" xml-att-value-re "\\)"))
 239   ;;[53]        AttDef     ::=          S Name S AttType S DefaultDecl
 240   (defvar xml-att-def-re         (concat "\\(?:" whitespace "*" xml-name-re
 241                                          whitespace "*" xml-att-type-re
 242                                          whitespace "*" xml-default-decl-re "\\)"))
 243   ;;[9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
 244   ;;               |  "'" ([^%&'] | PEReference | Reference)* "'"
 245   (defvar xml-entity-value-re    (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
 246                                          "\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
 247                                          xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
 248 ;;[75] ExternalID ::= 'SYSTEM' S SystemLiteral
 249 ;;                 | 'PUBLIC' S PubidLiteral S SystemLiteral
 250 ;;[76] NDataDecl ::=    S 'NDATA' S
 251 ;;[73] EntityDef  ::= EntityValue| (ExternalID NDataDecl?)
 252 ;;[71] GEDecl     ::= '<!ENTITY' S Name S EntityDef S? '>'
 253 ;;[74] PEDef      ::= EntityValue | ExternalID
 254 ;;[72] PEDecl     ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
 255 ;;[70] EntityDecl ::= GEDecl | PEDecl
 256
 257 ;; Note that this is setup so that we can do whitespace-skipping with
 258 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 259 ;; compared with `re-search-forward', but that has been fixed.  Also
 260 ;; note that the standard syntax table contains other characters with
 261 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 262 ;; which we might skip whitespace -- specifically, they're not
 263 ;; NameChars [XML 4].
 264
 265 (defvar xml-syntax-table
 266   (let ((table (make-syntax-table)))
 267     ;; Get space syntax correct per XML [3].
 268     (dotimes (c 31)
 269       (modify-syntax-entry c "." table)) ; all are space in standard table
 270     (dolist (c '(?\t ?\n ?\r))           ; these should be space
 271       (modify-syntax-entry c " " table))
 272     ;; For skipping attributes.
 273     (modify-syntax-entry ?\" "\"" table)
 274     (modify-syntax-entry ?' "\"" table)
 275     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 276     ;; are OK by default).
 277     (modify-syntax-entry ?. "_" table)
 278     (modify-syntax-entry ?: "_" table)
 279     ;; XML [89]
 280     (unless (featurep 'xemacs)
 281       (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 282                           #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 283                           #x30FD #x30FE))
 284         (modify-syntax-entry (decode-char 'ucs c) "w" table)))
 285     ;; Fixme: rest of [4]
 286     table)
 287   "Syntax table used by `xml-parse-region'.")
 288
 289 ;; XML [5]
 290 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 291 (eval-and-compile
 292   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 293
 294 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 295 ;;   document    ::=    prolog element Misc*
 296 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 297
 298 ;;;###autoload
 299 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 300   "Parse the region from BEG to END in BUFFER.
 301 If BUFFER is nil, it defaults to the current buffer.
 302 Returns the XML list for the region, or raises an error if the region
 303 is not well-formed XML.
 304 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 305 and returned as the first element of the list.
 306 If PARSE-NS is non-nil, then QNAMES are expanded."
 307   ;; Use fixed syntax table to ensure regexp char classes and syntax
 308   ;; specs DTRT.
 309   (with-syntax-table (standard-syntax-table)
 310     (let ((case-fold-search nil)        ; XML is case-sensitive.
 311           xml result dtd)
 312       (save-excursion
 313         (if buffer
 314             (set-buffer buffer))
 315         (save-restriction
 316           (narrow-to-region beg end)
 317           (goto-char (point-min))
 318           (while (not (eobp))
 319             (if (search-forward "<" nil t)
 320                 (progn
 321                   (forward-char -1)
 322                   (setq result (xml-parse-tag parse-dtd parse-ns))
 323                   (cond
 324                    ((null result)
 325                     ;; Not looking at an xml start tag.
 326                     (unless (eobp)
 327                       (forward-char 1)))
 328                    ((and xml (not xml-sub-parser))
 329                     ;; Translation of rule [1] of XML specifications
 330                     (error "XML: (Not Well-Formed) Only one root tag allowed"))
 331                    ((and (listp (car result))
 332                          parse-dtd)
 333                     (setq dtd (car result))
 334                     (if (cdr result)    ; possible leading comment
 335                         (add-to-list 'xml (cdr result))))
 336                    (t
 337                     (add-to-list 'xml result))))
 338               (goto-char (point-max))))
 339           (if parse-dtd
 340               (cons dtd (nreverse xml))
 341             (nreverse xml)))))))
 342
 343 (defun xml-maybe-do-ns (name default xml-ns)
 344   "Perform any namespace expansion.
 345 NAME is the name to perform the expansion on.
 346 DEFAULT is the default namespace.  XML-NS is a cons of namespace
 347 names to uris.  When namespace-aware parsing is off, then XML-NS
 348 is nil.
 349
 350 During namespace-aware parsing, any name without a namespace is
 351 put into the namespace identified by DEFAULT.  nil is used to
 352 specify that the name shouldn't be given a namespace."
 353   (if (consp xml-ns)
 354       (let* ((nsp (string-match ":" name))
 355              (lname (if nsp (substring name (match-end 0)) name))
 356              (prefix (if nsp (substring name 0 (match-beginning 0)) default))
 357              (special (and (string-equal lname "xmlns") (not prefix)))
 358              ;; Setting default to nil will insure that there is not
 359              ;; matching cons in xml-ns.  In which case we
 360              (ns (or (cdr (assoc (if special "xmlns" prefix)
 361                                  xml-ns))
 362                      "")))
 363         (cons ns (if special "" lname)))
 364     (intern name)))
 365
 366 (defun xml-parse-fragment (&optional parse-dtd parse-ns)
 367   "Parse xml-like fragments."
 368   (let ((xml-sub-parser t)
 369         children)
 370     (while (not (eobp))
 371       (let ((bit (xml-parse-tag
 372                   parse-dtd parse-ns)))
 373         (if children
 374             (setq children (append (list bit) children))
 375           (if (stringp bit)
 376               (setq children (list bit))
 377             (setq children bit)))))
 378     (reverse children)))
 379
 380 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 381   "Parse the tag at point.
 382 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 383 returned as the first element in the list.
 384 If PARSE-NS is non-nil, then QNAMES are expanded.
 385 Returns one of:
 386  - a list : the matching node
 387  - nil    : the point is not looking at a tag.
 388  - a pair : the first element is the DTD, the second is the node."
 389   (let ((xml-validating-parser (or parse-dtd xml-validating-parser))
 390         (xml-ns (if (consp parse-ns)
 391                     parse-ns
 392                   (if parse-ns
 393                       (list
 394                        ;; Default for empty prefix is no namespace
 395                        (cons ""      "")
 396                        ;; "xml" namespace
 397                        (cons "xml"   "http://www.w3.org/XML/1998/namespace")
 398                        ;; We need to seed the xmlns namespace
 399                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 400     (cond
 401      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 402      ;; beginning of a document).
 403      ((looking-at "<\\?")
 404       (search-forward "?>")
 405       (skip-syntax-forward " ")
 406       (xml-parse-tag parse-dtd xml-ns))
 407      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 408      ((looking-at "<!\\[CDATA\\[")
 409       (let ((pos (match-end 0)))
 410         (unless (search-forward "]]>" nil t)
 411           (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
 412         (concat
 413          (buffer-substring-no-properties pos (match-beginning 0))
 414          (xml-parse-string))))
 415      ;;  DTD for the document
 416      ((looking-at "<!DOCTYPE")
 417       (let ((dtd (xml-parse-dtd parse-ns)))
 418         (skip-syntax-forward " ")
 419         (if xml-validating-parser
 420             (cons dtd (xml-parse-tag nil xml-ns))
 421           (xml-parse-tag nil xml-ns))))
 422      ;;  skip comments
 423      ((looking-at "<!--")
 424       (search-forward "-->")
 425       (skip-syntax-forward " ")
 426       (unless (eobp)
 427         (xml-parse-tag parse-dtd xml-ns)))
 428      ;;  end tag
 429      ((looking-at "</")
 430       '())
 431      ;;  opening tag
 432      ((looking-at "<\\([^/>[:space:]]+\\)")
 433       (goto-char (match-end 1))
 434
 435       ;; Parse this node
 436       (let* ((node-name (match-string-no-properties 1))
 437              ;; Parse the attribute list.
 438              (attrs (xml-parse-attlist xml-ns))
 439              children)
 440
 441         ;; add the xmlns:* attrs to our cache
 442         (when (consp xml-ns)
 443           (dolist (attr attrs)
 444             (when (and (consp (car attr))
 445                        (equal "http://www.w3.org/2000/xmlns/"
 446                               (caar attr)))
 447               (push (cons (cdar attr) (cdr attr))
 448                     xml-ns))))
 449
 450         (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
 451
 452         ;; is this an empty element ?
 453         (if (looking-at "/>")
 454             (progn
 455               (forward-char 2)
 456               (nreverse children))
 457
 458           ;; is this a valid start tag ?
 459           (if (eq (char-after) ?>)
 460               (progn
 461                 (forward-char 1)
 462                 ;;  Now check that we have the right end-tag. Note that this
 463                 ;;  one might contain spaces after the tag name
 464                 (let ((end (concat "</" node-name "\\s-*>")))
 465                   (while (not (looking-at end))
 466                     (cond
 467                      ((looking-at "</")
 468                       (error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
 469                              node-name (point)))
 470                      ((= (char-after) ?<)
 471                       (let ((tag (xml-parse-tag nil xml-ns)))
 472                         (when tag
 473                           (push tag children))))
 474                      (t
 475                       (let ((expansion (xml-parse-string)))
 476                         (setq children
 477                               (if (stringp expansion)
 478                                   (if (stringp (car children))
 479                                       ;; The two strings were separated by a comment.
 480                                       (setq children (append (list (concat (car children) expansion))
 481                                                              (cdr children)))
 482                                     (setq children (append (list expansion) children)))
 483                                 (setq children (append expansion children))))))))
 484
 485                   (goto-char (match-end 0))
 486                   (nreverse children)))
 487             ;;  This was an invalid start tag (Expected ">", but didn't see it.)
 488             (error "XML: (Well-Formed) Couldn't parse tag: %s"
 489                    (buffer-substring-no-properties (- (point) 10) (+ (point) 1)))))))
 490      (t ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
 491       (unless xml-sub-parser            ; Usually, we error out.
 492         (error "XML: (Well-Formed) Invalid character"))
 493
 494       ;; However, if we're parsing incrementally, then we need to deal
 495       ;; with stray CDATA.
 496       (xml-parse-string)))))
 497
 498 (defun xml-parse-string ()
 499   "Parse the next whatever.  Could be a string, or an element."
 500   (let* ((pos (point))
 501          (string (progn (skip-chars-forward "^<")
 502                         (buffer-substring-no-properties pos (point)))))
 503     ;; Clean up the string.  As per XML specifications, the XML
 504     ;; processor should always pass the whole string to the
 505     ;; application.  But \r's should be replaced:
 506     ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 507     (setq pos 0)
 508     (while (string-match "\r\n?" string pos)
 509       (setq string (replace-match "\n" t t string))
 510       (setq pos (1+ (match-beginning 0))))
 511
 512     (xml-substitute-special string)))
 513
 514 (defun xml-parse-attlist (&optional xml-ns)
 515   "Return the attribute-list after point.
 516 Leave point at the first non-blank character after the tag."
 517   (let ((attlist ())
 518         end-pos name)
 519     (skip-syntax-forward " ")
 520     (while (looking-at (eval-when-compile
 521                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 522       (setq end-pos (match-end 0))
 523       (setq name (xml-maybe-do-ns (match-string-no-properties 1) nil xml-ns))
 524       (goto-char end-pos)
 525
 526       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 527
 528       ;; Do we have a string between quotes (or double-quotes),
 529       ;;  or a simple word ?
 530       (if (looking-at "\"\\([^\"]*\\)\"")
 531           (setq end-pos (match-end 0))
 532         (if (looking-at "'\\([^']*\\)'")
 533             (setq end-pos (match-end 0))
 534           (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
 535
 536       ;; Each attribute must be unique within a given element
 537       (if (assoc name attlist)
 538           (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
 539
 540       ;; Multiple whitespace characters should be replaced with a single one
 541       ;; in the attributes
 542       (let ((string (match-string-no-properties 1)))
 543         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 544         (let ((expansion (xml-substitute-special string)))
 545           (unless (stringp expansion)
 546                                         ; We say this is the constraint.  It is actually that neither
 547                                         ; external entities nor "<" can be in an attribute value.
 548             (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
 549           (push (cons name expansion) attlist)))
 550
 551       (goto-char end-pos)
 552       (skip-syntax-forward " "))
 553     (nreverse attlist)))
 554
 555 ;;*******************************************************************
 556 ;;**
 557 ;;**  The DTD (document type declaration)
 558 ;;**  The following functions know how to skip or parse the DTD of
 559 ;;**  a document
 560 ;;**
 561 ;;*******************************************************************
 562
 563 ;; Fixme: This fails at least if the DTD contains conditional sections.
 564
 565 (defun xml-skip-dtd ()
 566   "Skip the DTD at point.
 567 This follows the rule [28] in the XML specifications."
 568   (let ((xml-validating-parser nil))
 569     (xml-parse-dtd)))
 570
 571 (defun xml-parse-dtd (&optional parse-ns)
 572   "Parse the DTD at point."
 573   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 574   (skip-syntax-forward " ")
 575   (if (and (looking-at ">")
 576            xml-validating-parser)
 577       (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
 578
 579   ;;  Get the name of the document
 580   (looking-at xml-name-regexp)
 581   (let ((dtd (list (match-string-no-properties 0) 'dtd))
 582         type element end-pos)
 583     (goto-char (match-end 0))
 584
 585     (skip-syntax-forward " ")
 586     ;; XML [75]
 587     (cond ((looking-at "PUBLIC\\s-+")
 588            (goto-char (match-end 0))
 589            (unless (or (re-search-forward
 590                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 591                         nil t)
 592                        (re-search-forward
 593                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 594                         nil t))
 595              (error "XML: Missing Public ID"))
 596            (let ((pubid (match-string-no-properties 1)))
 597              (skip-syntax-forward " ")
 598              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 599                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 600                (error "XML: Missing System ID"))
 601              (push (list pubid (match-string-no-properties 1) 'public) dtd)))
 602           ((looking-at "SYSTEM\\s-+")
 603            (goto-char (match-end 0))
 604            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 605                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 606              (error "XML: Missing System ID"))
 607            (push (list (match-string-no-properties 1) 'system) dtd)))
 608     (skip-syntax-forward " ")
 609     (if (eq ?> (char-after))
 610         (forward-char)
 611       (if (not (eq (char-after) ?\[))
 612           (error "XML: Bad DTD")
 613         (forward-char)
 614         ;;  Parse the rest of the DTD
 615         ;;  Fixme: Deal with NOTATION, PIs.
 616         (while (not (looking-at "\\s-*\\]"))
 617           (skip-syntax-forward " ")
 618           (cond
 619
 620            ;;  Translation of rule [45] of XML specifications
 621            ((looking-at
 622              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 623
 624             (setq element (match-string-no-properties 1)
 625                   type    (match-string-no-properties 2))
 626             (setq end-pos (match-end 0))
 627
 628             ;;  Translation of rule [46] of XML specifications
 629             (cond
 630              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 631               (setq type 'empty))
 632              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 633               (setq type 'any))
 634              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 635               (setq type (xml-parse-elem-type (match-string-no-properties 1 type))))
 636              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 637               nil)
 638              (t
 639               (if xml-validating-parser
 640                   (error "XML: (Validity) Invalid element type in the DTD"))))
 641
 642             ;;  rule [45]: the element declaration must be unique
 643             (if (and (assoc element dtd)
 644                      xml-validating-parser)
 645                 (error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
 646                        element))
 647
 648             ;;  Store the element in the DTD
 649             (push (list element type) dtd)
 650             (goto-char end-pos))
 651
 652            ;; Translation of rule [52] of XML specifications
 653            ((looking-at (concat "<!ATTLIST[ \t\n\r]*\\(" xml-name-re
 654                                 "\\)[ \t\n\r]*\\(" xml-att-def-re
 655                                 "\\)*[ \t\n\r]*>"))
 656
 657             ;; We don't do anything with ATTLIST currently
 658             (goto-char (match-end 0)))
 659
 660            ((looking-at "<!--")
 661             (search-forward "-->"))
 662            ((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
 663                                 "\\)[ \t\n\r]*\\(" xml-entity-value-re
 664                                 "\\)[ \t\n\r]*>"))
 665             (let ((name  (match-string-no-properties 1))
 666                   (value (substring (match-string-no-properties 2) 1
 667                                     (- (length (match-string-no-properties 2)) 1))))
 668               (goto-char (match-end 0))
 669               (setq xml-entity-alist
 670                     (append xml-entity-alist
 671                             (list (cons name
 672                                         (with-temp-buffer
 673                                           (insert value)
 674                                           (goto-char (point-min))
 675                                           (xml-parse-fragment
 676                                            xml-validating-parser
 677                                            parse-ns))))))))
 678            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 679                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 680                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 681                 (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 682                                     "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
 683                                     "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 684                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
 685                                     "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
 686                                     "[ \t\n\r]*>")))
 687             (let ((name  (match-string-no-properties 1))
 688                   (file  (substring (match-string-no-properties 2) 1
 689                                     (- (length (match-string-no-properties 2)) 1))))
 690               (goto-char (match-end 0))
 691               (setq xml-entity-alist
 692                     (append xml-entity-alist
 693                             (list (cons name (with-temp-buffer
 694                                                (insert-file-contents file)
 695                                                (goto-char (point-min))
 696                                                (xml-parse-fragment
 697                                                 xml-validating-parser
 698                                                 parse-ns))))))))
 699            ;; skip parameter entity declarations
 700            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+%[ \t\n\r]+\\(" xml-name-re
 701                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 702                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 703                 (looking-at (concat "<!ENTITY[ \t\n\r]+"
 704                                     "%[ \t\n\r]+"
 705                                     "\\(" xml-name-re "\\)[ \t\n\r]+"
 706                                     "PUBLIC[ \t\n\r]+"
 707                                     "\\(\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 708                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'\\)[ \t\n\r]+"
 709                                     "\\(\"[^\"]+\"\\|'[^']+'\\)"
 710                                     "[ \t\n\r]*>")))
 711             (goto-char (match-end 0)))
 712            ;; skip parameter entities
 713            ((looking-at (concat "%" xml-name-re ";"))
 714             (goto-char (match-end 0)))
 715            (t
 716             (when xml-validating-parser
 717               (error "XML: (Validity) Invalid DTD item"))))))
 718       (if (looking-at "\\s-*]>")
 719           (goto-char (match-end 0))))
 720     (nreverse dtd)))
 721
 722 (defun xml-parse-elem-type (string)
 723   "Convert element type STRING into a Lisp structure."
 724
 725   (let (elem modifier)
 726     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 727         (progn
 728           (setq elem     (match-string-no-properties 1 string)
 729                 modifier (match-string-no-properties 2 string))
 730           (if (string-match "|" elem)
 731               (setq elem (cons 'choice
 732                                (mapcar 'xml-parse-elem-type
 733                                        (split-string elem "|"))))
 734             (if (string-match "," elem)
 735                 (setq elem (cons 'seq
 736                                  (mapcar 'xml-parse-elem-type
 737                                          (split-string elem ",")))))))
 738       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 739           (setq elem     (match-string-no-properties 1 string)
 740                 modifier (match-string-no-properties 2 string))))
 741
 742     (if (and (stringp elem) (string= elem "#PCDATA"))
 743         (setq elem 'pcdata))
 744
 745     (cond
 746      ((string= modifier "+")
 747       (list '+ elem))
 748      ((string= modifier "*")
 749       (list '* elem))
 750      ((string= modifier "?")
 751       (list '\? elem))
 752      (t
 753       elem))))
 754
 755 ;;*******************************************************************
 756 ;;**
 757 ;;**  Substituting special XML sequences
 758 ;;**
 759 ;;*******************************************************************
 760
 761 (defun xml-substitute-special (string)
 762   "Return STRING, after substituting entity references."
 763   ;; This originally made repeated passes through the string from the
 764   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 765   ;; "&#38;amp;" won't DTRT.
 766
 767   (let ((point 0)
 768         children end-point)
 769     (while (string-match "&\\([^;]*\\);" string point)
 770       (setq end-point (match-end 0))
 771       (let* ((this-part (match-string-no-properties 1 string))
 772              (prev-part (substring string point (match-beginning 0)))
 773              (entity (assoc this-part xml-entity-alist))
 774              (expansion
 775               (cond ((string-match "#\\([0-9]+\\)" this-part)
 776                      (let ((c (decode-char
 777                                'ucs
 778                                (string-to-number (match-string-no-properties 1 this-part)))))
 779                        (if c (string c))))
 780                     ((string-match "#x\\([[:xdigit:]]+\\)" this-part)
 781                      (let ((c (decode-char
 782                                'ucs
 783                                (string-to-number (match-string-no-properties 1 this-part) 16))))
 784                        (if c (string c))))
 785                     (entity
 786                      (cdr entity))
 787                     ((eq (length this-part) 0)
 788                      (error "XML: (Not Well-Formed) No entity given"))
 789                     (t
 790                      (if xml-validating-parser
 791                          (error "XML: (Validity) Undefined entity `%s'"
 792                                 this-part)
 793                        xml-undefined-entity)))))
 794
 795         (cond ((null children)
 796                ;; FIXME: If we have an entity that expands into XML, this won't work.
 797                (setq children
 798                      (concat prev-part expansion)))
 799               ((stringp children)
 800                (if (stringp expansion)
 801                    (setq children (concat children prev-part expansion))
 802                  (setq children (list expansion (concat prev-part children)))))
 803               ((and (stringp expansion)
 804                     (stringp (car children)))
 805                (setcar children (concat prev-part expansion (car children))))
 806               ((stringp expansion)
 807                (setq children (append (concat prev-part expansion)
 808                                       children)))
 809               ((stringp (car children))
 810                (setcar children (concat (car children) prev-part))
 811                (setq children (append expansion children)))
 812               (t
 813                (setq children (list expansion
 814                                     prev-part
 815                                     children))))
 816         (setq point end-point)))
 817     (cond ((stringp children)
 818            (concat children (substring string point)))
 819           ((stringp (car (last children)))
 820            (concat (car (last children)) (substring string point)))
 821           ((null children)
 822            string)
 823           (t
 824            (concat (mapconcat 'identity
 825                               (nreverse children)
 826                               "")
 827                    (substring string point))))))
 828
 829 (defun xml-substitute-numeric-entities (string)
 830   "Substitute SGML numeric entities by their respective utf characters.
 831 This function replaces numeric entities in the input STRING and
 832 returns the modified string.  For example \"&#42;\" gets replaced
 833 by \"*\"."
 834   (if (and string (stringp string))
 835       (let ((start 0))
 836         (while (string-match "&#\\([0-9]+\\);" string start)
 837           (condition-case nil
 838               (setq string (replace-match
 839                             (string (read (substring string
 840                                                      (match-beginning 1)
 841                                                      (match-end 1))))
 842                             nil nil string))
 843             (error nil))
 844           (setq start (1+ (match-beginning 0))))
 845         string)
 846     nil))
 847
 848 ;;*******************************************************************
 849 ;;**
 850 ;;**  Printing a tree.
 851 ;;**  This function is intended mainly for debugging purposes.
 852 ;;**
 853 ;;*******************************************************************
 854
 855 (defun xml-debug-print (xml &optional indent-string)
 856   "Outputs the XML in the current buffer.
 857 XML can be a tree or a list of nodes.
 858 The first line is indented with the optional INDENT-STRING."
 859   (setq indent-string (or indent-string ""))
 860   (dolist (node xml)
 861     (xml-debug-print-internal node indent-string)))
 862
 863 (defalias 'xml-print 'xml-debug-print)
 864
 865 (defun xml-escape-string (string)
 866   "Return the string with entity substitutions made from
 867 xml-entity-alist."
 868   (mapconcat (lambda (byte)
 869                (let ((char (char-to-string byte)))
 870                  (if (rassoc char xml-entity-alist)
 871                      (concat "&" (car (rassoc char xml-entity-alist)) ";")
 872                    char)))
 873              ;; This differs from the non-unicode branch.  Just
 874              ;; grabbing the string works here.
 875              string ""))
 876
 877 (defun xml-debug-print-internal (xml indent-string)
 878   "Outputs the XML tree in the current buffer.
 879 The first line is indented with INDENT-STRING."
 880   (let ((tree xml)
 881         attlist)
 882     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 883
 884     ;;  output the attribute list
 885     (setq attlist (xml-node-attributes tree))
 886     (while attlist
 887       (insert ?\  (symbol-name (caar attlist)) "=\""
 888               (xml-escape-string (cdar attlist)) ?\")
 889       (setq attlist (cdr attlist)))
 890
 891     (setq tree (xml-node-children tree))
 892
 893     (if (null tree)
 894         (insert ?/ ?>)
 895       (insert ?>)
 896
 897       ;;  output the children
 898       (dolist (node tree)
 899         (cond
 900          ((listp node)
 901           (insert ?\n)
 902           (xml-debug-print-internal node (concat indent-string "  ")))
 903          ((stringp node)
 904           (insert (xml-escape-string node)))
 905          (t
 906           (error "Invalid XML tree"))))
 907
 908       (when (not (and (null (cdr tree))
 909                       (stringp (car tree))))
 910         (insert ?\n indent-string))
 911       (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
 912
 913 (provide 'xml)
 914
 915 ;;; xml.el ends here