Second batch for 2.14
[alt-git.git] / gitweb / gitweb.perl
blob7cf68f07b773f7e520c1e6ba680bff65e5bc7f3a
1 #!/usr/bin/perl
3 # gitweb - simple web interface to track changes in git repositories
5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
6 # (C) 2005, Christian Gierke
8 # This program is licensed under the GPLv2
10 use 5.008;
11 use strict;
12 use warnings;
13 use CGI qw(:standard :escapeHTML -nosticky);
14 use CGI::Util qw(unescape);
15 use CGI::Carp qw(fatalsToBrowser set_message);
16 use Encode;
17 use Fcntl ':mode';
18 use File::Find qw();
19 use File::Basename qw(basename);
20 use Time::HiRes qw(gettimeofday tv_interval);
21 binmode STDOUT, ':utf8';
23 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
24 eval 'sub CGI::multi_param { CGI::param(@_) }'
27 our $t0 = [ gettimeofday() ];
28 our $number_of_git_cmds = 0;
30 BEGIN {
31 CGI->compile() if $ENV{'MOD_PERL'};
34 our $version = "++GIT_VERSION++";
36 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
37 sub evaluate_uri {
38 our $cgi;
40 our $my_url = $cgi->url();
41 our $my_uri = $cgi->url(-absolute => 1);
43 # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
44 # needed and used only for URLs with nonempty PATH_INFO
45 our $base_url = $my_url;
47 # When the script is used as DirectoryIndex, the URL does not contain the name
48 # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
49 # have to do it ourselves. We make $path_info global because it's also used
50 # later on.
52 # Another issue with the script being the DirectoryIndex is that the resulting
53 # $my_url data is not the full script URL: this is good, because we want
54 # generated links to keep implying the script name if it wasn't explicitly
55 # indicated in the URL we're handling, but it means that $my_url cannot be used
56 # as base URL.
57 # Therefore, if we needed to strip PATH_INFO, then we know that we have
58 # to build the base URL ourselves:
59 our $path_info = decode_utf8($ENV{"PATH_INFO"});
60 if ($path_info) {
61 # $path_info has already been URL-decoded by the web server, but
62 # $my_url and $my_uri have not. URL-decode them so we can properly
63 # strip $path_info.
64 $my_url = unescape($my_url);
65 $my_uri = unescape($my_uri);
66 if ($my_url =~ s,\Q$path_info\E$,, &&
67 $my_uri =~ s,\Q$path_info\E$,, &&
68 defined $ENV{'SCRIPT_NAME'}) {
69 $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
73 # target of the home link on top of all pages
74 our $home_link = $my_uri || "/";
77 # core git executable to use
78 # this can just be "git" if your webserver has a sensible PATH
79 our $GIT = "++GIT_BINDIR++/git";
81 # absolute fs-path which will be prepended to the project path
82 #our $projectroot = "/pub/scm";
83 our $projectroot = "++GITWEB_PROJECTROOT++";
85 # fs traversing limit for getting project list
86 # the number is relative to the projectroot
87 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
89 # string of the home link on top of all pages
90 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
92 # extra breadcrumbs preceding the home link
93 our @extra_breadcrumbs = ();
95 # name of your site or organization to appear in page titles
96 # replace this with something more descriptive for clearer bookmarks
97 our $site_name = "++GITWEB_SITENAME++"
98 || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
100 # html snippet to include in the <head> section of each page
101 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
102 # filename of html text to include at top of each page
103 our $site_header = "++GITWEB_SITE_HEADER++";
104 # html text to include at home page
105 our $home_text = "++GITWEB_HOMETEXT++";
106 # filename of html text to include at bottom of each page
107 our $site_footer = "++GITWEB_SITE_FOOTER++";
109 # URI of stylesheets
110 our @stylesheets = ("++GITWEB_CSS++");
111 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
112 our $stylesheet = undef;
113 # URI of GIT logo (72x27 size)
114 our $logo = "++GITWEB_LOGO++";
115 # URI of GIT favicon, assumed to be image/png type
116 our $favicon = "++GITWEB_FAVICON++";
117 # URI of gitweb.js (JavaScript code for gitweb)
118 our $javascript = "++GITWEB_JS++";
120 # URI and label (title) of GIT logo link
121 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
122 #our $logo_label = "git documentation";
123 our $logo_url = "http://git-scm.com/";
124 our $logo_label = "git homepage";
126 # source of projects list
127 our $projects_list = "++GITWEB_LIST++";
129 # the width (in characters) of the projects list "Description" column
130 our $projects_list_description_width = 25;
132 # group projects by category on the projects list
133 # (enabled if this variable evaluates to true)
134 our $projects_list_group_categories = 0;
136 # default category if none specified
137 # (leave the empty string for no category)
138 our $project_list_default_category = "";
140 # default order of projects list
141 # valid values are none, project, descr, owner, and age
142 our $default_projects_order = "project";
144 # show repository only if this file exists
145 # (only effective if this variable evaluates to true)
146 our $export_ok = "++GITWEB_EXPORT_OK++";
148 # don't generate age column on the projects list page
149 our $omit_age_column = 0;
151 # don't generate information about owners of repositories
152 our $omit_owner=0;
154 # show repository only if this subroutine returns true
155 # when given the path to the project, for example:
156 # sub { return -e "$_[0]/git-daemon-export-ok"; }
157 our $export_auth_hook = undef;
159 # only allow viewing of repositories also shown on the overview page
160 our $strict_export = "++GITWEB_STRICT_EXPORT++";
162 # list of git base URLs used for URL to where fetch project from,
163 # i.e. full URL is "$git_base_url/$project"
164 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
166 # default blob_plain mimetype and default charset for text/plain blob
167 our $default_blob_plain_mimetype = 'text/plain';
168 our $default_text_plain_charset = undef;
170 # file to use for guessing MIME types before trying /etc/mime.types
171 # (relative to the current git repository)
172 our $mimetypes_file = undef;
174 # assume this charset if line contains non-UTF-8 characters;
175 # it should be valid encoding (see Encoding::Supported(3pm) for list),
176 # for which encoding all byte sequences are valid, for example
177 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
178 # could be even 'utf-8' for the old behavior)
179 our $fallback_encoding = 'latin1';
181 # rename detection options for git-diff and git-diff-tree
182 # - default is '-M', with the cost proportional to
183 # (number of removed files) * (number of new files).
184 # - more costly is '-C' (which implies '-M'), with the cost proportional to
185 # (number of changed files + number of removed files) * (number of new files)
186 # - even more costly is '-C', '--find-copies-harder' with cost
187 # (number of files in the original tree) * (number of new files)
188 # - one might want to include '-B' option, e.g. '-B', '-M'
189 our @diff_opts = ('-M'); # taken from git_commit
191 # Disables features that would allow repository owners to inject script into
192 # the gitweb domain.
193 our $prevent_xss = 0;
195 # Path to the highlight executable to use (must be the one from
196 # http://www.andre-simon.de due to assumptions about parameters and output).
197 # Useful if highlight is not installed on your webserver's PATH.
198 # [Default: highlight]
199 our $highlight_bin = "++HIGHLIGHT_BIN++";
201 # information about snapshot formats that gitweb is capable of serving
202 our %known_snapshot_formats = (
203 # name => {
204 # 'display' => display name,
205 # 'type' => mime type,
206 # 'suffix' => filename suffix,
207 # 'format' => --format for git-archive,
208 # 'compressor' => [compressor command and arguments]
209 # (array reference, optional)
210 # 'disabled' => boolean (optional)}
212 'tgz' => {
213 'display' => 'tar.gz',
214 'type' => 'application/x-gzip',
215 'suffix' => '.tar.gz',
216 'format' => 'tar',
217 'compressor' => ['gzip', '-n']},
219 'tbz2' => {
220 'display' => 'tar.bz2',
221 'type' => 'application/x-bzip2',
222 'suffix' => '.tar.bz2',
223 'format' => 'tar',
224 'compressor' => ['bzip2']},
226 'txz' => {
227 'display' => 'tar.xz',
228 'type' => 'application/x-xz',
229 'suffix' => '.tar.xz',
230 'format' => 'tar',
231 'compressor' => ['xz'],
232 'disabled' => 1},
234 'zip' => {
235 'display' => 'zip',
236 'type' => 'application/x-zip',
237 'suffix' => '.zip',
238 'format' => 'zip'},
241 # Aliases so we understand old gitweb.snapshot values in repository
242 # configuration.
243 our %known_snapshot_format_aliases = (
244 'gzip' => 'tgz',
245 'bzip2' => 'tbz2',
246 'xz' => 'txz',
248 # backward compatibility: legacy gitweb config support
249 'x-gzip' => undef, 'gz' => undef,
250 'x-bzip2' => undef, 'bz2' => undef,
251 'x-zip' => undef, '' => undef,
254 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
255 # are changed, it may be appropriate to change these values too via
256 # $GITWEB_CONFIG.
257 our %avatar_size = (
258 'default' => 16,
259 'double' => 32
262 # Used to set the maximum load that we will still respond to gitweb queries.
263 # If server load exceed this value then return "503 server busy" error.
264 # If gitweb cannot determined server load, it is taken to be 0.
265 # Leave it undefined (or set to 'undef') to turn off load checking.
266 our $maxload = 300;
268 # configuration for 'highlight' (http://www.andre-simon.de/)
269 # match by basename
270 our %highlight_basename = (
271 #'Program' => 'py',
272 #'Library' => 'py',
273 'SConstruct' => 'py', # SCons equivalent of Makefile
274 'Makefile' => 'make',
276 # match by extension
277 our %highlight_ext = (
278 # main extensions, defining name of syntax;
279 # see files in /usr/share/highlight/langDefs/ directory
280 (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
281 # alternate extensions, see /etc/highlight/filetypes.conf
282 (map { $_ => 'c' } qw(c h)),
283 (map { $_ => 'sh' } qw(sh bash zsh ksh)),
284 (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
285 (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
286 (map { $_ => 'pl' } qw(pl perl pm)), # perhaps also 'cgi'
287 (map { $_ => 'make'} qw(make mak mk)),
288 (map { $_ => 'xml' } qw(xml xhtml html htm)),
291 # You define site-wide feature defaults here; override them with
292 # $GITWEB_CONFIG as necessary.
293 our %feature = (
294 # feature => {
295 # 'sub' => feature-sub (subroutine),
296 # 'override' => allow-override (boolean),
297 # 'default' => [ default options...] (array reference)}
299 # if feature is overridable (it means that allow-override has true value),
300 # then feature-sub will be called with default options as parameters;
301 # return value of feature-sub indicates if to enable specified feature
303 # if there is no 'sub' key (no feature-sub), then feature cannot be
304 # overridden
306 # use gitweb_get_feature(<feature>) to retrieve the <feature> value
307 # (an array) or gitweb_check_feature(<feature>) to check if <feature>
308 # is enabled
310 # Enable the 'blame' blob view, showing the last commit that modified
311 # each line in the file. This can be very CPU-intensive.
313 # To enable system wide have in $GITWEB_CONFIG
314 # $feature{'blame'}{'default'} = [1];
315 # To have project specific config enable override in $GITWEB_CONFIG
316 # $feature{'blame'}{'override'} = 1;
317 # and in project config gitweb.blame = 0|1;
318 'blame' => {
319 'sub' => sub { feature_bool('blame', @_) },
320 'override' => 0,
321 'default' => [0]},
323 # Enable the 'snapshot' link, providing a compressed archive of any
324 # tree. This can potentially generate high traffic if you have large
325 # project.
327 # Value is a list of formats defined in %known_snapshot_formats that
328 # you wish to offer.
329 # To disable system wide have in $GITWEB_CONFIG
330 # $feature{'snapshot'}{'default'} = [];
331 # To have project specific config enable override in $GITWEB_CONFIG
332 # $feature{'snapshot'}{'override'} = 1;
333 # and in project config, a comma-separated list of formats or "none"
334 # to disable. Example: gitweb.snapshot = tbz2,zip;
335 'snapshot' => {
336 'sub' => \&feature_snapshot,
337 'override' => 0,
338 'default' => ['tgz']},
340 # Enable text search, which will list the commits which match author,
341 # committer or commit text to a given string. Enabled by default.
342 # Project specific override is not supported.
344 # Note that this controls all search features, which means that if
345 # it is disabled, then 'grep' and 'pickaxe' search would also be
346 # disabled.
347 'search' => {
348 'override' => 0,
349 'default' => [1]},
351 # Enable grep search, which will list the files in currently selected
352 # tree containing the given string. Enabled by default. This can be
353 # potentially CPU-intensive, of course.
354 # Note that you need to have 'search' feature enabled too.
356 # To enable system wide have in $GITWEB_CONFIG
357 # $feature{'grep'}{'default'} = [1];
358 # To have project specific config enable override in $GITWEB_CONFIG
359 # $feature{'grep'}{'override'} = 1;
360 # and in project config gitweb.grep = 0|1;
361 'grep' => {
362 'sub' => sub { feature_bool('grep', @_) },
363 'override' => 0,
364 'default' => [1]},
366 # Enable the pickaxe search, which will list the commits that modified
367 # a given string in a file. This can be practical and quite faster
368 # alternative to 'blame', but still potentially CPU-intensive.
369 # Note that you need to have 'search' feature enabled too.
371 # To enable system wide have in $GITWEB_CONFIG
372 # $feature{'pickaxe'}{'default'} = [1];
373 # To have project specific config enable override in $GITWEB_CONFIG
374 # $feature{'pickaxe'}{'override'} = 1;
375 # and in project config gitweb.pickaxe = 0|1;
376 'pickaxe' => {
377 'sub' => sub { feature_bool('pickaxe', @_) },
378 'override' => 0,
379 'default' => [1]},
381 # Enable showing size of blobs in a 'tree' view, in a separate
382 # column, similar to what 'ls -l' does. This cost a bit of IO.
384 # To disable system wide have in $GITWEB_CONFIG
385 # $feature{'show-sizes'}{'default'} = [0];
386 # To have project specific config enable override in $GITWEB_CONFIG
387 # $feature{'show-sizes'}{'override'} = 1;
388 # and in project config gitweb.showsizes = 0|1;
389 'show-sizes' => {
390 'sub' => sub { feature_bool('showsizes', @_) },
391 'override' => 0,
392 'default' => [1]},
394 # Make gitweb use an alternative format of the URLs which can be
395 # more readable and natural-looking: project name is embedded
396 # directly in the path and the query string contains other
397 # auxiliary information. All gitweb installations recognize
398 # URL in either format; this configures in which formats gitweb
399 # generates links.
401 # To enable system wide have in $GITWEB_CONFIG
402 # $feature{'pathinfo'}{'default'} = [1];
403 # Project specific override is not supported.
405 # Note that you will need to change the default location of CSS,
406 # favicon, logo and possibly other files to an absolute URL. Also,
407 # if gitweb.cgi serves as your indexfile, you will need to force
408 # $my_uri to contain the script name in your $GITWEB_CONFIG.
409 'pathinfo' => {
410 'override' => 0,
411 'default' => [0]},
413 # Make gitweb consider projects in project root subdirectories
414 # to be forks of existing projects. Given project $projname.git,
415 # projects matching $projname/*.git will not be shown in the main
416 # projects list, instead a '+' mark will be added to $projname
417 # there and a 'forks' view will be enabled for the project, listing
418 # all the forks. If project list is taken from a file, forks have
419 # to be listed after the main project.
421 # To enable system wide have in $GITWEB_CONFIG
422 # $feature{'forks'}{'default'} = [1];
423 # Project specific override is not supported.
424 'forks' => {
425 'override' => 0,
426 'default' => [0]},
428 # Insert custom links to the action bar of all project pages.
429 # This enables you mainly to link to third-party scripts integrating
430 # into gitweb; e.g. git-browser for graphical history representation
431 # or custom web-based repository administration interface.
433 # The 'default' value consists of a list of triplets in the form
434 # (label, link, position) where position is the label after which
435 # to insert the link and link is a format string where %n expands
436 # to the project name, %f to the project path within the filesystem,
437 # %h to the current hash (h gitweb parameter) and %b to the current
438 # hash base (hb gitweb parameter); %% expands to %.
440 # To enable system wide have in $GITWEB_CONFIG e.g.
441 # $feature{'actions'}{'default'} = [('graphiclog',
442 # '/git-browser/by-commit.html?r=%n', 'summary')];
443 # Project specific override is not supported.
444 'actions' => {
445 'override' => 0,
446 'default' => []},
448 # Allow gitweb scan project content tags of project repository,
449 # and display the popular Web 2.0-ish "tag cloud" near the projects
450 # list. Note that this is something COMPLETELY different from the
451 # normal Git tags.
453 # gitweb by itself can show existing tags, but it does not handle
454 # tagging itself; you need to do it externally, outside gitweb.
455 # The format is described in git_get_project_ctags() subroutine.
456 # You may want to install the HTML::TagCloud Perl module to get
457 # a pretty tag cloud instead of just a list of tags.
459 # To enable system wide have in $GITWEB_CONFIG
460 # $feature{'ctags'}{'default'} = [1];
461 # Project specific override is not supported.
463 # In the future whether ctags editing is enabled might depend
464 # on the value, but using 1 should always mean no editing of ctags.
465 'ctags' => {
466 'override' => 0,
467 'default' => [0]},
469 # The maximum number of patches in a patchset generated in patch
470 # view. Set this to 0 or undef to disable patch view, or to a
471 # negative number to remove any limit.
473 # To disable system wide have in $GITWEB_CONFIG
474 # $feature{'patches'}{'default'} = [0];
475 # To have project specific config enable override in $GITWEB_CONFIG
476 # $feature{'patches'}{'override'} = 1;
477 # and in project config gitweb.patches = 0|n;
478 # where n is the maximum number of patches allowed in a patchset.
479 'patches' => {
480 'sub' => \&feature_patches,
481 'override' => 0,
482 'default' => [16]},
484 # Avatar support. When this feature is enabled, views such as
485 # shortlog or commit will display an avatar associated with
486 # the email of the committer(s) and/or author(s).
488 # Currently available providers are gravatar and picon.
489 # If an unknown provider is specified, the feature is disabled.
491 # Gravatar depends on Digest::MD5.
492 # Picon currently relies on the indiana.edu database.
494 # To enable system wide have in $GITWEB_CONFIG
495 # $feature{'avatar'}{'default'} = ['<provider>'];
496 # where <provider> is either gravatar or picon.
497 # To have project specific config enable override in $GITWEB_CONFIG
498 # $feature{'avatar'}{'override'} = 1;
499 # and in project config gitweb.avatar = <provider>;
500 'avatar' => {
501 'sub' => \&feature_avatar,
502 'override' => 0,
503 'default' => ['']},
505 # Enable displaying how much time and how many git commands
506 # it took to generate and display page. Disabled by default.
507 # Project specific override is not supported.
508 'timed' => {
509 'override' => 0,
510 'default' => [0]},
512 # Enable turning some links into links to actions which require
513 # JavaScript to run (like 'blame_incremental'). Not enabled by
514 # default. Project specific override is currently not supported.
515 'javascript-actions' => {
516 'override' => 0,
517 'default' => [0]},
519 # Enable and configure ability to change common timezone for dates
520 # in gitweb output via JavaScript. Enabled by default.
521 # Project specific override is not supported.
522 'javascript-timezone' => {
523 'override' => 0,
524 'default' => [
525 'local', # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
526 # or undef to turn off this feature
527 'gitweb_tz', # name of cookie where to store selected timezone
528 'datetime', # CSS class used to mark up dates for manipulation
531 # Syntax highlighting support. This is based on Daniel Svensson's
532 # and Sham Chukoury's work in gitweb-xmms2.git.
533 # It requires the 'highlight' program present in $PATH,
534 # and therefore is disabled by default.
536 # To enable system wide have in $GITWEB_CONFIG
537 # $feature{'highlight'}{'default'} = [1];
539 'highlight' => {
540 'sub' => sub { feature_bool('highlight', @_) },
541 'override' => 0,
542 'default' => [0]},
544 # Enable displaying of remote heads in the heads list
546 # To enable system wide have in $GITWEB_CONFIG
547 # $feature{'remote_heads'}{'default'} = [1];
548 # To have project specific config enable override in $GITWEB_CONFIG
549 # $feature{'remote_heads'}{'override'} = 1;
550 # and in project config gitweb.remoteheads = 0|1;
551 'remote_heads' => {
552 'sub' => sub { feature_bool('remote_heads', @_) },
553 'override' => 0,
554 'default' => [0]},
556 # Enable showing branches under other refs in addition to heads
558 # To set system wide extra branch refs have in $GITWEB_CONFIG
559 # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
560 # To have project specific config enable override in $GITWEB_CONFIG
561 # $feature{'extra-branch-refs'}{'override'} = 1;
562 # and in project config gitweb.extrabranchrefs = dirs of choice
563 # Every directory is separated with whitespace.
565 'extra-branch-refs' => {
566 'sub' => \&feature_extra_branch_refs,
567 'override' => 0,
568 'default' => []},
571 sub gitweb_get_feature {
572 my ($name) = @_;
573 return unless exists $feature{$name};
574 my ($sub, $override, @defaults) = (
575 $feature{$name}{'sub'},
576 $feature{$name}{'override'},
577 @{$feature{$name}{'default'}});
578 # project specific override is possible only if we have project
579 our $git_dir; # global variable, declared later
580 if (!$override || !defined $git_dir) {
581 return @defaults;
583 if (!defined $sub) {
584 warn "feature $name is not overridable";
585 return @defaults;
587 return $sub->(@defaults);
590 # A wrapper to check if a given feature is enabled.
591 # With this, you can say
593 # my $bool_feat = gitweb_check_feature('bool_feat');
594 # gitweb_check_feature('bool_feat') or somecode;
596 # instead of
598 # my ($bool_feat) = gitweb_get_feature('bool_feat');
599 # (gitweb_get_feature('bool_feat'))[0] or somecode;
601 sub gitweb_check_feature {
602 return (gitweb_get_feature(@_))[0];
606 sub feature_bool {
607 my $key = shift;
608 my ($val) = git_get_project_config($key, '--bool');
610 if (!defined $val) {
611 return ($_[0]);
612 } elsif ($val eq 'true') {
613 return (1);
614 } elsif ($val eq 'false') {
615 return (0);
619 sub feature_snapshot {
620 my (@fmts) = @_;
622 my ($val) = git_get_project_config('snapshot');
624 if ($val) {
625 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
628 return @fmts;
631 sub feature_patches {
632 my @val = (git_get_project_config('patches', '--int'));
634 if (@val) {
635 return @val;
638 return ($_[0]);
641 sub feature_avatar {
642 my @val = (git_get_project_config('avatar'));
644 return @val ? @val : @_;
647 sub feature_extra_branch_refs {
648 my (@branch_refs) = @_;
649 my $values = git_get_project_config('extrabranchrefs');
651 if ($values) {
652 $values = config_to_multi ($values);
653 @branch_refs = ();
654 foreach my $value (@{$values}) {
655 push @branch_refs, split /\s+/, $value;
659 return @branch_refs;
662 # checking HEAD file with -e is fragile if the repository was
663 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
664 # and then pruned.
665 sub check_head_link {
666 my ($dir) = @_;
667 my $headfile = "$dir/HEAD";
668 return ((-e $headfile) ||
669 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
672 sub check_export_ok {
673 my ($dir) = @_;
674 return (check_head_link($dir) &&
675 (!$export_ok || -e "$dir/$export_ok") &&
676 (!$export_auth_hook || $export_auth_hook->($dir)));
679 # process alternate names for backward compatibility
680 # filter out unsupported (unknown) snapshot formats
681 sub filter_snapshot_fmts {
682 my @fmts = @_;
684 @fmts = map {
685 exists $known_snapshot_format_aliases{$_} ?
686 $known_snapshot_format_aliases{$_} : $_} @fmts;
687 @fmts = grep {
688 exists $known_snapshot_formats{$_} &&
689 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
692 sub filter_and_validate_refs {
693 my @refs = @_;
694 my %unique_refs = ();
696 foreach my $ref (@refs) {
697 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
698 # 'heads' are added implicitly in get_branch_refs().
699 $unique_refs{$ref} = 1 if ($ref ne 'heads');
701 return sort keys %unique_refs;
704 # If it is set to code reference, it is code that it is to be run once per
705 # request, allowing updating configurations that change with each request,
706 # while running other code in config file only once.
708 # Otherwise, if it is false then gitweb would process config file only once;
709 # if it is true then gitweb config would be run for each request.
710 our $per_request_config = 1;
712 # read and parse gitweb config file given by its parameter.
713 # returns true on success, false on recoverable error, allowing
714 # to chain this subroutine, using first file that exists.
715 # dies on errors during parsing config file, as it is unrecoverable.
716 sub read_config_file {
717 my $filename = shift;
718 return unless defined $filename;
719 # die if there are errors parsing config file
720 if (-e $filename) {
721 do $filename;
722 die $@ if $@;
723 return 1;
725 return;
728 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
729 sub evaluate_gitweb_config {
730 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
731 our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
732 our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
734 # Protect against duplications of file names, to not read config twice.
735 # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
736 # there possibility of duplication of filename there doesn't matter.
737 $GITWEB_CONFIG = "" if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
738 $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
740 # Common system-wide settings for convenience.
741 # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
742 read_config_file($GITWEB_CONFIG_COMMON);
744 # Use first config file that exists. This means use the per-instance
745 # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
746 read_config_file($GITWEB_CONFIG) and return;
747 read_config_file($GITWEB_CONFIG_SYSTEM);
750 # Get loadavg of system, to compare against $maxload.
751 # Currently it requires '/proc/loadavg' present to get loadavg;
752 # if it is not present it returns 0, which means no load checking.
753 sub get_loadavg {
754 if( -e '/proc/loadavg' ){
755 open my $fd, '<', '/proc/loadavg'
756 or return 0;
757 my @load = split(/\s+/, scalar <$fd>);
758 close $fd;
760 # The first three columns measure CPU and IO utilization of the last one,
761 # five, and 10 minute periods. The fourth column shows the number of
762 # currently running processes and the total number of processes in the m/n
763 # format. The last column displays the last process ID used.
764 return $load[0] || 0;
766 # additional checks for load average should go here for things that don't export
767 # /proc/loadavg
769 return 0;
772 # version of the core git binary
773 our $git_version;
774 sub evaluate_git_version {
775 our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
776 $number_of_git_cmds++;
779 sub check_loadavg {
780 if (defined $maxload && get_loadavg() > $maxload) {
781 die_error(503, "The load average on the server is too high");
785 # ======================================================================
786 # input validation and dispatch
788 # input parameters can be collected from a variety of sources (presently, CGI
789 # and PATH_INFO), so we define an %input_params hash that collects them all
790 # together during validation: this allows subsequent uses (e.g. href()) to be
791 # agnostic of the parameter origin
793 our %input_params = ();
795 # input parameters are stored with the long parameter name as key. This will
796 # also be used in the href subroutine to convert parameters to their CGI
797 # equivalent, and since the href() usage is the most frequent one, we store
798 # the name -> CGI key mapping here, instead of the reverse.
800 # XXX: Warning: If you touch this, check the search form for updating,
801 # too.
803 our @cgi_param_mapping = (
804 project => "p",
805 action => "a",
806 file_name => "f",
807 file_parent => "fp",
808 hash => "h",
809 hash_parent => "hp",
810 hash_base => "hb",
811 hash_parent_base => "hpb",
812 page => "pg",
813 order => "o",
814 searchtext => "s",
815 searchtype => "st",
816 snapshot_format => "sf",
817 extra_options => "opt",
818 search_use_regexp => "sr",
819 ctag => "by_tag",
820 diff_style => "ds",
821 project_filter => "pf",
822 # this must be last entry (for manipulation from JavaScript)
823 javascript => "js"
825 our %cgi_param_mapping = @cgi_param_mapping;
827 # we will also need to know the possible actions, for validation
828 our %actions = (
829 "blame" => \&git_blame,
830 "blame_incremental" => \&git_blame_incremental,
831 "blame_data" => \&git_blame_data,
832 "blobdiff" => \&git_blobdiff,
833 "blobdiff_plain" => \&git_blobdiff_plain,
834 "blob" => \&git_blob,
835 "blob_plain" => \&git_blob_plain,
836 "commitdiff" => \&git_commitdiff,
837 "commitdiff_plain" => \&git_commitdiff_plain,
838 "commit" => \&git_commit,
839 "forks" => \&git_forks,
840 "heads" => \&git_heads,
841 "history" => \&git_history,
842 "log" => \&git_log,
843 "patch" => \&git_patch,
844 "patches" => \&git_patches,
845 "remotes" => \&git_remotes,
846 "rss" => \&git_rss,
847 "atom" => \&git_atom,
848 "search" => \&git_search,
849 "search_help" => \&git_search_help,
850 "shortlog" => \&git_shortlog,
851 "summary" => \&git_summary,
852 "tag" => \&git_tag,
853 "tags" => \&git_tags,
854 "tree" => \&git_tree,
855 "snapshot" => \&git_snapshot,
856 "object" => \&git_object,
857 # those below don't need $project
858 "opml" => \&git_opml,
859 "project_list" => \&git_project_list,
860 "project_index" => \&git_project_index,
863 # finally, we have the hash of allowed extra_options for the commands that
864 # allow them
865 our %allowed_options = (
866 "--no-merges" => [ qw(rss atom log shortlog history) ],
869 # fill %input_params with the CGI parameters. All values except for 'opt'
870 # should be single values, but opt can be an array. We should probably
871 # build an array of parameters that can be multi-valued, but since for the time
872 # being it's only this one, we just single it out
873 sub evaluate_query_params {
874 our $cgi;
876 while (my ($name, $symbol) = each %cgi_param_mapping) {
877 if ($symbol eq 'opt') {
878 $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
879 } else {
880 $input_params{$name} = decode_utf8($cgi->param($symbol));
885 # now read PATH_INFO and update the parameter list for missing parameters
886 sub evaluate_path_info {
887 return if defined $input_params{'project'};
888 return if !$path_info;
889 $path_info =~ s,^/+,,;
890 return if !$path_info;
892 # find which part of PATH_INFO is project
893 my $project = $path_info;
894 $project =~ s,/+$,,;
895 while ($project && !check_head_link("$projectroot/$project")) {
896 $project =~ s,/*[^/]*$,,;
898 return unless $project;
899 $input_params{'project'} = $project;
901 # do not change any parameters if an action is given using the query string
902 return if $input_params{'action'};
903 $path_info =~ s,^\Q$project\E/*,,;
905 # next, check if we have an action
906 my $action = $path_info;
907 $action =~ s,/.*$,,;
908 if (exists $actions{$action}) {
909 $path_info =~ s,^$action/*,,;
910 $input_params{'action'} = $action;
913 # list of actions that want hash_base instead of hash, but can have no
914 # pathname (f) parameter
915 my @wants_base = (
916 'tree',
917 'history',
920 # we want to catch, among others
921 # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
922 my ($parentrefname, $parentpathname, $refname, $pathname) =
923 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
925 # first, analyze the 'current' part
926 if (defined $pathname) {
927 # we got "branch:filename" or "branch:dir/"
928 # we could use git_get_type(branch:pathname), but:
929 # - it needs $git_dir
930 # - it does a git() call
931 # - the convention of terminating directories with a slash
932 # makes it superfluous
933 # - embedding the action in the PATH_INFO would make it even
934 # more superfluous
935 $pathname =~ s,^/+,,;
936 if (!$pathname || substr($pathname, -1) eq "/") {
937 $input_params{'action'} ||= "tree";
938 $pathname =~ s,/$,,;
939 } else {
940 # the default action depends on whether we had parent info
941 # or not
942 if ($parentrefname) {
943 $input_params{'action'} ||= "blobdiff_plain";
944 } else {
945 $input_params{'action'} ||= "blob_plain";
948 $input_params{'hash_base'} ||= $refname;
949 $input_params{'file_name'} ||= $pathname;
950 } elsif (defined $refname) {
951 # we got "branch". In this case we have to choose if we have to
952 # set hash or hash_base.
954 # Most of the actions without a pathname only want hash to be
955 # set, except for the ones specified in @wants_base that want
956 # hash_base instead. It should also be noted that hand-crafted
957 # links having 'history' as an action and no pathname or hash
958 # set will fail, but that happens regardless of PATH_INFO.
959 if (defined $parentrefname) {
960 # if there is parent let the default be 'shortlog' action
961 # (for http://git.example.com/repo.git/A..B links); if there
962 # is no parent, dispatch will detect type of object and set
963 # action appropriately if required (if action is not set)
964 $input_params{'action'} ||= "shortlog";
966 if ($input_params{'action'} &&
967 grep { $_ eq $input_params{'action'} } @wants_base) {
968 $input_params{'hash_base'} ||= $refname;
969 } else {
970 $input_params{'hash'} ||= $refname;
974 # next, handle the 'parent' part, if present
975 if (defined $parentrefname) {
976 # a missing pathspec defaults to the 'current' filename, allowing e.g.
977 # someproject/blobdiff/oldrev..newrev:/filename
978 if ($parentpathname) {
979 $parentpathname =~ s,^/+,,;
980 $parentpathname =~ s,/$,,;
981 $input_params{'file_parent'} ||= $parentpathname;
982 } else {
983 $input_params{'file_parent'} ||= $input_params{'file_name'};
985 # we assume that hash_parent_base is wanted if a path was specified,
986 # or if the action wants hash_base instead of hash
987 if (defined $input_params{'file_parent'} ||
988 grep { $_ eq $input_params{'action'} } @wants_base) {
989 $input_params{'hash_parent_base'} ||= $parentrefname;
990 } else {
991 $input_params{'hash_parent'} ||= $parentrefname;
995 # for the snapshot action, we allow URLs in the form
996 # $project/snapshot/$hash.ext
997 # where .ext determines the snapshot and gets removed from the
998 # passed $refname to provide the $hash.
1000 # To be able to tell that $refname includes the format extension, we
1001 # require the following two conditions to be satisfied:
1002 # - the hash input parameter MUST have been set from the $refname part
1003 # of the URL (i.e. they must be equal)
1004 # - the snapshot format MUST NOT have been defined already (e.g. from
1005 # CGI parameter sf)
1006 # It's also useless to try any matching unless $refname has a dot,
1007 # so we check for that too
1008 if (defined $input_params{'action'} &&
1009 $input_params{'action'} eq 'snapshot' &&
1010 defined $refname && index($refname, '.') != -1 &&
1011 $refname eq $input_params{'hash'} &&
1012 !defined $input_params{'snapshot_format'}) {
1013 # We loop over the known snapshot formats, checking for
1014 # extensions. Allowed extensions are both the defined suffix
1015 # (which includes the initial dot already) and the snapshot
1016 # format key itself, with a prepended dot
1017 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1018 my $hash = $refname;
1019 unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1020 next;
1022 my $sfx = $1;
1023 # a valid suffix was found, so set the snapshot format
1024 # and reset the hash parameter
1025 $input_params{'snapshot_format'} = $fmt;
1026 $input_params{'hash'} = $hash;
1027 # we also set the format suffix to the one requested
1028 # in the URL: this way a request for e.g. .tgz returns
1029 # a .tgz instead of a .tar.gz
1030 $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1031 last;
1036 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1037 $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1038 $searchtext, $search_regexp, $project_filter);
1039 sub evaluate_and_validate_params {
1040 our $action = $input_params{'action'};
1041 if (defined $action) {
1042 if (!is_valid_action($action)) {
1043 die_error(400, "Invalid action parameter");
1047 # parameters which are pathnames
1048 our $project = $input_params{'project'};
1049 if (defined $project) {
1050 if (!is_valid_project($project)) {
1051 undef $project;
1052 die_error(404, "No such project");
1056 our $project_filter = $input_params{'project_filter'};
1057 if (defined $project_filter) {
1058 if (!is_valid_pathname($project_filter)) {
1059 die_error(404, "Invalid project_filter parameter");
1063 our $file_name = $input_params{'file_name'};
1064 if (defined $file_name) {
1065 if (!is_valid_pathname($file_name)) {
1066 die_error(400, "Invalid file parameter");
1070 our $file_parent = $input_params{'file_parent'};
1071 if (defined $file_parent) {
1072 if (!is_valid_pathname($file_parent)) {
1073 die_error(400, "Invalid file parent parameter");
1077 # parameters which are refnames
1078 our $hash = $input_params{'hash'};
1079 if (defined $hash) {
1080 if (!is_valid_refname($hash)) {
1081 die_error(400, "Invalid hash parameter");
1085 our $hash_parent = $input_params{'hash_parent'};
1086 if (defined $hash_parent) {
1087 if (!is_valid_refname($hash_parent)) {
1088 die_error(400, "Invalid hash parent parameter");
1092 our $hash_base = $input_params{'hash_base'};
1093 if (defined $hash_base) {
1094 if (!is_valid_refname($hash_base)) {
1095 die_error(400, "Invalid hash base parameter");
1099 our @extra_options = @{$input_params{'extra_options'}};
1100 # @extra_options is always defined, since it can only be (currently) set from
1101 # CGI, and $cgi->param() returns the empty array in array context if the param
1102 # is not set
1103 foreach my $opt (@extra_options) {
1104 if (not exists $allowed_options{$opt}) {
1105 die_error(400, "Invalid option parameter");
1107 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1108 die_error(400, "Invalid option parameter for this action");
1112 our $hash_parent_base = $input_params{'hash_parent_base'};
1113 if (defined $hash_parent_base) {
1114 if (!is_valid_refname($hash_parent_base)) {
1115 die_error(400, "Invalid hash parent base parameter");
1119 # other parameters
1120 our $page = $input_params{'page'};
1121 if (defined $page) {
1122 if ($page =~ m/[^0-9]/) {
1123 die_error(400, "Invalid page parameter");
1127 our $searchtype = $input_params{'searchtype'};
1128 if (defined $searchtype) {
1129 if ($searchtype =~ m/[^a-z]/) {
1130 die_error(400, "Invalid searchtype parameter");
1134 our $search_use_regexp = $input_params{'search_use_regexp'};
1136 our $searchtext = $input_params{'searchtext'};
1137 our $search_regexp = undef;
1138 if (defined $searchtext) {
1139 if (length($searchtext) < 2) {
1140 die_error(403, "At least two characters are required for search parameter");
1142 if ($search_use_regexp) {
1143 $search_regexp = $searchtext;
1144 if (!eval { qr/$search_regexp/; 1; }) {
1145 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1146 die_error(400, "Invalid search regexp '$search_regexp'",
1147 esc_html($error));
1149 } else {
1150 $search_regexp = quotemeta $searchtext;
1155 # path to the current git repository
1156 our $git_dir;
1157 sub evaluate_git_dir {
1158 our $git_dir = "$projectroot/$project" if $project;
1161 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1162 sub configure_gitweb_features {
1163 # list of supported snapshot formats
1164 our @snapshot_fmts = gitweb_get_feature('snapshot');
1165 @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1167 # check that the avatar feature is set to a known provider name,
1168 # and for each provider check if the dependencies are satisfied.
1169 # if the provider name is invalid or the dependencies are not met,
1170 # reset $git_avatar to the empty string.
1171 our ($git_avatar) = gitweb_get_feature('avatar');
1172 if ($git_avatar eq 'gravatar') {
1173 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1174 } elsif ($git_avatar eq 'picon') {
1175 # no dependencies
1176 } else {
1177 $git_avatar = '';
1180 our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1181 @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1184 sub get_branch_refs {
1185 return ('heads', @extra_branch_refs);
1188 # custom error handler: 'die <message>' is Internal Server Error
1189 sub handle_errors_html {
1190 my $msg = shift; # it is already HTML escaped
1192 # to avoid infinite loop where error occurs in die_error,
1193 # change handler to default handler, disabling handle_errors_html
1194 set_message("Error occurred when inside die_error:\n$msg");
1196 # you cannot jump out of die_error when called as error handler;
1197 # the subroutine set via CGI::Carp::set_message is called _after_
1198 # HTTP headers are already written, so it cannot write them itself
1199 die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1201 set_message(\&handle_errors_html);
1203 # dispatch
1204 sub dispatch {
1205 if (!defined $action) {
1206 if (defined $hash) {
1207 $action = git_get_type($hash);
1208 $action or die_error(404, "Object does not exist");
1209 } elsif (defined $hash_base && defined $file_name) {
1210 $action = git_get_type("$hash_base:$file_name");
1211 $action or die_error(404, "File or directory does not exist");
1212 } elsif (defined $project) {
1213 $action = 'summary';
1214 } else {
1215 $action = 'project_list';
1218 if (!defined($actions{$action})) {
1219 die_error(400, "Unknown action");
1221 if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1222 !$project) {
1223 die_error(400, "Project needed");
1225 $actions{$action}->();
1228 sub reset_timer {
1229 our $t0 = [ gettimeofday() ]
1230 if defined $t0;
1231 our $number_of_git_cmds = 0;
1234 our $first_request = 1;
1235 sub run_request {
1236 reset_timer();
1238 evaluate_uri();
1239 if ($first_request) {
1240 evaluate_gitweb_config();
1241 evaluate_git_version();
1243 if ($per_request_config) {
1244 if (ref($per_request_config) eq 'CODE') {
1245 $per_request_config->();
1246 } elsif (!$first_request) {
1247 evaluate_gitweb_config();
1250 check_loadavg();
1252 # $projectroot and $projects_list might be set in gitweb config file
1253 $projects_list ||= $projectroot;
1255 evaluate_query_params();
1256 evaluate_path_info();
1257 evaluate_and_validate_params();
1258 evaluate_git_dir();
1260 configure_gitweb_features();
1262 dispatch();
1265 our $is_last_request = sub { 1 };
1266 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1267 our $CGI = 'CGI';
1268 our $cgi;
1269 sub configure_as_fcgi {
1270 require CGI::Fast;
1271 our $CGI = 'CGI::Fast';
1273 my $request_number = 0;
1274 # let each child service 100 requests
1275 our $is_last_request = sub { ++$request_number > 100 };
1277 sub evaluate_argv {
1278 my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1279 configure_as_fcgi()
1280 if $script_name =~ /\.fcgi$/;
1282 return unless (@ARGV);
1284 require Getopt::Long;
1285 Getopt::Long::GetOptions(
1286 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1287 'nproc|n=i' => sub {
1288 my ($arg, $val) = @_;
1289 return unless eval { require FCGI::ProcManager; 1; };
1290 my $proc_manager = FCGI::ProcManager->new({
1291 n_processes => $val,
1293 our $pre_listen_hook = sub { $proc_manager->pm_manage() };
1294 our $pre_dispatch_hook = sub { $proc_manager->pm_pre_dispatch() };
1295 our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1300 sub run {
1301 evaluate_argv();
1303 $first_request = 1;
1304 $pre_listen_hook->()
1305 if $pre_listen_hook;
1307 REQUEST:
1308 while ($cgi = $CGI->new()) {
1309 $pre_dispatch_hook->()
1310 if $pre_dispatch_hook;
1312 run_request();
1314 $post_dispatch_hook->()
1315 if $post_dispatch_hook;
1316 $first_request = 0;
1318 last REQUEST if ($is_last_request->());
1321 DONE_GITWEB:
1325 run();
1327 if (defined caller) {
1328 # wrapped in a subroutine processing requests,
1329 # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1330 return;
1331 } else {
1332 # pure CGI script, serving single request
1333 exit;
1336 ## ======================================================================
1337 ## action links
1339 # possible values of extra options
1340 # -full => 0|1 - use absolute/full URL ($my_uri/$my_url as base)
1341 # -replay => 1 - start from a current view (replay with modifications)
1342 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1343 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1344 sub href {
1345 my %params = @_;
1346 # default is to use -absolute url() i.e. $my_uri
1347 my $href = $params{-full} ? $my_url : $my_uri;
1349 # implicit -replay, must be first of implicit params
1350 $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1352 $params{'project'} = $project unless exists $params{'project'};
1354 if ($params{-replay}) {
1355 while (my ($name, $symbol) = each %cgi_param_mapping) {
1356 if (!exists $params{$name}) {
1357 $params{$name} = $input_params{$name};
1362 my $use_pathinfo = gitweb_check_feature('pathinfo');
1363 if (defined $params{'project'} &&
1364 (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1365 # try to put as many parameters as possible in PATH_INFO:
1366 # - project name
1367 # - action
1368 # - hash_parent or hash_parent_base:/file_parent
1369 # - hash or hash_base:/filename
1370 # - the snapshot_format as an appropriate suffix
1372 # When the script is the root DirectoryIndex for the domain,
1373 # $href here would be something like http://gitweb.example.com/
1374 # Thus, we strip any trailing / from $href, to spare us double
1375 # slashes in the final URL
1376 $href =~ s,/$,,;
1378 # Then add the project name, if present
1379 $href .= "/".esc_path_info($params{'project'});
1380 delete $params{'project'};
1382 # since we destructively absorb parameters, we keep this
1383 # boolean that remembers if we're handling a snapshot
1384 my $is_snapshot = $params{'action'} eq 'snapshot';
1386 # Summary just uses the project path URL, any other action is
1387 # added to the URL
1388 if (defined $params{'action'}) {
1389 $href .= "/".esc_path_info($params{'action'})
1390 unless $params{'action'} eq 'summary';
1391 delete $params{'action'};
1394 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1395 # stripping nonexistent or useless pieces
1396 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1397 || $params{'hash_parent'} || $params{'hash'});
1398 if (defined $params{'hash_base'}) {
1399 if (defined $params{'hash_parent_base'}) {
1400 $href .= esc_path_info($params{'hash_parent_base'});
1401 # skip the file_parent if it's the same as the file_name
1402 if (defined $params{'file_parent'}) {
1403 if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1404 delete $params{'file_parent'};
1405 } elsif ($params{'file_parent'} !~ /\.\./) {
1406 $href .= ":/".esc_path_info($params{'file_parent'});
1407 delete $params{'file_parent'};
1410 $href .= "..";
1411 delete $params{'hash_parent'};
1412 delete $params{'hash_parent_base'};
1413 } elsif (defined $params{'hash_parent'}) {
1414 $href .= esc_path_info($params{'hash_parent'}). "..";
1415 delete $params{'hash_parent'};
1418 $href .= esc_path_info($params{'hash_base'});
1419 if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1420 $href .= ":/".esc_path_info($params{'file_name'});
1421 delete $params{'file_name'};
1423 delete $params{'hash'};
1424 delete $params{'hash_base'};
1425 } elsif (defined $params{'hash'}) {
1426 $href .= esc_path_info($params{'hash'});
1427 delete $params{'hash'};
1430 # If the action was a snapshot, we can absorb the
1431 # snapshot_format parameter too
1432 if ($is_snapshot) {
1433 my $fmt = $params{'snapshot_format'};
1434 # snapshot_format should always be defined when href()
1435 # is called, but just in case some code forgets, we
1436 # fall back to the default
1437 $fmt ||= $snapshot_fmts[0];
1438 $href .= $known_snapshot_formats{$fmt}{'suffix'};
1439 delete $params{'snapshot_format'};
1443 # now encode the parameters explicitly
1444 my @result = ();
1445 for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1446 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1447 if (defined $params{$name}) {
1448 if (ref($params{$name}) eq "ARRAY") {
1449 foreach my $par (@{$params{$name}}) {
1450 push @result, $symbol . "=" . esc_param($par);
1452 } else {
1453 push @result, $symbol . "=" . esc_param($params{$name});
1457 $href .= "?" . join(';', @result) if scalar @result;
1459 # final transformation: trailing spaces must be escaped (URI-encoded)
1460 $href =~ s/(\s+)$/CGI::escape($1)/e;
1462 if ($params{-anchor}) {
1463 $href .= "#".esc_param($params{-anchor});
1466 return $href;
1470 ## ======================================================================
1471 ## validation, quoting/unquoting and escaping
1473 sub is_valid_action {
1474 my $input = shift;
1475 return undef unless exists $actions{$input};
1476 return 1;
1479 sub is_valid_project {
1480 my $input = shift;
1482 return unless defined $input;
1483 if (!is_valid_pathname($input) ||
1484 !(-d "$projectroot/$input") ||
1485 !check_export_ok("$projectroot/$input") ||
1486 ($strict_export && !project_in_list($input))) {
1487 return undef;
1488 } else {
1489 return 1;
1493 sub is_valid_pathname {
1494 my $input = shift;
1496 return undef unless defined $input;
1497 # no '.' or '..' as elements of path, i.e. no '.' or '..'
1498 # at the beginning, at the end, and between slashes.
1499 # also this catches doubled slashes
1500 if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1501 return undef;
1503 # no null characters
1504 if ($input =~ m!\0!) {
1505 return undef;
1507 return 1;
1510 sub is_valid_ref_format {
1511 my $input = shift;
1513 return undef unless defined $input;
1514 # restrictions on ref name according to git-check-ref-format
1515 if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1516 return undef;
1518 return 1;
1521 sub is_valid_refname {
1522 my $input = shift;
1524 return undef unless defined $input;
1525 # textual hashes are O.K.
1526 if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1527 return 1;
1529 # it must be correct pathname
1530 is_valid_pathname($input) or return undef;
1531 # check git-check-ref-format restrictions
1532 is_valid_ref_format($input) or return undef;
1533 return 1;
1536 # decode sequences of octets in utf8 into Perl's internal form,
1537 # which is utf-8 with utf8 flag set if needed. gitweb writes out
1538 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1539 sub to_utf8 {
1540 my $str = shift;
1541 return undef unless defined $str;
1543 if (utf8::is_utf8($str) || utf8::decode($str)) {
1544 return $str;
1545 } else {
1546 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1550 # quote unsafe chars, but keep the slash, even when it's not
1551 # correct, but quoted slashes look too horrible in bookmarks
1552 sub esc_param {
1553 my $str = shift;
1554 return undef unless defined $str;
1555 $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1556 $str =~ s/ /\+/g;
1557 return $str;
1560 # the quoting rules for path_info fragment are slightly different
1561 sub esc_path_info {
1562 my $str = shift;
1563 return undef unless defined $str;
1565 # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1566 $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1568 return $str;
1571 # quote unsafe chars in whole URL, so some characters cannot be quoted
1572 sub esc_url {
1573 my $str = shift;
1574 return undef unless defined $str;
1575 $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1576 $str =~ s/ /\+/g;
1577 return $str;
1580 # quote unsafe characters in HTML attributes
1581 sub esc_attr {
1583 # for XHTML conformance escaping '"' to '&quot;' is not enough
1584 return esc_html(@_);
1587 # replace invalid utf8 character with SUBSTITUTION sequence
1588 sub esc_html {
1589 my $str = shift;
1590 my %opts = @_;
1592 return undef unless defined $str;
1594 $str = to_utf8($str);
1595 $str = $cgi->escapeHTML($str);
1596 if ($opts{'-nbsp'}) {
1597 $str =~ s/ /&nbsp;/g;
1599 $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1600 return $str;
1603 # quote control characters and escape filename to HTML
1604 sub esc_path {
1605 my $str = shift;
1606 my %opts = @_;
1608 return undef unless defined $str;
1610 $str = to_utf8($str);
1611 $str = $cgi->escapeHTML($str);
1612 if ($opts{'-nbsp'}) {
1613 $str =~ s/ /&nbsp;/g;
1615 $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1616 return $str;
1619 # Sanitize for use in XHTML + application/xml+xhtml (valid XML 1.0)
1620 sub sanitize {
1621 my $str = shift;
1623 return undef unless defined $str;
1625 $str = to_utf8($str);
1626 $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1627 return $str;
1630 # Make control characters "printable", using character escape codes (CEC)
1631 sub quot_cec {
1632 my $cntrl = shift;
1633 my %opts = @_;
1634 my %es = ( # character escape codes, aka escape sequences
1635 "\t" => '\t', # tab (HT)
1636 "\n" => '\n', # line feed (LF)
1637 "\r" => '\r', # carrige return (CR)
1638 "\f" => '\f', # form feed (FF)
1639 "\b" => '\b', # backspace (BS)
1640 "\a" => '\a', # alarm (bell) (BEL)
1641 "\e" => '\e', # escape (ESC)
1642 "\013" => '\v', # vertical tab (VT)
1643 "\000" => '\0', # nul character (NUL)
1645 my $chr = ( (exists $es{$cntrl})
1646 ? $es{$cntrl}
1647 : sprintf('\%2x', ord($cntrl)) );
1648 if ($opts{-nohtml}) {
1649 return $chr;
1650 } else {
1651 return "<span class=\"cntrl\">$chr</span>";
1655 # Alternatively use unicode control pictures codepoints,
1656 # Unicode "printable representation" (PR)
1657 sub quot_upr {
1658 my $cntrl = shift;
1659 my %opts = @_;
1661 my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1662 if ($opts{-nohtml}) {
1663 return $chr;
1664 } else {
1665 return "<span class=\"cntrl\">$chr</span>";
1669 # git may return quoted and escaped filenames
1670 sub unquote {
1671 my $str = shift;
1673 sub unq {
1674 my $seq = shift;
1675 my %es = ( # character escape codes, aka escape sequences
1676 't' => "\t", # tab (HT, TAB)
1677 'n' => "\n", # newline (NL)
1678 'r' => "\r", # return (CR)
1679 'f' => "\f", # form feed (FF)
1680 'b' => "\b", # backspace (BS)
1681 'a' => "\a", # alarm (bell) (BEL)
1682 'e' => "\e", # escape (ESC)
1683 'v' => "\013", # vertical tab (VT)
1686 if ($seq =~ m/^[0-7]{1,3}$/) {
1687 # octal char sequence
1688 return chr(oct($seq));
1689 } elsif (exists $es{$seq}) {
1690 # C escape sequence, aka character escape code
1691 return $es{$seq};
1693 # quoted ordinary character
1694 return $seq;
1697 if ($str =~ m/^"(.*)"$/) {
1698 # needs unquoting
1699 $str = $1;
1700 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1702 return $str;
1705 # escape tabs (convert tabs to spaces)
1706 sub untabify {
1707 my $line = shift;
1709 while ((my $pos = index($line, "\t")) != -1) {
1710 if (my $count = (8 - ($pos % 8))) {
1711 my $spaces = ' ' x $count;
1712 $line =~ s/\t/$spaces/;
1716 return $line;
1719 sub project_in_list {
1720 my $project = shift;
1721 my @list = git_get_projects_list();
1722 return @list && scalar(grep { $_->{'path'} eq $project } @list);
1725 ## ----------------------------------------------------------------------
1726 ## HTML aware string manipulation
1728 # Try to chop given string on a word boundary between position
1729 # $len and $len+$add_len. If there is no word boundary there,
1730 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1731 # (marking chopped part) would be longer than given string.
1732 sub chop_str {
1733 my $str = shift;
1734 my $len = shift;
1735 my $add_len = shift || 10;
1736 my $where = shift || 'right'; # 'left' | 'center' | 'right'
1738 # Make sure perl knows it is utf8 encoded so we don't
1739 # cut in the middle of a utf8 multibyte char.
1740 $str = to_utf8($str);
1742 # allow only $len chars, but don't cut a word if it would fit in $add_len
1743 # if it doesn't fit, cut it if it's still longer than the dots we would add
1744 # remove chopped character entities entirely
1746 # when chopping in the middle, distribute $len into left and right part
1747 # return early if chopping wouldn't make string shorter
1748 if ($where eq 'center') {
1749 return $str if ($len + 5 >= length($str)); # filler is length 5
1750 $len = int($len/2);
1751 } else {
1752 return $str if ($len + 4 >= length($str)); # filler is length 4
1755 # regexps: ending and beginning with word part up to $add_len
1756 my $endre = qr/.{$len}\w{0,$add_len}/;
1757 my $begre = qr/\w{0,$add_len}.{$len}/;
1759 if ($where eq 'left') {
1760 $str =~ m/^(.*?)($begre)$/;
1761 my ($lead, $body) = ($1, $2);
1762 if (length($lead) > 4) {
1763 $lead = " ...";
1765 return "$lead$body";
1767 } elsif ($where eq 'center') {
1768 $str =~ m/^($endre)(.*)$/;
1769 my ($left, $str) = ($1, $2);
1770 $str =~ m/^(.*?)($begre)$/;
1771 my ($mid, $right) = ($1, $2);
1772 if (length($mid) > 5) {
1773 $mid = " ... ";
1775 return "$left$mid$right";
1777 } else {
1778 $str =~ m/^($endre)(.*)$/;
1779 my $body = $1;
1780 my $tail = $2;
1781 if (length($tail) > 4) {
1782 $tail = "... ";
1784 return "$body$tail";
1788 # takes the same arguments as chop_str, but also wraps a <span> around the
1789 # result with a title attribute if it does get chopped. Additionally, the
1790 # string is HTML-escaped.
1791 sub chop_and_escape_str {
1792 my ($str) = @_;
1794 my $chopped = chop_str(@_);
1795 $str = to_utf8($str);
1796 if ($chopped eq $str) {
1797 return esc_html($chopped);
1798 } else {
1799 $str =~ s/[[:cntrl:]]/?/g;
1800 return $cgi->span({-title=>$str}, esc_html($chopped));
1804 # Highlight selected fragments of string, using given CSS class,
1805 # and escape HTML. It is assumed that fragments do not overlap.
1806 # Regions are passed as list of pairs (array references).
1808 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1809 # '<span class="mark">foo</span>bar'
1810 sub esc_html_hl_regions {
1811 my ($str, $css_class, @sel) = @_;
1812 my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1813 @sel = grep { ref($_) eq 'ARRAY' } @sel;
1814 return esc_html($str, %opts) unless @sel;
1816 my $out = '';
1817 my $pos = 0;
1819 for my $s (@sel) {
1820 my ($begin, $end) = @$s;
1822 # Don't create empty <span> elements.
1823 next if $end <= $begin;
1825 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1826 %opts);
1828 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1829 if ($begin - $pos > 0);
1830 $out .= $cgi->span({-class => $css_class}, $escaped);
1832 $pos = $end;
1834 $out .= esc_html(substr($str, $pos), %opts)
1835 if ($pos < length($str));
1837 return $out;
1840 # return positions of beginning and end of each match
1841 sub matchpos_list {
1842 my ($str, $regexp) = @_;
1843 return unless (defined $str && defined $regexp);
1845 my @matches;
1846 while ($str =~ /$regexp/g) {
1847 push @matches, [$-[0], $+[0]];
1849 return @matches;
1852 # highlight match (if any), and escape HTML
1853 sub esc_html_match_hl {
1854 my ($str, $regexp) = @_;
1855 return esc_html($str) unless defined $regexp;
1857 my @matches = matchpos_list($str, $regexp);
1858 return esc_html($str) unless @matches;
1860 return esc_html_hl_regions($str, 'match', @matches);
1864 # highlight match (if any) of shortened string, and escape HTML
1865 sub esc_html_match_hl_chopped {
1866 my ($str, $chopped, $regexp) = @_;
1867 return esc_html_match_hl($str, $regexp) unless defined $chopped;
1869 my @matches = matchpos_list($str, $regexp);
1870 return esc_html($chopped) unless @matches;
1872 # filter matches so that we mark chopped string
1873 my $tail = "... "; # see chop_str
1874 unless ($chopped =~ s/\Q$tail\E$//) {
1875 $tail = '';
1877 my $chop_len = length($chopped);
1878 my $tail_len = length($tail);
1879 my @filtered;
1881 for my $m (@matches) {
1882 if ($m->[0] > $chop_len) {
1883 push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1884 last;
1885 } elsif ($m->[1] > $chop_len) {
1886 push @filtered, [ $m->[0], $chop_len + $tail_len ];
1887 last;
1889 push @filtered, $m;
1892 return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1895 ## ----------------------------------------------------------------------
1896 ## functions returning short strings
1898 # CSS class for given age value (in seconds)
1899 sub age_class {
1900 my $age = shift;
1902 if (!defined $age) {
1903 return "noage";
1904 } elsif ($age < 60*60*2) {
1905 return "age0";
1906 } elsif ($age < 60*60*24*2) {
1907 return "age1";
1908 } else {
1909 return "age2";
1913 # convert age in seconds to "nn units ago" string
1914 sub age_string {
1915 my $age = shift;
1916 my $age_str;
1918 if ($age > 60*60*24*365*2) {
1919 $age_str = (int $age/60/60/24/365);
1920 $age_str .= " years ago";
1921 } elsif ($age > 60*60*24*(365/12)*2) {
1922 $age_str = int $age/60/60/24/(365/12);
1923 $age_str .= " months ago";
1924 } elsif ($age > 60*60*24*7*2) {
1925 $age_str = int $age/60/60/24/7;
1926 $age_str .= " weeks ago";
1927 } elsif ($age > 60*60*24*2) {
1928 $age_str = int $age/60/60/24;
1929 $age_str .= " days ago";
1930 } elsif ($age > 60*60*2) {
1931 $age_str = int $age/60/60;
1932 $age_str .= " hours ago";
1933 } elsif ($age > 60*2) {
1934 $age_str = int $age/60;
1935 $age_str .= " min ago";
1936 } elsif ($age > 2) {
1937 $age_str = int $age;
1938 $age_str .= " sec ago";
1939 } else {
1940 $age_str .= " right now";
1942 return $age_str;
1945 use constant {
1946 S_IFINVALID => 0030000,
1947 S_IFGITLINK => 0160000,
1950 # submodule/subproject, a commit object reference
1951 sub S_ISGITLINK {
1952 my $mode = shift;
1954 return (($mode & S_IFMT) == S_IFGITLINK)
1957 # convert file mode in octal to symbolic file mode string
1958 sub mode_str {
1959 my $mode = oct shift;
1961 if (S_ISGITLINK($mode)) {
1962 return 'm---------';
1963 } elsif (S_ISDIR($mode & S_IFMT)) {
1964 return 'drwxr-xr-x';
1965 } elsif (S_ISLNK($mode)) {
1966 return 'lrwxrwxrwx';
1967 } elsif (S_ISREG($mode)) {
1968 # git cares only about the executable bit
1969 if ($mode & S_IXUSR) {
1970 return '-rwxr-xr-x';
1971 } else {
1972 return '-rw-r--r--';
1974 } else {
1975 return '----------';
1979 # convert file mode in octal to file type string
1980 sub file_type {
1981 my $mode = shift;
1983 if ($mode !~ m/^[0-7]+$/) {
1984 return $mode;
1985 } else {
1986 $mode = oct $mode;
1989 if (S_ISGITLINK($mode)) {
1990 return "submodule";
1991 } elsif (S_ISDIR($mode & S_IFMT)) {
1992 return "directory";
1993 } elsif (S_ISLNK($mode)) {
1994 return "symlink";
1995 } elsif (S_ISREG($mode)) {
1996 return "file";
1997 } else {
1998 return "unknown";
2002 # convert file mode in octal to file type description string
2003 sub file_type_long {
2004 my $mode = shift;
2006 if ($mode !~ m/^[0-7]+$/) {
2007 return $mode;
2008 } else {
2009 $mode = oct $mode;
2012 if (S_ISGITLINK($mode)) {
2013 return "submodule";
2014 } elsif (S_ISDIR($mode & S_IFMT)) {
2015 return "directory";
2016 } elsif (S_ISLNK($mode)) {
2017 return "symlink";
2018 } elsif (S_ISREG($mode)) {
2019 if ($mode & S_IXUSR) {
2020 return "executable";
2021 } else {
2022 return "file";
2024 } else {
2025 return "unknown";
2030 ## ----------------------------------------------------------------------
2031 ## functions returning short HTML fragments, or transforming HTML fragments
2032 ## which don't belong to other sections
2034 # format line of commit message.
2035 sub format_log_line_html {
2036 my $line = shift;
2038 $line = esc_html($line, -nbsp=>1);
2039 $line =~ s{
2042 # The output of "git describe", e.g. v2.10.0-297-gf6727b0
2043 # or hadoop-20160921-113441-20-g094fb7d
2044 (?<!-) # see strbuf_check_tag_ref(). Tags can't start with -
2045 [A-Za-z0-9.-]+
2046 (?!\.) # refs can't end with ".", see check_refname_format()
2047 -g[0-9a-fA-F]{7,40}
2049 # Just a normal looking Git SHA1
2050 [0-9a-fA-F]{7,40}
2054 $cgi->a({-href => href(action=>"object", hash=>$1),
2055 -class => "text"}, $1);
2056 }egx;
2058 return $line;
2061 # format marker of refs pointing to given object
2063 # the destination action is chosen based on object type and current context:
2064 # - for annotated tags, we choose the tag view unless it's the current view
2065 # already, in which case we go to shortlog view
2066 # - for other refs, we keep the current view if we're in history, shortlog or
2067 # log view, and select shortlog otherwise
2068 sub format_ref_marker {
2069 my ($refs, $id) = @_;
2070 my $markers = '';
2072 if (defined $refs->{$id}) {
2073 foreach my $ref (@{$refs->{$id}}) {
2074 # this code exploits the fact that non-lightweight tags are the
2075 # only indirect objects, and that they are the only objects for which
2076 # we want to use tag instead of shortlog as action
2077 my ($type, $name) = qw();
2078 my $indirect = ($ref =~ s/\^\{\}$//);
2079 # e.g. tags/v2.6.11 or heads/next
2080 if ($ref =~ m!^(.*?)s?/(.*)$!) {
2081 $type = $1;
2082 $name = $2;
2083 } else {
2084 $type = "ref";
2085 $name = $ref;
2088 my $class = $type;
2089 $class .= " indirect" if $indirect;
2091 my $dest_action = "shortlog";
2093 if ($indirect) {
2094 $dest_action = "tag" unless $action eq "tag";
2095 } elsif ($action =~ /^(history|(short)?log)$/) {
2096 $dest_action = $action;
2099 my $dest = "";
2100 $dest .= "refs/" unless $ref =~ m!^refs/!;
2101 $dest .= $ref;
2103 my $link = $cgi->a({
2104 -href => href(
2105 action=>$dest_action,
2106 hash=>$dest
2107 )}, esc_html($name));
2109 $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2110 $link . "</span>";
2114 if ($markers) {
2115 return ' <span class="refs">'. $markers . '</span>';
2116 } else {
2117 return "";
2121 # format, perhaps shortened and with markers, title line
2122 sub format_subject_html {
2123 my ($long, $short, $href, $extra) = @_;
2124 $extra = '' unless defined($extra);
2126 if (length($short) < length($long)) {
2127 $long =~ s/[[:cntrl:]]/?/g;
2128 return $cgi->a({-href => $href, -class => "list subject",
2129 -title => to_utf8($long)},
2130 esc_html($short)) . $extra;
2131 } else {
2132 return $cgi->a({-href => $href, -class => "list subject"},
2133 esc_html($long)) . $extra;
2137 # Rather than recomputing the url for an email multiple times, we cache it
2138 # after the first hit. This gives a visible benefit in views where the avatar
2139 # for the same email is used repeatedly (e.g. shortlog).
2140 # The cache is shared by all avatar engines (currently gravatar only), which
2141 # are free to use it as preferred. Since only one avatar engine is used for any
2142 # given page, there's no risk for cache conflicts.
2143 our %avatar_cache = ();
2145 # Compute the picon url for a given email, by using the picon search service over at
2146 # http://www.cs.indiana.edu/picons/search.html
2147 sub picon_url {
2148 my $email = lc shift;
2149 if (!$avatar_cache{$email}) {
2150 my ($user, $domain) = split('@', $email);
2151 $avatar_cache{$email} =
2152 "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2153 "$domain/$user/" .
2154 "users+domains+unknown/up/single";
2156 return $avatar_cache{$email};
2159 # Compute the gravatar url for a given email, if it's not in the cache already.
2160 # Gravatar stores only the part of the URL before the size, since that's the
2161 # one computationally more expensive. This also allows reuse of the cache for
2162 # different sizes (for this particular engine).
2163 sub gravatar_url {
2164 my $email = lc shift;
2165 my $size = shift;
2166 $avatar_cache{$email} ||=
2167 "//www.gravatar.com/avatar/" .
2168 Digest::MD5::md5_hex($email) . "?s=";
2169 return $avatar_cache{$email} . $size;
2172 # Insert an avatar for the given $email at the given $size if the feature
2173 # is enabled.
2174 sub git_get_avatar {
2175 my ($email, %opts) = @_;
2176 my $pre_white = ($opts{-pad_before} ? "&nbsp;" : "");
2177 my $post_white = ($opts{-pad_after} ? "&nbsp;" : "");
2178 $opts{-size} ||= 'default';
2179 my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2180 my $url = "";
2181 if ($git_avatar eq 'gravatar') {
2182 $url = gravatar_url($email, $size);
2183 } elsif ($git_avatar eq 'picon') {
2184 $url = picon_url($email);
2186 # Other providers can be added by extending the if chain, defining $url
2187 # as needed. If no variant puts something in $url, we assume avatars
2188 # are completely disabled/unavailable.
2189 if ($url) {
2190 return $pre_white .
2191 "<img width=\"$size\" " .
2192 "class=\"avatar\" " .
2193 "src=\"".esc_url($url)."\" " .
2194 "alt=\"\" " .
2195 "/>" . $post_white;
2196 } else {
2197 return "";
2201 sub format_search_author {
2202 my ($author, $searchtype, $displaytext) = @_;
2203 my $have_search = gitweb_check_feature('search');
2205 if ($have_search) {
2206 my $performed = "";
2207 if ($searchtype eq 'author') {
2208 $performed = "authored";
2209 } elsif ($searchtype eq 'committer') {
2210 $performed = "committed";
2213 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2214 searchtext=>$author,
2215 searchtype=>$searchtype), class=>"list",
2216 title=>"Search for commits $performed by $author"},
2217 $displaytext);
2219 } else {
2220 return $displaytext;
2224 # format the author name of the given commit with the given tag
2225 # the author name is chopped and escaped according to the other
2226 # optional parameters (see chop_str).
2227 sub format_author_html {
2228 my $tag = shift;
2229 my $co = shift;
2230 my $author = chop_and_escape_str($co->{'author_name'}, @_);
2231 return "<$tag class=\"author\">" .
2232 format_search_author($co->{'author_name'}, "author",
2233 git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2234 $author) .
2235 "</$tag>";
2238 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2239 sub format_git_diff_header_line {
2240 my $line = shift;
2241 my $diffinfo = shift;
2242 my ($from, $to) = @_;
2244 if ($diffinfo->{'nparents'}) {
2245 # combined diff
2246 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2247 if ($to->{'href'}) {
2248 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2249 esc_path($to->{'file'}));
2250 } else { # file was deleted (no href)
2251 $line .= esc_path($to->{'file'});
2253 } else {
2254 # "ordinary" diff
2255 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2256 if ($from->{'href'}) {
2257 $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2258 'a/' . esc_path($from->{'file'}));
2259 } else { # file was added (no href)
2260 $line .= 'a/' . esc_path($from->{'file'});
2262 $line .= ' ';
2263 if ($to->{'href'}) {
2264 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2265 'b/' . esc_path($to->{'file'}));
2266 } else { # file was deleted
2267 $line .= 'b/' . esc_path($to->{'file'});
2271 return "<div class=\"diff header\">$line</div>\n";
2274 # format extended diff header line, before patch itself
2275 sub format_extended_diff_header_line {
2276 my $line = shift;
2277 my $diffinfo = shift;
2278 my ($from, $to) = @_;
2280 # match <path>
2281 if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2282 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2283 esc_path($from->{'file'}));
2285 if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2286 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2287 esc_path($to->{'file'}));
2289 # match single <mode>
2290 if ($line =~ m/\s(\d{6})$/) {
2291 $line .= '<span class="info"> (' .
2292 file_type_long($1) .
2293 ')</span>';
2295 # match <hash>
2296 if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2297 # can match only for combined diff
2298 $line = 'index ';
2299 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2300 if ($from->{'href'}[$i]) {
2301 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2302 -class=>"hash"},
2303 substr($diffinfo->{'from_id'}[$i],0,7));
2304 } else {
2305 $line .= '0' x 7;
2307 # separator
2308 $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2310 $line .= '..';
2311 if ($to->{'href'}) {
2312 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2313 substr($diffinfo->{'to_id'},0,7));
2314 } else {
2315 $line .= '0' x 7;
2318 } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2319 # can match only for ordinary diff
2320 my ($from_link, $to_link);
2321 if ($from->{'href'}) {
2322 $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2323 substr($diffinfo->{'from_id'},0,7));
2324 } else {
2325 $from_link = '0' x 7;
2327 if ($to->{'href'}) {
2328 $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2329 substr($diffinfo->{'to_id'},0,7));
2330 } else {
2331 $to_link = '0' x 7;
2333 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2334 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2337 return $line . "<br/>\n";
2340 # format from-file/to-file diff header
2341 sub format_diff_from_to_header {
2342 my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2343 my $line;
2344 my $result = '';
2346 $line = $from_line;
2347 #assert($line =~ m/^---/) if DEBUG;
2348 # no extra formatting for "^--- /dev/null"
2349 if (! $diffinfo->{'nparents'}) {
2350 # ordinary (single parent) diff
2351 if ($line =~ m!^--- "?a/!) {
2352 if ($from->{'href'}) {
2353 $line = '--- a/' .
2354 $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2355 esc_path($from->{'file'}));
2356 } else {
2357 $line = '--- a/' .
2358 esc_path($from->{'file'});
2361 $result .= qq!<div class="diff from_file">$line</div>\n!;
2363 } else {
2364 # combined diff (merge commit)
2365 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2366 if ($from->{'href'}[$i]) {
2367 $line = '--- ' .
2368 $cgi->a({-href=>href(action=>"blobdiff",
2369 hash_parent=>$diffinfo->{'from_id'}[$i],
2370 hash_parent_base=>$parents[$i],
2371 file_parent=>$from->{'file'}[$i],
2372 hash=>$diffinfo->{'to_id'},
2373 hash_base=>$hash,
2374 file_name=>$to->{'file'}),
2375 -class=>"path",
2376 -title=>"diff" . ($i+1)},
2377 $i+1) .
2378 '/' .
2379 $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2380 esc_path($from->{'file'}[$i]));
2381 } else {
2382 $line = '--- /dev/null';
2384 $result .= qq!<div class="diff from_file">$line</div>\n!;
2388 $line = $to_line;
2389 #assert($line =~ m/^\+\+\+/) if DEBUG;
2390 # no extra formatting for "^+++ /dev/null"
2391 if ($line =~ m!^\+\+\+ "?b/!) {
2392 if ($to->{'href'}) {
2393 $line = '+++ b/' .
2394 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2395 esc_path($to->{'file'}));
2396 } else {
2397 $line = '+++ b/' .
2398 esc_path($to->{'file'});
2401 $result .= qq!<div class="diff to_file">$line</div>\n!;
2403 return $result;
2406 # create note for patch simplified by combined diff
2407 sub format_diff_cc_simplified {
2408 my ($diffinfo, @parents) = @_;
2409 my $result = '';
2411 $result .= "<div class=\"diff header\">" .
2412 "diff --cc ";
2413 if (!is_deleted($diffinfo)) {
2414 $result .= $cgi->a({-href => href(action=>"blob",
2415 hash_base=>$hash,
2416 hash=>$diffinfo->{'to_id'},
2417 file_name=>$diffinfo->{'to_file'}),
2418 -class => "path"},
2419 esc_path($diffinfo->{'to_file'}));
2420 } else {
2421 $result .= esc_path($diffinfo->{'to_file'});
2423 $result .= "</div>\n" . # class="diff header"
2424 "<div class=\"diff nodifferences\">" .
2425 "Simple merge" .
2426 "</div>\n"; # class="diff nodifferences"
2428 return $result;
2431 sub diff_line_class {
2432 my ($line, $from, $to) = @_;
2434 # ordinary diff
2435 my $num_sign = 1;
2436 # combined diff
2437 if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2438 $num_sign = scalar @{$from->{'href'}};
2441 my @diff_line_classifier = (
2442 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2443 { regexp => qr/^\\/, class => "incomplete" },
2444 { regexp => qr/^ {$num_sign}/, class => "ctx" },
2445 # classifier for context must come before classifier add/rem,
2446 # or we would have to use more complicated regexp, for example
2447 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2448 { regexp => qr/^[+ ]{$num_sign}/, class => "add" },
2449 { regexp => qr/^[- ]{$num_sign}/, class => "rem" },
2451 for my $clsfy (@diff_line_classifier) {
2452 return $clsfy->{'class'}
2453 if ($line =~ $clsfy->{'regexp'});
2456 # fallback
2457 return "";
2460 # assumes that $from and $to are defined and correctly filled,
2461 # and that $line holds a line of chunk header for unified diff
2462 sub format_unidiff_chunk_header {
2463 my ($line, $from, $to) = @_;
2465 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2466 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2468 $from_lines = 0 unless defined $from_lines;
2469 $to_lines = 0 unless defined $to_lines;
2471 if ($from->{'href'}) {
2472 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2473 -class=>"list"}, $from_text);
2475 if ($to->{'href'}) {
2476 $to_text = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2477 -class=>"list"}, $to_text);
2479 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2480 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2481 return $line;
2484 # assumes that $from and $to are defined and correctly filled,
2485 # and that $line holds a line of chunk header for combined diff
2486 sub format_cc_diff_chunk_header {
2487 my ($line, $from, $to) = @_;
2489 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2490 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2492 @from_text = split(' ', $ranges);
2493 for (my $i = 0; $i < @from_text; ++$i) {
2494 ($from_start[$i], $from_nlines[$i]) =
2495 (split(',', substr($from_text[$i], 1)), 0);
2498 $to_text = pop @from_text;
2499 $to_start = pop @from_start;
2500 $to_nlines = pop @from_nlines;
2502 $line = "<span class=\"chunk_info\">$prefix ";
2503 for (my $i = 0; $i < @from_text; ++$i) {
2504 if ($from->{'href'}[$i]) {
2505 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2506 -class=>"list"}, $from_text[$i]);
2507 } else {
2508 $line .= $from_text[$i];
2510 $line .= " ";
2512 if ($to->{'href'}) {
2513 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2514 -class=>"list"}, $to_text);
2515 } else {
2516 $line .= $to_text;
2518 $line .= " $prefix</span>" .
2519 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2520 return $line;
2523 # process patch (diff) line (not to be used for diff headers),
2524 # returning HTML-formatted (but not wrapped) line.
2525 # If the line is passed as a reference, it is treated as HTML and not
2526 # esc_html()'ed.
2527 sub format_diff_line {
2528 my ($line, $diff_class, $from, $to) = @_;
2530 if (ref($line)) {
2531 $line = $$line;
2532 } else {
2533 chomp $line;
2534 $line = untabify($line);
2536 if ($from && $to && $line =~ m/^\@{2} /) {
2537 $line = format_unidiff_chunk_header($line, $from, $to);
2538 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2539 $line = format_cc_diff_chunk_header($line, $from, $to);
2540 } else {
2541 $line = esc_html($line, -nbsp=>1);
2545 my $diff_classes = "diff";
2546 $diff_classes .= " $diff_class" if ($diff_class);
2547 $line = "<div class=\"$diff_classes\">$line</div>\n";
2549 return $line;
2552 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2553 # linked. Pass the hash of the tree/commit to snapshot.
2554 sub format_snapshot_links {
2555 my ($hash) = @_;
2556 my $num_fmts = @snapshot_fmts;
2557 if ($num_fmts > 1) {
2558 # A parenthesized list of links bearing format names.
2559 # e.g. "snapshot (_tar.gz_ _zip_)"
2560 return "snapshot (" . join(' ', map
2561 $cgi->a({
2562 -href => href(
2563 action=>"snapshot",
2564 hash=>$hash,
2565 snapshot_format=>$_
2567 }, $known_snapshot_formats{$_}{'display'})
2568 , @snapshot_fmts) . ")";
2569 } elsif ($num_fmts == 1) {
2570 # A single "snapshot" link whose tooltip bears the format name.
2571 # i.e. "_snapshot_"
2572 my ($fmt) = @snapshot_fmts;
2573 return
2574 $cgi->a({
2575 -href => href(
2576 action=>"snapshot",
2577 hash=>$hash,
2578 snapshot_format=>$fmt
2580 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2581 }, "snapshot");
2582 } else { # $num_fmts == 0
2583 return undef;
2587 ## ......................................................................
2588 ## functions returning values to be passed, perhaps after some
2589 ## transformation, to other functions; e.g. returning arguments to href()
2591 # returns hash to be passed to href to generate gitweb URL
2592 # in -title key it returns description of link
2593 sub get_feed_info {
2594 my $format = shift || 'Atom';
2595 my %res = (action => lc($format));
2596 my $matched_ref = 0;
2598 # feed links are possible only for project views
2599 return unless (defined $project);
2600 # some views should link to OPML, or to generic project feed,
2601 # or don't have specific feed yet (so they should use generic)
2602 return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2604 my $branch = undef;
2605 # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2606 # (fullname) to differentiate from tag links; this also makes
2607 # possible to detect branch links
2608 for my $ref (get_branch_refs()) {
2609 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2610 (defined $hash && $hash =~ m!^refs/\Q$ref\E/(.*)$!)) {
2611 $branch = $1;
2612 $matched_ref = $ref;
2613 last;
2616 # find log type for feed description (title)
2617 my $type = 'log';
2618 if (defined $file_name) {
2619 $type = "history of $file_name";
2620 $type .= "/" if ($action eq 'tree');
2621 $type .= " on '$branch'" if (defined $branch);
2622 } else {
2623 $type = "log of $branch" if (defined $branch);
2626 $res{-title} = $type;
2627 $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2628 $res{'file_name'} = $file_name;
2630 return %res;
2633 ## ----------------------------------------------------------------------
2634 ## git utility subroutines, invoking git commands
2636 # returns path to the core git executable and the --git-dir parameter as list
2637 sub git_cmd {
2638 $number_of_git_cmds++;
2639 return $GIT, '--git-dir='.$git_dir;
2642 # quote the given arguments for passing them to the shell
2643 # quote_command("command", "arg 1", "arg with ' and ! characters")
2644 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2645 # Try to avoid using this function wherever possible.
2646 sub quote_command {
2647 return join(' ',
2648 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2651 # get HEAD ref of given project as hash
2652 sub git_get_head_hash {
2653 return git_get_full_hash(shift, 'HEAD');
2656 sub git_get_full_hash {
2657 return git_get_hash(@_);
2660 sub git_get_short_hash {
2661 return git_get_hash(@_, '--short=7');
2664 sub git_get_hash {
2665 my ($project, $hash, @options) = @_;
2666 my $o_git_dir = $git_dir;
2667 my $retval = undef;
2668 $git_dir = "$projectroot/$project";
2669 if (open my $fd, '-|', git_cmd(), 'rev-parse',
2670 '--verify', '-q', @options, $hash) {
2671 $retval = <$fd>;
2672 chomp $retval if defined $retval;
2673 close $fd;
2675 if (defined $o_git_dir) {
2676 $git_dir = $o_git_dir;
2678 return $retval;
2681 # get type of given object
2682 sub git_get_type {
2683 my $hash = shift;
2685 open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2686 my $type = <$fd>;
2687 close $fd or return;
2688 chomp $type;
2689 return $type;
2692 # repository configuration
2693 our $config_file = '';
2694 our %config;
2696 # store multiple values for single key as anonymous array reference
2697 # single values stored directly in the hash, not as [ <value> ]
2698 sub hash_set_multi {
2699 my ($hash, $key, $value) = @_;
2701 if (!exists $hash->{$key}) {
2702 $hash->{$key} = $value;
2703 } elsif (!ref $hash->{$key}) {
2704 $hash->{$key} = [ $hash->{$key}, $value ];
2705 } else {
2706 push @{$hash->{$key}}, $value;
2710 # return hash of git project configuration
2711 # optionally limited to some section, e.g. 'gitweb'
2712 sub git_parse_project_config {
2713 my $section_regexp = shift;
2714 my %config;
2716 local $/ = "\0";
2718 open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2719 or return;
2721 while (my $keyval = <$fh>) {
2722 chomp $keyval;
2723 my ($key, $value) = split(/\n/, $keyval, 2);
2725 hash_set_multi(\%config, $key, $value)
2726 if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2728 close $fh;
2730 return %config;
2733 # convert config value to boolean: 'true' or 'false'
2734 # no value, number > 0, 'true' and 'yes' values are true
2735 # rest of values are treated as false (never as error)
2736 sub config_to_bool {
2737 my $val = shift;
2739 return 1 if !defined $val; # section.key
2741 # strip leading and trailing whitespace
2742 $val =~ s/^\s+//;
2743 $val =~ s/\s+$//;
2745 return (($val =~ /^\d+$/ && $val) || # section.key = 1
2746 ($val =~ /^(?:true|yes)$/i)); # section.key = true
2749 # convert config value to simple decimal number
2750 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2751 # to be multiplied by 1024, 1048576, or 1073741824
2752 sub config_to_int {
2753 my $val = shift;
2755 # strip leading and trailing whitespace
2756 $val =~ s/^\s+//;
2757 $val =~ s/\s+$//;
2759 if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2760 $unit = lc($unit);
2761 # unknown unit is treated as 1
2762 return $num * ($unit eq 'g' ? 1073741824 :
2763 $unit eq 'm' ? 1048576 :
2764 $unit eq 'k' ? 1024 : 1);
2766 return $val;
2769 # convert config value to array reference, if needed
2770 sub config_to_multi {
2771 my $val = shift;
2773 return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2776 sub git_get_project_config {
2777 my ($key, $type) = @_;
2779 return unless defined $git_dir;
2781 # key sanity check
2782 return unless ($key);
2783 # only subsection, if exists, is case sensitive,
2784 # and not lowercased by 'git config -z -l'
2785 if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2786 $lo =~ s/_//g;
2787 $key = join(".", lc($hi), $mi, lc($lo));
2788 return if ($lo =~ /\W/ || $hi =~ /\W/);
2789 } else {
2790 $key = lc($key);
2791 $key =~ s/_//g;
2792 return if ($key =~ /\W/);
2794 $key =~ s/^gitweb\.//;
2796 # type sanity check
2797 if (defined $type) {
2798 $type =~ s/^--//;
2799 $type = undef
2800 unless ($type eq 'bool' || $type eq 'int');
2803 # get config
2804 if (!defined $config_file ||
2805 $config_file ne "$git_dir/config") {
2806 %config = git_parse_project_config('gitweb');
2807 $config_file = "$git_dir/config";
2810 # check if config variable (key) exists
2811 return unless exists $config{"gitweb.$key"};
2813 # ensure given type
2814 if (!defined $type) {
2815 return $config{"gitweb.$key"};
2816 } elsif ($type eq 'bool') {
2817 # backward compatibility: 'git config --bool' returns true/false
2818 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2819 } elsif ($type eq 'int') {
2820 return config_to_int($config{"gitweb.$key"});
2822 return $config{"gitweb.$key"};
2825 # get hash of given path at given ref
2826 sub git_get_hash_by_path {
2827 my $base = shift;
2828 my $path = shift || return undef;
2829 my $type = shift;
2831 $path =~ s,/+$,,;
2833 open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2834 or die_error(500, "Open git-ls-tree failed");
2835 my $line = <$fd>;
2836 close $fd or return undef;
2838 if (!defined $line) {
2839 # there is no tree or hash given by $path at $base
2840 return undef;
2843 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
2844 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2845 if (defined $type && $type ne $2) {
2846 # type doesn't match
2847 return undef;
2849 return $3;
2852 # get path of entry with given hash at given tree-ish (ref)
2853 # used to get 'from' filename for combined diff (merge commit) for renames
2854 sub git_get_path_by_hash {
2855 my $base = shift || return;
2856 my $hash = shift || return;
2858 local $/ = "\0";
2860 open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2861 or return undef;
2862 while (my $line = <$fd>) {
2863 chomp $line;
2865 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423 gitweb'
2866 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f gitweb/README'
2867 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2868 close $fd;
2869 return $1;
2872 close $fd;
2873 return undef;
2876 ## ......................................................................
2877 ## git utility functions, directly accessing git repository
2879 # get the value of config variable either from file named as the variable
2880 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2881 # configuration variable in the repository config file.
2882 sub git_get_file_or_project_config {
2883 my ($path, $name) = @_;
2885 $git_dir = "$projectroot/$path";
2886 open my $fd, '<', "$git_dir/$name"
2887 or return git_get_project_config($name);
2888 my $conf = <$fd>;
2889 close $fd;
2890 if (defined $conf) {
2891 chomp $conf;
2893 return $conf;
2896 sub git_get_project_description {
2897 my $path = shift;
2898 return git_get_file_or_project_config($path, 'description');
2901 sub git_get_project_category {
2902 my $path = shift;
2903 return git_get_file_or_project_config($path, 'category');
2907 # supported formats:
2908 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2909 # - if its contents is a number, use it as tag weight,
2910 # - otherwise add a tag with weight 1
2911 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2912 # the same value multiple times increases tag weight
2913 # * `gitweb.ctag' multi-valued repo config variable
2914 sub git_get_project_ctags {
2915 my $project = shift;
2916 my $ctags = {};
2918 $git_dir = "$projectroot/$project";
2919 if (opendir my $dh, "$git_dir/ctags") {
2920 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2921 foreach my $tagfile (@files) {
2922 open my $ct, '<', $tagfile
2923 or next;
2924 my $val = <$ct>;
2925 chomp $val if $val;
2926 close $ct;
2928 (my $ctag = $tagfile) =~ s#.*/##;
2929 if ($val =~ /^\d+$/) {
2930 $ctags->{$ctag} = $val;
2931 } else {
2932 $ctags->{$ctag} = 1;
2935 closedir $dh;
2937 } elsif (open my $fh, '<', "$git_dir/ctags") {
2938 while (my $line = <$fh>) {
2939 chomp $line;
2940 $ctags->{$line}++ if $line;
2942 close $fh;
2944 } else {
2945 my $taglist = config_to_multi(git_get_project_config('ctag'));
2946 foreach my $tag (@$taglist) {
2947 $ctags->{$tag}++;
2951 return $ctags;
2954 # return hash, where keys are content tags ('ctags'),
2955 # and values are sum of weights of given tag in every project
2956 sub git_gather_all_ctags {
2957 my $projects = shift;
2958 my $ctags = {};
2960 foreach my $p (@$projects) {
2961 foreach my $ct (keys %{$p->{'ctags'}}) {
2962 $ctags->{$ct} += $p->{'ctags'}->{$ct};
2966 return $ctags;
2969 sub git_populate_project_tagcloud {
2970 my $ctags = shift;
2972 # First, merge different-cased tags; tags vote on casing
2973 my %ctags_lc;
2974 foreach (keys %$ctags) {
2975 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2976 if (not $ctags_lc{lc $_}->{topcount}
2977 or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2978 $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2979 $ctags_lc{lc $_}->{topname} = $_;
2983 my $cloud;
2984 my $matched = $input_params{'ctag'};
2985 if (eval { require HTML::TagCloud; 1; }) {
2986 $cloud = HTML::TagCloud->new;
2987 foreach my $ctag (sort keys %ctags_lc) {
2988 # Pad the title with spaces so that the cloud looks
2989 # less crammed.
2990 my $title = esc_html($ctags_lc{$ctag}->{topname});
2991 $title =~ s/ /&nbsp;/g;
2992 $title =~ s/^/&nbsp;/g;
2993 $title =~ s/$/&nbsp;/g;
2994 if (defined $matched && $matched eq $ctag) {
2995 $title = qq(<span class="match">$title</span>);
2997 $cloud->add($title, href(project=>undef, ctag=>$ctag),
2998 $ctags_lc{$ctag}->{count});
3000 } else {
3001 $cloud = {};
3002 foreach my $ctag (keys %ctags_lc) {
3003 my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3004 if (defined $matched && $matched eq $ctag) {
3005 $title = qq(<span class="match">$title</span>);
3007 $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3008 $cloud->{$ctag}{ctag} =
3009 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3012 return $cloud;
3015 sub git_show_project_tagcloud {
3016 my ($cloud, $count) = @_;
3017 if (ref $cloud eq 'HTML::TagCloud') {
3018 return $cloud->html_and_css($count);
3019 } else {
3020 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3021 return
3022 '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3023 join (', ', map {
3024 $cloud->{$_}->{'ctag'}
3025 } splice(@tags, 0, $count)) .
3026 '</div>';
3030 sub git_get_project_url_list {
3031 my $path = shift;
3033 $git_dir = "$projectroot/$path";
3034 open my $fd, '<', "$git_dir/cloneurl"
3035 or return wantarray ?
3036 @{ config_to_multi(git_get_project_config('url')) } :
3037 config_to_multi(git_get_project_config('url'));
3038 my @git_project_url_list = map { chomp; $_ } <$fd>;
3039 close $fd;
3041 return wantarray ? @git_project_url_list : \@git_project_url_list;
3044 sub git_get_projects_list {
3045 my $filter = shift || '';
3046 my $paranoid = shift;
3047 my @list;
3049 if (-d $projects_list) {
3050 # search in directory
3051 my $dir = $projects_list;
3052 # remove the trailing "/"
3053 $dir =~ s!/+$!!;
3054 my $pfxlen = length("$dir");
3055 my $pfxdepth = ($dir =~ tr!/!!);
3056 # when filtering, search only given subdirectory
3057 if ($filter && !$paranoid) {
3058 $dir .= "/$filter";
3059 $dir =~ s!/+$!!;
3062 File::Find::find({
3063 follow_fast => 1, # follow symbolic links
3064 follow_skip => 2, # ignore duplicates
3065 dangling_symlinks => 0, # ignore dangling symlinks, silently
3066 wanted => sub {
3067 # global variables
3068 our $project_maxdepth;
3069 our $projectroot;
3070 # skip project-list toplevel, if we get it.
3071 return if (m!^[/.]$!);
3072 # only directories can be git repositories
3073 return unless (-d $_);
3074 # don't traverse too deep (Find is super slow on os x)
3075 # $project_maxdepth excludes depth of $projectroot
3076 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3077 $File::Find::prune = 1;
3078 return;
3081 my $path = substr($File::Find::name, $pfxlen + 1);
3082 # paranoidly only filter here
3083 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3084 next;
3086 # we check related file in $projectroot
3087 if (check_export_ok("$projectroot/$path")) {
3088 push @list, { path => $path };
3089 $File::Find::prune = 1;
3092 }, "$dir");
3094 } elsif (-f $projects_list) {
3095 # read from file(url-encoded):
3096 # 'git%2Fgit.git Linus+Torvalds'
3097 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3098 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3099 open my $fd, '<', $projects_list or return;
3100 PROJECT:
3101 while (my $line = <$fd>) {
3102 chomp $line;
3103 my ($path, $owner) = split ' ', $line;
3104 $path = unescape($path);
3105 $owner = unescape($owner);
3106 if (!defined $path) {
3107 next;
3109 # if $filter is rpovided, check if $path begins with $filter
3110 if ($filter && $path !~ m!^\Q$filter\E/!) {
3111 next;
3113 if (check_export_ok("$projectroot/$path")) {
3114 my $pr = {
3115 path => $path
3117 if ($owner) {
3118 $pr->{'owner'} = to_utf8($owner);
3120 push @list, $pr;
3123 close $fd;
3125 return @list;
3128 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3129 # as side effects it sets 'forks' field to list of forks for forked projects
3130 sub filter_forks_from_projects_list {
3131 my $projects = shift;
3133 my %trie; # prefix tree of directories (path components)
3134 # generate trie out of those directories that might contain forks
3135 foreach my $pr (@$projects) {
3136 my $path = $pr->{'path'};
3137 $path =~ s/\.git$//; # forks of 'repo.git' are in 'repo/' directory
3138 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3139 next unless ($path); # skip '.git' repository: tests, git-instaweb
3140 next unless (-d "$projectroot/$path"); # containing directory exists
3141 $pr->{'forks'} = []; # there can be 0 or more forks of project
3143 # add to trie
3144 my @dirs = split('/', $path);
3145 # walk the trie, until either runs out of components or out of trie
3146 my $ref = \%trie;
3147 while (scalar @dirs &&
3148 exists($ref->{$dirs[0]})) {
3149 $ref = $ref->{shift @dirs};
3151 # create rest of trie structure from rest of components
3152 foreach my $dir (@dirs) {
3153 $ref = $ref->{$dir} = {};
3155 # create end marker, store $pr as a data
3156 $ref->{''} = $pr if (!exists $ref->{''});
3159 # filter out forks, by finding shortest prefix match for paths
3160 my @filtered;
3161 PROJECT:
3162 foreach my $pr (@$projects) {
3163 # trie lookup
3164 my $ref = \%trie;
3165 DIR:
3166 foreach my $dir (split('/', $pr->{'path'})) {
3167 if (exists $ref->{''}) {
3168 # found [shortest] prefix, is a fork - skip it
3169 push @{$ref->{''}{'forks'}}, $pr;
3170 next PROJECT;
3172 if (!exists $ref->{$dir}) {
3173 # not in trie, cannot have prefix, not a fork
3174 push @filtered, $pr;
3175 next PROJECT;
3177 # If the dir is there, we just walk one step down the trie.
3178 $ref = $ref->{$dir};
3180 # we ran out of trie
3181 # (shouldn't happen: it's either no match, or end marker)
3182 push @filtered, $pr;
3185 return @filtered;
3188 # note: fill_project_list_info must be run first,
3189 # for 'descr_long' and 'ctags' to be filled
3190 sub search_projects_list {
3191 my ($projlist, %opts) = @_;
3192 my $tagfilter = $opts{'tagfilter'};
3193 my $search_re = $opts{'search_regexp'};
3195 return @$projlist
3196 unless ($tagfilter || $search_re);
3198 # searching projects require filling to be run before it;
3199 fill_project_list_info($projlist,
3200 $tagfilter ? 'ctags' : (),
3201 $search_re ? ('path', 'descr') : ());
3202 my @projects;
3203 PROJECT:
3204 foreach my $pr (@$projlist) {
3206 if ($tagfilter) {
3207 next unless ref($pr->{'ctags'}) eq 'HASH';
3208 next unless
3209 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3212 if ($search_re) {
3213 next unless
3214 $pr->{'path'} =~ /$search_re/ ||
3215 $pr->{'descr_long'} =~ /$search_re/;
3218 push @projects, $pr;
3221 return @projects;
3224 our $gitweb_project_owner = undef;
3225 sub git_get_project_list_from_file {
3227 return if (defined $gitweb_project_owner);
3229 $gitweb_project_owner = {};
3230 # read from file (url-encoded):
3231 # 'git%2Fgit.git Linus+Torvalds'
3232 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3233 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3234 if (-f $projects_list) {
3235 open(my $fd, '<', $projects_list);
3236 while (my $line = <$fd>) {
3237 chomp $line;
3238 my ($pr, $ow) = split ' ', $line;
3239 $pr = unescape($pr);
3240 $ow = unescape($ow);
3241 $gitweb_project_owner->{$pr} = to_utf8($ow);
3243 close $fd;
3247 sub git_get_project_owner {
3248 my $project = shift;
3249 my $owner;
3251 return undef unless $project;
3252 $git_dir = "$projectroot/$project";
3254 if (!defined $gitweb_project_owner) {
3255 git_get_project_list_from_file();
3258 if (exists $gitweb_project_owner->{$project}) {
3259 $owner = $gitweb_project_owner->{$project};
3261 if (!defined $owner){
3262 $owner = git_get_project_config('owner');
3264 if (!defined $owner) {
3265 $owner = get_file_owner("$git_dir");
3268 return $owner;
3271 sub git_get_last_activity {
3272 my ($path) = @_;
3273 my $fd;
3275 $git_dir = "$projectroot/$path";
3276 open($fd, "-|", git_cmd(), 'for-each-ref',
3277 '--format=%(committer)',
3278 '--sort=-committerdate',
3279 '--count=1',
3280 map { "refs/$_" } get_branch_refs ()) or return;
3281 my $most_recent = <$fd>;
3282 close $fd or return;
3283 if (defined $most_recent &&
3284 $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3285 my $timestamp = $1;
3286 my $age = time - $timestamp;
3287 return ($age, age_string($age));
3289 return (undef, undef);
3292 # Implementation note: when a single remote is wanted, we cannot use 'git
3293 # remote show -n' because that command always work (assuming it's a remote URL
3294 # if it's not defined), and we cannot use 'git remote show' because that would
3295 # try to make a network roundtrip. So the only way to find if that particular
3296 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3297 # and when we find what we want.
3298 sub git_get_remotes_list {
3299 my $wanted = shift;
3300 my %remotes = ();
3302 open my $fd, '-|' , git_cmd(), 'remote', '-v';
3303 return unless $fd;
3304 while (my $remote = <$fd>) {
3305 chomp $remote;
3306 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3307 next if $wanted and not $remote eq $wanted;
3308 my ($url, $key) = ($1, $2);
3310 $remotes{$remote} ||= { 'heads' => () };
3311 $remotes{$remote}{$key} = $url;
3313 close $fd or return;
3314 return wantarray ? %remotes : \%remotes;
3317 # Takes a hash of remotes as first parameter and fills it by adding the
3318 # available remote heads for each of the indicated remotes.
3319 sub fill_remote_heads {
3320 my $remotes = shift;
3321 my @heads = map { "remotes/$_" } keys %$remotes;
3322 my @remoteheads = git_get_heads_list(undef, @heads);
3323 foreach my $remote (keys %$remotes) {
3324 $remotes->{$remote}{'heads'} = [ grep {
3325 $_->{'name'} =~ s!^$remote/!!
3326 } @remoteheads ];
3330 sub git_get_references {
3331 my $type = shift || "";
3332 my %refs;
3333 # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3334 # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3335 open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3336 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3337 or return;
3339 while (my $line = <$fd>) {
3340 chomp $line;
3341 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3342 if (defined $refs{$1}) {
3343 push @{$refs{$1}}, $2;
3344 } else {
3345 $refs{$1} = [ $2 ];
3349 close $fd or return;
3350 return \%refs;
3353 sub git_get_rev_name_tags {
3354 my $hash = shift || return undef;
3356 open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3357 or return;
3358 my $name_rev = <$fd>;
3359 close $fd;
3361 if ($name_rev =~ m|^$hash tags/(.*)$|) {
3362 return $1;
3363 } else {
3364 # catches also '$hash undefined' output
3365 return undef;
3369 ## ----------------------------------------------------------------------
3370 ## parse to hash functions
3372 sub parse_date {
3373 my $epoch = shift;
3374 my $tz = shift || "-0000";
3376 my %date;
3377 my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3378 my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3379 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3380 $date{'hour'} = $hour;
3381 $date{'minute'} = $min;
3382 $date{'mday'} = $mday;
3383 $date{'day'} = $days[$wday];
3384 $date{'month'} = $months[$mon];
3385 $date{'rfc2822'} = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3386 $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3387 $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3388 $mday, $months[$mon], $hour ,$min;
3389 $date{'iso-8601'} = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3390 1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3392 my ($tz_sign, $tz_hour, $tz_min) =
3393 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3394 $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3395 my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3396 ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3397 $date{'hour_local'} = $hour;
3398 $date{'minute_local'} = $min;
3399 $date{'tz_local'} = $tz;
3400 $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3401 1900+$year, $mon+1, $mday,
3402 $hour, $min, $sec, $tz);
3403 return %date;
3406 sub parse_tag {
3407 my $tag_id = shift;
3408 my %tag;
3409 my @comment;
3411 open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3412 $tag{'id'} = $tag_id;
3413 while (my $line = <$fd>) {
3414 chomp $line;
3415 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3416 $tag{'object'} = $1;
3417 } elsif ($line =~ m/^type (.+)$/) {
3418 $tag{'type'} = $1;
3419 } elsif ($line =~ m/^tag (.+)$/) {
3420 $tag{'name'} = $1;
3421 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3422 $tag{'author'} = $1;
3423 $tag{'author_epoch'} = $2;
3424 $tag{'author_tz'} = $3;
3425 if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3426 $tag{'author_name'} = $1;
3427 $tag{'author_email'} = $2;
3428 } else {
3429 $tag{'author_name'} = $tag{'author'};
3431 } elsif ($line =~ m/--BEGIN/) {
3432 push @comment, $line;
3433 last;
3434 } elsif ($line eq "") {
3435 last;
3438 push @comment, <$fd>;
3439 $tag{'comment'} = \@comment;
3440 close $fd or return;
3441 if (!defined $tag{'name'}) {
3442 return
3444 return %tag
3447 sub parse_commit_text {
3448 my ($commit_text, $withparents) = @_;
3449 my @commit_lines = split '\n', $commit_text;
3450 my %co;
3452 pop @commit_lines; # Remove '\0'
3454 if (! @commit_lines) {
3455 return;
3458 my $header = shift @commit_lines;
3459 if ($header !~ m/^[0-9a-fA-F]{40}/) {
3460 return;
3462 ($co{'id'}, my @parents) = split ' ', $header;
3463 while (my $line = shift @commit_lines) {
3464 last if $line eq "\n";
3465 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3466 $co{'tree'} = $1;
3467 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3468 push @parents, $1;
3469 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3470 $co{'author'} = to_utf8($1);
3471 $co{'author_epoch'} = $2;
3472 $co{'author_tz'} = $3;
3473 if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3474 $co{'author_name'} = $1;
3475 $co{'author_email'} = $2;
3476 } else {
3477 $co{'author_name'} = $co{'author'};
3479 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3480 $co{'committer'} = to_utf8($1);
3481 $co{'committer_epoch'} = $2;
3482 $co{'committer_tz'} = $3;
3483 if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3484 $co{'committer_name'} = $1;
3485 $co{'committer_email'} = $2;
3486 } else {
3487 $co{'committer_name'} = $co{'committer'};
3491 if (!defined $co{'tree'}) {
3492 return;
3494 $co{'parents'} = \@parents;
3495 $co{'parent'} = $parents[0];
3497 foreach my $title (@commit_lines) {
3498 $title =~ s/^ //;
3499 if ($title ne "") {
3500 $co{'title'} = chop_str($title, 80, 5);
3501 # remove leading stuff of merges to make the interesting part visible
3502 if (length($title) > 50) {
3503 $title =~ s/^Automatic //;
3504 $title =~ s/^merge (of|with) /Merge ... /i;
3505 if (length($title) > 50) {
3506 $title =~ s/(http|rsync):\/\///;
3508 if (length($title) > 50) {
3509 $title =~ s/(master|www|rsync)\.//;
3511 if (length($title) > 50) {
3512 $title =~ s/kernel.org:?//;
3514 if (length($title) > 50) {
3515 $title =~ s/\/pub\/scm//;
3518 $co{'title_short'} = chop_str($title, 50, 5);
3519 last;
3522 if (! defined $co{'title'} || $co{'title'} eq "") {
3523 $co{'title'} = $co{'title_short'} = '(no commit message)';
3525 # remove added spaces
3526 foreach my $line (@commit_lines) {
3527 $line =~ s/^ //;
3529 $co{'comment'} = \@commit_lines;
3531 my $age = time - $co{'committer_epoch'};
3532 $co{'age'} = $age;
3533 $co{'age_string'} = age_string($age);
3534 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3535 if ($age > 60*60*24*7*2) {
3536 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3537 $co{'age_string_age'} = $co{'age_string'};
3538 } else {
3539 $co{'age_string_date'} = $co{'age_string'};
3540 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3542 return %co;
3545 sub parse_commit {
3546 my ($commit_id) = @_;
3547 my %co;
3549 local $/ = "\0";
3551 open my $fd, "-|", git_cmd(), "rev-list",
3552 "--parents",
3553 "--header",
3554 "--max-count=1",
3555 $commit_id,
3556 "--",
3557 or die_error(500, "Open git-rev-list failed");
3558 %co = parse_commit_text(<$fd>, 1);
3559 close $fd;
3561 return %co;
3564 sub parse_commits {
3565 my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3566 my @cos;
3568 $maxcount ||= 1;
3569 $skip ||= 0;
3571 local $/ = "\0";
3573 open my $fd, "-|", git_cmd(), "rev-list",
3574 "--header",
3575 @args,
3576 ("--max-count=" . $maxcount),
3577 ("--skip=" . $skip),
3578 @extra_options,
3579 $commit_id,
3580 "--",
3581 ($filename ? ($filename) : ())
3582 or die_error(500, "Open git-rev-list failed");
3583 while (my $line = <$fd>) {
3584 my %co = parse_commit_text($line);
3585 push @cos, \%co;
3587 close $fd;
3589 return wantarray ? @cos : \@cos;
3592 # parse line of git-diff-tree "raw" output
3593 sub parse_difftree_raw_line {
3594 my $line = shift;
3595 my %res;
3597 # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M ls-files.c'
3598 # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M rev-tree.c'
3599 if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3600 $res{'from_mode'} = $1;
3601 $res{'to_mode'} = $2;
3602 $res{'from_id'} = $3;
3603 $res{'to_id'} = $4;
3604 $res{'status'} = $5;
3605 $res{'similarity'} = $6;
3606 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3607 ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3608 } else {
3609 $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3612 # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3613 # combined diff (for merge commit)
3614 elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3615 $res{'nparents'} = length($1);
3616 $res{'from_mode'} = [ split(' ', $2) ];
3617 $res{'to_mode'} = pop @{$res{'from_mode'}};
3618 $res{'from_id'} = [ split(' ', $3) ];
3619 $res{'to_id'} = pop @{$res{'from_id'}};
3620 $res{'status'} = [ split('', $4) ];
3621 $res{'to_file'} = unquote($5);
3623 # 'c512b523472485aef4fff9e57b229d9d243c967f'
3624 elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3625 $res{'commit'} = $1;
3628 return wantarray ? %res : \%res;
3631 # wrapper: return parsed line of git-diff-tree "raw" output
3632 # (the argument might be raw line, or parsed info)
3633 sub parsed_difftree_line {
3634 my $line_or_ref = shift;
3636 if (ref($line_or_ref) eq "HASH") {
3637 # pre-parsed (or generated by hand)
3638 return $line_or_ref;
3639 } else {
3640 return parse_difftree_raw_line($line_or_ref);
3644 # parse line of git-ls-tree output
3645 sub parse_ls_tree_line {
3646 my $line = shift;
3647 my %opts = @_;
3648 my %res;
3650 if ($opts{'-l'}) {
3651 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa 16717 panic.c'
3652 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3654 $res{'mode'} = $1;
3655 $res{'type'} = $2;
3656 $res{'hash'} = $3;
3657 $res{'size'} = $4;
3658 if ($opts{'-z'}) {
3659 $res{'name'} = $5;
3660 } else {
3661 $res{'name'} = unquote($5);
3663 } else {
3664 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
3665 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3667 $res{'mode'} = $1;
3668 $res{'type'} = $2;
3669 $res{'hash'} = $3;
3670 if ($opts{'-z'}) {
3671 $res{'name'} = $4;
3672 } else {
3673 $res{'name'} = unquote($4);
3677 return wantarray ? %res : \%res;
3680 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3681 sub parse_from_to_diffinfo {
3682 my ($diffinfo, $from, $to, @parents) = @_;
3684 if ($diffinfo->{'nparents'}) {
3685 # combined diff
3686 $from->{'file'} = [];
3687 $from->{'href'} = [];
3688 fill_from_file_info($diffinfo, @parents)
3689 unless exists $diffinfo->{'from_file'};
3690 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3691 $from->{'file'}[$i] =
3692 defined $diffinfo->{'from_file'}[$i] ?
3693 $diffinfo->{'from_file'}[$i] :
3694 $diffinfo->{'to_file'};
3695 if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3696 $from->{'href'}[$i] = href(action=>"blob",
3697 hash_base=>$parents[$i],
3698 hash=>$diffinfo->{'from_id'}[$i],
3699 file_name=>$from->{'file'}[$i]);
3700 } else {
3701 $from->{'href'}[$i] = undef;
3704 } else {
3705 # ordinary (not combined) diff
3706 $from->{'file'} = $diffinfo->{'from_file'};
3707 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3708 $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3709 hash=>$diffinfo->{'from_id'},
3710 file_name=>$from->{'file'});
3711 } else {
3712 delete $from->{'href'};
3716 $to->{'file'} = $diffinfo->{'to_file'};
3717 if (!is_deleted($diffinfo)) { # file exists in result
3718 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3719 hash=>$diffinfo->{'to_id'},
3720 file_name=>$to->{'file'});
3721 } else {
3722 delete $to->{'href'};
3726 ## ......................................................................
3727 ## parse to array of hashes functions
3729 sub git_get_heads_list {
3730 my ($limit, @classes) = @_;
3731 @classes = get_branch_refs() unless @classes;
3732 my @patterns = map { "refs/$_" } @classes;
3733 my @headslist;
3735 open my $fd, '-|', git_cmd(), 'for-each-ref',
3736 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3737 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3738 @patterns
3739 or return;
3740 while (my $line = <$fd>) {
3741 my %ref_item;
3743 chomp $line;
3744 my ($refinfo, $committerinfo) = split(/\0/, $line);
3745 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3746 my ($committer, $epoch, $tz) =
3747 ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3748 $ref_item{'fullname'} = $name;
3749 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3750 $name =~ s!^refs/($strip_refs|remotes)/!!;
3751 $ref_item{'name'} = $name;
3752 # for refs neither in 'heads' nor 'remotes' we want to
3753 # show their ref dir
3754 my $ref_dir = (defined $1) ? $1 : '';
3755 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3756 $ref_item{'name'} .= ' (' . $ref_dir . ')';
3759 $ref_item{'id'} = $hash;
3760 $ref_item{'title'} = $title || '(no commit message)';
3761 $ref_item{'epoch'} = $epoch;
3762 if ($epoch) {
3763 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3764 } else {
3765 $ref_item{'age'} = "unknown";
3768 push @headslist, \%ref_item;
3770 close $fd;
3772 return wantarray ? @headslist : \@headslist;
3775 sub git_get_tags_list {
3776 my $limit = shift;
3777 my @tagslist;
3779 open my $fd, '-|', git_cmd(), 'for-each-ref',
3780 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3781 '--format=%(objectname) %(objecttype) %(refname) '.
3782 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3783 'refs/tags'
3784 or return;
3785 while (my $line = <$fd>) {
3786 my %ref_item;
3788 chomp $line;
3789 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3790 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3791 my ($creator, $epoch, $tz) =
3792 ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3793 $ref_item{'fullname'} = $name;
3794 $name =~ s!^refs/tags/!!;
3796 $ref_item{'type'} = $type;
3797 $ref_item{'id'} = $id;
3798 $ref_item{'name'} = $name;
3799 if ($type eq "tag") {
3800 $ref_item{'subject'} = $title;
3801 $ref_item{'reftype'} = $reftype;
3802 $ref_item{'refid'} = $refid;
3803 } else {
3804 $ref_item{'reftype'} = $type;
3805 $ref_item{'refid'} = $id;
3808 if ($type eq "tag" || $type eq "commit") {
3809 $ref_item{'epoch'} = $epoch;
3810 if ($epoch) {
3811 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3812 } else {
3813 $ref_item{'age'} = "unknown";
3817 push @tagslist, \%ref_item;
3819 close $fd;
3821 return wantarray ? @tagslist : \@tagslist;
3824 ## ----------------------------------------------------------------------
3825 ## filesystem-related functions
3827 sub get_file_owner {
3828 my $path = shift;
3830 my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3831 my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3832 if (!defined $gcos) {
3833 return undef;
3835 my $owner = $gcos;
3836 $owner =~ s/[,;].*$//;
3837 return to_utf8($owner);
3840 # assume that file exists
3841 sub insert_file {
3842 my $filename = shift;
3844 open my $fd, '<', $filename;
3845 print map { to_utf8($_) } <$fd>;
3846 close $fd;
3849 ## ......................................................................
3850 ## mimetype related functions
3852 sub mimetype_guess_file {
3853 my $filename = shift;
3854 my $mimemap = shift;
3855 -r $mimemap or return undef;
3857 my %mimemap;
3858 open(my $mh, '<', $mimemap) or return undef;
3859 while (<$mh>) {
3860 next if m/^#/; # skip comments
3861 my ($mimetype, @exts) = split(/\s+/);
3862 foreach my $ext (@exts) {
3863 $mimemap{$ext} = $mimetype;
3866 close($mh);
3868 $filename =~ /\.([^.]*)$/;
3869 return $mimemap{$1};
3872 sub mimetype_guess {
3873 my $filename = shift;
3874 my $mime;
3875 $filename =~ /\./ or return undef;
3877 if ($mimetypes_file) {
3878 my $file = $mimetypes_file;
3879 if ($file !~ m!^/!) { # if it is relative path
3880 # it is relative to project
3881 $file = "$projectroot/$project/$file";
3883 $mime = mimetype_guess_file($filename, $file);
3885 $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3886 return $mime;
3889 sub blob_mimetype {
3890 my $fd = shift;
3891 my $filename = shift;
3893 if ($filename) {
3894 my $mime = mimetype_guess($filename);
3895 $mime and return $mime;
3898 # just in case
3899 return $default_blob_plain_mimetype unless $fd;
3901 if (-T $fd) {
3902 return 'text/plain';
3903 } elsif (! $filename) {
3904 return 'application/octet-stream';
3905 } elsif ($filename =~ m/\.png$/i) {
3906 return 'image/png';
3907 } elsif ($filename =~ m/\.gif$/i) {
3908 return 'image/gif';
3909 } elsif ($filename =~ m/\.jpe?g$/i) {
3910 return 'image/jpeg';
3911 } else {
3912 return 'application/octet-stream';
3916 sub blob_contenttype {
3917 my ($fd, $file_name, $type) = @_;
3919 $type ||= blob_mimetype($fd, $file_name);
3920 if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3921 $type .= "; charset=$default_text_plain_charset";
3924 return $type;
3927 # guess file syntax for syntax highlighting; return undef if no highlighting
3928 # the name of syntax can (in the future) depend on syntax highlighter used
3929 sub guess_file_syntax {
3930 my ($highlight, $file_name) = @_;
3931 return undef unless ($highlight && defined $file_name);
3932 my $basename = basename($file_name, '.in');
3933 return $highlight_basename{$basename}
3934 if exists $highlight_basename{$basename};
3936 $basename =~ /\.([^.]*)$/;
3937 my $ext = $1 or return undef;
3938 return $highlight_ext{$ext}
3939 if exists $highlight_ext{$ext};
3941 return undef;
3944 # run highlighter and return FD of its output,
3945 # or return original FD if no highlighting
3946 sub run_highlighter {
3947 my ($fd, $highlight, $syntax) = @_;
3948 return $fd unless ($highlight);
3950 close $fd;
3951 my $syntax_arg = (defined $syntax) ? "--syntax $syntax" : "--force";
3952 open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3953 quote_command($^X, '-CO', '-MEncode=decode,FB_DEFAULT', '-pse',
3954 '$_ = decode($fe, $_, FB_DEFAULT) if !utf8::decode($_);',
3955 '--', "-fe=$fallback_encoding")." | ".
3956 quote_command($highlight_bin).
3957 " --replace-tabs=8 --fragment $syntax_arg |"
3958 or die_error(500, "Couldn't open file or run syntax highlighter");
3959 return $fd;
3962 ## ======================================================================
3963 ## functions printing HTML: header, footer, error page
3965 sub get_page_title {
3966 my $title = to_utf8($site_name);
3968 unless (defined $project) {
3969 if (defined $project_filter) {
3970 $title .= " - projects in '" . esc_path($project_filter) . "'";
3972 return $title;
3974 $title .= " - " . to_utf8($project);
3976 return $title unless (defined $action);
3977 $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3979 return $title unless (defined $file_name);
3980 $title .= " - " . esc_path($file_name);
3981 if ($action eq "tree" && $file_name !~ m|/$|) {
3982 $title .= "/";
3985 return $title;
3988 sub get_content_type_html {
3989 # require explicit support from the UA if we are to send the page as
3990 # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3991 # we have to do this because MSIE sometimes globs '*/*', pretending to
3992 # support xhtml+xml but choking when it gets what it asked for.
3993 if (defined $cgi->http('HTTP_ACCEPT') &&
3994 $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3995 $cgi->Accept('application/xhtml+xml') != 0) {
3996 return 'application/xhtml+xml';
3997 } else {
3998 return 'text/html';
4002 sub print_feed_meta {
4003 if (defined $project) {
4004 my %href_params = get_feed_info();
4005 if (!exists $href_params{'-title'}) {
4006 $href_params{'-title'} = 'log';
4009 foreach my $format (qw(RSS Atom)) {
4010 my $type = lc($format);
4011 my %link_attr = (
4012 '-rel' => 'alternate',
4013 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4014 '-type' => "application/$type+xml"
4017 $href_params{'extra_options'} = undef;
4018 $href_params{'action'} = $type;
4019 $link_attr{'-href'} = href(%href_params);
4020 print "<link ".
4021 "rel=\"$link_attr{'-rel'}\" ".
4022 "title=\"$link_attr{'-title'}\" ".
4023 "href=\"$link_attr{'-href'}\" ".
4024 "type=\"$link_attr{'-type'}\" ".
4025 "/>\n";
4027 $href_params{'extra_options'} = '--no-merges';
4028 $link_attr{'-href'} = href(%href_params);
4029 $link_attr{'-title'} .= ' (no merges)';
4030 print "<link ".
4031 "rel=\"$link_attr{'-rel'}\" ".
4032 "title=\"$link_attr{'-title'}\" ".
4033 "href=\"$link_attr{'-href'}\" ".
4034 "type=\"$link_attr{'-type'}\" ".
4035 "/>\n";
4038 } else {
4039 printf('<link rel="alternate" title="%s projects list" '.
4040 'href="%s" type="text/plain; charset=utf-8" />'."\n",
4041 esc_attr($site_name), href(project=>undef, action=>"project_index"));
4042 printf('<link rel="alternate" title="%s projects feeds" '.
4043 'href="%s" type="text/x-opml" />'."\n",
4044 esc_attr($site_name), href(project=>undef, action=>"opml"));
4048 sub print_header_links {
4049 my $status = shift;
4051 # print out each stylesheet that exist, providing backwards capability
4052 # for those people who defined $stylesheet in a config file
4053 if (defined $stylesheet) {
4054 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4055 } else {
4056 foreach my $stylesheet (@stylesheets) {
4057 next unless $stylesheet;
4058 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4061 print_feed_meta()
4062 if ($status eq '200 OK');
4063 if (defined $favicon) {
4064 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4068 sub print_nav_breadcrumbs_path {
4069 my $dirprefix = undef;
4070 while (my $part = shift) {
4071 $dirprefix .= "/" if defined $dirprefix;
4072 $dirprefix .= $part;
4073 print $cgi->a({-href => href(project => undef,
4074 project_filter => $dirprefix,
4075 action => "project_list")},
4076 esc_html($part)) . " / ";
4080 sub print_nav_breadcrumbs {
4081 my %opts = @_;
4083 for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4084 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4086 if (defined $project) {
4087 my @dirname = split '/', $project;
4088 my $projectbasename = pop @dirname;
4089 print_nav_breadcrumbs_path(@dirname);
4090 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4091 if (defined $action) {
4092 my $action_print = $action ;
4093 if (defined $opts{-action_extra}) {
4094 $action_print = $cgi->a({-href => href(action=>$action)},
4095 $action);
4097 print " / $action_print";
4099 if (defined $opts{-action_extra}) {
4100 print " / $opts{-action_extra}";
4102 print "\n";
4103 } elsif (defined $project_filter) {
4104 print_nav_breadcrumbs_path(split '/', $project_filter);
4108 sub print_search_form {
4109 if (!defined $searchtext) {
4110 $searchtext = "";
4112 my $search_hash;
4113 if (defined $hash_base) {
4114 $search_hash = $hash_base;
4115 } elsif (defined $hash) {
4116 $search_hash = $hash;
4117 } else {
4118 $search_hash = "HEAD";
4120 my $action = $my_uri;
4121 my $use_pathinfo = gitweb_check_feature('pathinfo');
4122 if ($use_pathinfo) {
4123 $action .= "/".esc_url($project);
4125 print $cgi->start_form(-method => "get", -action => $action) .
4126 "<div class=\"search\">\n" .
4127 (!$use_pathinfo &&
4128 $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4129 $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4130 $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4131 $cgi->popup_menu(-name => 'st', -default => 'commit',
4132 -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4133 " " . $cgi->a({-href => href(action=>"search_help"),
4134 -title => "search help" }, "?") . " search:\n",
4135 $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4136 "<span title=\"Extended regular expression\">" .
4137 $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4138 -checked => $search_use_regexp) .
4139 "</span>" .
4140 "</div>" .
4141 $cgi->end_form() . "\n";
4144 sub git_header_html {
4145 my $status = shift || "200 OK";
4146 my $expires = shift;
4147 my %opts = @_;
4149 my $title = get_page_title();
4150 my $content_type = get_content_type_html();
4151 print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4152 -status=> $status, -expires => $expires)
4153 unless ($opts{'-no_http_header'});
4154 my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4155 print <<EOF;
4156 <?xml version="1.0" encoding="utf-8"?>
4157 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4158 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4159 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4160 <!-- git core binaries version $git_version -->
4161 <head>
4162 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4163 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4164 <meta name="robots" content="index, nofollow"/>
4165 <title>$title</title>
4167 # the stylesheet, favicon etc urls won't work correctly with path_info
4168 # unless we set the appropriate base URL
4169 if ($ENV{'PATH_INFO'}) {
4170 print "<base href=\"".esc_url($base_url)."\" />\n";
4172 print_header_links($status);
4174 if (defined $site_html_head_string) {
4175 print to_utf8($site_html_head_string);
4178 print "</head>\n" .
4179 "<body>\n";
4181 if (defined $site_header && -f $site_header) {
4182 insert_file($site_header);
4185 print "<div class=\"page_header\">\n";
4186 if (defined $logo) {
4187 print $cgi->a({-href => esc_url($logo_url),
4188 -title => $logo_label},
4189 $cgi->img({-src => esc_url($logo),
4190 -width => 72, -height => 27,
4191 -alt => "git",
4192 -class => "logo"}));
4194 print_nav_breadcrumbs(%opts);
4195 print "</div>\n";
4197 my $have_search = gitweb_check_feature('search');
4198 if (defined $project && $have_search) {
4199 print_search_form();
4203 sub git_footer_html {
4204 my $feed_class = 'rss_logo';
4206 print "<div class=\"page_footer\">\n";
4207 if (defined $project) {
4208 my $descr = git_get_project_description($project);
4209 if (defined $descr) {
4210 print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4213 my %href_params = get_feed_info();
4214 if (!%href_params) {
4215 $feed_class .= ' generic';
4217 $href_params{'-title'} ||= 'log';
4219 foreach my $format (qw(RSS Atom)) {
4220 $href_params{'action'} = lc($format);
4221 print $cgi->a({-href => href(%href_params),
4222 -title => "$href_params{'-title'} $format feed",
4223 -class => $feed_class}, $format)."\n";
4226 } else {
4227 print $cgi->a({-href => href(project=>undef, action=>"opml",
4228 project_filter => $project_filter),
4229 -class => $feed_class}, "OPML") . " ";
4230 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4231 project_filter => $project_filter),
4232 -class => $feed_class}, "TXT") . "\n";
4234 print "</div>\n"; # class="page_footer"
4236 if (defined $t0 && gitweb_check_feature('timed')) {
4237 print "<div id=\"generating_info\">\n";
4238 print 'This page took '.
4239 '<span id="generating_time" class="time_span">'.
4240 tv_interval($t0, [ gettimeofday() ]).