src/xlib-util.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Utility functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26
  27 (in-package :clfswm)
  28
  29
  30 ;; Window states
  31 (defconstant +withdrawn-state+ 0)
  32 (defconstant +normal-state+ 1)
  33 (defconstant +iconic-state+ 3)
  34
  35
  36 (defparameter *window-events* '(:structure-notify
  37                                 :property-change
  38                                 :colormap-change
  39                                 :focus-change
  40                                 :enter-window
  41                                 :leave-window
  42                                 :pointer-motion
  43                                 :exposure)
  44   "The events to listen for on managed windows.")
  45
  46
  47 (defparameter +netwm-supported+
  48   '(:_NET_SUPPORTING_WM_CHECK
  49     :_NET_NUMBER_OF_DESKTOPS
  50     :_NET_DESKTOP_GEOMETRY
  51     :_NET_DESKTOP_VIEWPORT
  52     :_NET_CURRENT_DESKTOP
  53     :_NET_WM_WINDOW_TYPE
  54     :_NET_CLIENT_LIST)
  55   "Supported NETWM properties.
  56 Window types are in +WINDOW-TYPES+.")
  57
  58 (defparameter +netwm-window-types+
  59   '((:_NET_WM_WINDOW_TYPE_DESKTOP . :desktop)
  60     (:_NET_WM_WINDOW_TYPE_DOCK . :dock)
  61     (:_NET_WM_WINDOW_TYPE_TOOLBAR . :toolbar)
  62     (:_NET_WM_WINDOW_TYPE_MENU . :menu)
  63     (:_NET_WM_WINDOW_TYPE_UTILITY . :utility)
  64     (:_NET_WM_WINDOW_TYPE_SPLASH . :splash)
  65     (:_NET_WM_WINDOW_TYPE_DIALOG . :dialog)
  66     (:_NET_WM_WINDOW_TYPE_NORMAL . :normal))
  67   "Alist mapping NETWM window types to keywords.")
  68
  69
  70
  71
  72 (defparameter *x-error-count* 0)
  73 (defparameter *max-x-error-count* 10000)
  74 (defparameter *clfswm-x-error-filename* "/tmp/clfswm-backtrace.error")
  75
  76
  77 (defmacro with-xlib-protect ((&optional name tag) &body body)
  78   "Ignore Xlib errors in body."
  79   `(handler-case
  80        (with-simple-restart (top-level "Return to clfswm's top level")
  81          ,@body)
  82      (xlib::x-error (c)
  83        (incf *x-error-count*)
  84        (when (> *x-error-count* *max-x-error-count*)
  85          (format t "Xlib error: ~A ~A: ~A~%" ,name (if ,tag ,tag ',body) c)
  86          (force-output)
  87          (write-backtrace *clfswm-x-error-filename*
  88                           (format nil "~%------- Additional information ---------
  89 Xlib error: ~A ~A: ~A
  90 Body: ~A
  91
  92 Features: ~A"
  93                                   ,name ,tag c ',body
  94                                   *features*))
  95          (error "Too many X errors: ~A (logged in ~A)" c *clfswm-x-error-filename*))
  96        #+:xlib-debug
  97        (progn
  98          (format t "Xlib error: ~A ~A: ~A~%" ,name (if ,tag ,tag ',body) c)
  99          (force-output)))))
 100
 101
 102 ;;(defmacro with-xlib-protect ((&optional name tag) &body body)
 103 ;;  `(progn
 104 ;;     ,@body))
 105
 106
 107
 108 (defmacro with-x-pointer (&body body)
 109   "Bind (x y) to mouse pointer positions"
 110   `(multiple-value-bind (x y)
 111        (xlib:query-pointer *root*)
 112      ,@body))
 113
 114
 115
 116 (declaim (inline window-x2 window-y2))
 117 (defun window-x2 (window)
 118   (+ (x-drawable-x window) (x-drawable-width window)))
 119
 120 (defun window-y2 (window)
 121   (+ (x-drawable-y window) (x-drawable-height window)))
 122
 123
 124
 125 ;;;
 126 ;;; Events management functions.
 127 ;;;
 128 (defparameter *unhandled-events* nil)
 129 (defparameter *current-event-mode* nil)
 130
 131 (eval-when (:compile-toplevel :load-toplevel :execute)
 132   (defun keyword->handle-event (mode keyword)
 133     (create-symbol 'handle-event-fun "-" mode "-" keyword)))
 134
 135 (defun handle-event->keyword (symbol)
 136   (let* ((name (string-downcase (symbol-name symbol)))
 137          (pos (search "handle-event-fun-" name)))
 138     (when (and pos (zerop pos))
 139       (let ((pos-mod (search "mode" name)))
 140         (when pos-mod
 141           (intern (string-upcase (subseq name (+ pos-mod 5))) :keyword))))))
 142 ;;        (values (intern (string-upcase (subseq name (+ pos-mod 5))) :keyword)
 143 ;;                (subseq name (length "handle-event-fun-") (1- pos-mod))))))))
 144
 145 (defparameter *handle-event-fun-symbols* nil)
 146
 147 (defun fill-handle-event-fun-symbols ()
 148   (with-all-internal-symbols (symbol :clfswm)
 149     (let ((pos (symbol-search "handle-event-fun-" symbol)))
 150       (when (and pos (zerop pos))
 151         (pushnew symbol *handle-event-fun-symbols*)))))
 152
 153
 154 (defmacro with-handle-event-symbol ((mode) &body body)
 155   "Bind symbol to all handle event functions available in mode"
 156   `(let ((pattern (format nil "handle-event-fun-~A" ,mode)))
 157      (dolist (symbol *handle-event-fun-symbols*)
 158        (let ((pos (symbol-search pattern symbol)))
 159          (when (and pos (zerop pos))
 160            ,@body)))))
 161
 162
 163 (defun find-handle-event-function (&optional (mode ""))
 164   "Print all handle event functions available in mode"
 165   (with-handle-event-symbol (mode)
 166     (print symbol)))
 167
 168 (defun assoc-keyword-handle-event (mode)
 169   "Associate all keywords in mode to their corresponding handle event functions.
 170 For example: main-mode :key-press is bound to handle-event-fun-main-mode-key-press"
 171   (setf *current-event-mode* mode)
 172   (with-handle-event-symbol (mode)
 173     (let ((keyword (handle-event->keyword symbol)))
 174       (when (fboundp symbol)
 175         #+:event-debug
 176         (progn
 177           (format t "~&Associating: ~S with ~S~%" symbol keyword)
 178           (force-output))
 179         (setf (symbol-function keyword) (symbol-function symbol))))))
 180
 181 (defun unassoc-keyword-handle-event (&optional (mode ""))
 182   "Unbound all keywords from their corresponding handle event functions."
 183   (setf *current-event-mode* nil)
 184   (with-handle-event-symbol (mode)
 185     (let ((keyword (handle-event->keyword symbol)))
 186       (when (fboundp keyword)
 187         #+:event-debug
 188         (progn
 189           (format t "~&Unassociating: ~S  ~S~%" symbol keyword)
 190           (force-output))
 191         (fmakunbound keyword)))))
 192
 193 (defmacro define-handler (mode keyword args &body body)
 194   "Like a defun but with a name expanded as handle-event-fun-'mode'-'keyword'
 195 For example (define-handler main-mode :key-press (args) ...)
 196 Expand in handle-event-fun-main-mode-key-press"
 197   `(defun ,(keyword->handle-event mode keyword) (&rest event-slots &key #+:event-debug event-key ,@args &allow-other-keys)
 198      (declare (ignorable event-slots))
 199      #+:event-debug (print (list *current-event-mode* event-key))
 200      ,@body))
 201
 202
 203 (defun event-hook-name (event-keyword)
 204   (create-symbol-in-package :clfswm '*event- event-keyword '-hook*))
 205
 206 (let ((event-hook-list nil))
 207   (defun get-event-hook-list ()
 208     event-hook-list)
 209
 210   (defmacro use-event-hook (event-keyword)
 211     (let ((symb (event-hook-name event-keyword)))
 212       (pushnew symb event-hook-list)
 213       `(defvar ,symb nil)))
 214
 215   (defun unuse-event-hook (event-keyword)
 216     (let ((symb (event-hook-name event-keyword)))
 217       (setf event-hook-list (remove symb event-hook-list))
 218       (makunbound symb)))
 219
 220   (defmacro add-event-hook (name &rest value)
 221     (let ((symb (event-hook-name name)))
 222       `(add-hook ,symb ,@value)))
 223
 224   (defmacro remove-event-hook (name &rest value)
 225     (let ((symb (event-hook-name name)))
 226       `(remove-hook ,symb ,@value)))
 227
 228   (defun clear-event-hooks ()
 229     (dolist (symb event-hook-list)
 230       (makunbound symb)))
 231
 232
 233   (defun optimize-event-hook ()
 234     "Remove unused event hooks"
 235     (dolist (symb event-hook-list)
 236       (when (and (boundp symb)
 237                  (null (symbol-value symb)))
 238         (makunbound symb)
 239         (setf event-hook-list (remove symb event-hook-list))))))
 240
 241
 242
 243 (defmacro define-event-hook (event-keyword args &body body)
 244   (let ((event-fun (gensym)))
 245     `(let ((,event-fun (lambda (&rest event-slots &key #+:event-debug event-key ,@args &allow-other-keys)
 246                          (declare (ignorable event-slots))
 247                          #+:event-debug (print (list ,event-keyword event-key))
 248                          ,@body)))
 249        (add-event-hook ,event-keyword ,event-fun)
 250        ,event-fun)))
 251
 252
 253 (defmacro event-defun (name args &body body)
 254   `(defun ,name (&rest event-slots &key #+:event-debug event-key ,@args &allow-other-keys)
 255      (declare (ignorable event-slots))
 256      #+:event-debug (print (list ,event-keyword event-key))
 257      ,@body))
 258
 259 (defun exit-handle-event ()
 260   (throw 'exit-handle-event nil))
 261
 262
 263 (defun handle-event (&rest event-slots &key event-key &allow-other-keys)
 264   (labels ((make-xlib-window (xobject)
 265              "For some reason the clx xid cache screws up returns pixmaps when
 266 they should be windows. So use this function to make a window out of them."
 267              ;; Workaround for pixmap error taken from STUMPWM - thanks:
 268              ;; XXX: In both the clisp and sbcl clx libraries, sometimes what
 269              ;; should be a window will be a pixmap instead. In this case, we
 270              ;; need to manually translate it to a window to avoid breakage
 271              ;; in stumpwm. So far the only slot that seems to be affected is
 272              ;; the :window slot for configure-request and reparent-notify
 273              ;; events. It appears as though the hash table of XIDs and clx
 274              ;; structures gets out of sync with X or perhaps X assigns a
 275              ;; duplicate ID for a pixmap and a window.
 276              #+clisp (make-instance 'xlib:window :id (slot-value xobject 'xlib::id) :display *display*)
 277              #+(or sbcl ecl openmcl) (xlib::make-window :id (slot-value xobject 'xlib::id) :display *display*)
 278              #-(or sbcl clisp ecl openmcl)
 279              (error 'not-implemented)))
 280     (handler-case
 281         (catch 'exit-handle-event
 282           (let ((win (getf event-slots :window)))
 283             (when (and win (not (xlib:window-p win)))
 284               (dbg "Pixmap Workaround! Should be a window: " win)
 285               (setf (getf event-slots :window) (make-xlib-window win))))
 286           (let ((hook-symbol (event-hook-name event-key)))
 287             (when (boundp hook-symbol)
 288               (apply #'call-hook (symbol-value hook-symbol) event-slots)))
 289           (if (fboundp event-key)
 290               (apply event-key event-slots)
 291               #+:event-debug (pushnew (list *current-event-mode* event-key) *unhandled-events* :test #'equal))
 292           (xlib:display-finish-output *display*))
 293       ((or xlib:window-error xlib:drawable-error) (c)
 294         #-xlib-debug (declare (ignore c))
 295         #+xlib-debug (format t "Ignore Xlib synchronous error: ~a~%" c)))
 296     t))
 297
 298
 299
 300
 301
 302 (defun parse-display-string (display)
 303   "Parse an X11 DISPLAY string and return the host and display from it."
 304   (let* ((colon (position #\: display))
 305          (host (subseq display 0 colon))
 306          (rest (subseq display (1+ colon)))
 307          (dot (position #\. rest))
 308          (num (parse-integer (subseq rest 0 dot))))
 309     (values host num)))
 310
 311
 312 ;;; Transparency support
 313 (let ((opaque #xFFFFFFFF))
 314   (defun window-transparency (window)
 315     "Return the window transparency"
 316     (float (/ (or (first (xlib:get-property window :_NET_WM_WINDOW_OPACITY)) opaque)  opaque)))
 317
 318   (defun set-window-transparency (window value)
 319     "Set the window transparency"
 320     (when (numberp value)
 321       (xlib:change-property window :_NET_WM_WINDOW_OPACITY
 322                             (list (max (min (round (* opaque (if (equal *transparent-background* t) value 1)))
 323                                             opaque)
 324                                        0))
 325                             :cardinal 32)))
 326
 327   (defsetf window-transparency set-window-transparency))
 328
 329
 330
 331 (defun window-state (win)
 332   "Get the state (iconic, normal, withdrawn) of a window."
 333   (first (xlib:get-property win :WM_STATE)))
 334
 335
 336 (defun set-window-state (win state)
 337   "Set the state (iconic, normal, withdrawn) of a window."
 338   (xlib:change-property win
 339                         :WM_STATE
 340                         (list state)
 341                         :WM_STATE
 342                         32))
 343
 344 (defsetf window-state set-window-state)
 345
 346
 347
 348 (defun window-hidden-p (window)
 349   (eql (window-state window) +iconic-state+))
 350
 351
 352
 353
 354 (defun unhide-window (window)
 355   (when window
 356     (when (window-hidden-p window)
 357       (xlib:map-window window)
 358       (setf (window-state window) +normal-state+
 359             (xlib:window-event-mask window) *window-events*))))
 360
 361
 362 (defun map-window (window)
 363   (when window
 364     (xlib:map-window window)))
 365
 366
 367 (defun delete-window (window)
 368   (send-client-message window :WM_PROTOCOLS
 369                        (xlib:intern-atom *display* :WM_DELETE_WINDOW)))
 370
 371 (defun destroy-window (window)
 372   (xlib:kill-client *display* (xlib:window-id window)))
 373
 374
 375 ;;(defconstant +exwm-atoms+
 376 ;;  (list "_NET_SUPPORTED"              "_NET_CLIENT_LIST"
 377 ;;      "_NET_CLIENT_LIST_STACKING"   "_NET_NUMBER_OF_DESKTOPS"
 378 ;;      "_NET_CURRENT_DESKTOP"        "_NET_DESKTOP_GEOMETRY"
 379 ;;      "_NET_DESKTOP_VIEWPORT"       "_NET_DESKTOP_NAMES"
 380 ;;      "_NET_ACTIVE_WINDOW"          "_NET_WORKAREA"
 381 ;;      "_NET_SUPPORTING_WM_CHECK"    "_NET_VIRTUAL_ROOTS"
 382 ;;      "_NET_DESKTOP_LAYOUT"
 383 ;;
 384 ;;        "_NET_RESTACK_WINDOW"         "_NET_REQUEST_FRAME_EXTENTS"
 385 ;;        "_NET_MOVERESIZE_WINDOW"      "_NET_CLOSE_WINDOW"
 386 ;;        "_NET_WM_MOVERESIZE"
 387 ;;
 388 ;;      "_NET_WM_SYNC_REQUEST"        "_NET_WM_PING"
 389 ;;
 390 ;;      "_NET_WM_NAME"                "_NET_WM_VISIBLE_NAME"
 391 ;;      "_NET_WM_ICON_NAME"           "_NET_WM_VISIBLE_ICON_NAME"
 392 ;;      "_NET_WM_DESKTOP"             "_NET_WM_WINDOW_TYPE"
 393 ;;      "_NET_WM_STATE"               "_NET_WM_STRUT"
 394 ;;      "_NET_WM_ICON_GEOMETRY"       "_NET_WM_ICON"
 395 ;;      "_NET_WM_PID"                 "_NET_WM_HANDLED_ICONS"
 396 ;;      "_NET_WM_USER_TIME"           "_NET_FRAME_EXTENTS"
 397 ;;        ;; "_NET_WM_MOVE_ACTIONS"
 398 ;;
 399 ;;      "_NET_WM_WINDOW_TYPE_DESKTOP" "_NET_WM_STATE_MODAL"
 400 ;;      "_NET_WM_WINDOW_TYPE_DOCK"    "_NET_WM_STATE_STICKY"
 401 ;;      "_NET_WM_WINDOW_TYPE_TOOLBAR" "_NET_WM_STATE_MAXIMIZED_VERT"
 402 ;;      "_NET_WM_WINDOW_TYPE_MENU"    "_NET_WM_STATE_MAXIMIZED_HORZ"
 403 ;;      "_NET_WM_WINDOW_TYPE_UTILITY" "_NET_WM_STATE_SHADED"
 404 ;;      "_NET_WM_WINDOW_TYPE_SPLASH"  "_NET_WM_STATE_SKIP_TASKBAR"
 405 ;;      "_NET_WM_WINDOW_TYPE_DIALOG"  "_NET_WM_STATE_SKIP_PAGER"
 406 ;;      "_NET_WM_WINDOW_TYPE_NORMAL"  "_NET_WM_STATE_HIDDEN"
 407 ;;                                    "_NET_WM_STATE_FULLSCREEN"
 408 ;;                                    "_NET_WM_STATE_ABOVE"
 409 ;;                                    "_NET_WM_STATE_BELOW"
 410 ;;                                    "_NET_WM_STATE_DEMANDS_ATTENTION"
 411 ;;
 412 ;;      "_NET_WM_ALLOWED_ACTIONS"
 413 ;;      "_NET_WM_ACTION_MOVE"
 414 ;;      "_NET_WM_ACTION_RESIZE"
 415 ;;      "_NET_WM_ACTION_SHADE"
 416 ;;      "_NET_WM_ACTION_STICK"
 417 ;;      "_NET_WM_ACTION_MAXIMIZE_HORZ"
 418 ;;      "_NET_WM_ACTION_MAXIMIZE_VERT"
 419 ;;      "_NET_WM_ACTION_FULLSCREEN"
 420 ;;      "_NET_WM_ACTION_CHANGE_DESKTOP"
 421 ;;      "_NET_WM_ACTION_CLOSE"
 422 ;;
 423 ;;      ))
 424 ;;
 425 ;;
 426 ;;(defun intern-atoms (display)
 427 ;;  (declare (type xlib:display display))
 428 ;;  (mapcar #'(lambda (atom-name) (xlib:intern-atom display atom-name))
 429 ;;        +exwm-atoms+)
 430 ;;  (values))
 431 ;;
 432 ;;
 433 ;;
 434 ;;(defun get-atoms-property (window property-atom atom-list-p)
 435 ;;  "Returns a list of atom-name (if atom-list-p is t) otherwise returns
 436 ;;   a list of atom-id."
 437 ;;  (xlib:get-property window property-atom
 438 ;;                   :transform (when atom-list-p
 439 ;;                                (lambda (id)
 440 ;;                                  (xlib:atom-name (xlib:drawable-display window) id)))))
 441 ;;
 442 ;;(defun set-atoms-property (window atoms property-atom &key (mode :replace))
 443 ;;  "Sets the property designates by `property-atom'. ATOMS is a list of atom-id
 444 ;;   or a list of keyword atom-names."
 445 ;;  (xlib:change-property window property-atom atoms :ATOM 32
 446 ;;                      :mode mode
 447 ;;                      :transform (unless (integerp (car atoms))
 448 ;;                                   (lambda (atom-key)
 449 ;;                                     (xlib:find-atom (xlib:drawable-display window) atom-key)))))
 450 ;;
 451 ;;
 452 ;;
 453 ;;
 454 ;;(defun net-wm-state (window)
 455 ;;  (get-atoms-property window :_NET_WM_STATE t))
 456 ;;
 457 ;;(defsetf net-wm-state (window &key (mode :replace)) (states)
 458 ;;  `(set-atoms-property ,window ,states :_NET_WM_STATE :mode ,mode))
 459
 460
 461 (defun hide-window (window)
 462   (when window
 463     (setf (window-state window) +iconic-state+
 464           (xlib:window-event-mask window) (remove :structure-notify *window-events*))
 465     (xlib:unmap-window window)
 466     (setf (xlib:window-event-mask window) *window-events*)))
 467
 468
 469
 470 (defun window-type (window)
 471   "Return one of :desktop, :dock, :toolbar, :utility, :splash,
 472 :dialog, :transient, :maxsize and :normal."
 473   (or (and (let ((hints (xlib:wm-normal-hints window)))
 474              (and hints (or (xlib:wm-size-hints-max-width hints)
 475                             (xlib:wm-size-hints-max-height hints)
 476                             (xlib:wm-size-hints-min-aspect hints)
 477                             (xlib:wm-size-hints-max-aspect hints))))
 478            :maxsize)
 479       (let ((net-wm-window-type (xlib:get-property window :_NET_WM_WINDOW_TYPE)))
 480         (when net-wm-window-type
 481           (dolist (type-atom net-wm-window-type)
 482             (when (assoc (xlib:atom-name *display* type-atom) +netwm-window-types+)
 483               (return (cdr (assoc (xlib:atom-name *display* type-atom) +netwm-window-types+)))))))
 484       (and (xlib:get-property window :WM_TRANSIENT_FOR)
 485            :transient)
 486       :normal))
 487
 488
 489
 490
 491 ;;; Stolen from Eclipse
 492 (defun send-configuration-notify (window x y w h bw)
 493   "Send a synthetic configure notify event to the given window (ICCCM 4.1.5)"
 494   (xlib:send-event window :configure-notify (xlib:make-event-mask :structure-notify)
 495                    :event-window window
 496                    :window window
 497                    :x x :y y
 498                    :width w
 499                    :height h
 500                    :border-width bw
 501                    :propagate-p nil))
 502
 503
 504
 505 (defun send-client-message (window type &rest data)
 506   "Send a client message to a client's window."
 507   (xlib:send-event window
 508                    :client-message nil
 509                    :window window
 510                    :type type
 511                    :format 32
 512                    :data data))
 513
 514
 515
 516
 517
 518 (defun raise-window (window)
 519   "Map the window if needed and bring it to the top of the stack. Does not affect focus."
 520   (when (xlib:window-p window)
 521     (when (window-hidden-p window)
 522       (unhide-window window))
 523     (setf (xlib:window-priority window) :above)))
 524
 525
 526 (defun no-focus ()
 527   "don't focus any window but still read keyboard events."
 528   (xlib:set-input-focus *display* *no-focus-window* :pointer-root))
 529
 530 (defun focus-window (window)
 531   "Give the window focus."
 532   (no-focus)
 533   (when (xlib:window-p window)
 534     (xlib:set-input-focus *display* window :parent)))
 535
 536 (defun raise-and-focus-window (window)
 537   "Raise and focus."
 538   (raise-window window)
 539   (focus-window window))
 540
 541
 542 (defun lower-window (window sibling)
 543   "Map the window if needed and bring it just above sibling. Does not affect focus."
 544   (when (xlib:window-p window)
 545     (when (window-hidden-p window)
 546       (unhide-window window))
 547     (setf (xlib:window-priority window sibling) :below)))
 548
 549
 550
 551
 552 (let ((cursor-font nil)
 553       (cursor nil)
 554       (pointer-grabbed nil))
 555   (defun free-grab-pointer ()
 556     (when cursor
 557       (xlib:free-cursor cursor)
 558       (setf cursor nil))
 559     (when cursor-font
 560       (xlib:close-font cursor-font)
 561       (setf cursor-font nil)))
 562
 563   (defun xgrab-init-pointer ()
 564     (setf pointer-grabbed nil))
 565
 566     (defun xgrab-pointer-p ()
 567       pointer-grabbed)
 568
 569     (defun xgrab-pointer (root cursor-char cursor-mask-char
 570                           &optional (pointer-mask '(:enter-window :pointer-motion
 571                                                     :button-press :button-release)) owner-p)
 572       "Grab the pointer and set the pointer shape."
 573       (when pointer-grabbed
 574         (xungrab-pointer))
 575       (setf pointer-grabbed t)
 576       (let* ((white (xlib:make-color :red 1.0 :green 1.0 :blue 1.0))
 577              (black (xlib:make-color :red 0.0 :green 0.0 :blue 0.0)))
 578         (cond (cursor-char
 579                (setf cursor-font (xlib:open-font *display* "cursor")
 580                      cursor (xlib:create-glyph-cursor :source-font cursor-font
 581                                                       :source-char (or cursor-char 68)
 582                                                       :mask-font cursor-font
 583                                                       :mask-char (or cursor-mask-char 69)
 584                                                       :foreground black
 585                                                       :background white))
 586                (xlib:grab-pointer root pointer-mask
 587                                        :owner-p owner-p  :sync-keyboard-p nil :sync-pointer-p nil :cursor cursor))
 588               (t
 589                (xlib:grab-pointer root pointer-mask
 590                                        :owner-p owner-p  :sync-keyboard-p nil :sync-pointer-p nil)))))
 591
 592     (defun xungrab-pointer ()
 593       "Remove the grab on the cursor and restore the cursor shape."
 594       (setf pointer-grabbed nil)
 595       (xlib:ungrab-pointer *display*)
 596       (xlib:display-finish-output *display*)
 597       (free-grab-pointer)))
 598
 599
 600 (let ((keyboard-grabbed nil))
 601   (defun xgrab-init-keyboard ()
 602     (setf keyboard-grabbed nil))
 603
 604   (defun xgrab-keyboard-p ()
 605     keyboard-grabbed)
 606
 607   (defun xgrab-keyboard (root)
 608     (setf keyboard-grabbed t)
 609     (xlib:grab-keyboard root :owner-p nil :sync-keyboard-p nil :sync-pointer-p nil))
 610
 611
 612   (defun xungrab-keyboard ()
 613     (setf keyboard-grabbed nil)
 614     (xlib:ungrab-keyboard *display*)))
 615
 616
 617
 618
 619
 620
 621 (defun ungrab-all-buttons (window)
 622   (xlib:ungrab-button window :any :modifiers :any))
 623
 624 (defun grab-all-buttons (window)
 625   (ungrab-all-buttons window)
 626   (xlib:grab-button window :any '(:button-press :button-release :pointer-motion)
 627                     :modifiers :any
 628                     :owner-p nil
 629                     :sync-pointer-p t
 630                     :sync-keyboard-p nil))
 631
 632 (defun ungrab-all-keys (window)
 633   (xlib:ungrab-key window :any :modifiers :any))
 634
 635
 636
 637 (defmacro with-grab-keyboard-and-pointer ((cursor mask old-cursor old-mask &optional ungrab-main) &body body)
 638   `(let ((pointer-grabbed (xgrab-pointer-p))
 639          (keyboard-grabbed (xgrab-keyboard-p)))
 640      (xgrab-pointer *root* ,cursor ,mask)
 641      (unless keyboard-grabbed
 642        (when ,ungrab-main
 643          (ungrab-main-keys))
 644        (xgrab-keyboard *root*))
 645      (unwind-protect
 646           (progn
 647             ,@body)
 648        (progn
 649          (if pointer-grabbed
 650              (xgrab-pointer *root* ,old-cursor ,old-mask)
 651              (xungrab-pointer))
 652          (unless keyboard-grabbed
 653            (when ,ungrab-main
 654              (grab-main-keys))
 655            (xungrab-keyboard))))))
 656
 657
 658 (defmacro with-grab-pointer ((&optional cursor-char cursor-mask-char) &body body)
 659   `(let ((pointer-grabbed-p (xgrab-pointer-p)))
 660      (unless pointer-grabbed-p
 661        (xgrab-pointer *root* ,cursor-char ,cursor-mask-char))
 662      (unwind-protect
 663           (progn
 664             ,@body)
 665        (unless pointer-grabbed-p
 666          (xungrab-pointer)))))
 667
 668
 669
 670
 671
 672 (defun stop-button-event ()
 673   (xlib:allow-events *display* :sync-pointer))
 674
 675 (defun replay-button-event ()
 676   (xlib:allow-events *display* :replay-pointer))
 677
 678
 679
 680
 681
 682
 683
 684
 685
 686 ;;; Mouse action on window
 687 (let (add-fn add-arg dx dy window)
 688   (define-handler move-window-mode :motion-notify (root-x root-y)
 689     (unless (compress-motion-notify)
 690       (if add-fn
 691           (multiple-value-bind (move-x move-y)
 692               (apply add-fn add-arg)
 693             (when move-x
 694               (setf (x-drawable-x window) (+ root-x dx)))
 695             (when move-y
 696               (setf (x-drawable-y window) (+ root-y dy))))
 697           (setf (x-drawable-x window) (+ root-x dx)
 698                 (x-drawable-y window) (+ root-y dy)))))
 699
 700   (define-handler move-window-mode :key-release ()
 701     (throw 'exit-move-window-mode nil))
 702
 703   (define-handler move-window-mode :button-release ()
 704     (throw 'exit-move-window-mode nil))
 705
 706   (defun move-window (orig-window orig-x orig-y &optional additional-fn additional-arg)
 707     (setf window orig-window
 708           add-fn additional-fn
 709           add-arg additional-arg
 710           dx (- (x-drawable-x window) orig-x)
 711           dy (- (x-drawable-y window) orig-y)
 712           (xlib:window-border window) (get-color *color-move-window*))
 713     (raise-window window)
 714     (with-grab-pointer ()
 715       (when additional-fn
 716         (apply additional-fn additional-arg))
 717       (generic-mode 'move-window-mode 'exit-move-window-mode
 718                     :original-mode '(main-mode)))))
 719
 720
 721 (let (add-fn add-arg window
 722              o-x o-y
 723              orig-width orig-height
 724              min-width max-width
 725              min-height max-height)
 726   (define-handler resize-window-mode :motion-notify (root-x root-y)
 727     (unless (compress-motion-notify)
 728       (if add-fn
 729           (multiple-value-bind (resize-w resize-h)
 730               (apply add-fn add-arg)
 731             (when resize-w
 732               (setf (x-drawable-width window) (min (max (+ orig-width (- root-x o-x)) 10 min-width) max-width)))
 733             (when resize-h
 734               (setf (x-drawable-height window) (min (max (+ orig-height (- root-y o-y)) 10 min-height) max-height))))
 735           (setf (x-drawable-width window) (min (max (+ orig-width (- root-x o-x)) 10 min-width) max-width)
 736                 (x-drawable-height window) (min (max (+ orig-height (- root-y o-y)) 10 min-height) max-height)))))
 737
 738   (define-handler resize-window-mode :key-release ()
 739     (throw 'exit-resize-window-mode nil))
 740
 741   (define-handler resize-window-mode :button-release ()
 742     (throw 'exit-resize-window-mode nil))
 743
 744   (defun resize-window (orig-window orig-x orig-y &optional additional-fn additional-arg)
 745     (let* ((hints (xlib:wm-normal-hints orig-window)))
 746       (setf window orig-window
 747             add-fn additional-fn
 748             add-arg additional-arg
 749             o-x orig-x
 750             o-y orig-y
 751             orig-width (x-drawable-width window)
 752             orig-height (x-drawable-height window)
 753             min-width (or (and hints (xlib:wm-size-hints-min-width hints)) 0)
 754             min-height (or (and hints (xlib:wm-size-hints-min-height hints)) 0)
 755             max-width (or (and hints (xlib:wm-size-hints-max-width hints)) most-positive-fixnum)
 756             max-height (or (and hints (xlib:wm-size-hints-max-height hints)) most-positive-fixnum)
 757             (xlib:window-border window) (get-color *color-move-window*))
 758       (raise-window window)
 759       (with-grab-pointer ()
 760         (when additional-fn
 761           (apply additional-fn additional-arg))
 762         (generic-mode 'resize-window-mode 'exit-resize-window-mode
 763                       :original-mode '(main-mode))))))
 764
 765
 766
 767 (define-handler wait-mouse-button-release-mode :button-release ()
 768   (throw 'exit-wait-mouse-button-release-mode nil))
 769
 770 (defun wait-mouse-button-release (&optional cursor-char cursor-mask-char)
 771   (with-grab-pointer (cursor-char cursor-mask-char)
 772     (generic-mode 'wait-mouse-button-release 'exit-wait-mouse-button-release-mode)))
 773
 774
 775
 776
 777
 778 (let ((color-hash (make-hash-table :test 'equal)))
 779   (defun get-color (color)
 780     (multiple-value-bind (val foundp)
 781         (gethash color color-hash)
 782       (if foundp
 783           val
 784           (setf (gethash color color-hash)
 785                 (xlib:alloc-color (xlib:screen-default-colormap *screen*) color))))))
 786
 787
 788
 789 (defgeneric ->color (color))
 790
 791 (defmethod ->color ((color-name string))
 792   color-name)
 793
 794 (defmethod ->color ((color integer))
 795   (labels ((hex->float (color)
 796              (/ (logand color #xFF) 256.0)))
 797     (xlib:make-color :blue (hex->float color)
 798                      :green (hex->float (ash color -8))
 799                      :red (hex->float  (ash color -16)))))
 800
 801 (defmethod ->color ((color list))
 802   (destructuring-bind (red green blue) color
 803     (xlib:make-color :blue red :green green :red blue)))
 804
 805 (defmethod ->color ((color xlib:color))
 806   color)
 807
 808 (defmethod ->color (color)
 809   (format t "Wrong color type: ~A~%" color)
 810   "White")
 811
 812
 813 (defun color->rgb (color)
 814   (multiple-value-bind (r g b)
 815       (xlib:color-rgb color)
 816     (+ (ash (round (* 256 r)) +16)
 817        (ash (round (* 256 g)) +8)
 818        (round (* 256 b)))))
 819
 820
 821
 822
 823
 824 (defmacro my-character->keysyms (ch)
 825   "Convert a char to a keysym"
 826   ;; XLIB:CHARACTER->KEYSYMS should probably be implemented in NEW-CLX
 827   ;; some day.  Or just copied from MIT-CLX or some other CLX
 828   ;; implementation (see translate.lisp and keysyms.lisp).  For now,
 829   ;; we do like this.  It suffices for modifiers and ASCII symbols.
 830   (if (fboundp 'xlib:character->keysyms)
 831       `(xlib:character->keysyms ,ch)
 832       `(list
 833        (case ,ch
 834          (:character-set-switch #xFF7E)
 835          (:left-shift #xFFE1)
 836          (:right-shift #xFFE2)
 837          (:left-control #xFFE3)
 838          (:right-control #xFFE4)
 839          (:caps-lock #xFFE5)
 840          (:shift-lock #xFFE6)
 841          (:left-meta #xFFE7)
 842          (:right-meta #xFFE8)
 843          (:left-alt #xFFE9)
 844          (:right-alt #xFFEA)
 845          (:left-super #xFFEB)
 846          (:right-super #xFFEC)
 847          (:left-hyper #xFFED)
 848          (:right-hyper #xFFEE)
 849          (t
 850           (etypecase ,ch
 851             (character
 852              ;; Latin-1 characters have their own value as keysym
 853              (if (< 31 (char-code ,ch) 256)
 854                  (char-code ,ch)
 855                  (error "Don't know how to get keysym from ~A" ,ch)))))))))
 856
 857
 858
 859
 860 (defun char->keycode (char)
 861   "Convert a character to a keycode"
 862   (xlib:keysym->keycodes *display* (first (my-character->keysyms char))))
 863
 864
 865 (defun keycode->char (code state)
 866   (xlib:keysym->character *display* (xlib:keycode->keysym *display* code 0) state))
 867
 868 (defun modifiers->state (modifier-list)
 869   (apply #'xlib:make-state-mask modifier-list))
 870
 871 (defun state->modifiers (state)
 872   (xlib:make-state-keys state))
 873
 874 (defun keycode->keysym (code modifiers)
 875   (xlib:keycode->keysym *display* code (cond ((member :shift modifiers) 1)
 876                                              ((member :mod-5 modifiers) 4)
 877                                              (t 0))))
 878
 879
 880
 881
 882
 883 (let ((modifier-list nil))
 884   (defun init-modifier-list ()
 885     (dolist (name '("Shift_L" "Shift_R" "Control_L" "Control_R"
 886                     "Alt_L" "Alt_R" "Meta_L" "Meta_R" "Hyper_L" "Hyper_R"
 887                     "Mode_switch" "script_switch" "ISO_Level3_Shift"
 888                     "Caps_Lock" "Scroll_Lock" "Num_Lock"))
 889       (awhen (xlib:keysym->keycodes *display* (keysym-name->keysym name))
 890         (push it modifier-list))))
 891
 892   (defun modifier-p (code)
 893     (member code modifier-list)))
 894
 895 (defun wait-no-key-or-button-press ()
 896   (with-grab-keyboard-and-pointer (66 67 66 67)
 897     (loop
 898        (let ((key (loop for k across (xlib:query-keymap *display*)
 899                      for code from 0
 900                      when (and (plusp k) (not (modifier-p code)))
 901                      return t))
 902              (button (loop for b in (xlib:make-state-keys (nth-value 4 (xlib:query-pointer *root*)))
 903                         when (member b '(:button-1 :button-2 :button-3 :button-4 :button-5))
 904                         return t)))
 905          (when (and (not key) (not button))
 906            (loop while (xlib:event-case (*display* :discard-p t :peek-p nil :timeout 0)
 907                          (:motion-notify () t)
 908                          (:key-press () t)
 909                          (:key-release () t)
 910                          (:button-press () t)
 911                          (:button-release () t)
 912                          (t nil)))
 913            (return))))))
 914
 915
 916 (defun wait-a-key-or-button-press ()
 917   (with-grab-keyboard-and-pointer (24 25 66 67)
 918     (loop
 919      (let ((key (loop for k across (xlib:query-keymap *display*)
 920                       unless (zerop k) return t))
 921            (button (loop for b in (xlib:make-state-keys (nth-value 4 (xlib:query-pointer *root*)))
 922                          when (member b '(:button-1 :button-2 :button-3 :button-4 :button-5))
 923                          return t)))
 924        (when (or key button)
 925          (return))))))
 926
 927
 928
 929 (defun compress-motion-notify ()
 930   (when *have-to-compress-notify*
 931     (loop while (xlib:event-cond (*display* :timeout 0)
 932                   (:motion-notify () t)))))
 933
 934
 935 (defun display-all-cursors (&optional (display-time 1))
 936   "Display all X11 cursors for display-time seconds"
 937   (loop for i from 0 to 152 by 2
 938      do (xgrab-pointer *root* i (1+ i))
 939        (dbg i)
 940        (sleep display-time)
 941        (xungrab-pointer)))
 942
 943
 944
 945 ;;; Double buffering tools
 946 (defun clear-pixmap-buffer (window gc)
 947   (if (equal *transparent-background* :pseudo)
 948       (xlib:copy-area *background-image* *background-gc*
 949                       (x-drawable-x window) (x-drawable-y window)
 950                       (x-drawable-width window) (x-drawable-height window)
 951                       *pixmap-buffer* 0 0)
 952       (xlib:with-gcontext (gc :foreground (xlib:gcontext-background gc)
 953                               :background (xlib:gcontext-foreground gc))
 954         (xlib:draw-rectangle *pixmap-buffer* gc
 955                              0 0 (x-drawable-width window) (x-drawable-height window)
 956                              t))))
 957
 958
 959 (defun copy-pixmap-buffer (window gc)
 960   (xlib:copy-area *pixmap-buffer* gc
 961                   0 0 (x-drawable-width window) (x-drawable-height window)
 962                   window 0 0))
 963
 964
 965
 966 (defun is-a-key-pressed-p ()
 967   (loop for k across (xlib:query-keymap *display*)
 968      when (plusp k)
 969      return t))
 970
 971 ;;; Windows wm class and name tests
 972 (defmacro defun-equal-wm-class (symbol class)
 973   `(defun ,symbol (window)
 974      (when (xlib:window-p window)
 975        (string-equal (xlib:get-wm-class window) ,class))))
 976
 977 (defmacro defun-equal-wm-name (symbol name)
 978   `(defun ,symbol (window)
 979      (when (xlib:window-p window)
 980        (string-equal (xlib:wm-name window) ,name))))
 981