src/clfswm-internal.lisp

   1 ;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28 (defgeneric child-border-size (child))
  29
  30 (defmethod child-border-size ((child frame))
  31   (x-drawable-border-width (frame-window child)))
  32
  33 (defmethod child-border-size ((child xlib:window))
  34   (x-drawable-border-width child))
  35
  36 (defmethod child-border-size (child)
  37   (declare (ignore child))
  38   0)
  39
  40 (defgeneric set-child-border-size (child value))
  41
  42 (defmethod set-child-border-size ((child frame) value)
  43   (setf (x-drawable-border-width (frame-window child)) value))
  44
  45 (defmethod set-child-border-size ((child xlib:window) value)
  46   (setf (x-drawable-border-width child) value))
  47
  48 (defmethod set-child-border-size (child value)
  49   (declare (ignore child value)))
  50
  51 (defsetf child-border-size set-child-border-size)
  52
  53
  54
  55 ;;; Conversion functions
  56 ;;; Float -> Pixel conversion
  57 (defun x-fl->px (x parent)
  58   "Convert float X coordinate to pixel"
  59   (round (+ (* x (frame-rw parent)) (frame-rx parent))))
  60
  61 (defun y-fl->px (y parent)
  62   "Convert float Y coordinate to pixel"
  63   (round (+ (* y (frame-rh parent)) (frame-ry parent))))
  64
  65 (defun w-fl->px (w parent)
  66   "Convert float Width coordinate to pixel"
  67   (round (* w (frame-rw parent))))
  68
  69 (defun h-fl->px (h parent)
  70   "Convert float Height coordinate to pixel"
  71   (round (* h (frame-rh parent))))
  72
  73 ;;; Pixel -> Float conversion
  74 (defun x-px->fl (x parent)
  75   "Convert pixel X coordinate to float"
  76   (/ (- x (frame-rx parent) (child-border-size parent)) (frame-rw parent)))
  77
  78 (defun y-px->fl (y parent)
  79   "Convert pixel Y coordinate to float"
  80   (/ (- y (frame-ry parent) (child-border-size parent)) (frame-rh parent)))
  81
  82 (defun w-px->fl (w parent)
  83   "Convert pixel Width coordinate to float"
  84   (/ w (frame-rw parent)))
  85
  86 (defun h-px->fl (h parent)
  87   "Convert pixel Height coordinate to float"
  88   (/ h (frame-rh parent)))
  89
  90
  91
  92 (defun rect-hidden-p (rect1 rect2)
  93   "Return T if child-rect1 hide child-rect2"
  94   (and *show-hide-policy*
  95        (funcall *show-hide-policy* (child-rect-x rect1) (child-rect-x rect2))
  96        (funcall *show-hide-policy* (child-rect-y rect1) (child-rect-y rect2))
  97        (funcall *show-hide-policy* (+ (child-rect-x rect2) (child-rect-w rect2))
  98                 (+ (child-rect-x rect1) (child-rect-w rect1)))
  99        (funcall *show-hide-policy* (+ (child-rect-y rect2) (child-rect-h rect2))
 100                 (+ (child-rect-y rect1) (child-rect-h rect1)))))
 101
 102
 103
 104 (defgeneric frame-p (frame))
 105 (defmethod frame-p ((frame frame))
 106   (declare (ignore frame))
 107   t)
 108 (defmethod frame-p (frame)
 109   (declare (ignore frame))
 110   nil)
 111
 112
 113
 114 ;;; in-*: Find if point (x,y) is in frame, window or child
 115 (defun in-rect (x y xr yr wr hr)
 116   (and (<= xr x (+ xr wr))
 117        (<= yr y (+ yr hr))))
 118
 119 (defun in-frame (frame x y)
 120   (and (frame-p frame)
 121        (in-rect x y (frame-rx frame) (frame-ry frame) (frame-rw frame) (frame-rh frame))))
 122
 123 (defun in-window (window x y)
 124   (and (xlib:window-p window)
 125        (in-rect x y
 126                 (x-drawable-x window) (x-drawable-y window)
 127                 (x-drawable-width window) (x-drawable-height window))))
 128
 129 (defgeneric in-child (child x y))
 130
 131 (defmethod in-child ((child frame) x y)
 132   (in-frame child x y))
 133 (defmethod in-child ((child xlib:window) x y)
 134   (in-window child x y))
 135 (defmethod in-child (child x y)
 136   (declare (ignore child x y))
 137   nil)
 138
 139
 140
 141
 142 (defun frame-selected-child (frame)
 143   (when (frame-p frame)
 144     (with-slots (child selected-pos) frame
 145       (let ((len (length child)))
 146         (cond ((minusp selected-pos) (setf selected-pos 0))
 147               ((>= selected-pos len) (setf selected-pos (max (1- len) 0)))))
 148       (nth selected-pos child))))
 149
 150
 151
 152
 153
 154 (defgeneric child-equal-p (child-1 child-2))
 155
 156 (defmethod child-equal-p ((child-1 xlib:window) (child-2 xlib:window))
 157   (xlib:window-equal child-1 child-2))
 158
 159 (defmethod child-equal-p ((child-1 frame) (child-2 frame))
 160   (equal child-1 child-2))
 161
 162 (defmethod child-equal-p (child-1 child-2)
 163   (declare (ignore child-1 child-2))
 164   nil)
 165
 166
 167
 168
 169 (declaim (inline child-member child-remove child-position))
 170
 171 (defun child-member (child list)
 172   (member child list :test #'child-equal-p))
 173
 174 (defun child-remove (child list)
 175   (remove child list :test #'child-equal-p))
 176
 177 (defun child-position (child list)
 178   (position child list :test #'child-equal-p))
 179
 180
 181
 182 ;;; Frame data manipulation functions
 183 (defun frame-data-slot (frame slot)
 184   "Return the value associated to data slot"
 185   (when (frame-p frame)
 186     (second (assoc slot (frame-data frame)))))
 187
 188 (defun set-frame-data-slot (frame slot value)
 189   "Set the value associated to data slot"
 190   (when (frame-p frame)
 191     (with-slots (data) frame
 192       (setf data (remove (assoc slot data) data))
 193       (push (list slot value) data))
 194     value))
 195
 196 (defsetf frame-data-slot set-frame-data-slot)
 197
 198
 199 (defun remove-frame-data-slot (frame slot)
 200   "Remove a slot in frame data slots"
 201   (when (frame-p frame)
 202     (with-slots (data) frame
 203       (setf data (remove (assoc slot data) data)))))
 204
 205
 206
 207 (defun managed-window-p (window frame)
 208   "Return t only if window is managed by frame"
 209   (if (frame-p frame)
 210       (with-slots ((managed forced-managed-window)
 211                    (unmanaged forced-unmanaged-window)) frame
 212         (and (xlib:window-p window)
 213              (not (child-member window unmanaged))
 214              (not (member (xlib:wm-name window) unmanaged :test #'string-equal-p))
 215              (or (member :all (frame-managed-type frame))
 216                  (member (window-type window) (frame-managed-type frame))
 217                  (child-member window managed)
 218                  (member (xlib:wm-name window) managed :test #'string-equal-p))))
 219       t))
 220
 221
 222 (defun add-in-never-managed-window-list (value)
 223   (pushnew value *never-managed-window-list* :test #'equal))
 224
 225 (defun never-managed-window-p (window)
 226   (when (xlib:window-p window)
 227     (dolist (type *never-managed-window-list*)
 228       (when (funcall (first type) window)
 229         (return (values t (second type)))))))
 230
 231
 232
 233 (defgeneric child-name (child))
 234
 235 (defmethod child-name ((child xlib:window))
 236   (xlib:wm-name child))
 237
 238 (defmethod child-name ((child frame))
 239   (frame-name child))
 240
 241 (defmethod child-name (child)
 242   (declare (ignore child))
 243   "???")
 244
 245
 246 (defgeneric set-child-name (child name))
 247
 248 (defmethod set-child-name ((child xlib:window) name)
 249   (setf (xlib:wm-name child) name))
 250
 251 (defmethod set-child-name ((child frame) name)
 252   (setf (frame-name child) name))
 253
 254 (defmethod set-child-name (child name)
 255   (declare (ignore child name)))
 256
 257 (defsetf child-name set-child-name)
 258
 259
 260
 261
 262 (defgeneric child-fullname (child))
 263
 264 (defmethod child-fullname ((child xlib:window))
 265   (format nil "~A (~A)" (or (xlib:wm-name child) "?") (or (xlib:get-wm-class child) "?")))
 266
 267 (defmethod child-fullname ((child frame))
 268   (aif (frame-name child)
 269        (format nil "~A (Frame ~A)" it (frame-number child))
 270        (format nil "Frame ~A" (frame-number child))))
 271
 272 (defmethod child-fullname (child)
 273   (declare (ignore child))
 274   "???")
 275
 276
 277 (defgeneric child-transparency (child))
 278
 279 (defmethod child-transparency ((child xlib:window))
 280   (window-transparency child))
 281
 282 (defmethod child-transparency ((child frame))
 283   (window-transparency (frame-window child)))
 284
 285 (defmethod child-transparency (child)
 286   (declare (ignore child))
 287   1)
 288
 289 (defgeneric set-child-transparency (child value))
 290
 291 (defmethod set-child-transparency ((child xlib:window) value)
 292   (setf (window-transparency child) value))
 293
 294 (defmethod set-child-transparency ((child frame) value)
 295   (setf (window-transparency (frame-window child)) value))
 296
 297 (defmethod set-child-transparency (child value)
 298   (declare (ignore child value)))
 299
 300 (defsetf child-transparency set-child-transparency)
 301
 302
 303
 304 (defgeneric child-x (child))
 305 (defmethod child-x ((child xlib:window))
 306   (x-drawable-x child))
 307 (defmethod child-x ((child frame))
 308   (frame-rx child))
 309
 310 (defgeneric child-y (child))
 311 (defmethod child-y ((child xlib:window))
 312   (x-drawable-y child))
 313 (defmethod child-y ((child frame))
 314   (frame-ry child))
 315
 316 (defgeneric child-width (child))
 317 (defmethod child-width ((child xlib:window))
 318   (x-drawable-width child))
 319 (defmethod child-width ((child frame))
 320   (frame-rw child))
 321
 322 (defgeneric child-height (child))
 323 (defmethod child-height ((child xlib:window))
 324   (x-drawable-height child))
 325 (defmethod child-height ((child frame))
 326   (frame-rh child))
 327
 328 (defgeneric child-x2 (child))
 329 (defmethod child-x2 ((child xlib:window))
 330   (+ (x-drawable-x child) (x-drawable-width child)))
 331 (defmethod child-x2 ((child frame))
 332   (+ (frame-rx child) (frame-rw child)))
 333
 334 (defgeneric child-y2 (child))
 335 (defmethod child-y2 ((child xlib:window))
 336   (+ (x-drawable-y child) (x-drawable-height child)))
 337 (defmethod child-y2 ((child frame))
 338   (+ (frame-ry child) (frame-rh child)))
 339
 340
 341
 342 (defgeneric child-center (child))
 343
 344 (defmethod child-center ((child xlib:window))
 345   (values (+ (x-drawable-x child) (/ (x-drawable-width child) 2))
 346           (+ (x-drawable-y child) (/ (x-drawable-height child) 2))))
 347
 348 (defmethod child-center ((child frame))
 349   (values (+ (frame-rx child) (/ (frame-rw child) 2))
 350           (+ (frame-ry child) (/ (frame-rh child) 2))))
 351
 352 (defun child-distance (child1 child2)
 353   (multiple-value-bind (x1 y1) (child-center child1)
 354     (multiple-value-bind (x2 y2) (child-center child2)
 355       (values (+ (abs (- x2 x1)) (abs (- y2 y1)))
 356               (- x2 x1)
 357               (- y2 y1)))))
 358
 359 (defun middle-child-x (child)
 360   (+ (child-x child) (/ (child-width child) 2)))
 361
 362 (defun middle-child-y (child)
 363   (+ (child-y child) (/ (child-height child) 2)))
 364
 365 (declaim (inline adj-border-xy adj-border-wh))
 366 (defgeneric adj-border-xy (value child))
 367 (defgeneric adj-border-wh (value child))
 368
 369 (defmethod adj-border-xy (v (child xlib:window))
 370   (+ v (x-drawable-border-width child)))
 371
 372 (defmethod adj-border-xy (v (child frame))
 373   (+ v (x-drawable-border-width (frame-window child))))
 374
 375 (defmethod adj-border-wh (v (child xlib:window))
 376   (- v (* (x-drawable-border-width child) 2)))
 377
 378 (defmethod adj-border-wh (v (child frame))
 379   (- v (* (x-drawable-border-width (frame-window child)) 2)))
 380
 381
 382 (declaim (inline anti-adj-border-xy anti-adj-border-wh))
 383 (defgeneric anti-adj-border-xy (value child))
 384 (defgeneric anti-adj-border-wh (value child))
 385
 386 (defmethod anti-adj-border-xy (v (child xlib:window))
 387   (- v (x-drawable-border-width child)))
 388
 389 (defmethod anti-adj-border-xy (v (child frame))
 390   (- v (x-drawable-border-width (frame-window child))))
 391
 392 (defmethod anti-adj-border-wh (v (child xlib:window))
 393   (+ v (* (x-drawable-border-width child) 2)))
 394
 395 (defmethod anti-adj-border-wh (v (child frame))
 396   (+ v (* (x-drawable-border-width (frame-window child)) 2)))
 397
 398
 399
 400
 401 (defmacro with-focus-window ((window) &body body)
 402   `(let ((,window (xlib:input-focus *display*)))
 403      (when (and ,window (not (xlib:window-equal ,window *no-focus-window*)))
 404        ,@body)))
 405
 406
 407
 408 ;; (with-all-children (*root-frame* child) (typecase child (xlib:window (print child)) (frame (print (frame-number child)))))
 409 (defmacro with-all-children ((root child) &body body)
 410   (let ((rec (gensym))
 411         (sub-child (gensym)))
 412     `(block nil
 413        (labels ((,rec (,child)
 414                   ,@body
 415                   (when (frame-p ,child)
 416                     (dolist (,sub-child (reverse (frame-child ,child)))
 417                       (,rec ,sub-child)))))
 418          (,rec ,root)))))
 419
 420
 421 ;; (with-all-children (*root-frame* child) (typecase child (xlib:window (print child)) (frame (print (frame-number child)))))
 422 (defmacro with-all-children-reversed ((root child) &body body)
 423   (let ((rec (gensym))
 424         (sub-child (gensym)))
 425     `(block nil
 426        (labels ((,rec (,child)
 427                   ,@body
 428                   (when (frame-p ,child)
 429                     (dolist (,sub-child (frame-child ,child))
 430                       (,rec ,sub-child)))))
 431          (,rec ,root)))))
 432
 433
 434
 435
 436
 437 ;; (with-all-frames (*root-frame* frame) (print (frame-number frame)))
 438 (defmacro with-all-frames ((root frame) &body body)
 439   (let ((rec (gensym))
 440         (child (gensym)))
 441     `(block nil
 442        (labels ((,rec (,frame)
 443                   (when (frame-p ,frame)
 444                     ,@body
 445                     (dolist (,child (reverse (frame-child ,frame)))
 446                       (,rec ,child)))))
 447          (,rec ,root)))))
 448
 449
 450 ;; (with-all-windows (*root-frame* window) (print window))
 451 (defmacro with-all-windows ((root window) &body body)
 452   (let ((rec (gensym))
 453         (child (gensym)))
 454     `(block nil
 455        (labels ((,rec (,window)
 456                   (when (xlib:window-p ,window)
 457                     ,@body)
 458                   (when (frame-p ,window)
 459                     (dolist (,child (reverse (frame-child ,window)))
 460                       (,rec ,child)))))
 461          (,rec ,root)))))
 462
 463
 464
 465 ;; (with-all-frames-windows (*root-frame* child) (print child) (print (frame-number child)))
 466 (defmacro with-all-windows-frames ((root child) body-window body-frame)
 467   (let ((rec (gensym))
 468         (sub-child (gensym)))
 469     `(block nil
 470        (labels ((,rec (,child)
 471                   (typecase ,child
 472                     (xlib:window ,body-window)
 473                     (frame ,body-frame
 474                            (dolist (,sub-child (reverse (frame-child ,child)))
 475                              (,rec ,sub-child))))))
 476          (,rec ,root)))))
 477
 478 (defmacro with-all-windows-frames-and-parent ((root child parent) body-window body-frame)
 479   (let ((rec (gensym))
 480         (sub-child (gensym)))
 481     `(block nil
 482        (labels ((,rec (,child ,parent)
 483                   (typecase ,child
 484                     (xlib:window ,body-window)
 485                     (frame ,body-frame
 486                            (dolist (,sub-child (reverse (frame-child ,child)))
 487                              (,rec ,sub-child ,child))))))
 488          (,rec ,root nil)))))
 489
 490
 491
 492 (defun create-frame-window ()
 493   (let ((win (xlib:create-window :parent *root*
 494                                  :x 0
 495                                  :y 0
 496                                  :width 200
 497                                  :height 200
 498                                  :background (get-color *frame-background*)
 499                                  :colormap (xlib:screen-default-colormap *screen*)
 500                                  :border-width *border-size*
 501                                  :border (get-color *color-selected*)
 502                                  :event-mask '(:exposure :button-press :button-release :pointer-motion :enter-window))))
 503     (setf (window-transparency win) *frame-transparency*)
 504     win))
 505
 506 (defun create-frame-gc (window)
 507   (xlib:create-gcontext :drawable window
 508                         :foreground (get-color *frame-foreground*)
 509                         :background (get-color *frame-background*)
 510                         :font *default-font*
 511                         :line-style :solid))
 512
 513
 514 (defun destroy-all-frames-window ()
 515   (with-all-frames (*root-frame* frame)
 516     (when (frame-gc frame)
 517       (xlib:free-gcontext (frame-gc frame))
 518       (setf (frame-gc frame) nil))
 519     (when (frame-window frame)
 520       (xlib:destroy-window (frame-window frame))
 521       (setf (frame-window frame) nil))))
 522
 523 (defun create-all-frames-window ()
 524   (with-all-frames (*root-frame* frame)
 525     (unless (frame-window frame)
 526       (setf (frame-window frame) (create-frame-window)))
 527     (unless (frame-gc frame)
 528       (setf (frame-gc frame) (create-frame-gc (frame-window frame)))))
 529   (with-all-frames (*root-frame* frame)
 530     (dolist (child (frame-child frame))
 531       (handler-case
 532           (dbg (child-fullname child))
 533         (error (c)
 534           (setf (frame-child frame) (remove child (frame-child frame) :test #'child-equal-p))
 535           (dbg c child))))))
 536
 537
 538
 539
 540 (defun frame-find-free-number ()
 541   (let ((all-numbers nil))
 542     (with-all-frames (*root-frame* frame)
 543       (pushnew (frame-number frame) all-numbers))
 544     (find-free-number all-numbers)))
 545
 546
 547 (defun create-frame (&rest args &key (number (frame-find-free-number)) &allow-other-keys)
 548   (let* ((window (create-frame-window))
 549          (gc (create-frame-gc window)))
 550     (apply #'make-instance 'frame :number number :window window :gc gc args)))
 551
 552
 553 (defun add-frame (frame parent)
 554   (push frame (frame-child parent))
 555   frame)
 556
 557
 558 (defun place-frame (frame parent prx pry prw prh)
 559   "Place a frame from real (pixel) coordinates"
 560   (when (and (frame-p frame) (frame-p parent))
 561     (with-slots (window x y w h) frame
 562       (setf (x-drawable-x window) prx
 563             (x-drawable-y window) pry
 564             (x-drawable-width window) prw
 565             (x-drawable-height window) prh
 566             x (x-px->fl prx parent)
 567             y (y-px->fl pry parent)
 568             w (w-px->fl prw parent)
 569             h (h-px->fl prh parent))
 570       (xlib:display-finish-output *display*))))
 571
 572
 573
 574 (defun find-child (to-find root)
 575   "Find to-find in root or in its children"
 576   (with-all-children (root child)
 577     (when (child-equal-p child to-find)
 578       (return-from find-child t))))
 579
 580
 581
 582 (defmacro with-find-in-all-frames (test &optional return-value)
 583   `(let (ret)
 584      (block return-block
 585        (with-all-frames (root frame)
 586          (when ,test
 587            (if first-foundp
 588                (return-from return-block (or ,return-value frame))
 589                (setf ret frame))))
 590        (or ,return-value ret))))
 591
 592 (defun find-parent-frame  (to-find &optional (root *root-frame*) first-foundp)
 593   "Return the parent frame of to-find"
 594   (with-find-in-all-frames
 595       (child-member to-find (frame-child frame))))
 596
 597 (defun find-frame-window (window &optional (root *root-frame*) first-foundp)
 598   "Return the frame with the window window"
 599   (with-find-in-all-frames
 600       (xlib:window-equal window (frame-window frame))))
 601
 602 (defun find-frame-by-name (name &optional (root *root-frame*) first-foundp)
 603   "Find a frame from its name"
 604   (when name
 605     (with-find-in-all-frames
 606         (string-equal name (frame-name frame)))))
 607
 608 (defun find-frame-by-number (number &optional (root *root-frame*) first-foundp)
 609   "Find a frame from its number"
 610   (when (numberp number)
 611     (with-find-in-all-frames
 612         (= number (frame-number frame)))))
 613
 614
 615 (defun find-child-in-parent (child base)
 616   "Return t if child is in base or in its parents"
 617   (labels ((rec (base)
 618              (when (child-equal-p child base)
 619                (return-from find-child-in-parent t))
 620              (let ((parent (find-parent-frame base)))
 621                (when parent
 622                  (rec parent)))))
 623     (rec base)))
 624
 625 ;;; Multiple roots support (replace the old *current-root* variable)
 626 (let ((root-list nil)
 627       (current-child nil))
 628   (defun get-root-list ()
 629     root-list)
 630
 631   (let ((save-root-list nil))
 632     (defun save-root-list ()
 633       (setf save-root-list nil)
 634       (dolist (root root-list)
 635         (push (copy-root root) save-root-list)))
 636     (defun restore-root-list ()
 637       (setf root-list nil)
 638       (dolist (root save-root-list)
 639         (push (copy-root root) root-list))))
 640
 641   (defmacro with-saved-root-list (() &body body)
 642     `(progn
 643        (save-root-list)
 644        ,@body
 645        (restore-root-list)))
 646
 647   (defun reset-root-list ()
 648     (setf root-list nil
 649           current-child nil))
 650
 651   (defun define-as-root (child x y width height)
 652     (push (make-root :child child :original child :current-child nil :x x :y y :w width :h height) root-list))
 653
 654   (defun find-root-by-coordinates (x y)
 655     (dolist (root root-list)
 656       (when (in-rect x y (root-x root) (root-y root) (root-w root) (root-h root))
 657         (return root))))
 658
 659   (defun root (x &optional y)
 660     "Return the root at coordinates (x,y) if y is not nil.
 661      Otherwise, return the x nth root in root-list"
 662     (if y
 663         (find-root-by-coordinates x y)
 664         (nth x root-list)))
 665
 666   (defun all-root-child ()
 667     (loop for root in root-list
 668        collect (root-child root)))
 669
 670   (defmacro with-all-root-child ((root) &body body)
 671     (let ((root-symb (gensym)))
 672       `(dolist (,root-symb (get-root-list))
 673          (let ((,root (root-child ,root-symb)))
 674            ,@body))))
 675
 676   (labels ((generic-child-root-p (child function)
 677              (dolist (root root-list)
 678                (when (child-equal-p child (funcall function root))
 679                  (return root)))))
 680     (defun child-root-p (child)
 681       (generic-child-root-p child #'root-child))
 682
 683     (defun child-original-root-p (child)
 684       (generic-child-root-p child #'root-original)))
 685
 686   (defun change-root (old-root new-child)
 687     (when (and old-root new-child)
 688       (setf (root-child old-root) new-child)))
 689
 690   (defun find-root (child)
 691     (aif (child-original-root-p child)
 692          it
 693          (awhen (find-parent-frame child)
 694            (find-root it))))
 695
 696   (defun find-child-in-all-root (child)
 697     (dolist (root root-list)
 698       (when (find-child child (root-child root))
 699         (return-from find-child-in-all-root root))))
 700
 701   (defun find-current-root ()
 702     (root-child (find-root (current-child))))
 703
 704   (defun exchange-root-geometry (root-1 root-2)
 705     (when (and root-1 root-2)
 706       (rotatef (root-x root-1) (root-x root-2))
 707       (rotatef (root-y root-1) (root-y root-2))
 708       (rotatef (root-w root-1) (root-w root-2))
 709       (rotatef (root-h root-1) (root-h root-2))))
 710
 711   (defun rotate-root-geometry ()
 712     (let* ((current (first root-list))
 713            (orig-x (root-x current))
 714            (orig-y (root-y current))
 715            (orig-w (root-w current))
 716            (orig-h (root-h current)))
 717       (dolist (elem (rest root-list))
 718         (setf (root-x current) (root-x elem)
 719               (root-y current) (root-y elem)
 720               (root-w current) (root-w elem)
 721               (root-h current) (root-h elem)
 722               current elem))
 723       (let ((last (car (last root-list))))
 724         (setf (root-x last) orig-x
 725               (root-y last) orig-y
 726               (root-w last) orig-w
 727               (root-h last) orig-h))))
 728
 729   (defun anti-rotate-root-geometry ()
 730     (setf root-list (nreverse root-list))
 731     (rotate-root-geometry)
 732     (setf root-list (nreverse root-list)))
 733
 734   ;;; Current child functions
 735   (defun current-child ()
 736     current-child)
 737
 738   (defun current-child-setter (value)
 739     (awhen (find-root value)
 740       (setf (root-current-child it) value))
 741     (setf current-child value))
 742
 743   (defmacro with-current-child ((new-child) &body body)
 744     "Temporarly change the current child"
 745     (let ((old-child (gensym))
 746           (ret (gensym)))
 747       `(let ((,old-child (current-child)))
 748          (setf (current-child) ,new-child)
 749          (let ((,ret (multiple-value-list (progn ,@body))))
 750            (setf (current-child) ,old-child)
 751            (values-list ,ret)))))
 752
 753   (defun child-is-a-current-child-p (child)
 754     (find child root-list :test #'child-equal-p :key #'root-current-child)))
 755
 756 (defsetf current-child current-child-setter)
 757
 758 (defun ensure-at-least-one-root ()
 759   (unless (get-root-list)
 760     (let ((frame (create-frame)))
 761       (add-frame frame *root-frame*)
 762       (define-as-root frame 0 0 (xlib:screen-width *screen*) (xlib:screen-height *screen*))
 763       (add-frame (create-frame) frame))))
 764
 765
 766
 767
 768
 769
 770 (defun is-in-current-child-p (child)
 771   (and (frame-p (current-child))
 772        (child-member child (frame-child (current-child)))))
 773
 774
 775
 776 (defun fixe-real-size (frame parent)
 777   "Fixe real (pixel) coordinates in float coordinates"
 778   (when (frame-p frame)
 779     (with-slots (x y w h rx ry rw rh) frame
 780       (setf x (x-px->fl rx parent)
 781             y (y-px->fl ry parent)
 782             w (w-px->fl (anti-adj-border-wh rw parent) parent)
 783             h (h-px->fl (anti-adj-border-wh rh parent) parent)))))
 784
 785 (defun fixe-real-size-current-child ()
 786   "Fixe real (pixel) coordinates in float coordinates for children in the current child"
 787   (when (frame-p (current-child))
 788     (dolist (child (frame-child (current-child)))
 789       (fixe-real-size child (current-child)))))
 790
 791
 792
 793 ;;; Multiple physical screen helper
 794 (defun add-placed-frame-tmp (frame n)   ;; For test
 795   (add-frame (create-frame :x 0.01 :y 0.01 :w 0.4 :h 0.4) frame)
 796   (add-frame (create-frame :x 0.55 :y 0.01 :w 0.4 :h 0.4) frame)
 797   (add-frame (create-frame :x 0.03 :y 0.5 :w 0.64 :h 0.44) frame)
 798   (when (plusp n)
 799     (add-placed-frame-tmp (first (frame-child frame)) (1- n))))
 800
 801 (defun parse-xinerama-info (line)
 802   (remove nil
 803           (mapcar (lambda (string)
 804                     (parse-integer string :junk-allowed t))
 805                   (split-string (substitute #\space #\x (substitute #\space #\, line))))))
 806
 807 (defun get-connected-heads-size (&optional (fake (string= (getenv "DISPLAY") ":1")))
 808   (labels ((heads-info ()
 809              (if (not fake)
 810                  (do-shell "xdpyinfo -ext XINERAMA")
 811                  (progn
 812                    (setf *show-root-frame-p* t)
 813                    (do-shell "echo '    available colormap entries:    256 per subfield
 814     red, green, blue masks:    0xff0000, 0xff00, 0xff
 815     significant bits in color specification:    8 bits
 816
 817 XINERAMA version 1.1 opcode: 150
 818   head #0: 500x300 @ 10,10
 819   head #1: 480x300 @ 520,20
 820   head #2: 600x250 @ 310,330'")))))
 821     (when (xlib:query-extension *display* "XINERAMA")
 822       (let ((output (heads-info))
 823             (sizes nil))
 824         (loop for line = (read-line output nil nil)
 825            while line
 826            do (when (search " head " line)
 827                 (destructuring-bind (w h x y)
 828                     (parse-xinerama-info line)
 829                   (push (list x y w h) sizes))))
 830         (remove-duplicates sizes :test #'equal)))))
 831         ;;'((10 10 500 300) (550 50 400 400) (100 320 400 270))))))
 832         ;;'((10 10 500 580) (540 50 470 500))))))
 833
 834
 835 (defun place-frames-from-xinerama-infos ()
 836   "Place frames according to xdpyinfo/xinerama informations"
 837   (reset-root-list)
 838   (let ((sizes (get-connected-heads-size))
 839         (width (xlib:screen-width *screen*))
 840         (height (xlib:screen-height *screen*)))
 841     (format t "Screen sizes: ~A~%" sizes)
 842     ;; Add frames in *root-frame* until we get the same number as screen heads
 843     (loop while (< (length (frame-child *root-frame*)) (length sizes))
 844        do (let ((frame (create-frame)))
 845             (add-frame frame *root-frame*)))
 846     ;; On the opposite way: remove frames until there is more than screen heads in *root-frame*
 847     (when (and sizes (> (length (frame-child *root-frame*)) (length sizes)))
 848       (dotimes (i (- (length (frame-child *root-frame*)) (length sizes)))
 849         (let ((deleted-child (pop (frame-child *root-frame*))))
 850           (typecase deleted-child
 851             (xlib:window (push deleted-child (frame-child (first (frame-child *root-frame*)))))
 852             (frame (dolist (child (frame-child deleted-child))
 853                      (push child (frame-child (first (frame-child *root-frame*)))))))
 854           (setf (frame-layout (first (frame-child *root-frame*))) 'tile-space-layout
 855                 (frame-data-slot (first (frame-child *root-frame*)) :tile-layout-keep-position) :yes))))
 856     (loop for size in sizes
 857        for frame in (frame-child *root-frame*)
 858        do (destructuring-bind (x y w h) size
 859             (setf (frame-x frame) (float (/ x width))
 860                   (frame-y frame) (float (/ y height))
 861                   (frame-w frame) (float (/ w width))
 862                   (frame-h frame) (float (/ h height)))
 863             ;;(add-placed-frame-tmp frame 2)  ;; For tests
 864             (unless (frame-child frame)
 865               (add-frame (create-frame) frame))
 866             (define-as-root frame x y w h)))))
 867
 868
 869 (defun finish-configuring-root ()
 870   (ensure-at-least-one-root)
 871   (setf (current-child) (first (frame-child (first (frame-child *root-frame*))))))
 872
 873
 874
 875 (defun get-all-windows (&optional (root *root-frame*))
 876   "Return all windows in root and in its children"
 877   (let ((acc nil))
 878     (with-all-windows (root window)
 879       (push window acc))
 880     acc))
 881
 882 (defun get-all-frame-windows (&optional (root *root-frame*))
 883   "Return all frame windows in root and in its children"
 884   (let ((acc nil))
 885     (with-all-frames (root frame)
 886       (push (frame-window frame) acc))
 887     acc))
 888
 889
 890 (defun get-hidden-windows ()
 891   "Return all hiddens windows"
 892   (let ((all-windows (get-all-windows))
 893         (hidden-windows (remove-if-not #'window-hidden-p
 894                                        (copy-list (xlib:query-tree *root*)))))
 895     (set-difference hidden-windows all-windows)))
 896
 897
 898
 899 ;;; Current window utilities
 900 (defun get-current-window ()
 901   (typecase (current-child)
 902     (xlib:window  (current-child))
 903     (frame (frame-selected-child (current-child)))))
 904
 905 (defmacro with-current-window (&body body)
 906   "Bind 'window' to the current window"
 907   `(let ((window (get-current-window)))
 908       (when (xlib:window-p window)
 909         ,@body)))
 910
 911 (defun get-first-window ()
 912   (typecase (current-child)
 913     (xlib:window  (current-child))
 914     (frame (or (first (frame-child (current-child)))
 915                (current-child)))))
 916
 917
 918
 919
 920
 921 (defun display-frame-info (frame)
 922   (when (frame-p frame)
 923     (let ((dy (+ (xlib:max-char-ascent *default-font*) (xlib:max-char-descent *default-font*))))
 924       (with-slots (name number gc window child hidden-children) frame
 925         (setf (xlib:gcontext-background gc) (get-color *frame-background*)
 926               (xlib:window-background window) (get-color *frame-background*))
 927         (clear-pixmap-buffer window gc)
 928         (setf (xlib:gcontext-foreground gc) (get-color (if (and (child-root-p frame)
 929                                                                 (child-equal-p frame (current-child)))
 930                                                            *frame-foreground-root* *frame-foreground*)))
 931         (xlib:draw-glyphs *pixmap-buffer* gc 5 dy
 932                           (format nil "Frame: ~A~A"
 933                                   number
 934                                   (if name  (format nil " - ~A" name) "")))
 935         (let ((pos dy))
 936           (when (child-root-p frame)
 937             (when *child-selection*
 938               (xlib:draw-glyphs *pixmap-buffer* gc 5 (incf pos dy)
 939                                 (with-output-to-string (str)
 940                                   (format str "  Selection: ")
 941                                   (dolist (child *child-selection*)
 942                                     (typecase child
 943                                       (xlib:window (format str "  ~A " (xlib:wm-name child)))
 944                                       (frame (format str "  frame:~A[~A] " (frame-number child)
 945                                                      (aif (frame-name child) it "")))))))))
 946           (dolist (ch child)
 947             (xlib:draw-glyphs *pixmap-buffer* gc 5 (incf pos dy)
 948                               (format nil "  ~A" (ensure-printable (child-fullname ch))))))
 949         (copy-pixmap-buffer window gc)
 950         (values t t)))))
 951
 952
 953 (defgeneric rename-child (child name))
 954
 955 (defmethod rename-child ((child frame) name)
 956   (setf (frame-name child) name)
 957   (display-frame-info child))
 958
 959 (defmethod rename-child ((child xlib:window) name)
 960   (setf (xlib:wm-name child) name))
 961
 962 (defmethod rename-child (child name)
 963   (declare (ignore child name)))
 964
 965
 966 (defun get-parent-layout (child parent)
 967   (aif (child-root-p child)
 968        (values (- (root-x it) (child-border-size child)) (- (root-y it) (child-border-size child))
 969                (root-w it) (root-h it))
 970        (if (or (frame-p child) (managed-window-p child parent))
 971            (if (frame-p parent)
 972                (aif (frame-layout parent)
 973                     (funcall it child parent)
 974                     (no-layout child parent))
 975                (values (- (child-border-size child)) (- (child-border-size child))
 976                        (xlib:screen-width *screen*)
 977                        (xlib:screen-height *screen*)))
 978            (values (x-drawable-x child) (x-drawable-y child)
 979                    (x-drawable-width child) (x-drawable-height child)))))
 980
 981
 982
 983
 984
 985 (defgeneric adapt-child-to-parent (child parent))
 986
 987 (defmethod adapt-child-to-parent ((window xlib:window) parent)
 988   (when (managed-window-p window parent)
 989     (multiple-value-bind (nx ny nw nh)
 990         (get-parent-layout window parent)
 991       (setf nw (max nw 1)  nh (max nh 1))
 992       (let ((change nil))
 993         (when (or (/= (x-drawable-x window) nx)
 994                   (/= (x-drawable-y window) ny))
 995           (setf change :moved))
 996         (when (or (/= (x-drawable-width window) nw)
 997                   (/= (x-drawable-height window) nh))
 998           (setf change :resized))
 999         (when change
1000           (xlib:with-state (window)
1001             (setf (x-drawable-x window) nx
1002                   (x-drawable-y window) ny
1003                   (x-drawable-width window) nw
1004                   (x-drawable-height window) nh)))
1005         change))))
1006
1007
1008 (defmethod adapt-child-to-parent ((frame frame) parent)
1009   (declare (ignore parent))
1010     (with-slots (rx ry rw rh window) frame
1011       (let ((change nil))
1012         (when (or (/= (x-drawable-x window) rx)
1013                   (/= (x-drawable-y window) ry))
1014           (setf change :moved))
1015         (when (or (/= (x-drawable-width window) rw)
1016                   (/= (x-drawable-height window) rh))
1017           (setf change :resized))
1018         (when change
1019           (xlib:with-state (window)
1020             (setf (x-drawable-x window) rx
1021                   (x-drawable-y window) ry
1022                   (x-drawable-width window) rw
1023                   (x-drawable-height window) rh)))
1024         change)))
1025
1026 (defmethod adapt-child-to-parent (child parent)
1027   (declare (ignore child parent))
1028   nil)
1029
1030
1031 (defgeneric set-child-stack-order (window child)
1032   (:documentation "Raise window if child is NIL else put window just below child"))
1033
1034 (defmethod set-child-stack-order (window (child xlib:window))
1035   (lower-window window child))
1036
1037 (defmethod set-child-stack-order (window (child frame))
1038   (lower-window window (frame-window child)))
1039
1040 (defmethod set-child-stack-order (window child)
1041   (declare (ignore child))
1042   (raise-window window))
1043
1044
1045
1046 (defgeneric show-child (child parent previous))
1047
1048 (defmethod show-child ((frame frame) parent previous)
1049   (declare (ignore parent))
1050   (with-slots (window show-window-p) frame
1051     (if (and show-window-p
1052              (or *show-root-frame-p* (not (child-root-p frame))))
1053         (progn
1054           (map-window window)
1055           (set-child-stack-order window previous)
1056           (display-frame-info frame))
1057         (hide-window window))))
1058
1059
1060
1061 (defun hide-unmanaged-window-p (parent)
1062   (let ((action (frame-data-slot parent :unmanaged-window-action)))
1063     (case action
1064       (:hide t)
1065       (:show nil)
1066       (t *hide-unmanaged-window*))))
1067
1068
1069 (defmethod show-child ((window xlib:window) parent previous)
1070   (if (or (managed-window-p window parent)
1071           (child-equal-p window (current-child))
1072           (not (hide-unmanaged-window-p parent))
1073           (child-is-a-current-child-p parent))
1074       (progn
1075         (map-window window)
1076         (set-child-stack-order window previous))
1077       (hide-window window)))
1078
1079 (defmethod show-child (child parent raise-p)
1080   (declare (ignore child parent raise-p))
1081   ())
1082
1083
1084 (defgeneric hide-child (child))
1085
1086 (defmethod hide-child ((frame frame))
1087   (with-slots (window) frame
1088     (xlib:unmap-window window)))
1089
1090 (defmethod hide-child ((window xlib:window))
1091   (hide-window window))
1092
1093 (defmethod hide-child (child)
1094   (declare (ignore child))
1095   ())
1096
1097
1098 (defgeneric select-child (child selected))
1099
1100 (labels ((get-selected-color (child selected-p)
1101            (get-color (cond ((child-equal-p child (current-child)) *color-selected*)
1102                             (selected-p *color-maybe-selected*)
1103                             (t *color-unselected*)))))
1104   (defmethod select-child ((frame frame) selected-p)
1105     (when (and (frame-p frame) (frame-window frame))
1106       (setf (xlib:window-border (frame-window frame))
1107             (get-selected-color frame selected-p))))
1108
1109   (defmethod select-child ((window xlib:window) selected-p)
1110     (setf (xlib:window-border window)
1111           (get-selected-color window selected-p)))
1112
1113   (defmethod select-child (child selected)
1114     (declare (ignore child selected))
1115     ()))
1116
1117 (defun select-current-frame (selected)
1118   (select-child (current-child) selected))
1119
1120 (defun unselect-all-frames ()
1121   (with-all-children (*root-frame* child)
1122     (select-child child nil)))
1123
1124
1125
1126 (defun set-focus-to-current-child ()
1127   (labels ((rec (child)
1128              (typecase child
1129                (xlib:window (focus-window child))
1130                (frame (rec (frame-selected-child child))))))
1131     (no-focus)
1132     (rec (current-child))))
1133
1134
1135
1136
1137 (defun adapt-frame-to-parent (frame parent)
1138   (multiple-value-bind (nx ny nw nh)
1139       (get-parent-layout frame parent)
1140     (with-slots (rx ry rw rh window) frame
1141       (setf rx nx  ry ny
1142             rw (max nw 1)
1143             rh (max nh 1)))))
1144
1145
1146 (defun adapt-child-to-rect (rect)
1147   (let ((window (typecase (child-rect-child rect)
1148                   (xlib:window (when (managed-window-p (child-rect-child rect) (child-rect-parent rect))
1149                                  (child-rect-child rect)))
1150                   (frame (frame-window (child-rect-child rect))))))
1151     (when window
1152       (let ((change (or (/= (x-drawable-x window) (child-rect-x rect))
1153                         (/= (x-drawable-y window) (child-rect-y rect))
1154                         (/= (x-drawable-width window) (child-rect-w rect))
1155                         (/= (x-drawable-height window) (child-rect-h rect)))))
1156         (when change
1157           (setf (x-drawable-x window) (child-rect-x rect)
1158                 (x-drawable-y window) (child-rect-y rect)
1159                 (x-drawable-width window) (child-rect-w rect)
1160                 (x-drawable-height window) (child-rect-h rect)))
1161         change))))
1162
1163
1164
1165
1166 (defun show-all-children (&optional (from-root-frame nil))
1167   "Show all children and hide those not in a root frame"
1168   (declare (ignore from-root-frame))
1169   (let ((geometry-change nil)
1170         (displayed-child nil)
1171         (hidden-child nil))
1172     (labels ((in-displayed-list (child)
1173                (member child displayed-child :test (lambda (c rect)
1174                                                      (child-equal-p c (child-rect-child rect)))))
1175
1176              (add-in-hidden-list (child)
1177                (pushnew child hidden-child :test #'child-equal-p))
1178
1179              (set-geometry (child parent in-current-root child-current-root-p)
1180                (if (or in-current-root child-current-root-p)
1181                    (when (frame-p child)
1182                      (adapt-frame-to-parent child (if child-current-root-p nil parent)))
1183                    (add-in-hidden-list child)))
1184
1185              (recurse-on-frame-child (child in-current-root child-current-root-p selected-p)
1186                (let ((selected-child (frame-selected-child child)))
1187                  (dolist (sub-child (frame-child child))
1188                    (rec sub-child child
1189                         (and selected-p (child-equal-p sub-child selected-child))
1190                         (or in-current-root child-current-root-p)))))
1191
1192              (hidden-child-p (rect)
1193                (dolist (r displayed-child)
1194                  (when (and (rect-hidden-p r rect)
1195                             (or (not (xlib:window-p (child-rect-child r)))
1196                                 (eq (window-type (child-rect-child r)) :normal)))
1197                    (return t))))
1198
1199              (select-and-display (child parent selected-p)
1200                (multiple-value-bind (nx ny nw nh)
1201                    (get-parent-layout child parent)
1202                  (let ((rect (make-child-rect :child child :parent parent
1203                                               :selected-p selected-p
1204                                               :x nx :y ny :w nw :h nh)))
1205                    (if (and *show-hide-policy* (hidden-child-p rect))
1206                        (add-in-hidden-list child)
1207                        (push rect displayed-child)))))
1208
1209              (display-displayed-child ()
1210                (let ((previous nil))
1211                  (dolist (rect (nreverse displayed-child))
1212                    (when (adapt-child-to-rect rect)
1213                      (setf geometry-change t))
1214                    (select-child (child-rect-child rect) (child-rect-selected-p rect))
1215                    (show-child (child-rect-child rect)
1216                                (child-rect-parent rect)
1217                                previous)
1218                    (setf previous (child-rect-child rect)))))
1219
1220              (rec (child parent selected-p in-current-root)
1221                (let ((child-current-root-p (child-root-p child)))
1222                  (unless (in-displayed-list child)
1223                    (set-geometry child parent in-current-root child-current-root-p))
1224                  (when (frame-p child)
1225                    (recurse-on-frame-child child in-current-root child-current-root-p selected-p))
1226                  (when (and (or in-current-root child-current-root-p)
1227                             (not (in-displayed-list child)))
1228                    (select-and-display child parent selected-p)))))
1229
1230       (rec *root-frame* nil t (child-root-p *root-frame*))
1231       (display-displayed-child)
1232       (dolist (child hidden-child)
1233         (hide-child child))
1234       (set-focus-to-current-child)
1235       (xlib:display-finish-output *display*)
1236       geometry-change)))
1237
1238
1239
1240
1241 (defun hide-all-children (root &optional except)
1242   "Hide all root children"
1243   (when (and (frame-p root) (not (child-equal-p root except)))
1244     (dolist (child (frame-child root))
1245       (hide-all child except))))
1246
1247 (defun hide-all (root &optional except)
1248   "Hide root and all its children"
1249   (unless (child-equal-p root except)
1250     (hide-child root))
1251   (hide-all-children root except))
1252
1253
1254
1255
1256
1257 (defun focus-child (child parent)
1258   "Focus child - Return true if something has change"
1259   (when (and (frame-p parent)
1260              (child-member child (frame-child parent)))
1261     (when (not (child-equal-p child (frame-selected-child parent)))
1262       (with-slots ((parent-child child) selected-pos) parent
1263         (setf parent-child (nth-insert selected-pos child (child-remove child parent-child))))
1264       t)))
1265
1266 (defun focus-child-rec (child parent)
1267   "Focus child and its parents - Return true if something has change"
1268   (let ((change nil))
1269     (labels ((rec (child parent)
1270                (when (focus-child child parent)
1271                  (setf change t))
1272                (when parent
1273                  (rec parent (find-parent-frame parent)))))
1274       (rec child parent))
1275     change))
1276
1277
1278 (defun set-current-child-generic (child)
1279   (unless (child-equal-p (current-child) child)
1280     (setf (current-child) child)
1281     t))
1282
1283 (defgeneric set-current-child (child parent window-parent))
1284
1285 (defmethod set-current-child ((child xlib:window) parent window-parent)
1286   (set-current-child-generic (if window-parent parent child)))
1287
1288 (defmethod set-current-child ((child frame) parent window-parent)
1289   (declare (ignore parent window-parent))
1290   (set-current-child-generic child))
1291
1292 (defmethod set-current-child (child parent window-parent)
1293   (declare (ignore child parent window-parent))
1294   ())
1295
1296
1297 (defun set-current-root (child parent window-parent)
1298   "Set current root if parent is not in current root"
1299   (let ((root (find-root child)))
1300     (when (and root window-parent
1301                (not (child-root-p child))
1302                (not (find-child parent (root-child root))))
1303       (change-root root parent)
1304       t)))
1305
1306 (defun focus-all-children (child parent &optional (window-parent t))
1307   "Focus child and its parents -
1308 For window: set current child to window or its parent according to window-parent"
1309   (let ((new-focus (focus-child-rec child parent))
1310         (new-current-child (set-current-child child parent window-parent))
1311         (new-root (set-current-root child parent window-parent)))
1312     (or new-focus new-current-child new-root)))
1313
1314
1315
1316
1317 (defun select-next-level ()
1318   "Select the next level in frame"
1319   (select-current-frame :maybe)
1320   (when (frame-p (current-child))
1321     (awhen (frame-selected-child (current-child))
1322       (setf (current-child) it)))
1323   (show-all-children))
1324
1325 (defun select-previous-level ()
1326   "Select the previous level in frame"
1327   (unless (child-root-p (current-child))
1328     (select-current-frame :maybe)
1329     (awhen (find-parent-frame (current-child))
1330       (setf (current-child) it))
1331     (show-all-children)))
1332
1333
1334 (defun enter-frame ()
1335   "Enter in the selected frame - ie make it the root frame"
1336   (let ((root (find-root (current-child))))
1337     (when (and root (not (child-equal-p (root-child root) (current-child))))
1338       (change-root root (current-child)))
1339     (show-all-children t)))
1340
1341 (defun leave-frame ()
1342   "Leave the selected frame - ie make its parent the root frame"
1343   (let ((root (find-root (current-child))))
1344     (unless (or (child-equal-p (root-child root) *root-frame*)
1345                 (child-original-root-p (root-child root)))
1346       (awhen (and root (find-parent-frame (root-child root)))
1347         (when (frame-p it)
1348           (change-root root it)))
1349       (show-all-children))))
1350
1351
1352 ;;; Other actions (select-next-child, select-next-brother...) are in
1353 ;;; clfswm-circulate-mode.lisp
1354
1355
1356
1357 (defun frame-lower-child ()
1358   "Lower the child in the current frame"
1359   (when (frame-p (current-child))
1360     (with-slots (child selected-pos) (current-child)
1361       (unless (>= selected-pos (length child))
1362         (when (nth (1+ selected-pos) child)
1363           (rotatef (nth selected-pos child)
1364                    (nth (1+ selected-pos) child)))
1365         (incf selected-pos)))
1366     (show-all-children)))
1367
1368
1369 (defun frame-raise-child ()
1370   "Raise the child in the current frame"
1371   (when (frame-p (current-child))
1372     (with-slots (child selected-pos) (current-child)
1373       (unless (< selected-pos 1)
1374         (when (nth (1- selected-pos) child)
1375           (rotatef (nth selected-pos child)
1376                    (nth (1- selected-pos) child)))
1377         (decf selected-pos)))
1378     (show-all-children)))
1379
1380
1381 (defun frame-select-next-child ()
1382   "Select the next child in the current frame"
1383   (when (frame-p (current-child))
1384     (with-slots (child selected-pos) (current-child)
1385       (setf selected-pos (mod (1+ selected-pos) (max (length child) 1))))
1386     (show-all-children)))
1387
1388
1389 (defun frame-select-previous-child ()
1390   "Select the previous child in the current frame"
1391   (when (frame-p (current-child))
1392     (with-slots (child selected-pos) (current-child)
1393       (setf selected-pos (mod (1- selected-pos) (max (length child) 1))))
1394     (show-all-children)))
1395
1396
1397
1398 (defun switch-to-root-frame (&key (show-later nil))
1399   "Switch to the root frame"
1400   (let ((root (find-root (current-child))))
1401     (when root
1402       (change-root root (root-original root)))
1403     (unless show-later
1404       (show-all-children t))))
1405
1406 (defun switch-and-select-root-frame (&key (show-later nil))
1407   "Switch and select the root frame"
1408   (let ((root (find-root (current-child))))
1409     (when root
1410       (change-root root (root-original root))
1411       (setf (current-child) (root-original root)))
1412     (unless show-later
1413       (show-all-children t))))
1414
1415
1416 (defun toggle-show-root-frame ()
1417   "Show/Hide the root frame"
1418   (setf *show-root-frame-p* (not *show-root-frame-p*))
1419   (show-all-children))
1420
1421
1422
1423 (defun prevent-current-*-equal-child (child)
1424   " Prevent current-root and current-child equal to child"
1425   (if (child-original-root-p child)
1426       nil
1427       (progn
1428         (awhen (child-root-p child)
1429           (change-root it (find-parent-frame child)))
1430         (when (child-equal-p child (current-child))
1431           (awhen (find-root child)
1432             (setf (current-child) (root-child it))))
1433         t)))
1434
1435
1436
1437 (defun remove-child-in-frame (child frame)
1438   "Remove the child in frame"
1439   (when (frame-p frame)
1440     (setf (frame-child frame) (child-remove child (frame-child frame)))))
1441
1442 (defun remove-child-in-frames (child root)
1443   "Remove child in the frame root and in all its children"
1444   (with-all-frames (root frame)
1445     (remove-child-in-frame child frame)))
1446
1447
1448 (defun remove-child-in-all-frames (child)
1449   "Remove child in all frames from *root-frame*"
1450   (when (prevent-current-*-equal-child child)
1451     (remove-child-in-frames child *root-frame*)))
1452
1453
1454 (defun delete-child-in-frames (child root &optional (close-methode 'delete-window))
1455   "Delete child in the frame root and in all its children
1456 Warning:frame window and gc are freeed."
1457   (with-all-frames (root frame)
1458     (remove-child-in-frame child frame)
1459     (unless (find-frame-window (frame-window frame))
1460       (awhen (frame-gc frame) (xlib:free-gcontext it) (setf it nil))
1461       (awhen (frame-window frame) (xlib:destroy-window it) (setf it nil))))
1462   (when (xlib:window-p child)
1463     (funcall close-methode child)
1464     (netwm-remove-in-client-list child)))
1465
1466
1467
1468 (defun delete-child-in-all-frames (child &optional (close-methode 'delete-window))
1469   "Delete child in all frames from *root-frame*"
1470   (when (prevent-current-*-equal-child child)
1471     (delete-child-in-frames child *root-frame* close-methode)))
1472
1473 (defun delete-child-and-children-in-frames (child root &optional (close-methode 'delete-window))
1474   "Delete child and its children in the frame root and in all its children
1475 Warning:frame window and gc are freeed."
1476   (when (and (frame-p child) (frame-child child))
1477     (dolist (ch (frame-child child))
1478       (delete-child-and-children-in-frames ch root close-methode)))
1479   (delete-child-in-frames child root close-methode))
1480
1481 (defun delete-child-and-children-in-all-frames (child &optional (close-methode 'delete-window))
1482   "Delete child and its children in all frames from *root-frame*"
1483   (when (prevent-current-*-equal-child child)
1484     (when (frame-p child)
1485       (delete-child-and-children-in-frames child *root-frame* close-methode))
1486     (when (xlib:window-p child)
1487       (funcall close-methode child))))
1488
1489
1490 (defun clean-windows-in-all-frames ()
1491   "Remove all xlib:windows present in *root-frame* and not in the xlib tree"
1492   (let ((x-tree (xlib:query-tree *root*)))
1493     (with-all-frames (*root-frame* frame)
1494       (dolist (child (frame-child frame))
1495         (when (xlib:window-p child)
1496           (unless (member child x-tree :test #'xlib:window-equal)
1497             (when (prevent-current-*-equal-child child)
1498               (setf (frame-child frame)
1499                     (child-remove child (frame-child frame))))))))))
1500
1501
1502
1503 (defun do-all-frames-nw-hook (window)
1504   "Call nw-hook of each frame."
1505   (catch 'nw-hook-loop
1506     (let ((found nil))
1507       (with-all-frames (*root-frame* frame)
1508         (awhen (frame-nw-hook frame)
1509           (setf found (call-hook it frame window))))
1510       found)))
1511
1512
1513
1514 (defun process-new-window (window)
1515   "When a new window is created (or when we are scanning initial
1516 windows), this function dresses the window up and gets it ready to be
1517 managed."
1518   (setf (xlib:window-event-mask window) *window-events*)
1519   (set-window-state window +normal-state+)
1520   (setf (x-drawable-border-width window) (case (window-type window)
1521                                            (:normal *border-size*)
1522                                            (:maxsize 0)
1523                                            (:transient *border-size*)
1524                                            (:dialog *border-size*)
1525                                            (t *border-size*)))
1526   (grab-all-buttons window)
1527   (unless (never-managed-window-p window)
1528     (unless (do-all-frames-nw-hook window)
1529       (call-hook *default-nw-hook* *root-frame* window)))
1530   (netwm-add-in-client-list window))
1531
1532
1533
1534
1535 (defun with-all-mapped-windows (screen fun)
1536   (let ((all-windows (get-all-windows)))
1537     (dolist (win (xlib:query-tree (xlib:screen-root screen)))
1538       (unless (child-member win all-windows)
1539         (let ((map-state (xlib:window-map-state win))
1540               (wm-state (window-state win)))
1541           (unless (or (eql (xlib:window-override-redirect win) :on)
1542                       (eql win *no-focus-window*)
1543                       (is-notify-window-p win))
1544             (when (or (eql map-state :viewable)
1545                       (eql wm-state +iconic-state+))
1546               (funcall fun win))))))))
1547
1548 (defun store-root-background ()
1549   (with-all-mapped-windows *screen* #'hide-window)
1550   (setf *background-image* (xlib:create-pixmap :width (xlib:screen-width *screen*)
1551                                                :height (xlib:screen-height *screen*)
1552                                                :depth (xlib:screen-root-depth *screen*)
1553                                                :drawable *root*)
1554         *background-gc* (xlib:create-gcontext :drawable *background-image*
1555                                               :foreground (get-color *frame-foreground*)
1556                                               :background (get-color *frame-background*)
1557                                               :font *default-font*
1558                                               :line-style :solid))
1559   (xlib:copy-area *root* *background-gc*
1560                   0 0 (xlib:screen-width *screen*) (xlib:screen-height *screen*)
1561                   *background-image* 0 0)
1562   (with-all-mapped-windows *screen* #'unhide-window))
1563
1564
1565
1566
1567 (defun hide-existing-windows (screen)
1568   "Hide all existing windows in screen"
1569   (dolist (win (xlib:query-tree (xlib:screen-root screen)))
1570     (hide-window win)))
1571
1572
1573
1574 (defun process-existing-windows (screen)
1575   "Windows present when clfswm starts up must be absorbed by clfswm."
1576   (setf *in-process-existing-windows* t)
1577   (let ((id-list nil)
1578         (all-windows (get-all-windows))
1579         (all-frame-windows (get-all-frame-windows)))
1580     (dolist (win (xlib:query-tree (xlib:screen-root screen)))
1581       (unless (or (child-member win all-windows)
1582                   (child-member win all-frame-windows))
1583         (let ((map-state (xlib:window-map-state win))
1584               (wm-state (window-state win)))
1585           (unless (or (eql (xlib:window-override-redirect win) :on)
1586                       (eql win *no-focus-window*)
1587                       (is-notify-window-p win)
1588                       (never-managed-window-p win))
1589             (when (or (eql map-state :viewable)
1590                       (eql wm-state +iconic-state+))
1591               (format t "Processing ~S: type=~A ~S~%" (xlib:wm-name win) (window-type win) win)
1592               (unhide-window win)
1593               (process-new-window win)
1594               (map-window win)
1595               (raise-window win)
1596               (pushnew (xlib:window-id win) id-list))))))
1597     (netwm-set-client-list id-list))
1598   (setf *in-process-existing-windows* nil))
1599
1600
1601 ;;; Child order manipulation functions
1602 (defun put-child-on-top (child parent)
1603   "Put the child on top of its parent children"
1604   (when (frame-p parent)
1605     (setf (frame-child parent) (cons child (child-remove child (frame-child parent)))
1606           (frame-selected-pos parent) 0)))
1607
1608 (defun put-child-on-bottom (child parent)
1609   "Put the child at the bottom of its parent children"
1610   (when (frame-p parent)
1611     (setf (frame-child parent) (append (child-remove child (frame-child parent)) (list child))
1612           (frame-selected-pos parent) 0)))
1613
1614