configure.ac

   1 m4_define([adg_version],[0.7.2])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[3:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[2:0:0])
   8
   9 m4_define([gtkdoc_prereq],[1.12])dnl Support introspection annotations
  10 m4_define([gobject_prereq],[2.10.1])
  11 m4_define([cairo_prereq],[1.7.4])
  12 m4_define([cairo_gobject_prereq],cairo_prereq)
  13 m4_define([gtk2_prereq],[2.12.0])
  14 m4_define([gtk3_prereq],[3.0.0])
  15 m4_define([pangocairo_prereq],[1.18.0])
  16 m4_define([gi_prereq],[0.9.5])dnl Picked up from clutter
  17
  18
  19 # Initialization
  20
  21 dnl autoconf 2.62 is required by GObject introspection:
  22 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  23 AC_PREREQ([2.62])
  24 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  25 AC_CONFIG_SRCDIR([configure.ac])
  26 AC_CONFIG_HEADERS([src/config.h])
  27 AC_CONFIG_AUX_DIR([build])
  28 AC_CONFIG_MACRO_DIR([build])
  29 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  30
  31 dnl m4 backward compatibility stuff
  32 m4_ifdef([AM_SILENT_RULES],
  33          [AM_SILENT_RULES([yes])],
  34          [AC_SUBST([AM_V_GEN],[])])
  35 m4_ifdef([AM_SUBST_NOTMAKE],[],
  36          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  37 m4_ifdef([AM_COND_IF],[],
  38          [AC_DEFUN([AM_COND_IF],
  39                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  40
  41
  42 # Check for host information
  43
  44 AC_CANONICAL_HOST
  45 case "${host}" in
  46   *-*-linux*)
  47     guessed_host=linux
  48     ;;
  49   *-*-freebsd*)
  50     guessed_host=freebsd
  51     ;;
  52   *-*-mingw*)
  53     guessed_host=mingw
  54     ;;
  55   *-*-solaris*)
  56     guessed_host=solaris
  57     ;;
  58   *-*-darwin*)
  59     guessed_host=darwin
  60     ;;
  61   *-*-beos*)
  62     guessed_host=beos
  63     ;;
  64   *-*-cygwin*)
  65     guessed_host=cygwin
  66     ;;
  67   *-*-minix*)
  68     guessed_host=minix
  69     ;;
  70   *-*-aix*)
  71     guessed_host=aix
  72     ;;
  73   *)
  74     guessed_host=unknown
  75     ;;
  76 esac
  77 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  78 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  79
  80
  81 # Check for programs
  82
  83 AC_PROG_CC
  84 AC_PROG_SED
  85 PKG_PROG_PKG_CONFIG
  86 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  87 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  88 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  89 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  90 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  91 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  92 AM_COND_IF([OS_WINDOWS],
  93            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
  94             AC_PATH_PROG([WINE],[wine])])
  95
  96
  97 # Check for libraries
  98
  99 AC_CHECK_LIB([m],[cos])
 100
 101
 102 # Libtool initialization
 103
 104 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 105 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 106 m4_ifset([LT_INIT],
 107          [LT_INIT([disable-static win32-dll])],
 108          [AC_DISABLE_STATIC
 109           AC_LIBTOOL_WIN32_DLL
 110           AC_PROG_LIBTOOL])
 111
 112
 113 # I18n
 114
 115 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
 116 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 117 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 118                    [Define to the domain used by gettext.])
 119 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 120 IT_PROG_INTLTOOL([0.35.0])
 121 AM_GLIB_GNU_GETTEXT
 122 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 123 AC_CONFIG_COMMANDS([default],
 124                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 125         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 126     esac],
 127                    [SED="${SED}"])
 128
 129
 130 # Check for required packages
 131
 132 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 133 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 134 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 135 PKG_CHECK_MODULES([CAIRO_GOBJECT],[cairo-gobject],
 136                   [AC_DEFINE_UNQUOTED([CAIRO_GOBJECT_ENABLED],[1],
 137                                       [Defined if GObject support in cairo is present.])],
 138                   [:])
 139
 140
 141 # Check for optional packages
 142
 143 dnl PangoCairo
 144 AC_ARG_ENABLE([pango],
 145               [AS_HELP_STRING([--enable-pango],
 146                               [use pango for rendering text @<:@default=check@:>@])],
 147               [],[enable_pango=check])
 148 AS_IF([test "x${enable_pango}" != "xno"],
 149       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 150                          [enable_pango=yes
 151                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 152                                              [Defined if the pango support is enabled.])],
 153                          [AS_IF([test "x${enable_pango}" = "xyes"],
 154                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 155                                 [enable_pango=no])])])
 156 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 157
 158 dnl GTK+ support
 159 AC_ARG_WITH(gtk,
 160             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 161                             [include GTK+ specific widgets @<:@default=check@:>@])],
 162             [],[with_gtk=check])
 163 AS_CASE(["${with_gtk}"],
 164         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 165         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 166         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 167         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 168         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 169
 170 # GTK+ autodetection, giving precedence to GTK+3
 171 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 172       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,[gtk_pkg=gtk3],[:])])
 173 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 174       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,[gtk_pkg=gtk2],[:])])
 175 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 176
 177
 178 # Handle "check" graceful degradation
 179 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 180
 181 # Handle failures
 182 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 183       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 184
 185 AS_IF([test "x${with_gtk}" = "xgtk3"],
 186       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 187                           [Defined if the GTK+3 support is enabled.])])
 188 AS_IF([test "x${with_gtk}" = "xgtk2"],
 189       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 190                           [Defined if the GTK+2 support is enabled.])])
 191
 192 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 193 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 194 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 195
 196 dnl Glade catalog dir
 197 AC_ARG_WITH(glade_catalogdir,
 198             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 199                             [where to install the glade catalogs @<:@default=check@:>@])],
 200             [],[with_glade_catalogdir=check])
 201
 202 # Both "check" and "yes" mean gladeui autodetection,
 203 # but "yes" will fail on gladeui not found
 204 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 205       [glade_pkg=check])
 206
 207 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 208 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 209       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 210 AS_IF([test "x${glade_pkg}" = "xcheck"],
 211       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 212 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 213       [NTD_UNEXPAND([${glade_pkg}],
 214                     [catalogdir],
 215                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 216                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 217
 218 # Handle "yes" failure
 219 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 220       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 221
 222 # Handle "check" graceful degradation
 223 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 224       [with_glade_catalogdir=no])
 225
 226 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 227 AM_COND_IF([HAVE_GLADE],
 228            [enable_glade=yes
 229             report_glade="
 230                   Glade catalog dir: ${with_glade_catalogdir}"],
 231            [enable_glade=no
 232             report_glade=""])
 233 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 234
 235 dnl gtk-doc
 236 GTK_DOC_CHECK(gtkdoc_prereq)
 237
 238 dnl GObject introspection
 239 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 240 AC_ARG_WITH(girdir,
 241             [AS_HELP_STRING([--with-girdir=DIR],
 242                             [where the gir files are installed @<:@default=check@:>@])],
 243             [],[with_girdir=check])
 244 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_girdir}" = "xcheck"],
 245       [NTD_UNEXPAND([gobject-introspection-1.0],
 246                     [girdir],
 247                     [with_girdir="${NTD_UNEXPANDED}"])])
 248 AC_SUBST([GIRDIR],${with_girdir})
 249 AC_ARG_WITH(typelibdir,
 250             [AS_HELP_STRING([--with-typelibdir=DIR],
 251                             [where the typelib files are installed @<:@default=check@:>@])],
 252             [],[with_typelibdir=check])
 253 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_typelibdir}" = "xcheck"],
 254       [NTD_UNEXPAND([gobject-introspection-1.0],
 255                     [typelibdir],
 256                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 257 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 258 AM_COND_IF([HAVE_INTROSPECTION],
 259            [report_introspection="
 260          Where to install gir files: ${with_girdir}
 261  Where to install the typelib files: ${with_typelibdir}"],
 262            [report_introspection=""])
 263
 264 dnl GLib test framework
 265 AC_ARG_ENABLE([test_framework],
 266               [AS_HELP_STRING([--enable-test-framework],
 267                               [enable GLib test framework @<:@default=check@:>@])],
 268               [],[enable_test_framework=check])
 269 AS_IF([test "x${enable_test_framework}" != "xno"],
 270       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 271                         [enable_test_framework=yes],
 272                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 273                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 274                                [enable_test_framework=no])])])
 275 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 276
 277
 278 # Check for compiler characteristics
 279
 280 AC_C_CONST
 281
 282
 283 # Windows substitutions for NSis installer
 284
 285 dnl By default DLLDIR is set to "$prefix/bin", with "$prefix" got from
 286 dnl gobject-2.0.pc: all the DLLs *must* be under the same directory.
 287 AC_ARG_VAR([DLLDIR], Place where Windows DLLs must be picked from)
 288 AS_IF([test -z "$DLLDIR"],
 289       [DLLDIR="$($PKG_CONFIG --variable=prefix gobject-2.0)/bin"])
 290 AM_SUBST_NOTMAKE([DLLDIR])
 291
 292 dnl -win$ARCH will be appended to the installer file name
 293 AS_IF([test "x${host_cpu}" = "xx86_64"],[ARCH=64],[ARCH=32])
 294 AC_SUBST([ARCH])
 295 AM_SUBST_NOTMAKE([ARCH])
 296
 297
 298 # Additional substitutions
 299
 300 dnl The GObject dependency can be made optional by skipping
 301 dnl the building of the GObject wrappers.
 302 CPML_REQUIRES='cairo >= cairo_prereq gobject-2.0 >= gobject_prereq'
 303 AM_COND_IF([HAVE_PANGO],
 304       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 305        ADG_H_ADDITIONAL='
 306 #include <pango/pango.h>
 307 #include "adg/adg-text.h"
 308 #include "adg/adg-pango-style.h"
 309 '],
 310       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 311        ADG_H_ADDITIONAL=''])
 312 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 313 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 314 AM_COND_IF([HAVE_GTK],
 315            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 316 #include <gtk/gtk.h>
 317 #include \"adg/adg-gtk-utils.h\"
 318 #include \"adg/adg-gtk-area.h\"
 319 #include \"adg/adg-gtk-layout.h\"
 320 "
 321             ADG_CANVAS_H_ADDITIONAL='
 322 #include <gtk/gtk.h>
 323
 324 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 325                                                  const gchar    *paper_name,
 326                                                  GtkPageOrientation orientation);
 327 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 328                                                  GtkPageSetup   *page_setup);
 329 GtkPageSetup *  adg_canvas_get_page_setup       (AdgCanvas      *canvas);
 330 '],
 331            [ADG_CANVAS_H_ADDITIONAL=''])
 332
 333 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 334 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 335 AC_SUBST([CPML_REQUIRES])
 336 AC_SUBST([ADG_API_VERSION],adg_api_version)
 337 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 338 AC_SUBST([ADG_REQUIRES])
 339 AC_SUBST([ADG_H_ADDITIONAL])
 340 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 341
 342 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 343 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 344 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 345 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 346
 347 dnl CPML compiler flags and library dependencies
 348 CPML_CFLAGS="$CAIRO_CFLAGS $GOBJECT_CFLAGS"
 349 CPML_LIBS="$CAIRO_LIBS $GOBJECT_LIBS"
 350 AC_SUBST([CPML_CFLAGS])
 351 AC_SUBST([CPML_LIBS])
 352
 353 dnl ADG compiler flags and library dependencies
 354 ADG_CFLAGS="$CAIRO_GOBJECT_CFLAGS"
 355 ADG_LIBS="$CAIRO_GOBJECT_LIBS"
 356 AM_COND_IF([HAVE_PANGO],
 357            [ADG_CFLAGS="$PANGO_CFLAGS $ADG_CFLAGS"
 358             ADG_LIBS="$PANGO_LIBS $ADG_LIBS"])
 359 AM_COND_IF([HAVE_GTK2],
 360            [ADG_CFLAGS="$GTK2_CFLAGS $ADG_CFLAGS"
 361             ADG_LIBS="$GTK2_LIBS $ADG_LIBS"])
 362 AM_COND_IF([HAVE_GTK3],
 363            [ADG_CFLAGS="$GTK3_CFLAGS $ADG_CFLAGS"
 364             ADG_LIBS="$GTK3_LIBS $ADG_LIBS"])
 365 AC_SUBST([ADG_CFLAGS])
 366 AC_SUBST([ADG_LIBS])
 367
 368
 369 # Generation
 370
 371 AC_CONFIG_FILES([build/adg.nsi
 372                  Makefile
 373                  src/Makefile
 374                  src/cpml/cpml-1.pc
 375                  src/cpml/Makefile
 376                  src/cpml/tests/Makefile
 377                  src/adg/adg-1.pc
 378                  src/adg.h
 379                  src/adg/Makefile
 380                  src/adg/adg-canvas.h
 381                  src/adg/tests/Makefile
 382                  demo/Makefile
 383                  demo/cpml-demo.ui
 384                  demo/adg-demo.ui
 385                  po/Makefile.in
 386                  po-properties/Makefile.in
 387                  docs/Makefile
 388                  docs/cpml/Makefile
 389                  docs/cpml/bookinfo.xml
 390                  docs/adg/Makefile
 391                  docs/adg/bookinfo.xml])
 392 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 393 AC_OUTPUT
 394
 395
 396 # Report
 397
 398 AC_MSG_NOTICE([generating report
 399
 400 AC_PACKAGE_NAME adg_version will be built with the following options:
 401 ----------------------------------------------------------
 402                   API compatibility: adg_api_version
 403                 CPML library to use: internal (cpml-adg_version)
 404          Build pango based entities: ${enable_pango}
 405                        GTK+ support: ${with_gtk}
 406              Install glade catalogs: ${enable_glade}${report_glade}
 407                 Build API reference: ${enable_gtk_doc}
 408              GObject instrospection: ${enable_introspection}${report_introspection}
 409              Test framework support: ${enable_test_framework}
 410 ])