ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003  Free Software Foundation, Inc.
   5
   6 This file is part of GLD, the Gnu Linker.
   7
   8 GLD is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU General Public License as published by
  10 the Free Software Foundation; either version 2, or (at your option)
  11 any later version.
  12
  13 GLD is distributed in the hope that it will be useful,
  14 but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 GNU General Public License for more details.
  17
  18 You should have received a copy of the GNU General Public License
  19 along with GLD; see the file COPYING.  If not, write to the Free
  20 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 02111-1307, USA.  */
  22
  23 /*
  24 This was written by steve chamberlain
  25                     sac@cygnus.com
  26 */
  27
  28
  29 #include <stdio.h>
  30
  31 #include "bfd.h"
  32 #include "sysdep.h"
  33 #include "safe-ctype.h"
  34 #include "bfdlink.h"
  35 #include "ld.h"
  36 #include "ldmisc.h"
  37 #include "ldexp.h"
  38 #include "ldlang.h"
  39 #include <ldgram.h>
  40 #include "ldfile.h"
  41 #include "ldlex.h"
  42 #include "ldmain.h"
  43 #include "libiberty.h"
  44
  45 /* The type of top-level parser input.
  46    yylex and yyparse (indirectly) both check this.  */
  47 input_type parser_input;
  48
  49 /* Line number in the current input file.
  50    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  51 unsigned int lineno = 1;
  52
  53 /* The string we are currently lexing, or NULL if we are reading a
  54    file.  */
  55 const char *lex_string = NULL;
  56
  57 /* Support for flex reading from more than one input file (stream).
  58    `include_stack' is flex's input state for each open file;
  59    `file_name_stack' is the file names.  `lineno_stack' is the current
  60    line numbers.
  61
  62    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  63    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  64
  65 #undef YY_INPUT
  66 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  67
  68 #define MAX_INCLUDE_DEPTH 10
  69 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  70 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  71 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  72 static unsigned int include_stack_ptr = 0;
  73 static int vers_node_nesting = 0;
  74
  75 static void yy_input (char *, int *, int);
  76 static void comment (void);
  77 static void lex_warn_invalid (char *where, char *what);
  78
  79 /* STATES
  80         EXPRESSION      definitely in an expression
  81         SCRIPT          definitely in a script
  82         BOTH            either EXPRESSION or SCRIPT
  83         DEFSYMEXP       in an argument to -defsym
  84         MRI             in an MRI script
  85         VERS_START      starting a Sun style mapfile
  86         VERS_SCRIPT     a Sun style mapfile
  87         VERS_NODE       a node within a Sun style mapfile
  88 */
  89 #define RTOKEN(x)  {  yylval.token = x; return x; }
  90
  91 /* Some versions of flex want this.  */
  92 #ifndef yywrap
  93 int yywrap (void) { return 1; }
  94 #endif
  95 %}
  96
  97 %a 4000
  98 %o 5000
  99
 100 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 101 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 102 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 103 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 104 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 105 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 106 WHITE           [ \t\n\r]+
 107
 108 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 109
 110 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 111 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 112
 113 %s SCRIPT
 114 %s EXPRESSION
 115 %s BOTH
 116 %s DEFSYMEXP
 117 %s MRI
 118 %s VERS_START
 119 %s VERS_SCRIPT
 120 %s VERS_NODE
 121 %%
 122
 123   if (parser_input != input_selected)
 124     {
 125       /* The first token of the input determines the initial parser state.  */
 126       input_type t = parser_input;
 127       parser_input = input_selected;
 128       switch (t)
 129         {
 130         case input_script: return INPUT_SCRIPT; break;
 131         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 132         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 133         case input_defsym: return INPUT_DEFSYM; break;
 134         default: abort ();
 135         }
 136     }
 137
 138 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 139
 140
 141 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 142 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 143 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 144 <DEFSYMEXP>"="                  { RTOKEN('='); }
 145
 146 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 147                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 148                                 yylval.bigint.str = NULL;
 149                                 return INT;
 150                         }
 151
 152 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 153                                    int ibase ;
 154                                    switch (yytext[yyleng - 1]) {
 155                                     case 'X':
 156                                     case 'x':
 157                                     case 'H':
 158                                     case 'h':
 159                                      ibase = 16;
 160                                      break;
 161                                     case 'O':
 162                                     case 'o':
 163                                      ibase = 8;
 164                                      break;
 165                                     case 'B':
 166                                     case 'b':
 167                                      ibase = 2;
 168                                      break;
 169                                     default:
 170                                      ibase = 10;
 171                                    }
 172                                    yylval.integer = bfd_scan_vma (yytext, 0,
 173                                                                   ibase);
 174                                    yylval.bigint.str = NULL;
 175                                    return INT;
 176                                  }
 177 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 178                                   char *s = yytext;
 179                                   int ibase = 0;
 180
 181                                   if (*s == '$')
 182                                     {
 183                                       ++s;
 184                                       ibase = 16;
 185                                     }
 186                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 187                                   yylval.bigint.str = NULL;
 188                                   if (yytext[yyleng - 1] == 'M'
 189                                       || yytext[yyleng - 1] == 'm')
 190                                     {
 191                                       yylval.integer *= 1024 * 1024;
 192                                     }
 193                                   else if (yytext[yyleng - 1] == 'K'
 194                                       || yytext[yyleng - 1]=='k')
 195                                     {
 196                                       yylval.integer *= 1024;
 197                                     }
 198                                   else if (yytext[0] == '0'
 199                                            && (yytext[1] == 'x'
 200                                                || yytext[1] == 'X'))
 201                                     {
 202                                       yylval.bigint.str = xstrdup (yytext + 2);
 203                                     }
 204                                   return INT;
 205                                 }
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"="          { RTOKEN('=');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"}"                 { RTOKEN('}') ; }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"{"                 { RTOKEN('{'); }
 240 <BOTH,SCRIPT,EXPRESSION,MRI>")"                 { RTOKEN(')');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"("                 { RTOKEN('(');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 243 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 244 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 245 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 246 <BOTH,SCRIPT>"VERSION"          { RTOKEN(VERSIONK);}
 247 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 248 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 249 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 250 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 252 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 254 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 255 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"              { RTOKEN(LOADADDR);}
 256 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 257 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 258 <EXPRESSION,BOTH>"ASSERT"               { RTOKEN(ASSERT_K); }
 259 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 260 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 261 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 262 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 264 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 265 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 266 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 267 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 268 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 269 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 270 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 271 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 272 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 273 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 274 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 275 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 276 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 277 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 278 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 279 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 280 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 281 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 282 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 283 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 284 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 285 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 286 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 287 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 288 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 289 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 290 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 291 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 292 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT); }
 293 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 294 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 295 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 296 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 297 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 298 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 299 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 300 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 301 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 302 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 303 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 304 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 305 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"              { RTOKEN(SUBALIGN);}
 306 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"               { RTOKEN(PROVIDE); }
 307 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 308 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"        { RTOKEN(EXCLUDE_FILE); }
 309 <MRI>"#".*\n?                   { ++ lineno; }
 310 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 311 <MRI>"*".*                      { /* Mri comment line */ }
 312 <MRI>";".*                      { /* Mri comment line */ }
 313 <MRI>"END"                      { RTOKEN(ENDWORD); }
 314 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 315 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 316 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 317 <MRI>"BASE"                     { RTOKEN(BASE); }
 318 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 319 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 320 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 321 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 322 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 323 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 324 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 325 <MRI>"CASE"                     { RTOKEN(CASE); }
 326 <MRI>"START"                    { RTOKEN(START); }
 327 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 328 <MRI>"SECT"                     { RTOKEN(SECT); }
 329 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 330 <MRI>"end"                      { RTOKEN(ENDWORD); }
 331 <MRI>"alignmod"         { RTOKEN(ALIGNMOD);}
 332 <MRI>"align"            { RTOKEN(ALIGN_K);}
 333 <MRI>"chip"                     { RTOKEN(CHIP); }
 334 <MRI>"base"                     { RTOKEN(BASE); }
 335 <MRI>"alias"                     { RTOKEN(ALIAS); }
 336 <MRI>"truncate"                     { RTOKEN(TRUNCATE); }
 337 <MRI>"load"                     { RTOKEN(LOAD); }
 338 <MRI>"public"                   { RTOKEN(PUBLIC); }
 339 <MRI>"order"                    { RTOKEN(ORDER); }
 340 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 341 <MRI>"format"                   { RTOKEN(FORMAT); }
 342 <MRI>"case"                     { RTOKEN(CASE); }
 343 <MRI>"extern"                   { RTOKEN(EXTERN); }
 344 <MRI>"start"                    { RTOKEN(START); }
 345 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 346 <MRI>"sect"                     { RTOKEN(SECT); }
 347 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 348
 349 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 350 /* Filename without commas, needed to parse mri stuff */
 351                                  yylval.name = xstrdup (yytext);
 352                                   return NAME;
 353                                 }
 354
 355
 356 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 357                                  yylval.name = xstrdup (yytext);
 358                                   return NAME;
 359                                 }
 360 <BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
 361                                   yylval.name = xstrdup (yytext + 2);
 362                                   return LNAME;
 363                                 }
 364 <SCRIPT>{WILDCHAR}* {
 365                 /* Annoyingly, this pattern can match comments, and we have
 366                    longest match issues to consider.  So if the first two
 367                    characters are a comment opening, put the input back and
 368                    try again.  */
 369                 if (yytext[0] == '/' && yytext[1] == '*')
 370                   {
 371                     yyless (2);
 372                     comment ();
 373                   }
 374                 else
 375                   {
 376                     yylval.name = xstrdup (yytext);
 377                     return NAME;
 378                   }
 379         }
 380
 381 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 382                                         /* No matter the state, quotes
 383                                            give what's inside */
 384                                         yylval.name = xstrdup (yytext + 1);
 385                                         yylval.name[yyleng - 2] = 0;
 386                                         return NAME;
 387                                 }
 388 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 389 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 390
 391 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 392
 393 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 394
 395 <VERS_NODE>local                { RTOKEN(LOCAL); }
 396
 397 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 398
 399 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 400                                   return VERS_IDENTIFIER; }
 401
 402 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 403                                   return VERS_TAG; }
 404
 405 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 406
 407 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 408                                   vers_node_nesting = 0;
 409                                   return *yytext;
 410                                 }
 411 <VERS_SCRIPT>"}"                { return *yytext; }
 412 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 413 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 414                                     BEGIN(VERS_SCRIPT);
 415                                   return *yytext;
 416                                 }
 417
 418 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 419
 420 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 421
 422 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 423
 424 <<EOF>> {
 425   include_stack_ptr--;
 426
 427   if (include_stack_ptr == 0)
 428   {
 429     yyterminate ();
 430   }
 431   else
 432   {
 433     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 434   }
 435
 436   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 437   lineno = lineno_stack[include_stack_ptr];
 438
 439   return END;
 440 }
 441
 442 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 443 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 444
 445 %%
 446 \f
 447
 448 /* Switch flex to reading script file NAME, open on FILE,
 449    saving the current input info on the include stack.  */
 450
 451 void
 452 lex_push_file (FILE *file, const char *name)
 453 {
 454   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 455     {
 456       einfo ("%F:includes nested too deeply\n");
 457     }
 458   file_name_stack[include_stack_ptr] = name;
 459   lineno_stack[include_stack_ptr] = lineno;
 460   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 461
 462   include_stack_ptr++;
 463   lineno = 1;
 464   yyin = file;
 465   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 466 }
 467
 468 /* Return a newly created flex input buffer containing STRING,
 469    which is SIZE bytes long.  */
 470
 471 static YY_BUFFER_STATE
 472 yy_create_string_buffer (const char *string, size_t size)
 473 {
 474   YY_BUFFER_STATE b;
 475
 476   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 477   b = malloc (sizeof (struct yy_buffer_state));
 478   b->yy_input_file = 0;
 479   b->yy_buf_size = size;
 480
 481   /* yy_ch_buf has to be 2 characters longer than the size given because
 482      we need to put in 2 end-of-buffer characters.  */
 483   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 484
 485   b->yy_ch_buf[0] = '\n';
 486   strcpy (b->yy_ch_buf+1, string);
 487   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 488   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 489   b->yy_n_chars = size+1;
 490   b->yy_buf_pos = &b->yy_ch_buf[1];
 491
 492   b->yy_is_our_buffer = 1;
 493   b->yy_is_interactive = 0;
 494   b->yy_at_bol = 1;
 495   b->yy_fill_buffer = 0;
 496
 497   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 498      a flex internal interface in the first place!  */
 499 #ifdef YY_BUFFER_NEW
 500   b->yy_buffer_status = YY_BUFFER_NEW;
 501 #else
 502   b->yy_eof_status = EOF_NOT_SEEN;
 503 #endif
 504
 505   return b;
 506 }
 507
 508 /* Switch flex to reading from STRING, saving the current input info
 509    on the include stack.  */
 510
 511 void
 512 lex_redirect (const char *string)
 513 {
 514   YY_BUFFER_STATE tmp;
 515
 516   yy_init = 0;
 517   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 518     {
 519       einfo("%F: macros nested too deeply\n");
 520     }
 521   file_name_stack[include_stack_ptr] = "redirect";
 522   lineno_stack[include_stack_ptr] = lineno;
 523   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 524   include_stack_ptr++;
 525   lineno = 1;
 526   tmp = yy_create_string_buffer (string, strlen (string));
 527   yy_switch_to_buffer (tmp);
 528 }
 529 \f
 530 /* Functions to switch to a different flex start condition,
 531    saving the current start condition on `state_stack'.  */
 532
 533 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 534 static int *state_stack_p = state_stack;
 535
 536 void
 537 ldlex_script (void)
 538 {
 539   *(state_stack_p)++ = yy_start;
 540   BEGIN (SCRIPT);
 541 }
 542
 543 void
 544 ldlex_mri_script (void)
 545 {
 546   *(state_stack_p)++ = yy_start;
 547   BEGIN (MRI);
 548 }
 549
 550 void
 551 ldlex_version_script (void)
 552 {
 553   *(state_stack_p)++ = yy_start;
 554   BEGIN (VERS_START);
 555 }
 556
 557 void
 558 ldlex_version_file (void)
 559 {
 560   *(state_stack_p)++ = yy_start;
 561   BEGIN (VERS_SCRIPT);
 562 }
 563
 564 void
 565 ldlex_defsym (void)
 566 {
 567   *(state_stack_p)++ = yy_start;
 568   BEGIN (DEFSYMEXP);
 569 }
 570
 571 void
 572 ldlex_expression (void)
 573 {
 574   *(state_stack_p)++ = yy_start;
 575   BEGIN (EXPRESSION);
 576 }
 577
 578 void
 579 ldlex_both (void)
 580 {
 581   *(state_stack_p)++ = yy_start;
 582   BEGIN (BOTH);
 583 }
 584
 585 void
 586 ldlex_popstate (void)
 587 {
 588   yy_start = *(--state_stack_p);
 589 }
 590 \f
 591
 592 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 593    either the number of characters read, or 0 to indicate EOF.  */
 594
 595 static void
 596 yy_input (char *buf, int *result, int max_size)
 597 {
 598   *result = 0;
 599   if (YY_CURRENT_BUFFER->yy_input_file)
 600     {
 601       if (yyin)
 602         {
 603           *result = fread (buf, 1, max_size, yyin);
 604           if (*result < max_size && ferror (yyin))
 605             einfo ("%F%P: read in flex scanner failed\n");
 606         }
 607     }
 608 }
 609
 610 /* Eat the rest of a C-style comment.  */
 611
 612 static void
 613 comment (void)
 614 {
 615   int c;
 616
 617   while (1)
 618   {
 619     c = input();
 620     while (c != '*' && c != EOF)
 621     {
 622       if (c == '\n')
 623         lineno++;
 624       c = input();
 625     }
 626
 627     if (c == '*')
 628     {
 629       c = input();
 630       while (c == '*')
 631        c = input();
 632       if (c == '/')
 633        break;                   /* found the end */
 634     }
 635
 636     if (c == '\n')
 637       lineno++;
 638
 639     if (c == EOF)
 640     {
 641       einfo( "%F%P: EOF in comment\n");
 642       break;
 643     }
 644   }
 645 }
 646
 647 /* Warn the user about a garbage character WHAT in the input
 648    in context WHERE.  */
 649
 650 static void
 651 lex_warn_invalid (char *where, char *what)
 652 {
 653   char buf[5];
 654
 655   /* If we have found an input file whose format we do not recognize,
 656      and we are therefore treating it as a linker script, and we find
 657      an invalid character, then most likely this is a real object file
 658      of some different format.  Treat it as such.  */
 659   if (ldfile_assumed_script)
 660     {
 661       bfd_set_error (bfd_error_file_not_recognized);
 662       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 663     }
 664
 665   if (! ISPRINT (*what))
 666     {
 667       sprintf (buf, "\\%03o", (unsigned int) *what);
 668       what = buf;
 669     }
 670
 671   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 672 }