configure.ac

   1 m4_define([adg_version],[0.7.2])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[3:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[2:0:0])
   8
   9 m4_define([gtkdoc_prereq],[1.12])dnl Support introspection annotations
  10 m4_define([gobject_prereq],[2.10.1])
  11 m4_define([cairo_prereq],[1.7.4])
  12 m4_define([gtk2_prereq],[2.12.0])
  13 m4_define([gtk3_prereq],[3.0.0])
  14 m4_define([pangocairo_prereq],[1.18.0])
  15 m4_define([gi_prereq],[0.9.5])dnl Picked up from clutter
  16
  17
  18 # Initialization
  19
  20 dnl autoconf 2.62 is required by GObject introspection:
  21 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  22 AC_PREREQ([2.62])
  23 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_HEADERS([src/config.h])
  26 AC_CONFIG_AUX_DIR([build])
  27 AC_CONFIG_MACRO_DIR([build])
  28 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  29
  30 dnl m4 backward compatibility stuff
  31 m4_ifdef([AM_SILENT_RULES],
  32          [AM_SILENT_RULES([yes])],
  33          [AC_SUBST([AM_V_GEN],[])])
  34 m4_ifdef([AM_SUBST_NOTMAKE],[],
  35          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  36 m4_ifdef([AM_COND_IF],[],
  37          [AC_DEFUN([AM_COND_IF],
  38                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  39
  40
  41 # Check for host information
  42
  43 AC_CANONICAL_HOST
  44 case "${host}" in
  45   *-*-linux*)
  46     guessed_host=linux
  47     ;;
  48   *-*-freebsd*)
  49     guessed_host=freebsd
  50     ;;
  51   *-*-mingw*)
  52     guessed_host=mingw
  53     ;;
  54   *-*-solaris*)
  55     guessed_host=solaris
  56     ;;
  57   *-*-darwin*)
  58     guessed_host=darwin
  59     ;;
  60   *-*-beos*)
  61     guessed_host=beos
  62     ;;
  63   *-*-cygwin*)
  64     guessed_host=cygwin
  65     ;;
  66   *-*-minix*)
  67     guessed_host=minix
  68     ;;
  69   *-*-aix*)
  70     guessed_host=aix
  71     ;;
  72   *)
  73     guessed_host=unknown
  74     ;;
  75 esac
  76 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  77 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  78
  79
  80 # Check for programs
  81
  82 AC_PROG_CC
  83 AC_PROG_SED
  84 PKG_PROG_PKG_CONFIG
  85 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  86 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  87 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  88 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  89 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  90 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  91 AM_COND_IF([OS_WINDOWS],
  92            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
  93             AC_PATH_PROG([WINE],[wine])])
  94
  95
  96 # Check for libraries
  97
  98 AC_CHECK_LIB([m],[cos])
  99
 100
 101 # Libtool initialization
 102
 103 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 104 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 105 m4_ifset([LT_INIT],
 106          [LT_INIT([disable-static win32-dll])],
 107          [AC_DISABLE_STATIC
 108           AC_LIBTOOL_WIN32_DLL
 109           AC_PROG_LIBTOOL])
 110
 111
 112 # I18n
 113
 114 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
 115 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 116 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 117                    [Define to the domain used by gettext.])
 118 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 119 IT_PROG_INTLTOOL([0.35.0])
 120 AM_GLIB_GNU_GETTEXT
 121 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 122 AC_CONFIG_COMMANDS([default],
 123                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 124         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 125     esac],
 126                    [SED="${SED}"])
 127
 128
 129 # Check for required packages
 130
 131 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 132 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 133 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 134 PKG_CHECK_MODULES([CAIRO_GOBJECT],[cairo-gobject],
 135                   [AC_DEFINE_UNQUOTED([CAIRO_GOBJECT_ENABLED],[1],
 136                                       [Defined if GObject support in cairo is present.])],
 137                   [:])
 138
 139
 140 # Check for optional packages
 141
 142 dnl PangoCairo
 143 AC_ARG_ENABLE([pango],
 144               [AS_HELP_STRING([--enable-pango],
 145                               [use pango for rendering text @<:@default=check@:>@])],
 146               [],[enable_pango=check])
 147 AS_IF([test "x${enable_pango}" != "xno"],
 148       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 149                          [enable_pango=yes
 150                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 151                                              [Defined if the pango support is enabled.])],
 152                          [AS_IF([test "x${enable_pango}" = "xyes"],
 153                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 154                                 [enable_pango=no])])])
 155 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 156
 157 dnl GTK+ support
 158 AC_ARG_WITH(gtk,
 159             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 160                             [include GTK+ specific widgets @<:@default=check@:>@])],
 161             [],[with_gtk=check])
 162 AS_CASE(["${with_gtk}"],
 163         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 164         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 165         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 166         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 167         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 168
 169 # GTK+ autodetection, giving precedence to GTK+3
 170 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 171       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,[gtk_pkg=gtk3],[:])])
 172 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 173       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,[gtk_pkg=gtk2],[:])])
 174 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 175
 176
 177 # Handle "check" graceful degradation
 178 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 179
 180 # Handle failures
 181 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 182       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 183
 184 AS_IF([test "x${with_gtk}" = "xgtk3"],
 185       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 186                           [Defined if the GTK+3 support is enabled.])])
 187 AS_IF([test "x${with_gtk}" = "xgtk2"],
 188       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 189                           [Defined if the GTK+2 support is enabled.])])
 190
 191 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 192 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 193 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 194
 195 dnl Glade catalog dir
 196 AC_ARG_WITH(glade_catalogdir,
 197             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 198                             [where to install the glade catalogs @<:@default=check@:>@])],
 199             [],[with_glade_catalogdir=check])
 200
 201 # Both "check" and "yes" mean gladeui autodetection,
 202 # but "yes" will fail on gladeui not found
 203 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 204       [glade_pkg=check])
 205
 206 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 207 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 208       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 209 AS_IF([test "x${glade_pkg}" = "xcheck"],
 210       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 211 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 212       [NTD_UNEXPAND([${glade_pkg}],
 213                     [catalogdir],
 214                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 215                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 216
 217 # Handle "yes" failure
 218 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 219       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 220
 221 # Handle "check" graceful degradation
 222 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 223       [with_glade_catalogdir=no])
 224
 225 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 226 AM_COND_IF([HAVE_GLADE],
 227            [enable_glade=yes
 228             report_glade="
 229                   Glade catalog dir: ${with_glade_catalogdir}"],
 230            [enable_glade=no
 231             report_glade=""])
 232 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 233
 234 dnl gtk-doc
 235 GTK_DOC_CHECK(gtkdoc_prereq)
 236
 237 dnl GObject introspection
 238 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 239 AC_ARG_WITH(girdir,
 240             [AS_HELP_STRING([--with-girdir=DIR],
 241                             [where the gir files are installed @<:@default=check@:>@])],
 242             [],[with_girdir=check])
 243 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_girdir}" = "xcheck"],
 244       [NTD_UNEXPAND([gobject-introspection-1.0],
 245                     [girdir],
 246                     [with_girdir="${NTD_UNEXPANDED}"])])
 247 AC_SUBST([GIRDIR],${with_girdir})
 248 AC_ARG_WITH(typelibdir,
 249             [AS_HELP_STRING([--with-typelibdir=DIR],
 250                             [where the typelib files are installed @<:@default=check@:>@])],
 251             [],[with_typelibdir=check])
 252 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_typelibdir}" = "xcheck"],
 253       [NTD_UNEXPAND([gobject-introspection-1.0],
 254                     [typelibdir],
 255                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 256 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 257 AM_COND_IF([HAVE_INTROSPECTION],
 258            [report_introspection="
 259          Where to install gir files: ${with_girdir}
 260  Where to install the typelib files: ${with_typelibdir}"],
 261            [report_introspection=""])
 262
 263 dnl GLib test framework
 264 AC_ARG_ENABLE([test_framework],
 265               [AS_HELP_STRING([--enable-test-framework],
 266                               [enable GLib test framework @<:@default=check@:>@])],
 267               [],[enable_test_framework=check])
 268 AS_IF([test "x${enable_test_framework}" != "xno"],
 269       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 270                         [enable_test_framework=yes],
 271                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 272                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 273                                [enable_test_framework=no])])])
 274 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 275
 276
 277 # Check for compiler characteristics
 278
 279 AC_C_CONST
 280
 281
 282 # Windows substitutions for NSis installer
 283
 284 dnl By default DLLDIR is set to "$prefix/bin", with "$prefix" got from
 285 dnl gobject-2.0.pc: all the DLLs *must* be under the same directory.
 286 AC_ARG_VAR([DLLDIR], Place where Windows DLLs must be picked from)
 287 AS_IF([test -z "$DLLDIR"],
 288       [DLLDIR="$($PKG_CONFIG --variable=prefix gobject-2.0)/bin"])
 289 AM_SUBST_NOTMAKE([DLLDIR])
 290
 291 dnl -win$ARCH will be appended to the installer file name
 292 AS_IF([test "x${host_cpu}" = "xx86_64"],[ARCH=64],[ARCH=32])
 293 AC_SUBST([ARCH])
 294 AM_SUBST_NOTMAKE([ARCH])
 295
 296
 297 # Additional substitutions
 298
 299 dnl The GObject dependency can be made optional by skipping
 300 dnl the building of the GObject wrappers.
 301 CPML_REQUIRES='cairo >= cairo_prereq gobject-2.0 >= gobject_prereq'
 302 AM_COND_IF([HAVE_PANGO],
 303       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 304        ADG_H_ADDITIONAL='
 305 #include <pango/pango.h>
 306 #include "adg/adg-text.h"
 307 #include "adg/adg-pango-style.h"
 308 '],
 309       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 310        ADG_H_ADDITIONAL=''])
 311 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 312 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 313 AM_COND_IF([HAVE_GTK],
 314            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 315 #include <gtk/gtk.h>
 316 #include \"adg/adg-gtk-utils.h\"
 317 #include \"adg/adg-gtk-area.h\"
 318 #include \"adg/adg-gtk-layout.h\"
 319 "
 320             ADG_CANVAS_H_ADDITIONAL='
 321 #include <gtk/gtk.h>
 322
 323 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 324                                                  const gchar    *paper_name,
 325                                                  GtkPageOrientation orientation);
 326 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 327                                                  GtkPageSetup   *page_setup);
 328 GtkPageSetup *  adg_canvas_get_page_setup       (AdgCanvas      *canvas);
 329 '],
 330            [ADG_CANVAS_H_ADDITIONAL=''])
 331
 332 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 333 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 334 AC_SUBST([CPML_REQUIRES])
 335 AC_SUBST([ADG_API_VERSION],adg_api_version)
 336 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 337 AC_SUBST([ADG_REQUIRES])
 338 AC_SUBST([ADG_H_ADDITIONAL])
 339 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 340
 341 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 342 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 343 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 344 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 345
 346 dnl CPML compiler flags and library dependencies
 347 CPML_CFLAGS="$CAIRO_CFLAGS $GOBJECT_CFLAGS"
 348 CPML_LIBS="$CAIRO_LIBS $GOBJECT_LIBS"
 349 AC_SUBST([CPML_CFLAGS])
 350 AC_SUBST([CPML_LIBS])
 351
 352 dnl ADG compiler flags and library dependencies
 353 ADG_CFLAGS="$CAIRO_GOBJECT_CFLAGS"
 354 ADG_LIBS="$CAIRO_GOBJECT_LIBS"
 355 AM_COND_IF([HAVE_PANGO],
 356            [ADG_CFLAGS="$PANGO_CFLAGS $ADG_CFLAGS"
 357             ADG_LIBS="$PANGO_LIBS $ADG_LIBS"])
 358 AM_COND_IF([HAVE_GTK2],
 359            [ADG_CFLAGS="$GTK2_CFLAGS $ADG_CFLAGS"
 360             ADG_LIBS="$GTK2_LIBS $ADG_LIBS"])
 361 AM_COND_IF([HAVE_GTK3],
 362            [ADG_CFLAGS="$GTK3_CFLAGS $ADG_CFLAGS"
 363             ADG_LIBS="$GTK3_LIBS $ADG_LIBS"])
 364 AC_SUBST([ADG_CFLAGS])
 365 AC_SUBST([ADG_LIBS])
 366
 367
 368 # Generation
 369
 370 AC_CONFIG_FILES([build/adg.nsi
 371                  Makefile
 372                  src/Makefile
 373                  src/cpml/cpml-1.pc
 374                  src/cpml/Makefile
 375                  src/cpml/tests/Makefile
 376                  src/adg/adg-1.pc
 377                  src/adg.h
 378                  src/adg/Makefile
 379                  src/adg/adg-canvas.h
 380                  src/adg/tests/Makefile
 381                  demo/Makefile
 382                  demo/cpml-demo.ui
 383                  demo/adg-demo.ui
 384                  po/Makefile.in
 385                  po-properties/Makefile.in
 386                  docs/Makefile
 387                  docs/cpml/Makefile
 388                  docs/cpml/bookinfo.xml
 389                  docs/adg/Makefile
 390                  docs/adg/bookinfo.xml])
 391 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 392 AC_OUTPUT
 393
 394
 395 # Report
 396
 397 AC_MSG_NOTICE([generating report
 398
 399 AC_PACKAGE_NAME adg_version will be built with the following options:
 400 ----------------------------------------------------------
 401                   API compatibility: adg_api_version
 402                 CPML library to use: internal (cpml-adg_version)
 403          Build pango based entities: ${enable_pango}
 404                        GTK+ support: ${with_gtk}
 405              Install glade catalogs: ${enable_glade}${report_glade}
 406                 Build API reference: ${enable_gtk_doc}
 407              GObject instrospection: ${enable_introspection}${report_introspection}
 408              Test framework support: ${enable_test_framework}
 409 ])