src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46
  47 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  48   (let ((change nil))
  49     (labels ((has-x (mask) (= 1 (logand mask 1)))
  50              (has-y (mask) (= 2 (logand mask 2)))
  51              (has-w (mask) (= 4 (logand mask 4)))
  52              (has-h (mask) (= 8 (logand mask 8)))
  53              (has-bw (mask) (= 16 (logand mask 16)))
  54              (has-stackmode (mask) (= 64 (logand mask 64)))
  55              (adjust-from-request ()
  56                (when (has-x value-mask) (setf (x-drawable-x window) x
  57                                               change :moved))
  58                (when (has-y value-mask) (setf (x-drawable-y window) y
  59                                               change :moved))
  60                (when (has-h value-mask) (setf (x-drawable-height window) height
  61                                               change :resized))
  62                (when (has-w value-mask) (setf (x-drawable-width window) width
  63                                               change :resized))))
  64       (when window
  65         (xlib:with-state (window)
  66           (let ((current-root (find-current-root)))
  67             (if (find-child window current-root)
  68                 (let ((parent (find-parent-frame window current-root)))
  69                   (if (and parent (managed-window-p window parent))
  70                       (setf change (adapt-child-to-parent window parent))
  71                       (adjust-from-request)))
  72                 (adjust-from-request)))
  73           (when (has-bw value-mask)
  74             (setf (x-drawable-border-width window) border-width
  75                   change :resized))
  76           (when (has-stackmode value-mask)
  77             (case stack-mode
  78               (:above
  79                (unless (null-size-window-p window)
  80                  (when (or (child-equal-p window (current-child))
  81                            (is-in-current-child-p window))
  82                    (setf change (or change :moved))
  83                    (raise-window window)
  84                    (focus-window window)
  85                    (focus-all-children window (find-parent-frame window (find-current-root)))))))))
  86         (unless (eq change :resized)
  87           ;; To be ICCCM compliant, send a fake configuration notify event only when
  88           ;; the window has moved and not when it has been resized or the border width has changed.
  89           (send-configuration-notify window (x-drawable-x window) (x-drawable-y window)
  90                                      (x-drawable-width window) (x-drawable-height window)
  91                                      (x-drawable-border-width window)))))))
  92
  93
  94 (define-handler main-mode :map-request (window send-event-p)
  95   (unless send-event-p
  96     (unless (find-child window *root-frame*)
  97       (unhide-window window)
  98       (process-new-window window)
  99       (map-window window)
 100       (unless (null-size-window-p window)
 101         (multiple-value-bind (never-managed raise)
 102             (never-managed-window-p window)
 103           (unless (and never-managed raise)
 104             (show-all-children)))))))
 105
 106
 107
 108 (define-handler main-mode :unmap-notify (send-event-p event-window window)
 109   (unless (and (not send-event-p)
 110                (not (xlib:window-equal window event-window)))
 111     (when (find-child window *root-frame*)
 112       (setf (window-state window) +withdrawn-state+)
 113       (xlib:unmap-window window)
 114       (remove-child-in-all-frames window)
 115       (show-all-children))))
 116
 117
 118
 119
 120
 121 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 122   (unless (or send-event-p
 123               (xlib:window-equal window event-window))
 124     (when (find-child window *root-frame*)
 125       (delete-child-in-all-frames window)
 126       (show-all-children)
 127       (xlib:destroy-window window))))
 128
 129 (define-handler main-mode :enter-notify  (window root-x root-y)
 130   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 131                (> root-y (- (xlib:screen-height *screen*) 3)))
 132     (case (if (frame-p (current-child))
 133               (frame-focus-policy (current-child))
 134               *default-focus-policy*)
 135       (:sloppy (focus-window window))
 136       (:sloppy-strict (when (and (frame-p (current-child))
 137                                  (child-member window (frame-child (current-child))))
 138                         (focus-window window)))
 139       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 140                              (parent (find-parent-frame child)))
 141                         (unless (or (child-root-p child)
 142                                     (equal (typecase child
 143                                              (xlib:window parent)
 144                                              (t child))
 145                                            (current-child)))
 146                             (focus-all-children child parent)
 147                             (show-all-children)))))))
 148
 149 (define-handler main-mode :exposure (window)
 150   (awhen (find-frame-window window)
 151     (display-frame-info it)))
 152
 153
 154 (define-handler main-mode :configure-notify (window)
 155   (when (child-equal-p window *root*)
 156     (unless (null-size-window-in-frame *root-frame*)
 157       (unless (eql (place-frames-from-xinerama-infos) :update)
 158         (finish-configuring-root))
 159       (show-all-children)
 160       (call-hook *root-size-change-hook*))))
 161
 162
 163 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 164   "Handle X errors"
 165   (cond
 166     ;; ignore asynchronous window errors
 167     ((and asynchronous
 168           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 169      #+:xlib-debug (format t "~&Ignoring XLib asynchronous error: ~s~%" error-key))
 170     ((eq error-key 'xlib:access-error)
 171      (write-line "~&Another window manager is running.")
 172      (throw 'exit-clfswm nil))
 173     ;; all other asynchronous errors are printed.
 174     (asynchronous
 175      #+:xlib-debug (format t "~&Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 176     ;;((find error-key '(xlib:window-error xlib:drawable-error xlib:match-error))
 177     ;; (format t "~&Ignoring Xlib error: ~S ~S~%" error-key key-vals))
 178     (t
 179      (apply 'error error-key :display display :error-key error-key key-vals))))
 180
 181
 182 (defun main-loop ()
 183   (loop
 184      (with-xlib-protect (:main-loop nil)
 185        (call-hook *loop-hook*)
 186        (process-timers)
 187        (when (xlib:event-listen *display* *loop-timeout*)
 188          (xlib:process-event *display* :handler #'handle-event))
 189        (xlib:display-finish-output *display*)
 190        (setf *x-error-count* 0))))
 191
 192
 193
 194
 195 (defun open-display (display-str protocol)
 196   (multiple-value-bind (host display-num) (parse-display-string display-str)
 197     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 198           (xlib:display-error-handler *display*) 'error-handler
 199           (getenv "DISPLAY") display-str)))
 200
 201
 202
 203 (defun default-init-hook ()
 204   (place-frames-from-xinerama-infos)
 205   (finish-configuring-root))
 206
 207
 208 (defun init-display ()
 209   (reset-root-list)
 210   (reset-bind-or-jump-slots)
 211   (reset-open-menu)
 212   (fill-handle-event-fun-symbols)
 213   (assoc-keyword-handle-event 'main-mode)
 214   (setf *screen* (first (xlib:display-roots *display*))
 215         *root* (xlib:screen-root *screen*)
 216         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 217         *default-font* (xlib:open-font *display* *default-font-string*)
 218         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 219                                             :height (xlib:screen-height *screen*)
 220                                             :depth (xlib:screen-root-depth *screen*)
 221                                             :drawable *root*)
 222         *in-second-mode* nil
 223         *x-error-count* 0)
 224   (store-root-background)
 225   (init-modifier-list)
 226   (xgrab-init-pointer)
 227   (xgrab-init-keyboard)
 228   (init-last-child)
 229   (call-hook *binding-hook*)
 230   (clear-timers)
 231   (map-window *no-focus-window*)
 232   (dbg *display*)
 233   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 234                                                               :substructure-notify
 235                                                               :structure-notify
 236                                                               :property-change
 237                                                               ;;:resize-redirect
 238                                                               :exposure
 239                                                               :button-press
 240                                                               :button-release
 241                                                               :pointer-motion))
 242   (xlib:display-finish-output *display*)
 243   ;;(intern-atoms *display*)
 244   (netwm-set-properties)
 245   (xlib:display-force-output *display*)
 246   (setf *child-selection* nil)
 247   (setf *root-frame* (create-frame :name "Root" :number 0)
 248         (current-child) *root-frame*)
 249   (call-hook *init-hook*)
 250   (process-existing-windows *screen*)
 251   (show-all-children)
 252   (grab-main-keys)
 253   (xlib:display-finish-output *display*)
 254   (optimize-event-hook))
 255
 256
 257
 258
 259 (defun read-conf-file ()
 260   (let* ((conf (conf-file-name)))
 261     (if conf
 262         (handler-case (load conf)
 263           (error (c)
 264             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 265             (values nil (format nil "~s" c) conf))
 266           (:no-error (&rest args)
 267             (declare (ignore args))
 268             (values t nil conf)))
 269         (values t nil nil))))
 270
 271
 272
 273
 274
 275
 276 (defun exit-clfswm ()
 277   "Exit clfswm"
 278   (throw 'exit-clfswm nil))
 279
 280 (defun reset-clfswm ()
 281   "Reset clfswm"
 282   (throw 'exit-main-loop nil))
 283
 284
 285
 286
 287 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 288                          (read-conf-file-p t) (alternate-conf nil)
 289                          error-msg)
 290   (conf-file-name alternate-conf)
 291   (when read-conf-file-p
 292     (read-conf-file))
 293   (create-configuration-menu :clear t)
 294   (call-hook *main-entrance-hook*)
 295   (handler-case
 296       (open-display display protocol)
 297     (xlib:access-error (c)
 298       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 299       (force-output)
 300       (exit-clfswm)))
 301   (handler-case
 302       (init-display)
 303     (xlib:access-error (c)
 304       (ungrab-main-keys)
 305       (xlib:destroy-window *no-focus-window*)
 306       (xlib:close-display *display*)
 307       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 308       (force-output)
 309       (exit-clfswm)))
 310   (when error-msg
 311     (info-mode error-msg))
 312   (catch 'exit-main-loop
 313       (unwind-protect
 314            (main-loop)
 315         (progn
 316           (ungrab-main-keys)
 317           (xlib:destroy-window *no-focus-window*)
 318           (xlib:free-pixmap *pixmap-buffer*)
 319           (destroy-all-frames-window)
 320           (call-hook *close-hook*)
 321           (clear-event-hooks)
 322           (xlib:close-display *display*)
 323           #+:event-debug
 324           (format t "~2&Unhandled events: ~A~%" *unhandled-events*)))))
 325
 326
 327
 328 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 329              (read-conf-file-p t)
 330              (alternate-conf nil))
 331   (let (error-msg)
 332     (catch 'exit-clfswm
 333       (loop
 334          (handler-case
 335              (if *other-window-manager*
 336                  (run-other-window-manager)
 337                  (main-unprotected :display display :protocol protocol
 338                                    :read-conf-file-p read-conf-file-p
 339                                    :alternate-conf alternate-conf
 340                                    :error-msg error-msg))
 341            (error (c)
 342              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 343                (format t "~&~A~%Reinitializing...~%" msg)
 344                (setf error-msg (list (list msg *info-color-title*)
 345                                      "Reinitializing...")))))))))
 346
 347
 348