src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46
  47 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  48   (let ((change nil))
  49     (labels ((has-x (mask) (= 1 (logand mask 1)))
  50              (has-y (mask) (= 2 (logand mask 2)))
  51              (has-w (mask) (= 4 (logand mask 4)))
  52              (has-h (mask) (= 8 (logand mask 8)))
  53              (has-bw (mask) (= 16 (logand mask 16)))
  54              (has-stackmode (mask) (= 64 (logand mask 64)))
  55              (adjust-from-request ()
  56                (when (has-x value-mask) (setf (x-drawable-x window) x
  57                                               change :moved))
  58                (when (has-y value-mask) (setf (x-drawable-y window) y
  59                                               change :moved))
  60                (when (has-h value-mask) (setf (x-drawable-height window) height
  61                                               change :resized))
  62                (when (has-w value-mask) (setf (x-drawable-width window) width
  63                                               change :resized))))
  64       (when window
  65         (xlib:with-state (window)
  66           (let ((current-root (find-current-root)))
  67             (if (find-child window current-root)
  68                 (let ((parent (find-parent-frame window current-root)))
  69                   (if (and parent (managed-window-p window parent))
  70                       (setf change (adapt-child-to-parent window parent))
  71                       (adjust-from-request)))
  72                 (adjust-from-request)))
  73           (when (has-bw value-mask)
  74             (setf (x-drawable-border-width window) border-width
  75                   change :resized))
  76           (when (has-stackmode value-mask)
  77             (case stack-mode
  78               (:above
  79                (when (or (child-equal-p window (current-child))
  80                          (is-in-current-child-p window))
  81                  (setf change (or change :moved))
  82                  (focus-window window)
  83                  (focus-all-children window (find-parent-frame window (find-current-root)))
  84                  (show-all-children))))))
  85         (unless (eq change :resized)
  86           ;; To be ICCCM compliant, send a fake configuration notify event only when
  87           ;; the window has moved and not when it has been resized or the border width has changed.
  88           (send-configuration-notify window (x-drawable-x window) (x-drawable-y window)
  89                                      (x-drawable-width window) (x-drawable-height window)
  90                                      (x-drawable-border-width window)))))))
  91
  92
  93 (define-handler main-mode :map-request (window send-event-p)
  94   (unless send-event-p
  95     (unless (find-child window *root-frame*)
  96       (unhide-window window)
  97       (process-new-window window)
  98       (map-window window)
  99       (multiple-value-bind (never-managed raise)
 100           (never-managed-window-p window)
 101         (unless (and never-managed raise)
 102           (show-all-children))))))
 103
 104
 105
 106 (define-handler main-mode :unmap-notify (send-event-p event-window window)
 107   (unless (and (not send-event-p)
 108                (not (xlib:window-equal window event-window)))
 109     (when (find-child window *root-frame*)
 110       (setf (window-state window) +withdrawn-state+)
 111       (remove-child-in-all-frames window)
 112       (show-all-children))))
 113
 114
 115 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 116   (unless (or send-event-p
 117               (xlib:window-equal window event-window))
 118     (when (find-child window *root-frame*)
 119       (delete-child-in-all-frames window)
 120       (show-all-children))))
 121
 122
 123 (define-handler main-mode :enter-notify  (window root-x root-y)
 124   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 125                (> root-y (- (xlib:screen-height *screen*) 3)))
 126     (case (if (frame-p (current-child))
 127               (frame-focus-policy (current-child))
 128               *default-focus-policy*)
 129       (:sloppy (focus-window window))
 130       (:sloppy-strict (when (and (frame-p (current-child))
 131                                  (child-member window (frame-child (current-child))))
 132                         (focus-window window)))
 133       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 134                              (parent (find-parent-frame child)))
 135                         (unless (or (child-root-p child)
 136                                     (equal (typecase child
 137                                              (xlib:window parent)
 138                                              (t child))
 139                                            (current-child)))
 140                             (focus-all-children child parent)
 141                             (show-all-children)))))))
 142
 143 (define-handler main-mode :exposure (window)
 144   (awhen (find-frame-window window)
 145     (display-frame-info it)))
 146
 147
 148 (define-handler main-mode :configure-notify (window)
 149   (when (child-equal-p window *root*)
 150     (unless (eql (place-frames-from-xinerama-infos) :update)
 151       (finish-configuring-root))
 152     (show-all-children)
 153     (call-hook *root-size-change-hook*)))
 154
 155
 156 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 157   "Handle X errors"
 158   (cond
 159     ;; ignore asynchronous window errors
 160     ((and asynchronous
 161           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 162      #+:xlib-debug (format t "~&Ignoring XLib asynchronous error: ~s~%" error-key))
 163     ((eq error-key 'xlib:access-error)
 164      (write-line "~&Another window manager is running.")
 165      (throw 'exit-clfswm nil))
 166     ;; all other asynchronous errors are printed.
 167     (asynchronous
 168      #+:xlib-debug (format t "~&Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 169     ;;((find error-key '(xlib:window-error xlib:drawable-error xlib:match-error))
 170     ;; (format t "~&Ignoring Xlib error: ~S ~S~%" error-key key-vals))
 171     (t
 172      (apply 'error error-key :display display :error-key error-key key-vals))))
 173
 174
 175 (defun main-loop ()
 176   (loop
 177      (with-xlib-protect (:main-loop nil)
 178        (call-hook *loop-hook*)
 179        (process-timers)
 180        (when (xlib:event-listen *display* *loop-timeout*)
 181          (xlib:process-event *display* :handler #'handle-event))
 182        (xlib:display-finish-output *display*)
 183        (setf *x-error-count* 0))))
 184
 185
 186
 187
 188 (defun open-display (display-str protocol)
 189   (multiple-value-bind (host display-num) (parse-display-string display-str)
 190     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 191           (xlib:display-error-handler *display*) 'error-handler
 192           (getenv "DISPLAY") display-str)))
 193
 194
 195
 196 (defun default-init-hook ()
 197   (place-frames-from-xinerama-infos)
 198   (finish-configuring-root))
 199
 200
 201 (defun init-display ()
 202   (reset-root-list)
 203   (reset-last-head-size)
 204   (reset-bind-or-jump-slots)
 205   (reset-open-menu)
 206   (fill-handle-event-fun-symbols)
 207   (assoc-keyword-handle-event 'main-mode)
 208   (setf *screen* (first (xlib:display-roots *display*))
 209         *root* (xlib:screen-root *screen*)
 210         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 211         *default-font* (xlib:open-font *display* *default-font-string*)
 212         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 213                                             :height (xlib:screen-height *screen*)
 214                                             :depth (xlib:screen-root-depth *screen*)
 215                                             :drawable *root*)
 216         *in-second-mode* nil
 217         *x-error-count* 0)
 218   (store-root-background)
 219   (init-modifier-list)
 220   (xgrab-init-pointer)
 221   (xgrab-init-keyboard)
 222   (init-last-child)
 223   (call-hook *binding-hook*)
 224   (clear-timers)
 225   (map-window *no-focus-window*)
 226   (dbg *display*)
 227   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 228                                                               :substructure-notify
 229                                                               :structure-notify
 230                                                               :property-change
 231                                                               ;;:resize-redirect
 232                                                               :exposure
 233                                                               :button-press
 234                                                               :button-release
 235                                                               :pointer-motion))
 236   (xlib:display-finish-output *display*)
 237   ;;(intern-atoms *display*)
 238   (netwm-set-properties)
 239   (xlib:display-force-output *display*)
 240   (setf *child-selection* nil)
 241   (setf *root-frame* (create-frame :name "Root" :number 0)
 242         (current-child) *root-frame*)
 243   (call-hook *init-hook*)
 244   (process-existing-windows *screen*)
 245   (show-all-children)
 246   (grab-main-keys)
 247   (xlib:display-finish-output *display*)
 248   (optimize-event-hook))
 249
 250
 251
 252
 253 (defun read-conf-file ()
 254   (let* ((conf (conf-file-name)))
 255     (if conf
 256         (handler-case (load conf)
 257           (error (c)
 258             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 259             (values nil (format nil "~s" c) conf))
 260           (:no-error (&rest args)
 261             (declare (ignore args))
 262             (values t nil conf)))
 263         (values t nil nil))))
 264
 265
 266
 267
 268
 269
 270 (defun exit-clfswm ()
 271   "Exit clfswm"
 272   (throw 'exit-clfswm nil))
 273
 274 (defun reset-clfswm ()
 275   "Reset clfswm"
 276   (throw 'exit-main-loop nil))
 277
 278
 279
 280
 281 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 282                          (read-conf-file-p t) (alternate-conf nil)
 283                          error-msg)
 284   (conf-file-name alternate-conf)
 285   (when read-conf-file-p
 286     (read-conf-file))
 287   (create-configuration-menu :clear t)
 288   (call-hook *main-entrance-hook*)
 289   (handler-case
 290       (open-display display protocol)
 291     (xlib:access-error (c)
 292       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 293       (force-output)
 294       (exit-clfswm)))
 295   (handler-case
 296       (init-display)
 297     (xlib:access-error (c)
 298       (ungrab-main-keys)
 299       (xlib:destroy-window *no-focus-window*)
 300       (xlib:close-display *display*)
 301       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 302       (force-output)
 303       (exit-clfswm)))
 304   (when error-msg
 305     (info-mode error-msg))
 306   (catch 'exit-main-loop
 307       (unwind-protect
 308            (main-loop)
 309         (progn
 310           (ungrab-main-keys)
 311           (xlib:destroy-window *no-focus-window*)
 312           (xlib:free-pixmap *pixmap-buffer*)
 313           (destroy-all-frames-window)
 314           (call-hook *close-hook*)
 315           (clear-event-hooks)
 316           (xlib:close-display *display*)
 317           #+:event-debug
 318           (format t "~2&Unhandled events: ~A~%" *unhandled-events*)))))
 319
 320
 321
 322 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 323              (read-conf-file-p t)
 324              (alternate-conf nil))
 325   (let (error-msg)
 326     (catch 'exit-clfswm
 327       (loop
 328          (handler-case
 329              (if *other-window-manager*
 330                  (run-other-window-manager)
 331                  (main-unprotected :display display :protocol protocol
 332                                    :read-conf-file-p read-conf-file-p
 333                                    :alternate-conf alternate-conf
 334                                    :error-msg error-msg))
 335            (error (c)
 336              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 337                (format t "~&~A~%Reinitializing...~%" msg)
 338                (setf error-msg (list (list msg *info-color-title*)
 339                                      "Reinitializing...")))))))))
 340
 341
 342