sql/fdml.lisp

   1 ;;;; -*- Mode: LISP; Syntax: ANSI-Common-Lisp; Base: 10 -*-
   2 ;;;; *************************************************************************
   3 ;;;;
   4 ;;;; $Id$
   5 ;;;;
   6 ;;;; The CLSQL Functional Data Manipulation Language (FDML).
   7 ;;;;
   8 ;;;; This file is part of CLSQL.
   9 ;;;;
  10 ;;;; CLSQL users are granted the rights to distribute and use this software
  11 ;;;; as governed by the terms of the Lisp Lesser GNU Public License
  12 ;;;; (http://opensource.franz.com/preamble.html), also known as the LLGPL.
  13 ;;;; *************************************************************************
  14
  15 (in-package #:clsql-sys)
  16
  17 ;;; Basic operations on databases
  18
  19 (defmethod database-query-result-set ((expr %sql-expression) database
  20                                       &key full-set result-types)
  21   (database-query-result-set (sql-output expr database) database
  22                              :full-set full-set :result-types result-types))
  23
  24 (defmethod execute-command ((sql-expression string)
  25                             &key (database *default-database*))
  26   (record-sql-command sql-expression database)
  27   (let ((res (database-execute-command sql-expression database)))
  28     (record-sql-result res database))
  29   (values))
  30
  31 (defmethod execute-command ((expr %sql-expression)
  32                             &key (database *default-database*))
  33   (execute-command (sql-output expr database) :database database)
  34   (values))
  35
  36 (defmethod query ((query-expression string) &key (database *default-database*)
  37                   (result-types :auto) (flatp nil) (field-names t))
  38   (record-sql-command query-expression database)
  39   (multiple-value-bind (rows names)
  40       (database-query query-expression database result-types field-names)
  41     (let ((result (if (and flatp (= 1 (length (car rows))))
  42                       (mapcar #'car rows)
  43                     rows)))
  44       (record-sql-result result database)
  45       (if field-names
  46           (values result names)
  47         result))))
  48
  49 (defmethod query ((expr %sql-expression) &key (database *default-database*)
  50                   (result-types :auto) (flatp nil) (field-names t))
  51   (query (sql-output expr database) :database database :flatp flatp
  52          :result-types result-types :field-names field-names))
  53
  54 (defmethod query ((expr sql-object-query) &key (database *default-database*)
  55                   (result-types :auto) (flatp nil) (field-names t))
  56   (declare (ignore result-types field-names))
  57   (apply #'select (append (slot-value expr 'objects)
  58                           (slot-value expr 'exp)
  59                           (when (slot-value expr 'refresh)
  60                             (list :refresh (sql-output expr database)))
  61                           (when (or flatp (slot-value expr 'flatp) )
  62                             (list :flatp t))
  63                           (list :database database))))
  64
  65
  66 (defun print-query (query-exp &key titles (formats t) (sizes t) (stream t)
  67                               (database *default-database*))
  68   "Prints a tabular report of the results returned by the SQL
  69 query QUERY-EXP, which may be a symbolic SQL expression or a
  70 string, in DATABASE which defaults to *DEFAULT-DATABASE*. The
  71 report is printed onto STREAM which has a default value of t
  72 which means that *STANDARD-OUTPUT* is used. The TITLE argument,
  73 which defaults to nil, allows the specification of a list of
  74 strings to use as column titles in the tabular output. SIZES
  75 accepts a list of column sizes, one for each column selected by
  76 QUERY-EXP, to use in formatting the tabular report. The default
  77 value of t means that minimum sizes are computed. FORMATS is a
  78 list of format strings to be used for printing each column
  79 selected by QUERY-EXP. The default value of FORMATS is t meaning
  80 that ~A is used to format all columns or ~VA if column sizes are
  81 used."
  82   (flet ((compute-sizes (data)
  83            (mapcar #'(lambda (x)
  84                        (apply #'max (mapcar #'(lambda (y)
  85                                                 (if (null y) 3 (length y)))
  86                                             x)))
  87                    (apply #'mapcar (cons #'list data))))
  88          (format-record (record control sizes)
  89            (format stream "~&~?" control
  90                    (if (null sizes) record
  91                        (mapcan #'(lambda (s f) (list s f)) sizes record)))))
  92     (let* ((query-exp (etypecase query-exp
  93                         (string query-exp)
  94                         (sql-query (sql-output query-exp database))))
  95            (data (query query-exp :database database :result-types nil
  96                         :field-names nil))
  97            (sizes (if (or (null sizes) (listp sizes)) sizes
  98                       (compute-sizes (if titles (cons titles data) data))))
  99            (formats (if (or (null formats) (not (listp formats)))
 100                         (make-list (length (car data)) :initial-element
 101                                    (if (null sizes) "~A " "~VA "))
 102                         formats))
 103            (control-string (format nil "~{~A~}" formats)))
 104       (when titles (format-record titles control-string sizes))
 105       (dolist (d data (values)) (format-record d control-string sizes)))))
 106
 107 (defun insert-records (&key (into nil)
 108                             (attributes nil)
 109                             (values nil)
 110                             (av-pairs nil)
 111                             (query nil)
 112                             (database *default-database*))
 113   "Inserts records into the table specified by INTO in DATABASE
 114 which defaults to *DEFAULT-DATABASE*. There are five ways of
 115 specifying the values inserted into each row. In the first VALUES
 116 contains a list of values to insert and ATTRIBUTES, AV-PAIRS and
 117 QUERY are nil. This can be used when values are supplied for all
 118 attributes in INTO. In the second, ATTRIBUTES is a list of column
 119 names, VALUES is a corresponding list of values and AV-PAIRS and
 120 QUERY are nil. In the third, ATTRIBUTES, VALUES and QUERY are nil
 121 and AV-PAIRS is an alist of (attribute value) pairs. In the
 122 fourth, VALUES, AV-PAIRS and ATTRIBUTES are nil and QUERY is a
 123 symbolic SQL query expression in which the selected columns also
 124 exist in INTO. In the fifth method, VALUES and AV-PAIRS are nil
 125 and ATTRIBUTES is a list of column names and QUERY is a symbolic
 126 SQL query expression which returns values for the specified
 127 columns."
 128   (let ((stmt (make-sql-insert :into into :attrs attributes
 129                                :vals values :av-pairs av-pairs
 130                                :subquery query)))
 131     (execute-command stmt :database database)))
 132
 133 (defun make-sql-insert (&key (into nil)
 134                             (attrs nil)
 135                             (vals nil)
 136                             (av-pairs nil)
 137                             (subquery nil))
 138   (unless into
 139       (error 'sql-user-error :message ":into keyword not supplied"))
 140   (let ((insert (make-instance 'sql-insert :into into)))
 141     (with-slots (attributes values query)
 142       insert
 143
 144       (cond ((and vals (not attrs) (not query) (not av-pairs))
 145              (setf values vals))
 146             ((and vals attrs (not subquery) (not av-pairs))
 147              (setf attributes attrs)
 148              (setf values vals))
 149             ((and av-pairs (not vals) (not attrs) (not subquery))
 150              (setf attributes (mapcar #'car av-pairs))
 151              (setf values (mapcar #'cadr av-pairs)))
 152             ((and subquery (not vals) (not attrs) (not av-pairs))
 153              (setf query subquery))
 154             ((and subquery attrs (not vals) (not av-pairs))
 155              (setf attributes attrs)
 156              (setf query subquery))
 157             (t
 158              (error 'sql-user-error
 159                     :message "bad or ambiguous keyword combination.")))
 160       insert)))
 161
 162 (defun delete-records (&key (from nil)
 163                             (where nil)
 164                             (database *default-database*))
 165   "Deletes records satisfying the SQL expression WHERE from the
 166 table specified by FROM in DATABASE specifies a database which
 167 defaults to *DEFAULT-DATABASE*."
 168   (let ((stmt (make-instance 'sql-delete :from from :where where)))
 169     (execute-command stmt :database database)))
 170
 171 (defun update-records (table &key (attributes nil)
 172                             (values nil)
 173                             (av-pairs nil)
 174                             (where nil)
 175                             (database *default-database*))
 176   "Updates the attribute values of existing records satsifying
 177 the SQL expression WHERE in the table specified by TABLE in
 178 DATABASE which defaults to *DEFAULT-DATABASE*. There are three
 179 ways of specifying the values to update for each row. In the
 180 first, VALUES contains a list of values to use in the update and
 181 ATTRIBUTES and AV-PAIRS are nil. This can be used when values are
 182 supplied for all attributes in TABLE. In the second, ATTRIBUTES
 183 is a list of column names, VALUES is a corresponding list of
 184 values and AV-PAIRS is nil. In the third, ATTRIBUTES and VALUES
 185 are nil and AV-PAIRS is an alist of (attribute value) pairs."
 186   (when av-pairs
 187     (setf attributes (mapcar #'car av-pairs)
 188           values (mapcar #'cadr av-pairs)))
 189   (let ((stmt (make-instance 'sql-update :table table
 190                              :attributes attributes
 191                              :values values
 192                              :where where)))
 193     (execute-command stmt :database database)))
 194
 195
 196 ;;; Iteration
 197
 198 (defmacro do-query (((&rest args) query-expression
 199                      &key (database '*default-database*) (result-types :auto))
 200                     &body body)
 201   "Repeatedly executes BODY within a binding of ARGS on the
 202 fields of each row selected by the SQL query QUERY-EXPRESSION,
 203 which may be a string or a symbolic SQL expression, in DATABASE
 204 which defaults to *DEFAULT-DATABASE*. The values returned by the
 205 execution of BODY are returned. RESULT-TYPES is a list of symbols
 206 which specifies the lisp type for each field returned by
 207 QUERY-EXPRESSION. If RESULT-TYPES is nil all results are returned
 208 as strings whereas the default value of :auto means that the lisp
 209 types are automatically computed for each field."
 210   (let ((result-set (gensym "RESULT-SET-"))
 211         (qe (gensym "QUERY-EXPRESSION-"))
 212         (columns (gensym "COLUMNS-"))
 213         (row (gensym "ROW-"))
 214         (db (gensym "DB-")))
 215     `(let ((,qe ,query-expression))
 216       (typecase ,qe
 217         (sql-object-query
 218          (dolist (,row (query ,qe))
 219            (destructuring-bind ,args
 220                ,row
 221              ,@body)))
 222         (t
 223          ;; Functional query
 224          (let ((,db ,database))
 225            (multiple-value-bind (,result-set ,columns)
 226                (database-query-result-set ,qe ,db
 227                                           :full-set nil
 228                                           :result-types ,result-types)
 229              (when ,result-set
 230                (unwind-protect
 231                     (do ((,row (make-list ,columns)))
 232                         ((not (database-store-next-row ,result-set ,db ,row))
 233                          nil)
 234                       (destructuring-bind ,args ,row
 235                         ,@body))
 236                  (database-dump-result-set ,result-set ,db))))))))))
 237
 238 (defun map-query (output-type-spec function query-expression
 239                   &key (database *default-database*)
 240                   (result-types :auto))
 241   "Map the function FUNCTION over the attribute values of each
 242 row selected by the SQL query QUERY-EXPRESSION, which may be a
 243 string or a symbolic SQL expression, in DATABASE which defaults
 244 to *DEFAULT-DATABASE*. The results of the function are collected
 245 as specified in OUTPUT-TYPE-SPEC and returned like in
 246 MAP. RESULT-TYPES is a list of symbols which specifies the lisp
 247 type for each field returned by QUERY-EXPRESSION. If RESULT-TYPES
 248 is nil all results are returned as strings whereas the default
 249 value of :auto means that the lisp types are automatically
 250 computed for each field."
 251   (typecase query-expression
 252     (sql-object-query
 253      (map output-type-spec #'(lambda (x) (apply function x))
 254           (query query-expression)))
 255     (t
 256      ;; Functional query
 257      (macrolet ((type-specifier-atom (type)
 258                   `(if (atom ,type) ,type (car ,type))))
 259        (case (type-specifier-atom output-type-spec)
 260          ((nil)
 261           (map-query-for-effect function query-expression database
 262                                 result-types))
 263          (list
 264           (map-query-to-list function query-expression database result-types))
 265          ((simple-vector simple-string vector string array simple-array
 266                          bit-vector simple-bit-vector base-string
 267                          simple-base-string)
 268           (map-query-to-simple output-type-spec function query-expression
 269                                database result-types))
 270          (t
 271           (funcall #'map-query
 272                    (cmucl-compat:result-type-or-lose output-type-spec t)
 273                    function query-expression :database database
 274                    :result-types result-types)))))))
 275
 276 (defun map-query-for-effect (function query-expression database result-types)
 277   (multiple-value-bind (result-set columns)
 278       (database-query-result-set query-expression database :full-set nil
 279                                  :result-types result-types)
 280     (let ((flatp (and (= columns 1)
 281                       (typep query-expression 'sql-query)
 282                       (slot-value query-expression 'flatp))))
 283       (when result-set
 284         (unwind-protect
 285              (do ((row (make-list columns)))
 286                  ((not (database-store-next-row result-set database row))
 287                   nil)
 288                (if flatp
 289                    (apply function row)
 290                    (funcall function row)))
 291           (database-dump-result-set result-set database))))))
 292
 293 (defun map-query-to-list (function query-expression database result-types)
 294   (multiple-value-bind (result-set columns)
 295       (database-query-result-set query-expression database :full-set nil
 296                                  :result-types result-types)
 297     (let ((flatp (and (= columns 1)
 298                       (typep query-expression 'sql-query)
 299                       (slot-value query-expression 'flatp))))
 300       (when result-set
 301         (unwind-protect
 302              (let ((result (list nil)))
 303                (do ((row (make-list columns))
 304                     (current-cons result (cdr current-cons)))
 305                    ((not (database-store-next-row result-set database row))
 306                     (cdr result))
 307                  (rplacd current-cons
 308                          (list (if flatp
 309                                    (apply function row)
 310                                    (funcall function (copy-list row)))))))
 311           (database-dump-result-set result-set database))))))
 312
 313 (defun map-query-to-simple (output-type-spec function query-expression database result-types)
 314   (multiple-value-bind (result-set columns rows)
 315       (database-query-result-set query-expression database :full-set t
 316                                  :result-types result-types)
 317     (let ((flatp (and (= columns 1)
 318                       (typep query-expression 'sql-query)
 319                       (slot-value query-expression 'flatp))))
 320       (when result-set
 321         (unwind-protect
 322              (if rows
 323                  ;; We know the row count in advance, so we allocate once
 324                  (do ((result
 325                        (cmucl-compat:make-sequence-of-type output-type-spec rows))
 326                       (row (make-list columns))
 327                       (index 0 (1+ index)))
 328                      ((not (database-store-next-row result-set database row))
 329                       result)
 330                    (declare (fixnum index))
 331                    (setf (aref result index)
 332                          (if flatp
 333                              (apply function row)
 334                              (funcall function (copy-list row)))))
 335                  ;; Database can't report row count in advance, so we have
 336                  ;; to grow and shrink our vector dynamically
 337                  (do ((result
 338                        (cmucl-compat:make-sequence-of-type output-type-spec 100))
 339                       (allocated-length 100)
 340                       (row (make-list columns))
 341                       (index 0 (1+ index)))
 342                      ((not (database-store-next-row result-set database row))
 343                       (cmucl-compat:shrink-vector result index))
 344                    (declare (fixnum allocated-length index))
 345                    (when (>= index allocated-length)
 346                      (setq allocated-length (* allocated-length 2)
 347                            result (adjust-array result allocated-length)))
 348                    (setf (aref result index)
 349                          (if flatp
 350                              (apply function row)
 351                              (funcall function (copy-list row))))))
 352           (database-dump-result-set result-set database))))))
 353
 354 ;;; Row processing macro from CLSQL
 355
 356 (defmacro for-each-row (((&rest fields) &key from order-by where distinct limit)
 357                         &body body)
 358   (let ((d (gensym "DISTINCT-"))
 359         (bind-fields (loop for f in fields collect (car f)))
 360         (w (gensym "WHERE-"))
 361         (o (gensym "ORDER-BY-"))
 362         (frm (gensym "FROM-"))
 363         (l (gensym "LIMIT-"))
 364         (q (gensym "QUERY-")))
 365     `(let ((,frm ,from)
 366            (,w ,where)
 367            (,d ,distinct)
 368            (,l ,limit)
 369            (,o ,order-by))
 370       (let ((,q (query-string ',fields ,frm ,w ,d ,o ,l)))
 371         (loop for tuple in (query ,q)
 372               collect (destructuring-bind ,bind-fields tuple
 373                    ,@body))))))
 374
 375 (defun query-string (fields from where distinct order-by limit)
 376   (concatenate
 377    'string
 378    (format nil "select ~A~{~A~^,~} from ~{~A~^ and ~}"
 379            (if distinct "distinct " "") (field-names fields)
 380            (from-names from))
 381    (if where (format nil " where ~{~A~^ ~}"
 382                      (where-strings where)) "")
 383    (if order-by (format nil " order by ~{~A~^, ~}"
 384                         (order-by-strings order-by)))
 385    (if limit (format nil " limit ~D" limit) "")))
 386
 387 (defun lisp->sql-name (field)
 388   (typecase field
 389     (string field)
 390     (symbol (string-upcase (symbol-name field)))
 391     (cons (cadr field))
 392     (t (format nil "~A" field))))
 393
 394 (defun field-names (field-forms)
 395   "Return a list of field name strings from a fields form"
 396   (loop for field-form in field-forms
 397         collect
 398         (lisp->sql-name
 399          (if (cadr field-form)
 400              (cadr field-form)
 401              (car field-form)))))
 402
 403 (defun from-names (from)
 404   "Return a list of field name strings from a fields form"
 405   (loop for table in (if (atom from) (list from) from)
 406         collect (lisp->sql-name table)))
 407
 408
 409 (defun where-strings (where)
 410   (loop for w in (if (atom (car where)) (list where) where)
 411         collect
 412         (if (consp w)
 413             (format nil "~A ~A ~A" (second w) (first w) (third w))
 414             (format nil "~A" w))))
 415
 416 (defun order-by-strings (order-by)
 417   (loop for o in order-by
 418         collect
 419         (if (atom o)
 420             (lisp->sql-name o)
 421             (format nil "~A ~A" (lisp->sql-name (car o))
 422                     (lisp->sql-name (cadr o))))))
 423
 424
 425 ;;; Large objects support
 426
 427 (defun create-large-object (&key (database *default-database*))
 428   "Creates a new large object in the database and returns the object identifier"
 429   (database-create-large-object database))
 430
 431 (defun write-large-object (object-id data &key (database *default-database*))
 432   "Writes data to the large object"
 433   (database-write-large-object object-id data database))
 434
 435 (defun read-large-object (object-id &key (database *default-database*))
 436   "Reads the large object content"
 437   (database-read-large-object object-id database))
 438
 439 (defun delete-large-object (object-id &key (database *default-database*))
 440   "Deletes the large object in the database"
 441   (database-delete-large-object object-id database))
 442
 443
 444 ;;; Prepared statements
 445
 446 (defun prepare-sql (sql-stmt types &key (database *default-database*) (result-types :auto) field-names)
 447   "Prepares a SQL statement for execution. TYPES contains a
 448 list of types corresponding to the input parameters. Returns a
 449 prepared-statement object.
 450
 451 A type can be
 452   :int
 453   :double
 454   :null
 455   (:blob n)
 456   (:string n)
 457 "
 458   (unless (db-type-has-prepared-stmt? (database-type database))
 459     (error 'sql-user-error
 460            :message
 461            (format nil
 462                    "Database backend type ~:@(~A~) does not support prepared statements."
 463                    (database-type database))))
 464
 465   (database-prepare sql-stmt types database result-types field-names))
 466
 467 (defun bind-parameter (prepared-stmt position value)
 468   "Sets the value of a parameter is in prepared statement."
 469   (database-bind-parameter prepared-stmt position value)
 470   value)
 471
 472 (defun run-prepared-sql (prepared-stmt)
 473   "Execute the prepared sql statment. All input parameters must be bound."
 474   (database-run-prepared prepared-stmt))
 475
 476 (defun free-prepared-sql (prepared-stmt)
 477   "Delete the objects associated with a prepared statement."
 478   (database-free-prepared prepared-stmt))