sqlite.lisp

   1 (defpackage :sqlite
   2   (:use :cl :iter)
   3   (:export :sqlite-error
   4            :sqlite-constraint-error
   5            :sqlite-error-db-handle
   6            :sqlite-error-code
   7            :sqlite-error-message
   8            :sqlite-error-sql
   9            :sqlite-handle
  10            :connect
  11            :set-busy-timeout
  12            :disconnect
  13            :sqlite-statement
  14            :prepare-statement
  15            :finalize-statement
  16            :step-statement
  17            :reset-statement
  18            :clear-statement-bindings
  19            :statement-column-value
  20            :statement-column-names
  21            :statement-bind-parameter-names
  22            :bind-parameter
  23            :execute-non-query
  24            :execute-to-list
  25            :execute-single
  26            :execute-one-row-m-v
  27            :last-insert-rowid
  28            :with-transaction
  29            :with-open-database))
  30
  31 (in-package :sqlite)
  32
  33 (define-condition sqlite-error (simple-error)
  34   ((handle     :initform nil :initarg :db-handle
  35                :reader sqlite-error-db-handle)
  36    (error-code :initform nil :initarg :error-code
  37                :reader sqlite-error-code)
  38    (error-msg  :initform nil :initarg :error-msg
  39                :reader sqlite-error-message)
  40    (statement  :initform nil :initarg :statement
  41                :reader sqlite-error-statement)
  42    (sql        :initform nil :initarg :sql
  43                :reader sqlite-error-sql)))
  44
  45 (define-condition sqlite-constraint-error (sqlite-error)
  46   ())
  47
  48 (defun sqlite-error (error-code message &key
  49                      statement
  50                      (db-handle (if statement (db statement)))
  51                      (sql-text (if statement (sql statement))))
  52   (error (if (eq error-code :constraint)
  53              'sqlite-constraint-error
  54              'sqlite-error)
  55          :format-control (if (listp message) (first message) message)
  56          :format-arguments (if (listp message) (rest message))
  57          :db-handle db-handle
  58          :error-code error-code
  59          :error-msg (if db-handle
  60                         (sqlite-ffi:sqlite3-errmsg (handle db-handle)))
  61          :statement statement
  62          :sql sql-text))
  63
  64 (defmethod print-object :after ((obj sqlite-error) stream)
  65   (unless *print-escape*
  66     (when (or (and (sqlite-error-code obj)
  67                    (not (eq (sqlite-error-code obj) :ok)))
  68               (sqlite-error-message obj))
  69       (format stream "~&Code ~A: ~A."
  70               (or (sqlite-error-code obj) :OK)
  71               (or (sqlite-error-message obj) "no message")))
  72     (when (sqlite-error-db-handle obj)
  73       (format stream "~&Database: ~A"
  74               (database-path (sqlite-error-db-handle obj))))
  75     (when (sqlite-error-sql obj)
  76       (format stream "~&SQL: ~A" (sqlite-error-sql obj)))))
  77
  78 ;(declaim (optimize (speed 3) (safety 0) (debug 0)))
  79
  80 (defclass sqlite-handle ()
  81   ((handle :accessor handle)
  82    (database-path :accessor database-path)
  83    (cache :accessor cache)
  84    (statements :initform nil :accessor sqlite-handle-statements))
  85   (:documentation "Class that encapsulates the connection to the database. Use connect and disconnect."))
  86
  87 (defmethod initialize-instance :after ((object sqlite-handle) &key (database-path ":memory:") &allow-other-keys)
  88   (cffi:with-foreign-object (ppdb 'sqlite-ffi:p-sqlite3)
  89     (let ((error-code (sqlite-ffi:sqlite3-open database-path ppdb)))
  90       (if (eq error-code :ok)
  91           (setf (handle object) (cffi:mem-ref ppdb 'sqlite-ffi:p-sqlite3)
  92                 (database-path object) database-path)
  93           (sqlite-error error-code (list "Could not open sqlite3 database ~A" database-path)))))
  94   (setf (cache object) (make-instance 'sqlite.cache:mru-cache :cache-size 16 :destructor #'really-finalize-statement)))
  95
  96 (defun connect (database-path &key busy-timeout)
  97   "Connect to the sqlite database at the given DATABASE-PATH. Returns the SQLITE-HANDLE connected to the database. Use DISCONNECT to disconnect.
  98    Operations will wait for locked databases for up to BUSY-TIMEOUT milliseconds; if BUSY-TIMEOUT is NIL, then operations on locked databases will fail immediately."
  99   (let ((db (make-instance 'sqlite-handle
 100                            :database-path (etypecase database-path
 101                                             (string database-path)
 102                                             (pathname (namestring database-path))))))
 103     (when busy-timeout
 104       (set-busy-timeout db busy-timeout))
 105     db))
 106
 107 (defun set-busy-timeout (db milliseconds)
 108   "Sets the maximum amount of time to wait for a locked database."
 109   (sqlite-ffi:sqlite3-busy-timeout (handle db) milliseconds))
 110
 111 (defun disconnect (handle)
 112   "Disconnects the given HANDLE from the database. All further operations on the handle are invalid."
 113   (sqlite.cache:purge-cache (cache handle))
 114   (iter (with statements = (copy-list (sqlite-handle-statements handle)))
 115         (declare (dynamic-extent statements))
 116         (for statement in statements)
 117         (really-finalize-statement statement))
 118   (let ((error-code (sqlite-ffi:sqlite3-close (handle handle))))
 119     (unless (eq error-code :ok)
 120       (sqlite-error error-code "Could not close sqlite3 database." :db-handle handle))
 121     (slot-makunbound handle 'handle)))
 122
 123 (defclass sqlite-statement ()
 124   ((db :reader db :initarg :db)
 125    (handle :accessor handle)
 126    (sql :reader sql :initarg :sql)
 127    (columns-count :accessor resultset-columns-count)
 128    (columns-names :accessor resultset-columns-names :reader statement-column-names)
 129    (parameters-count :accessor parameters-count)
 130    (parameters-names :accessor parameters-names :reader statement-bind-parameter-names))
 131   (:documentation "Class that represents the prepared statement."))
 132
 133 (defmethod initialize-instance :after ((object sqlite-statement) &key &allow-other-keys)
 134   (cffi:with-foreign-object (p-statement 'sqlite-ffi:p-sqlite3-stmt)
 135     (cffi:with-foreign-object (p-tail '(:pointer :char))
 136       (cffi:with-foreign-string (sql (sql object))
 137         (let ((error-code (sqlite-ffi:sqlite3-prepare (handle (db object)) sql -1 p-statement p-tail)))
 138           (unless (eq error-code :ok)
 139             (sqlite-error error-code "Could not prepare an sqlite statement."
 140                           :db-handle (db object) :sql-text (sql object)))
 141           (unless (zerop (cffi:mem-ref (cffi:mem-ref p-tail '(:pointer :char)) :uchar))
 142             (sqlite-error nil "SQL string contains more than one SQL statement." :sql-text (sql object)))
 143           (setf (handle object) (cffi:mem-ref p-statement 'sqlite-ffi:p-sqlite3-stmt)
 144                 (resultset-columns-count object) (sqlite-ffi:sqlite3-column-count (handle object))
 145                 (resultset-columns-names object) (loop
 146                                                     for i below (resultset-columns-count object)
 147                                                     collect (sqlite-ffi:sqlite3-column-name (handle object) i))
 148                 (parameters-count object) (sqlite-ffi:sqlite3-bind-parameter-count (handle object))
 149                 (parameters-names object) (loop
 150                                              for i from 1 to (parameters-count object)
 151                                              collect (sqlite-ffi:sqlite3-bind-parameter-name (handle object) i))))))))
 152
 153 (defun prepare-statement (db sql)
 154   "Prepare the statement to the DB that will execute the commands that are in SQL.
 155
 156 Returns the SQLITE-STATEMENT.
 157
 158 SQL must contain exactly one statement.
 159 SQL may have some positional (not named) parameters specified with question marks.
 160
 161 Example:
 162
 163  select name from users where id = ?"
 164   (or (sqlite.cache:get-from-cache (cache db) sql)
 165       (let ((statement (make-instance 'sqlite-statement :db db :sql sql)))
 166         (push statement (sqlite-handle-statements db))
 167         statement)))
 168
 169 (defun really-finalize-statement (statement)
 170   (setf (sqlite-handle-statements (db statement))
 171         (delete statement (sqlite-handle-statements (db statement))))
 172   (sqlite-ffi:sqlite3-finalize (handle statement))
 173   (slot-makunbound statement 'handle))
 174
 175 (defun finalize-statement (statement)
 176   "Finalizes the statement and signals that associated resources may be released.
 177 Note: does not immediately release resources because statements are cached."
 178   (reset-statement statement)
 179   (sqlite.cache:put-to-cache (cache (db statement)) (sql statement) statement))
 180
 181 (defun step-statement (statement)
 182   "Steps to the next row of the resultset of STATEMENT.
 183 Returns T is successfully advanced to the next row and NIL if there are no more rows."
 184   (let ((error-code (sqlite-ffi:sqlite3-step (handle statement))))
 185     (case error-code
 186       (:done nil)
 187       (:row t)
 188       (t
 189        (sqlite-error error-code "Error while stepping an sqlite statement." :statement statement)))))
 190
 191 (defun reset-statement (statement)
 192   "Resets the STATEMENT and prepare it to be called again."
 193   (let ((error-code (sqlite-ffi:sqlite3-reset (handle statement))))
 194     (unless (eq error-code :ok)
 195       (sqlite-error error-code "Error while resetting an sqlite statement." :statement statement))))
 196
 197 (defun clear-statement-bindings (statement)
 198   "Sets all binding values to NULL."
 199   (let ((error-code (sqlite-ffi:sqlite3-clear-bindings (handle statement))))
 200     (unless (eq error-code :ok)
 201       (sqlite-error error-code "Error while clearing bindings of an sqlite statement."
 202                     :statement statement))))
 203
 204 (defun statement-column-value (statement column-number)
 205   "Returns the COLUMN-NUMBER-th column's value of the current row of the STATEMENT. Columns are numbered from zero.
 206 Returns:
 207  * NIL for NULL
 208  * INTEGER for integers
 209  * DOUBLE-FLOAT for floats
 210  * STRING for text
 211  * (SIMPLE-ARRAY (UNSIGNED-BYTE 8)) for BLOBs"
 212   (let ((type (sqlite-ffi:sqlite3-column-type (handle statement) column-number)))
 213     (ecase type
 214       (:null nil)
 215       (:text (sqlite-ffi:sqlite3-column-text (handle statement) column-number))
 216       (:integer (sqlite-ffi:sqlite3-column-int64 (handle statement) column-number))
 217       (:float (sqlite-ffi:sqlite3-column-double (handle statement) column-number))
 218       (:blob (let* ((blob-length (sqlite-ffi:sqlite3-column-bytes (handle statement) column-number))
 219                     (result (make-array (the fixnum blob-length) :element-type '(unsigned-byte 8)))
 220                     (blob (sqlite-ffi:sqlite3-column-blob (handle statement) column-number)))
 221                (loop
 222                   for i below blob-length
 223                   do (setf (aref result i) (cffi:mem-aref blob :unsigned-char i)))
 224                result)))))
 225
 226 (defun execute-non-query (db sql &rest parameters)
 227   "Executes the query SQL to the database DB with given PARAMETERS. Returns nothing.
 228
 229 Example:
 230
 231 \(execute-non-query db \"insert into users (user_name, real_name) values (?, ?)\" \"joe\" \"Joe the User\")
 232
 233 See BIND-PARAMETER for the list of supported parameter types."
 234   (declare (dynamic-extent parameters))
 235   (let ((stmt (prepare-statement db sql)))
 236     (iter (for i from 1)
 237           (declare (type fixnum i))
 238           (for value in parameters)
 239           (bind-parameter stmt i value))
 240     (step-statement stmt)
 241     (finalize-statement stmt)
 242     (values)))
 243
 244 (defun execute-to-list (db sql &rest parameters)
 245   "Executes the query SQL to the database DB with given PARAMETERS. Returns the results as list of lists.
 246
 247 Example:
 248
 249 \(execute-to-list db \"select id, user_name, real_name from users where user_name = ?\" \"joe\")
 250 =>
 251 \((1 \"joe\" \"Joe the User\")
 252  (2 \"joe\" \"Another Joe\"))
 253
 254 See BIND-PARAMETER for the list of supported parameter types."
 255   (declare (dynamic-extent parameters))
 256   (let ((stmt (prepare-statement db sql))
 257         result)
 258     (iter (for i from 1)
 259           (declare (type fixnum i))
 260           (for value in parameters)
 261           (bind-parameter stmt i value))
 262     (loop (if (step-statement stmt)
 263               (push (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 264                           (declare (type fixnum i))
 265                           (collect (statement-column-value stmt i)))
 266                     result)
 267               (return)))
 268     (finalize-statement stmt)
 269     (nreverse result)))
 270
 271 (defun execute-one-row-m-v (db sql &rest parameters)
 272   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first row as multiple values.
 273
 274 Example:
 275 \(execute-one-row-m-v db \"select id, user_name, real_name from users where id = ?\" 1)
 276 =>
 277 \(values 1 \"joe\" \"Joe the User\")
 278
 279 See BIND-PARAMETER for the list of supported parameter types."
 280   (let ((stmt (prepare-statement db sql)))
 281     (unwind-protect
 282          (progn
 283            (iter (for i from 1)
 284                  (declare (type fixnum i))
 285                  (for value in parameters)
 286                  (bind-parameter stmt i value))
 287            (if (step-statement stmt)
 288                (return-from execute-one-row-m-v
 289                  (values-list (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 290                                     (declare (type fixnum i))
 291                                     (collect (statement-column-value stmt i)))))
 292                (return-from execute-one-row-m-v
 293                  (values-list (loop repeat (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))) collect nil)))))
 294       (finalize-statement stmt))))
 295
 296 (defun statement-parameter-index (statement parameter-name)
 297   (sqlite-ffi:sqlite3-bind-parameter-index (handle statement) parameter-name))
 298
 299 (defun bind-parameter (statement parameter value)
 300   "Sets the PARAMETER-th parameter in STATEMENT to the VALUE.
 301 Parameters are numbered from one.
 302 Supported types:
 303  * NULL. Passed as NULL
 304  * INTEGER. Passed as an 64-bit integer
 305  * STRING. Passed as a string
 306  * FLOAT. Passed as a double
 307  * (VECTOR (UNSIGNED-BYTE 8)) and VECTOR that contains integers in range [0,256). Passed as a BLOB"
 308   (let ((index (etypecase parameter
 309                  (integer parameter)
 310                  (string (statement-parameter-index statement parameter)))))
 311     (declare (type fixnum index))
 312     (let ((error-code (typecase value
 313                         (null (sqlite-ffi:sqlite3-bind-null (handle statement) index))
 314                         (integer (sqlite-ffi:sqlite3-bind-int64 (handle statement) index value))
 315                         (double-float (sqlite-ffi:sqlite3-bind-double (handle statement) index value))
 316                         (real (sqlite-ffi:sqlite3-bind-double (handle statement) index (coerce value 'double-float)))
 317                         (string (sqlite-ffi:sqlite3-bind-text (handle statement) index value -1 (sqlite-ffi:destructor-transient)))
 318                         ((vector (unsigned-byte 8)) (cffi:with-pointer-to-vector-data (ptr value)
 319                                                       (sqlite-ffi:sqlite3-bind-blob (handle statement) index ptr (length value) (sqlite-ffi:destructor-transient))))
 320                         (vector (cffi:with-foreign-object (array :unsigned-char (length value))
 321                                   (loop
 322                                      for i from 0 below (length value)
 323                                      do (setf (cffi:mem-aref array :unsigned-char i) (aref value i)))
 324                                   (sqlite-ffi:sqlite3-bind-blob (handle statement) index array (length value) (sqlite-ffi:destructor-transient))))
 325                         (t
 326                          (sqlite-error nil
 327                                        (list "Do not know how to pass value ~A of type ~A to sqlite."
 328                                              value (type-of value))
 329                                        :statement statement)))))
 330       (unless (eq error-code :ok)
 331         (sqlite-error error-code
 332                       (list "Error when binding parameter ~A to value ~A." parameter value)
 333                       :statement statement)))))
 334
 335 (defun execute-single (db sql &rest parameters)
 336   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first column of the first row as single value.
 337
 338 Example:
 339 \(execute-single db \"select user_name from users where id = ?\" 1)
 340 =>
 341 \"joe\"
 342
 343 See BIND-PARAMETER for the list of supported parameter types."
 344   (declare (dynamic-extent parameters))
 345   (let ((stmt (prepare-statement db sql)))
 346     (unwind-protect
 347          (progn
 348            (iter (for i from 1)
 349                  (declare (type fixnum i))
 350                  (for value in parameters)
 351                  (bind-parameter stmt i value))
 352            (if (step-statement stmt)
 353                (statement-column-value stmt 0)
 354                nil))
 355       (finalize-statement stmt))))
 356
 357 (defun last-insert-rowid (db)
 358   "Returns the auto-generated ID of the last inserted row on the database connection DB."
 359   (sqlite-ffi:sqlite3-last-insert-rowid (handle db)))
 360
 361 (defmacro with-transaction (db &body body)
 362   "Wraps the BODY inside the transaction."
 363   (let ((ok (gensym "TRANSACTION-COMMIT-"))
 364         (db-var (gensym "DB-")))
 365     `(let (,ok
 366            (,db-var ,db))
 367        (execute-non-query ,db-var "begin transaction")
 368        (unwind-protect
 369             (multiple-value-prog1
 370                 (progn ,@body)
 371               (setf ,ok t))
 372          (if ,ok
 373              (execute-non-query ,db-var "commit transaction")
 374              (execute-non-query ,db-var "rollback transaction"))))))
 375
 376 (defmacro with-open-database ((db path &key busy-timeout) &body body)
 377   `(let ((,db (connect ,path :busy-timeout ,busy-timeout)))
 378      (unwind-protect
 379           (progn ,@body)
 380        (disconnect ,db))))
 381
 382 (defmacro-driver (FOR vars IN-SQLITE-QUERY query-expression ON-DATABASE db &optional WITH-PARAMETERS parameters)
 383   (let ((statement (gensym "STATEMENT-"))
 384         (kwd (if generate 'generate 'for)))
 385     `(progn (with ,statement = (prepare-statement ,db ,query-expression))
 386             (finally-protected (when ,statement (finalize-statement ,statement)))
 387             ,@(when parameters
 388                     (list `(initially ,@(iter (for i from 1)
 389                                               (for value in parameters)
 390                                               (collect `(sqlite:bind-parameter ,statement ,i ,value))))))
 391             (,kwd ,(if (symbolp vars)
 392                        `(values ,vars)
 393                        `(values ,@vars))
 394                   next (progn (if (step-statement ,statement)
 395                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 396                                                   (collect `(statement-column-value ,statement ,i))))
 397                                   (terminate)))))))
 398
 399 (defmacro-driver (FOR vars ON-SQLITE-STATEMENT statement)
 400   (let ((statement-var (gensym "STATEMENT-"))
 401         (kwd (if generate 'generate 'for)))
 402     `(progn (with ,statement-var = ,statement)
 403             (,kwd ,(if (symbolp vars)
 404                        `(values ,vars)
 405                        `(values ,@vars))
 406                   next (progn (if (step-statement ,statement-var)
 407                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 408                                                   (collect `(statement-column-value ,statement-var ,i))))
 409                                   (terminate)))))))