ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003  Free Software Foundation, Inc.
   5
   6 This file is part of GLD, the Gnu Linker.
   7
   8 GLD is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU General Public License as published by
  10 the Free Software Foundation; either version 2, or (at your option)
  11 any later version.
  12
  13 GLD is distributed in the hope that it will be useful,
  14 but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 GNU General Public License for more details.
  17
  18 You should have received a copy of the GNU General Public License
  19 along with GLD; see the file COPYING.  If not, write to the Free
  20 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 02111-1307, USA.  */
  22
  23 /*
  24 This was written by steve chamberlain
  25                     sac@cygnus.com
  26 */
  27
  28
  29 #include <stdio.h>
  30
  31 #ifdef MPW
  32 /* Prevent enum redefinition problems. */
  33 #define TRUE_FALSE_ALREADY_DEFINED
  34 #endif /* MPW */
  35
  36 #include "bfd.h"
  37 #include "sysdep.h"
  38 #include "safe-ctype.h"
  39 #include "bfdlink.h"
  40 #include "ld.h"
  41 #include "ldmisc.h"
  42 #include "ldexp.h"
  43 #include "ldlang.h"
  44 #include <ldgram.h>
  45 #include "ldfile.h"
  46 #include "ldlex.h"
  47 #include "ldmain.h"
  48 #include "libiberty.h"
  49
  50 /* The type of top-level parser input.
  51    yylex and yyparse (indirectly) both check this.  */
  52 input_type parser_input;
  53
  54 /* Line number in the current input file.
  55    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  56 unsigned int lineno = 1;
  57
  58 /* The string we are currently lexing, or NULL if we are reading a
  59    file.  */
  60 const char *lex_string = NULL;
  61
  62 /* Support for flex reading from more than one input file (stream).
  63    `include_stack' is flex's input state for each open file;
  64    `file_name_stack' is the file names.  `lineno_stack' is the current
  65    line numbers.
  66
  67    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  68    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  69
  70 #undef YY_INPUT
  71 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  72
  73 #define MAX_INCLUDE_DEPTH 10
  74 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  75 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  76 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  77 static unsigned int include_stack_ptr = 0;
  78 static int vers_node_nesting = 0;
  79
  80 static void yy_input (char *, int *, int);
  81 static void comment (void);
  82 static void lex_warn_invalid (char *where, char *what);
  83
  84 /* STATES
  85         EXPRESSION      definitely in an expression
  86         SCRIPT          definitely in a script
  87         BOTH            either EXPRESSION or SCRIPT
  88         DEFSYMEXP       in an argument to -defsym
  89         MRI             in an MRI script
  90         VERS_START      starting a Sun style mapfile
  91         VERS_SCRIPT     a Sun style mapfile
  92         VERS_NODE       a node within a Sun style mapfile
  93 */
  94 #define RTOKEN(x)  {  yylval.token = x; return x; }
  95
  96 /* Some versions of flex want this.  */
  97 #ifndef yywrap
  98 int yywrap (void) { return 1; }
  99 #endif
 100 %}
 101
 102 %a 4000
 103 %o 5000
 104
 105 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 106 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 107 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 108 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 109 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 110 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 111 WHITE           [ \t\n\r]+
 112
 113 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 114
 115 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 116 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^]([*?.$_a-zA-Z0-9\[\]\-\!\^]|::)*
 117
 118 %s SCRIPT
 119 %s EXPRESSION
 120 %s BOTH
 121 %s DEFSYMEXP
 122 %s MRI
 123 %s VERS_START
 124 %s VERS_SCRIPT
 125 %s VERS_NODE
 126 %%
 127
 128   if (parser_input != input_selected)
 129     {
 130       /* The first token of the input determines the initial parser state.  */
 131       input_type t = parser_input;
 132       parser_input = input_selected;
 133       switch (t)
 134         {
 135         case input_script: return INPUT_SCRIPT; break;
 136         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 137         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 138         case input_defsym: return INPUT_DEFSYM; break;
 139         default: abort ();
 140         }
 141     }
 142
 143 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 144
 145
 146 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 147 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 148 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 149 <DEFSYMEXP>"="                  { RTOKEN('='); }
 150
 151 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 152                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 153                                 yylval.bigint.str = NULL;
 154                                 return INT;
 155                         }
 156
 157 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 158                                    int ibase ;
 159                                    switch (yytext[yyleng - 1]) {
 160                                     case 'X':
 161                                     case 'x':
 162                                     case 'H':
 163                                     case 'h':
 164                                      ibase = 16;
 165                                      break;
 166                                     case 'O':
 167                                     case 'o':
 168                                      ibase = 8;
 169                                      break;
 170                                     case 'B':
 171                                     case 'b':
 172                                      ibase = 2;
 173                                      break;
 174                                     default:
 175                                      ibase = 10;
 176                                    }
 177                                    yylval.integer = bfd_scan_vma (yytext, 0,
 178                                                                   ibase);
 179                                    yylval.bigint.str = NULL;
 180                                    return INT;
 181                                  }
 182 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 183                                   char *s = yytext;
 184                                   int ibase = 0;
 185
 186                                   if (*s == '$')
 187                                     {
 188                                       ++s;
 189                                       ibase = 16;
 190                                     }
 191                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 192                                   yylval.bigint.str = NULL;
 193                                   if (yytext[yyleng - 1] == 'M'
 194                                       || yytext[yyleng - 1] == 'm')
 195                                     {
 196                                       yylval.integer *= 1024 * 1024;
 197                                     }
 198                                   else if (yytext[yyleng - 1] == 'K'
 199                                       || yytext[yyleng - 1]=='k')
 200                                     {
 201                                       yylval.integer *= 1024;
 202                                     }
 203                                   else if (yytext[0] == '0'
 204                                            && (yytext[1] == 'x'
 205                                                || yytext[1] == 'X'))
 206                                     {
 207                                       yylval.bigint.str = xstrdup (yytext + 2);
 208                                     }
 209                                   return INT;
 210                                 }
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 240 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI>"="          { RTOKEN('=');}
 243 <BOTH,SCRIPT,EXPRESSION,MRI>"}"                 { RTOKEN('}') ; }
 244 <BOTH,SCRIPT,EXPRESSION,MRI>"{"                 { RTOKEN('{'); }
 245 <BOTH,SCRIPT,EXPRESSION,MRI>")"                 { RTOKEN(')');}
 246 <BOTH,SCRIPT,EXPRESSION,MRI>"("                 { RTOKEN('(');}
 247 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 248 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 249 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 250 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 251 <BOTH,SCRIPT>"VERSION"          { RTOKEN(VERSIONK);}
 252 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 253 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 254 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 255 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 256 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 257 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 258 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 259 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"              { RTOKEN(LOADADDR);}
 260 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 261 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 262 <EXPRESSION,BOTH>"ASSERT"               { RTOKEN(ASSERT_K); }
 263 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 264 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 265 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 266 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 267 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 268 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 269 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 270 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 271 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 272 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 273 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 274 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 275 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 276 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 277 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 278 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 279 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 280 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 281 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 282 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 283 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 284 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 285 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 286 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 287 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 288 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 289 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 290 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 291 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 292 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 293 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 294 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 295 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 296 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT); }
 297 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 298 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 299 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 300 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 301 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 302 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 303 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 304 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 305 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 306 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 307 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 308 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 309 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"               { RTOKEN(PROVIDE); }
 310 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 311 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"        { RTOKEN(EXCLUDE_FILE); }
 312 <MRI>"#".*\n?                   { ++ lineno; }
 313 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 314 <MRI>"*".*                      { /* Mri comment line */ }
 315 <MRI>";".*                      { /* Mri comment line */ }
 316 <MRI>"END"                      { RTOKEN(ENDWORD); }
 317 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 318 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 319 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 320 <MRI>"BASE"                     { RTOKEN(BASE); }
 321 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 322 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 323 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 324 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 325 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 326 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 327 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 328 <MRI>"CASE"                     { RTOKEN(CASE); }
 329 <MRI>"START"                    { RTOKEN(START); }
 330 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 331 <MRI>"SECT"                     { RTOKEN(SECT); }
 332 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 333 <MRI>"end"                      { RTOKEN(ENDWORD); }
 334 <MRI>"alignmod"         { RTOKEN(ALIGNMOD);}
 335 <MRI>"align"            { RTOKEN(ALIGN_K);}
 336 <MRI>"chip"                     { RTOKEN(CHIP); }
 337 <MRI>"base"                     { RTOKEN(BASE); }
 338 <MRI>"alias"                     { RTOKEN(ALIAS); }
 339 <MRI>"truncate"                     { RTOKEN(TRUNCATE); }
 340 <MRI>"load"                     { RTOKEN(LOAD); }
 341 <MRI>"public"                   { RTOKEN(PUBLIC); }
 342 <MRI>"order"                    { RTOKEN(ORDER); }
 343 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 344 <MRI>"format"                   { RTOKEN(FORMAT); }
 345 <MRI>"case"                     { RTOKEN(CASE); }
 346 <MRI>"extern"                   { RTOKEN(EXTERN); }
 347 <MRI>"start"                    { RTOKEN(START); }
 348 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 349 <MRI>"sect"                     { RTOKEN(SECT); }
 350 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 351
 352 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 353 /* Filename without commas, needed to parse mri stuff */
 354                                  yylval.name = xstrdup (yytext);
 355                                   return NAME;
 356                                 }
 357
 358
 359 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 360                                  yylval.name = xstrdup (yytext);
 361                                   return NAME;
 362                                 }
 363 <BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
 364                                   yylval.name = xstrdup (yytext + 2);
 365                                   return LNAME;
 366                                 }
 367 <SCRIPT>{WILDCHAR}* {
 368                 /* Annoyingly, this pattern can match comments, and we have
 369                    longest match issues to consider.  So if the first two
 370                    characters are a comment opening, put the input back and
 371                    try again.  */
 372                 if (yytext[0] == '/' && yytext[1] == '*')
 373                   {
 374                     yyless (2);
 375                     comment ();
 376                   }
 377                 else
 378                   {
 379                     yylval.name = xstrdup (yytext);
 380                     return NAME;
 381                   }
 382         }
 383
 384 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 385                                         /* No matter the state, quotes
 386                                            give what's inside */
 387                                         yylval.name = xstrdup (yytext + 1);
 388                                         yylval.name[yyleng - 2] = 0;
 389                                         return NAME;
 390                                 }
 391 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 392 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 393
 394 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 395
 396 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 397
 398 <VERS_NODE>local                { RTOKEN(LOCAL); }
 399
 400 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 401
 402 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 403                                   return VERS_IDENTIFIER; }
 404
 405 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 406                                   return VERS_TAG; }
 407
 408 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 409
 410 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 411                                   vers_node_nesting = 0;
 412                                   return *yytext;
 413                                 }
 414 <VERS_SCRIPT>"}"                { return *yytext; }
 415 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 416 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 417                                     BEGIN(VERS_SCRIPT);
 418                                   return *yytext;
 419                                 }
 420
 421 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 422
 423 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 424
 425 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 426
 427 <<EOF>> {
 428   include_stack_ptr--;
 429
 430   if (include_stack_ptr == 0)
 431   {
 432     yyterminate ();
 433   }
 434   else
 435   {
 436     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 437   }
 438
 439   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 440   lineno = lineno_stack[include_stack_ptr];
 441
 442   return END;
 443 }
 444
 445 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 446 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 447
 448 %%
 449 \f
 450
 451 /* Switch flex to reading script file NAME, open on FILE,
 452    saving the current input info on the include stack.  */
 453
 454 void
 455 lex_push_file (FILE *file, const char *name)
 456 {
 457   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 458     {
 459       einfo ("%F:includes nested too deeply\n");
 460     }
 461   file_name_stack[include_stack_ptr] = name;
 462   lineno_stack[include_stack_ptr] = lineno;
 463   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 464
 465   include_stack_ptr++;
 466   lineno = 1;
 467   yyin = file;
 468   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 469 }
 470
 471 /* Return a newly created flex input buffer containing STRING,
 472    which is SIZE bytes long.  */
 473
 474 static YY_BUFFER_STATE
 475 yy_create_string_buffer (const char *string, size_t size)
 476 {
 477   YY_BUFFER_STATE b;
 478
 479   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 480   b = malloc (sizeof (struct yy_buffer_state));
 481   b->yy_input_file = 0;
 482   b->yy_buf_size = size;
 483
 484   /* yy_ch_buf has to be 2 characters longer than the size given because
 485      we need to put in 2 end-of-buffer characters.  */
 486   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 487
 488   b->yy_ch_buf[0] = '\n';
 489   strcpy (b->yy_ch_buf+1, string);
 490   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 491   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 492   b->yy_n_chars = size+1;
 493   b->yy_buf_pos = &b->yy_ch_buf[1];
 494
 495   b->yy_is_our_buffer = 1;
 496   b->yy_is_interactive = 0;
 497   b->yy_at_bol = 1;
 498   b->yy_fill_buffer = 0;
 499
 500   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 501      a flex internal interface in the first place!  */
 502 #ifdef YY_BUFFER_NEW
 503   b->yy_buffer_status = YY_BUFFER_NEW;
 504 #else
 505   b->yy_eof_status = EOF_NOT_SEEN;
 506 #endif
 507
 508   return b;
 509 }
 510
 511 /* Switch flex to reading from STRING, saving the current input info
 512    on the include stack.  */
 513
 514 void
 515 lex_redirect (const char *string)
 516 {
 517   YY_BUFFER_STATE tmp;
 518
 519   yy_init = 0;
 520   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 521     {
 522       einfo("%F: macros nested too deeply\n");
 523     }
 524   file_name_stack[include_stack_ptr] = "redirect";
 525   lineno_stack[include_stack_ptr] = lineno;
 526   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 527   include_stack_ptr++;
 528   lineno = 1;
 529   tmp = yy_create_string_buffer (string, strlen (string));
 530   yy_switch_to_buffer (tmp);
 531 }
 532 \f
 533 /* Functions to switch to a different flex start condition,
 534    saving the current start condition on `state_stack'.  */
 535
 536 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 537 static int *state_stack_p = state_stack;
 538
 539 void
 540 ldlex_script (void)
 541 {
 542   *(state_stack_p)++ = yy_start;
 543   BEGIN (SCRIPT);
 544 }
 545
 546 void
 547 ldlex_mri_script (void)
 548 {
 549   *(state_stack_p)++ = yy_start;
 550   BEGIN (MRI);
 551 }
 552
 553 void
 554 ldlex_version_script (void)
 555 {
 556   *(state_stack_p)++ = yy_start;
 557   BEGIN (VERS_START);
 558 }
 559
 560 void
 561 ldlex_version_file (void)
 562 {
 563   *(state_stack_p)++ = yy_start;
 564   BEGIN (VERS_SCRIPT);
 565 }
 566
 567 void
 568 ldlex_defsym (void)
 569 {
 570   *(state_stack_p)++ = yy_start;
 571   BEGIN (DEFSYMEXP);
 572 }
 573
 574 void
 575 ldlex_expression (void)
 576 {
 577   *(state_stack_p)++ = yy_start;
 578   BEGIN (EXPRESSION);
 579 }
 580
 581 void
 582 ldlex_both (void)
 583 {
 584   *(state_stack_p)++ = yy_start;
 585   BEGIN (BOTH);
 586 }
 587
 588 void
 589 ldlex_popstate (void)
 590 {
 591   yy_start = *(--state_stack_p);
 592 }
 593 \f
 594
 595 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 596    either the number of characters read, or 0 to indicate EOF.  */
 597
 598 static void
 599 yy_input (char *buf, int *result, int max_size)
 600 {
 601   *result = 0;
 602   if (YY_CURRENT_BUFFER->yy_input_file)
 603     {
 604       if (yyin)
 605         {
 606           *result = fread (buf, 1, max_size, yyin);
 607           if (*result < max_size && ferror (yyin))
 608             einfo ("%F%P: read in flex scanner failed\n");
 609         }
 610     }
 611 }
 612
 613 /* Eat the rest of a C-style comment.  */
 614
 615 static void
 616 comment (void)
 617 {
 618   int c;
 619
 620   while (1)
 621   {
 622     c = input();
 623     while (c != '*' && c != EOF)
 624     {
 625       if (c == '\n')
 626         lineno++;
 627       c = input();
 628     }
 629
 630     if (c == '*')
 631     {
 632       c = input();
 633       while (c == '*')
 634        c = input();
 635       if (c == '/')
 636        break;                   /* found the end */
 637     }
 638
 639     if (c == '\n')
 640       lineno++;
 641
 642     if (c == EOF)
 643     {
 644       einfo( "%F%P: EOF in comment\n");
 645       break;
 646     }
 647   }
 648 }
 649
 650 /* Warn the user about a garbage character WHAT in the input
 651    in context WHERE.  */
 652
 653 static void
 654 lex_warn_invalid (char *where, char *what)
 655 {
 656   char buf[5];
 657
 658   /* If we have found an input file whose format we do not recognize,
 659      and we are therefore treating it as a linker script, and we find
 660      an invalid character, then most likely this is a real object file
 661      of some different format.  Treat it as such.  */
 662   if (ldfile_assumed_script)
 663     {
 664       bfd_set_error (bfd_error_file_not_recognized);
 665       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 666     }
 667
 668   if (! ISPRINT (*what))
 669     {
 670       sprintf (buf, "\\%03o", (unsigned int) *what);
 671       what = buf;
 672     }
 673
 674   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 675 }