configure.in

   1 AC_INIT
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE(barvinok, 0.29)
   4 AC_PROG_CC
   5 gl_EARLY
   6
   7 AC_PROG_CXX
   8 AM_PROG_LEX
   9 AC_PROG_YACC
  10 AC_SUBST(versioninfo)
  11 versioninfo=18:0:1
  12
  13 AC_CANONICAL_HOST
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_SUBST(BV_LDFLAGS)
  16 case $host in
  17         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  18         if test "$enable_shared" = yes; then
  19                 BV_LDFLAGS="-no-undefined"
  20         fi
  21         ;;
  22 esac
  23
  24 AC_PROG_LIBTOOL
  25
  26 gl_MODULES(argp progname)
  27 gl_INIT
  28
  29 PKG_PROG_PKG_CONFIG
  30
  31 AC_CHECK_HEADERS(getopt.h)
  32 AC_CHECK_HEADERS(sys/times.h)
  33
  34 AC_MSG_CHECKING(whether to build shared libbarvinok)
  35 AC_ARG_ENABLE(shared_barvinok,
  36         AS_HELP_STRING([--enable-shared-barvinok],
  37                        [build shared barvinok library]),
  38         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  39 AC_MSG_RESULT($bv_cv_shared_barvinok)
  40 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  41         BV_LDFLAGS="$BV_LDFLAGS -static"
  42 fi
  43
  44 AC_CXX_GNUCXX_HASHMAP
  45
  46 AC_ARG_WITH(default-prefix,
  47         AS_HELP_STRING([--with-default-prefix=DIR],
  48             [Default installation prefix of optional packages]))
  49 if test "${with_default_prefix+set}" = set; then
  50         if test "${with_ginac_prefix+set}" != set -a \
  51            -f "$with_default_prefix/lib/pkgconfig/ginac.pc"; then
  52                 with_ginac_prefix=$with_default_prefix
  53         fi
  54         if test "${with_libgmp+set}" != set -a \
  55            -f "$with_default_prefix/include/gmp.h"; then
  56                 with_libgmp=$with_default_prefix
  57         fi
  58         if test "${with_ntl+set}" != set -a \
  59            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  60                 with_ntl=$with_default_prefix
  61         fi
  62         if test "${with_cddlib+set}" != set -a \
  63            -f "$with_default_prefix/include/cddmp.h"; then
  64                 with_cddlib=$with_default_prefix
  65         fi
  66         if test "${with_glpk+set}" != set -a \
  67            -f "$with_default_prefix/include/glpk.h"; then
  68                 with_glpk=$with_default_prefix
  69         fi
  70         if test "${with_topcom+set}" != set -a \
  71            -f "$with_default_prefix/bin/points2triangs"; then
  72                 with_topcom=$with_default_prefix
  73         fi
  74 fi
  75
  76 dnl Check for GMP library
  77 AC_MSG_CHECKING(whether to use GMP)
  78 AC_ARG_WITH(libgmp,
  79         [  --with-libgmp           DIR Location of the GMP Distribution],
  80         gmp_package=$withval, gmp_package=yes)
  81 if test "x$gmp_package" = "xno"; then
  82         AC_MSG_RESULT(no)
  83         AC_MSG_ERROR(Need gmp)
  84 else
  85         AC_MSG_RESULT(yes)
  86         if test "x$gmp_package" = "xyes"; then
  87                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  88         else
  89             bv_configure_args="$bv_configure_args --with-libgmp=$gmp_package"
  90             bv_configure_args="$bv_configure_args --with-gmp=$gmp_package"
  91             GMP_DIR=$gmp_package
  92             if test ! -d "$GMP_DIR"; then
  93                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  94             fi
  95             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  96             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  97         fi
  98         poly_cv_gmpfatal="no"
  99         AC_CHECK_HEADER(gmp.h,
 100                 [AC_CHECK_LIB(gmp,main,
 101                     [],
 102                     [poly_cv_gmpfatal="yes"])],
 103                 [poly_cv_gmpfatal="yes"])
 104         if test "$poly_cv_gmpfatal" = "yes"; then
 105                 AC_MSG_ERROR([GMP not found])
 106         fi
 107 fi
 108 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 109
 110 # BV_SUBMODULE(SUBMODULE)
 111 AC_DEFUN([BV_SUBMODULE],[
 112         AC_ARG_WITH($1,
 113                 [AS_HELP_STRING([--with-$1=bundled|system],
 114                                 [Which $1 to use])])
 115         AC_ARG_WITH($1_prefix,
 116                 [AS_HELP_STRING([--with-$1-prefix=DIR],
 117                                 [Location of system $1])])
 118         if test "x$with_$1_prefix" != "x"; then
 119                 if test "x$with_$1" != "x" -a "x$with_$1" != "xsystem"; then
 120                         AC_MSG_ERROR([Setting $with_$1_prefix implies use of system $1])
 121                 fi
 122                 with_$1="system"
 123         fi
 124         case "$with_$1" in
 125         no)
 126                 if test "$2" = "required"; then
 127                         AC_MSG_ERROR(Need $1)
 128                 fi
 129                 ;;
 130         bundled|system)
 131                 ;;
 132         *)
 133                 if test -d $srcdir/.git -a \
 134                         -d $srcdir/$1 -a \
 135                         ! -d $srcdir/$1/.git; then
 136                         AC_MSG_WARN(
 137 [git repo detected, but submodule $1 not initialized])
 138                         AC_MSG_WARN([You may want to run])
 139                         AC_MSG_WARN([   git submodule init])
 140                         AC_MSG_WARN([   git submodule update])
 141                         AC_MSG_WARN([   sh autogen.sh])
 142                 fi
 143                 if test -f $srcdir/$1/configure; then
 144                         with_$1="bundled"
 145                 elif test "$2" = "required"; then
 146                         with_$1="system"
 147                 else
 148                         with_$1="no"
 149                 fi
 150                 ;;
 151         esac
 152 ])
 153
 154 BV_SUBMODULE(polylib,required)
 155 AC_MSG_CHECKING([which PolyLib to use])
 156 AC_MSG_RESULT($with_polylib)
 157
 158 AC_SUBST(POLYLIB_CPPFLAGS)
 159 AC_SUBST(POLYLIB_LDFLAGS)
 160 AC_SUBST(POLYLIB_LIBS)
 161 if test "$with_polylib" = "bundled"; then
 162         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 163         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 164 else
 165         POLYLIB_LIBS="-lpolylibgmp"
 166         if test "x$with_polylib_prefix" != "x"; then
 167                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 168                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 169         fi
 170         SAVE_CPPFLAGS="$CPPFLAGS"
 171         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 172         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 173                 AC_MSG_ERROR(Need PolyLib)
 174         ])
 175         CPPFLAGS="$SAVE_CPPFLAGS"
 176 fi
 177
 178 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 179
 180 BV_SUBMODULE(piplib,required)
 181 AC_MSG_CHECKING([which piplib to use])
 182 AC_MSG_RESULT($with_piplib)
 183
 184 AC_SUBST(PIPLIB_CPPFLAGS)
 185 AC_SUBST(PIPLIB_LDFLAGS)
 186 AC_SUBST(PIPLIB_LIBS)
 187 if test "$with_piplib" = "bundled"; then
 188         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 189         bv_configure_args="$bv_configure_args --with-bits=gmp"
 190         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 191 else
 192         PIPLIB_LIBS="-lpiplibMP"
 193         if test "x$with_piplib_prefix" != "x"; then
 194                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 195                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 196         fi
 197         SAVE_CPPFLAGS="$CPPFLAGS"
 198         SAVE_LDFLAGS="$LDFLAGS"
 199         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 200         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 201         AC_CHECK_LIB(piplibMP, pip_solve,[
 202             AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 203                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 204             ],[#include <stdio.h>
 205                #include <piplib/piplibMP.h>])
 206         ],[
 207             AC_MSG_ERROR([Piplib not found])
 208         ])
 209         CPPFLAGS="$SAVE_CPPFLAGS"
 210         LDFLAGS="$SAVE_LDFLAGS"
 211 fi
 212 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 213
 214 AC_MSG_CHECKING(if the fractional representation should be used)
 215 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 216                                           [Don't use fractional representation])],
 217             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 218 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 219                                       [Don't use fractional representation])],
 220             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 221 AC_MSG_RESULT($bv_cv_modulo)
 222 if test "x$bv_cv_modulo" != "xno" ; then
 223         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 224 fi
 225
 226 AC_MSG_CHECKING(whether to use incremental algorithm)
 227 AC_ARG_ENABLE(incremental,
 228         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 229                         [Enable incremental algorithm [bf]])],
 230         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 231 AC_MSG_RESULT($bv_cv_incremental)
 232 case $bv_cv_incremental in
 233         yes | bf)
 234                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 235                           [Use breadth-first incremental algorithm])
 236         ;;
 237         df)
 238                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 239                           [Use depth-first incremental algorithm])
 240         ;;
 241 esac
 242
 243 AC_ARG_WITH(ntl,
 244             [  --with-ntl=DIR          DIR Location of NTL],
 245             [ echo "Package ntl : $withval" && ntl_package=$withval],
 246             [ ntl_package=yes ])
 247
 248 if test "$ntl_package" = "no"; then
 249     AC_MSG_ERROR(Need ntl)
 250 fi
 251
 252 AC_SUBST(NTL_CPPFLAGS)
 253 AC_SUBST(NTL_LDFLAGS)
 254 if test "$ntl_package" != "yes"; then
 255     NTL_CPPFLAGS="-I$ntl_package/include"
 256     NTL_LDFLAGS="-L$ntl_package/lib"
 257 fi
 258
 259 SAVE_CPPFLAGS="$CPPFLAGS"
 260 SAVE_LDFLAGS="$LDFLAGS"
 261 CPPFLAGS="$NTL_CPPFLAGS $CPPFLAGS"
 262 LDFLAGS="$NTL_LDFLAGS $LDFLAGS"
 263 AC_EGREP_CPP(yes, [
 264     #include <NTL/ZZ.h>
 265     #ifdef NTL_GMP_LIP
 266     yes
 267     #endif
 268     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 269
 270 AC_CHECK_LIB(ntl, main,[],[
 271     AC_MSG_ERROR(Need ntl)
 272 ])
 273 CPPFLAGS="$SAVE_CPPFLAGS"
 274 LDFLAGS="$SAVE_LDFLAGS"
 275
 276 AC_SUBST(bv_cone_hilbert_basis)
 277 AC_MSG_CHECKING(whether to compile zsolve)
 278 AC_ARG_WITH(bernstein,
 279             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 280             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 281 AC_MSG_RESULT($with_zsolve)
 282
 283 use_zsolve=false
 284 if test "$with_zsolve" != "no"; then
 285         if test "$GCC" = "yes"; then
 286                 $CC --version |
 287                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 288                 (read major minor
 289                         if test $major -gt 3; then
 290                                 exit 0
 291                         fi
 292                         if test $major -eq 3 -a $minor -ge 4; then
 293                                 exit 0
 294                         fi
 295                         exit 1
 296                 ) && use_zsolve=true
 297         fi
 298         if test "$use_zsolve" = false; then
 299                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 300         else
 301                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 302                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 303         fi
 304 fi
 305 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 306
 307 AC_MSG_CHECKING(whether to compile bernstein)
 308 AC_ARG_WITH(bernstein,
 309             [AS_HELP_STRING([--without-bernstein],[do not compile bernstein])],
 310             [ with_bernstein=$withval],  [ with_bernstein=yes ])
 311 AC_MSG_RESULT($with_bernstein)
 312
 313 AC_ARG_WITH(ginac_prefix,
 314         [AS_HELP_STRING([--with-ginac-prefix=DIR],[Installation prefix of GiNaC])])
 315 if test "x$with_ginac_prefix" != "x"; then
 316         export PKG_CONFIG_PATH="$with_ginac_prefix/lib/pkgconfig${PKG_CONFIG_PATH+:$PKG_CONFIG_PATH}"
 317 fi
 318
 319 AC_SUBST(bv_barvinok_bound)
 320 have_ginac=false
 321 if test "$with_bernstein" != "no"; then
 322         PKG_CHECK_EXISTS([ginac], [
 323                 PKG_CHECK_MODULES(ginac, ginac)
 324                 have_ginac=true
 325                 AC_DEFINE(HAVE_GINAC,[],[use GiNaC])
 326                 EXTRA_PACKAGE_LIBS="-lbernstein $EXTRA_PACKAGE_LIBS"
 327                 bv_barvinok_bound="barvinok_bound\$(EXEEXT) test_bound\$(EXEEXT)"
 328         ])
 329 fi
 330 AM_CONDITIONAL(HAVE_GINAC, test x$have_ginac = xtrue)
 331
 332 BV_SUBMODULE(omega,optional)
 333 AC_MSG_CHECKING([which omega to use])
 334 AC_MSG_RESULT($with_omega)
 335
 336 AC_SUBST(OMEGA_CPPFLAGS)
 337 AC_SUBST(OMEGA_LDFLAGS)
 338 AC_SUBST(OMEGA_LIBS)
 339 AC_SUBST(OMEGA_CODEGEN_LIBS)
 340 AC_SUBST(bv_omega_programs)
 341 have_omega=false
 342 have_codegen=false
 343 case "$with_omega" in
 344 bundled)
 345         have_omega=true
 346         have_codegen=true
 347         OMEGA_CPPFLAGS="-I\$(top_srcdir)/omega/omega_lib/include"
 348         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/basic/include"
 349         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/code_gen/include"
 350         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/omega_calc/include"
 351         ;;
 352 system)
 353     if test "x$omega_package" != "xyes"; then
 354         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 355         OMEGA_LDFLAGS="-L$omega_package/lib"
 356     else
 357         for i in /usr/include /usr/local/include; do
 358             if test -f $i/omega/omega.h; then
 359                 OMEGA_CPPFLAGS="-I$i/omega"
 360             fi
 361         done
 362     fi
 363
 364     AC_LANG_PUSH(C++)
 365     SAVE_CPPFLAGS="$CPPFLAGS"
 366     SAVE_LDFLAGS="$LDFLAGS"
 367     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 368     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 369     AC_CHECK_HEADERS([omega.h],[
 370         OMEGA_LIBS="-lomega"
 371         AC_CHECK_LIB(code_gen,main,[
 372                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 373                 have_codegen=true
 374         ])
 375         have_omega=true
 376     ],[AC_MSG_WARN(Omega not found)])
 377     CPPFLAGS="$SAVE_CPPFLAGS"
 378     LDFLAGS="$SAVE_LDFLAGS"
 379     AC_LANG_POP
 380     ;;
 381 esac
 382 if test "$have_omega" = true; then
 383         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 384 fi
 385 if test "$have_codegen" = true -a x$have_ginac = xtrue; then
 386         AC_CHECK_HEADERS([sys/resource.h], [],
 387                 [AC_DEFINE([OMIT_GETRUSAGE], [], [Don't use getrusage in occ])])
 388         bv_omega_programs="occ\$(EXEEXT) $bv_omega_programs"
 389 fi
 390 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 391 AM_CONDITIONAL(BUNDLED_OMEGA, test $with_omega = bundled)
 392
 393 use_parker=false
 394 AC_MSG_CHECKING(whether to compile parker)
 395 AC_ARG_WITH(parker,
 396             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 397             [ with_parker=$withval],  [ with_parker=yes ])
 398 AC_MSG_RESULT($with_parker)
 399
 400 if test "$with_parker" != "no"; then
 401         AC_MSG_CHECKING(for mona)
 402         AC_ARG_WITH(mona,
 403                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 404                                 [], [AC_MSG_RESULT(not specified)])
 405
 406         if test "x$with_mona" != "x"; then
 407                 AC_SUBST(MONAPATH)
 408                 MONAPATH=$with_mona
 409                 AC_MSG_RESULT($MONAPATH)
 410                 use_parker=true
 411                 AC_DEFINE(USE_PARKER,[],[use parker])
 412         fi
 413
 414         if test "x$with_mona" = "x"; then
 415                 AC_MSG_WARN(mona source directory required to compile parker)
 416                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 417         fi
 418 fi
 419 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 420
 421 AC_MSG_CHECKING(whether to use cddlib)
 422 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 423             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 424 AC_MSG_RESULT($cddlib_package)
 425
 426 have_cddlib=false
 427 if test "$cddlib_package" != "no"; then
 428     if test "x$cddlib_package" != "xyes"; then
 429         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 430         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 431     fi
 432     AC_TRY_LINK([
 433 #define GMPRATIONAL
 434 #include <setoper.h>
 435 #include <cddmp.h>
 436 ], [
 437     mytype a;
 438     dd_init(a); ], [
 439         have_cddlib=true
 440         AC_CHECK_LIB(cddgmp, main,[
 441                 SAVE_LIBS="$LIBS"
 442                 LIBS="-lcddgmp $LIBS"
 443                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 444                 AC_LANG_PUSH(C++)
 445                 AC_RUN_IFELSE(AC_LANG_PROGRAM([[#define GMPRATIONAL
 446 #include <setoper.h>
 447 #include <cdd.h>]],
 448                 [[
 449         const char *filename = SRCDIR"/cdd94e-test";
 450         FILE *f;
 451         dd_MatrixPtr M;
 452         dd_LPType *lp;
 453         dd_ErrorType err = dd_NoError;
 454
 455         dd_set_global_constants();
 456
 457         f = fopen(filename, "r");
 458         M = dd_PolyFile2Matrix(f, &err);
 459         lp = dd_Matrix2LP(M, &err);
 460         dd_LPSolve(lp, dd_DualSimplex, &err);
 461         return lp->LPS == dd_Inconsistent;
 462                 ]]),[
 463                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 464                 ],[
 465                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 466                         LIBS="$SAVE_LIBS"
 467                         have_cddlib=false
 468                 ])
 469                 AC_LANG_POP
 470         ],[have_cddlib=false])
 471     ])
 472 fi
 473 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 474
 475
 476
 477 AC_MSG_CHECKING(whether to use GLPK)
 478 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 479             [ glpk_package=$withval],  [ glpk_package=yes ])
 480 AC_MSG_RESULT($glpk_package)
 481
 482 have_glpk=false
 483 if test "$glpk_package" != "no"; then
 484     if test "x$glpk_package" != "xyes"; then
 485         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 486         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 487     fi
 488     AC_CHECK_HEADERS([glpk.h],[
 489         have_glpk=true
 490         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 491     ])
 492 fi
 493 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 494
 495 AC_MSG_CHECKING(location of TOPCOM)
 496 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 497             [topcom_package=$withval], [topcom_package=unspecified])
 498 AC_MSG_RESULT($topcom_package)
 499 have_topcom=false
 500 if test "$topcom_package" != no; then
 501         topcom_path="$PATH"
 502         if test "$topcom_package" != unspecified; then
 503                 topcom_path="$topcom_package/bin"
 504         fi
 505         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 506         if test -n "$POINTS2TRIANGS"; then
 507                 have_topcom=true
 508                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 509                                     [Path of points2triangs])
 510         fi
 511 fi
 512 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 513
 514 AC_SUBST(GIT_HEAD_ID)
 515 AC_SUBST(GIT_HEAD)
 516 AC_SUBST(GIT_HEAD_VERSION)
 517 if test -f $srcdir/.git/HEAD; then
 518     GIT_HEAD="$srcdir/.git/index"
 519     GIT_REPO="$srcdir/.git"
 520     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 521 elif test -f $srcdir/GIT_HEAD_ID; then
 522     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 523 else
 524     mysrcdir=`(cd $srcdir; pwd)`
 525     head=`basename $mysrcdir | sed -e 's/.*-//'`
 526     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 527     head3=`echo $head2 | sed -e 's/........................................//'`
 528     base=`basename $mysrcdir | sed -e 's/-.*//'`
 529     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 530         GIT_HEAD_ID="barvinok-$VERSION-$head
 531     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 532         GIT_HEAD_ID="barvinok-$VERSION-$head
 533     else
 534         GIT_HEAD_ID="UNKNOWN"
 535     fi
 536 fi
 537 if test -z "$GIT_REPO" ; then
 538     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 539 else
 540     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 541 fi
 542 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 543
 544 AC_LANG_PUSH(C++)
 545 AC_TRY_COMPILE([
 546                 #include <set>
 547                 void negate();
 548         ], [negate()],
 549         suffix="normal", suffix="broken")
 550 AC_CONFIG_COMMANDS([barvinok/set.h],
 551                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 552                    [suffix="$suffix"])
 553 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 554                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 555                    [suffix="$suffix"])
 556 use_fdstream=false
 557 SAVE_CPPFLAGS="$CPPFLAGS"
 558 CPPFLAGS="-I$srcdir $CPPFLAGS"
 559 AC_TRY_COMPILE([#include "fdstream.h"],[],
 560         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 561         use_fdstream=true])
 562 CPPFLAGS="$SAVE_CPPFLAGS"
 563 AC_LANG_POP
 564 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 565
 566 PACKAGE_LIBS="-lbarvinok -lbarvinok-core $EXTRA_PACKAGE_LIBS -lpolylibgmp -lpiplibMP"
 567 AX_CREATE_PKGCONFIG_INFO
 568
 569 AC_CONFIG_HEADERS(config.h)
 570 AC_CONFIG_FILES(Makefile lib/Makefile zsolve/Makefile doc/Makefile)
 571 AC_CONFIG_FILES(omega_interface/Makefile)
 572 AC_CONFIG_FILES(parker/Makefile)
 573 if test $with_polylib = bundled; then
 574         AC_CONFIG_SUBDIRS(polylib)
 575 fi
 576 if test $with_piplib = bundled; then
 577         AC_CONFIG_SUBDIRS(piplib)
 578 fi
 579 if test x$have_ginac = xtrue; then
 580     AC_CONFIG_SUBDIRS(bernstein)
 581 fi
 582 if test $with_omega = bundled; then
 583         AC_CONFIG_SUBDIRS(omega)
 584 fi
 585 AC_CONFIG_COMMANDS_POST([
 586         dnl pass on arguments to subdir configures, but don't
 587         dnl add them to config.status
 588         ac_configure_args="$ac_configure_args $bv_configure_args"
 589 ])
 590 AC_OUTPUT