configure.ac

   1 m4_define([adg_version],[0.7.2])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[3:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[2:0:0])
   8
   9 m4_define([gtkdoc_prereq],[1.12])dnl Support introspection annotations
  10 m4_define([gobject_prereq],[2.10.1])
  11 m4_define([cairo_prereq],[1.7.4])
  12 m4_define([gtk2_prereq],[2.12.0])
  13 m4_define([gtk3_prereq],[3.0.0])
  14 m4_define([pangocairo_prereq],[1.18.0])
  15 m4_define([gi_prereq],[0.9.5])dnl Picked up from clutter
  16
  17
  18 # Initialization
  19
  20 dnl autoconf 2.62 is required by GObject introspection:
  21 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  22 AC_PREREQ([2.62])
  23 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_HEADERS([src/config.h])
  26 AC_CONFIG_AUX_DIR([build])
  27 AC_CONFIG_MACRO_DIR([build])
  28 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  29
  30 dnl m4 backward compatibility stuff
  31 m4_ifdef([AM_SILENT_RULES],
  32          [AM_SILENT_RULES([yes])],
  33          [AC_SUBST([AM_V_GEN],[])])
  34 m4_ifdef([AM_SUBST_NOTMAKE],[],
  35          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  36 m4_ifdef([AM_COND_IF],[],
  37          [AC_DEFUN([AM_COND_IF],
  38                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  39
  40
  41 # Check for host information
  42
  43 AC_CANONICAL_HOST
  44 case "${host}" in
  45   *-*-linux*)
  46     guessed_host=linux
  47     ;;
  48   *-*-freebsd*)
  49     guessed_host=freebsd
  50     ;;
  51   *-*-mingw*)
  52     guessed_host=mingw
  53     ;;
  54   *-*-solaris*)
  55     guessed_host=solaris
  56     ;;
  57   *-*-darwin*)
  58     guessed_host=darwin
  59     ;;
  60   *-*-beos*)
  61     guessed_host=beos
  62     ;;
  63   *-*-cygwin*)
  64     guessed_host=cygwin
  65     ;;
  66   *-*-minix*)
  67     guessed_host=minix
  68     ;;
  69   *-*-aix*)
  70     guessed_host=aix
  71     ;;
  72   *)
  73     guessed_host=unknown
  74     ;;
  75 esac
  76 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  77 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  78
  79
  80 # Check for programs
  81
  82 AC_PROG_CC
  83 AC_PROG_SED
  84 PKG_PROG_PKG_CONFIG
  85 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  86 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  87 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  88 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  89 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  90 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  91 AM_COND_IF([OS_WINDOWS],
  92            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
  93             AC_PATH_PROG([WINE],[wine])])
  94
  95
  96 # Check for libraries
  97
  98 AC_CHECK_LIB([m],[cos])
  99
 100
 101 # Libtool initialization
 102
 103 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 104 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 105 m4_ifset([LT_INIT],
 106          [LT_INIT([disable-static win32-dll])],
 107          [AC_DISABLE_STATIC
 108           AC_LIBTOOL_WIN32_DLL
 109           AC_PROG_LIBTOOL])
 110
 111
 112 # I18n
 113
 114 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
 115 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 116 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 117                    [Define to the domain used by gettext.])
 118 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 119 IT_PROG_INTLTOOL([0.35.0])
 120 AM_GLIB_GNU_GETTEXT
 121 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 122 AC_CONFIG_COMMANDS([default],
 123                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 124         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 125     esac],
 126                    [SED="${SED}"])
 127
 128
 129 # Check for required packages
 130
 131 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 132 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 133 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 134
 135
 136 # Check for optional packages
 137
 138 dnl PangoCairo
 139 AC_ARG_ENABLE([pango],
 140               [AS_HELP_STRING([--enable-pango],
 141                               [use pango for rendering text @<:@default=check@:>@])],
 142               [],[enable_pango=check])
 143 AS_IF([test "x${enable_pango}" != "xno"],
 144       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 145                          [enable_pango=yes
 146                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 147                                              [Defined if the pango support is enabled.])],
 148                          [AS_IF([test "x${enable_pango}" = "xyes"],
 149                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 150                                 [enable_pango=no])])])
 151 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 152
 153 dnl GTK+ support
 154 AC_ARG_WITH(gtk,
 155             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 156                             [include GTK+ specific widgets @<:@default=check@:>@])],
 157             [],[with_gtk=check])
 158 AS_CASE(["${with_gtk}"],
 159         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 160         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 161         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 162         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 163         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 164
 165 # GTK+ autodetection, giving precedence to GTK+3
 166 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 167       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,[gtk_pkg=gtk3],[:])])
 168 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 169       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,[gtk_pkg=gtk2],[:])])
 170 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 171
 172
 173 # Handle "check" graceful degradation
 174 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 175
 176 # Handle failures
 177 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 178       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 179
 180 AS_IF([test "x${with_gtk}" = "xgtk3"],
 181       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 182                           [Defined if the GTK+3 support is enabled.])])
 183 AS_IF([test "x${with_gtk}" = "xgtk2"],
 184       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 185                           [Defined if the GTK+2 support is enabled.])])
 186
 187 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 188 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 189 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 190
 191 dnl Glade catalog dir
 192 AC_ARG_WITH(glade_catalogdir,
 193             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 194                             [where to install the glade catalogs @<:@default=check@:>@])],
 195             [],[with_glade_catalogdir=check])
 196
 197 # Both "check" and "yes" mean gladeui autodetection,
 198 # but "yes" will fail on gladeui not found
 199 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 200       [glade_pkg=check])
 201
 202 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 203 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 204       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 205 AS_IF([test "x${glade_pkg}" = "xcheck"],
 206       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 207 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 208       [NTD_UNEXPAND([${glade_pkg}],
 209                     [catalogdir],
 210                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 211                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 212
 213 # Handle "yes" failure
 214 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 215       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 216
 217 # Handle "check" graceful degradation
 218 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 219       [with_glade_catalogdir=no])
 220
 221 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 222 AM_COND_IF([HAVE_GLADE],
 223            [enable_glade=yes
 224             report_glade="
 225                   Glade catalog dir: ${with_glade_catalogdir}"],
 226            [enable_glade=no
 227             report_glade=""])
 228 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 229
 230 dnl gtk-doc
 231 GTK_DOC_CHECK(gtkdoc_prereq)
 232
 233 dnl GObject introspection
 234 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 235 AC_ARG_WITH(girdir,
 236             [AS_HELP_STRING([--with-girdir=DIR],
 237                             [where the gir files are installed @<:@default=check@:>@])],
 238             [],[with_girdir=check])
 239 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_girdir}" = "xcheck"],
 240       [NTD_UNEXPAND([gobject-introspection-1.0],
 241                     [girdir],
 242                     [with_girdir="${NTD_UNEXPANDED}"])])
 243 AC_SUBST([GIRDIR],${with_girdir})
 244 AC_ARG_WITH(typelibdir,
 245             [AS_HELP_STRING([--with-typelibdir=DIR],
 246                             [where the typelib files are installed @<:@default=check@:>@])],
 247             [],[with_typelibdir=check])
 248 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_typelibdir}" = "xcheck"],
 249       [NTD_UNEXPAND([gobject-introspection-1.0],
 250                     [typelibdir],
 251                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 252 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 253 AM_COND_IF([HAVE_INTROSPECTION],
 254            [report_introspection="
 255          Where to install gir files: ${with_girdir}
 256  Where to install the typelib files: ${with_typelibdir}"],
 257            [report_introspection=""])
 258
 259 dnl If introspection is used GObject support in cairo must be enabled,
 260 dnl that is the cairo-gobject library must be present. That support
 261 dnl was introduced since cairo 1.10.0.
 262 PKG_CHECK_MODULES([CAIRO_GOBJECT],[cairo-gobject],
 263                   [AC_DEFINE_UNQUOTED([CAIRO_GOBJECT_ENABLED],[1],
 264                                       [Defined if GObject support in cairo is present.])],
 265                   [AS_IF([test "x${enable_introspection}" = "xyes"],
 266                          [AC_MSG_ERROR([GObject introspection requires the cairo-gobject library])])])
 267
 268 dnl GLib test framework
 269 AC_ARG_ENABLE([test_framework],
 270               [AS_HELP_STRING([--enable-test-framework],
 271                               [enable GLib test framework @<:@default=check@:>@])],
 272               [],[enable_test_framework=check])
 273 AS_IF([test "x${enable_test_framework}" != "xno"],
 274       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 275                         [enable_test_framework=yes],
 276                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 277                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 278                                [enable_test_framework=no])])])
 279 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 280
 281
 282 # Check for compiler characteristics
 283
 284 AC_C_CONST
 285
 286
 287 # Windows substitutions for NSis installer
 288
 289 dnl By default DLLDIR is set to "$prefix/bin", with "$prefix" got from
 290 dnl gobject-2.0.pc: all the DLLs *must* be under the same directory.
 291 AC_ARG_VAR([DLLDIR], Place where Windows DLLs must be picked from)
 292 AS_IF([test -z "$DLLDIR"],
 293       [DLLDIR="$($PKG_CONFIG --variable=prefix gobject-2.0)/bin"])
 294 AM_SUBST_NOTMAKE([DLLDIR])
 295
 296 dnl -win$ARCH will be appended to the installer file name
 297 AS_IF([test "x${host_cpu}" = "xx86_64"],[ARCH=64],[ARCH=32])
 298 AC_SUBST([ARCH])
 299 AM_SUBST_NOTMAKE([ARCH])
 300
 301
 302 # Additional substitutions
 303
 304 dnl The GObject dependency can be made optional by skipping
 305 dnl the building of the GObject wrappers.
 306 CPML_REQUIRES='cairo >= cairo_prereq gobject-2.0 >= gobject_prereq'
 307 AM_COND_IF([HAVE_PANGO],
 308       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 309        ADG_H_ADDITIONAL='
 310 #include <pango/pango.h>
 311 #include "adg/adg-text.h"
 312 #include "adg/adg-pango-style.h"
 313 '],
 314       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 315        ADG_H_ADDITIONAL=''])
 316 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 317 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 318 AM_COND_IF([HAVE_GTK],
 319            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 320 #include <gtk/gtk.h>
 321 #include \"adg/adg-gtk-utils.h\"
 322 #include \"adg/adg-gtk-area.h\"
 323 #include \"adg/adg-gtk-layout.h\"
 324 "
 325             ADG_CANVAS_H_ADDITIONAL='
 326 #include <gtk/gtk.h>
 327
 328 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 329                                                  const gchar    *paper_name,
 330                                                  GtkPageOrientation orientation);
 331 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 332                                                  GtkPageSetup   *page_setup);
 333 GtkPageSetup *  adg_canvas_get_page_setup       (AdgCanvas      *canvas);
 334 '],
 335            [ADG_CANVAS_H_ADDITIONAL=''])
 336
 337 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 338 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 339 AC_SUBST([CPML_REQUIRES])
 340 AC_SUBST([ADG_API_VERSION],adg_api_version)
 341 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 342 AC_SUBST([ADG_REQUIRES])
 343 AC_SUBST([ADG_H_ADDITIONAL])
 344 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 345
 346 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 347 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 348 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 349 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 350
 351 dnl CPML compiler flags and library dependencies
 352 CPML_CFLAGS="$CAIRO_CFLAGS $GOBJECT_CFLAGS"
 353 CPML_LIBS="$CAIRO_LIBS $GOBJECT_LIBS"
 354 AC_SUBST([CPML_CFLAGS])
 355 AC_SUBST([CPML_LIBS])
 356
 357 dnl ADG compiler flags and library dependencies
 358 ADG_CFLAGS="$CAIRO_GOBJECT_CFLAGS"
 359 ADG_LIBS="$CAIRO_GOBJECT_LIBS"
 360 AM_COND_IF([HAVE_PANGO],
 361            [ADG_CFLAGS="$PANGO_CFLAGS $ADG_CFLAGS"
 362             ADG_LIBS="$PANGO_LIBS $ADG_LIBS"])
 363 AM_COND_IF([HAVE_GTK2],
 364            [ADG_CFLAGS="$GTK2_CFLAGS $ADG_CFLAGS"
 365             ADG_LIBS="$GTK2_LIBS $ADG_LIBS"])
 366 AM_COND_IF([HAVE_GTK3],
 367            [ADG_CFLAGS="$GTK3_CFLAGS $ADG_CFLAGS"
 368             ADG_LIBS="$GTK3_LIBS $ADG_LIBS"])
 369 AC_SUBST([ADG_CFLAGS])
 370 AC_SUBST([ADG_LIBS])
 371
 372
 373 # Generation
 374
 375 AC_CONFIG_FILES([build/adg.nsi
 376                  Makefile
 377                  src/Makefile
 378                  src/cpml/cpml-1.pc
 379                  src/cpml/Makefile
 380                  src/cpml/tests/Makefile
 381                  src/adg/adg-1.pc
 382                  src/adg.h
 383                  src/adg/Makefile
 384                  src/adg/adg-canvas.h
 385                  src/adg/tests/Makefile
 386                  demo/Makefile
 387                  demo/cpml-demo.ui
 388                  demo/adg-demo.ui
 389                  po/Makefile.in
 390                  po-properties/Makefile.in
 391                  docs/Makefile
 392                  docs/cpml/Makefile
 393                  docs/cpml/bookinfo.xml
 394                  docs/adg/Makefile
 395                  docs/adg/bookinfo.xml])
 396 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 397 AC_OUTPUT
 398
 399
 400 # Report
 401
 402 AC_MSG_NOTICE([generating report
 403
 404 AC_PACKAGE_NAME adg_version will be built with the following options:
 405 ----------------------------------------------------------
 406                   API compatibility: adg_api_version
 407                 CPML library to use: internal (cpml-adg_version)
 408          Build pango based entities: ${enable_pango}
 409                        GTK+ support: ${with_gtk}
 410              Install glade catalogs: ${enable_glade}${report_glade}
 411                 Build API reference: ${enable_gtk_doc}
 412              GObject instrospection: ${enable_introspection}${report_introspection}
 413              Test framework support: ${enable_test_framework}
 414 ])