configure.ac

   1 m4_define([adg_version],[0.7.2])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[3:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[2:0:0])
   8
   9 m4_define([gtkdoc_prereq],[1.12])dnl Support introspection annotations
  10 m4_define([gobject_prereq],[2.10.1])
  11 m4_define([cairo_prereq],[1.7.4])
  12 m4_define([gtk2_prereq],[2.12.0])
  13 m4_define([gtk3_prereq],[3.0.0])
  14 m4_define([pangocairo_prereq],[1.18.0])
  15 m4_define([gi_prereq],[0.9.5])dnl Picked up from clutter
  16
  17
  18 # Initialization
  19
  20 dnl autoconf 2.62 is required by GObject introspection:
  21 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  22 AC_PREREQ([2.62])
  23 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_HEADERS([src/config.h])
  26 AC_CONFIG_AUX_DIR([build])
  27 AC_CONFIG_MACRO_DIR([build])
  28 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  29
  30 dnl m4 backward compatibility stuff
  31 m4_ifdef([AM_SILENT_RULES],
  32          [AM_SILENT_RULES([yes])],
  33          [AC_SUBST([AM_V_GEN],[])])
  34 m4_ifdef([AM_SUBST_NOTMAKE],[],
  35          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  36 m4_ifdef([AM_COND_IF],[],
  37          [AC_DEFUN([AM_COND_IF],
  38                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  39
  40
  41 # Check for host information
  42
  43 AC_CANONICAL_HOST
  44 case "${host}" in
  45   *-*-linux*)
  46     guessed_host=linux
  47     ;;
  48   *-*-freebsd*)
  49     guessed_host=freebsd
  50     ;;
  51   *-*-mingw*)
  52     guessed_host=mingw
  53     ;;
  54   *-*-solaris*)
  55     guessed_host=solaris
  56     ;;
  57   *-*-darwin*)
  58     guessed_host=darwin
  59     ;;
  60   *-*-beos*)
  61     guessed_host=beos
  62     ;;
  63   *-*-cygwin*)
  64     guessed_host=cygwin
  65     ;;
  66   *-*-minix*)
  67     guessed_host=minix
  68     ;;
  69   *-*-aix*)
  70     guessed_host=aix
  71     ;;
  72   *)
  73     guessed_host=unknown
  74     ;;
  75 esac
  76 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  77 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  78
  79
  80 # Check for programs
  81
  82 AC_PROG_CC
  83 AC_PROG_SED
  84 PKG_PROG_PKG_CONFIG
  85 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  86 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  87 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  88 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  89 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  90 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  91 AM_COND_IF([OS_WINDOWS],
  92            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
  93             AC_PATH_PROG([WINE],[wine])])
  94
  95
  96 # Check for libraries
  97
  98 AC_CHECK_LIB([m],[cos])
  99
 100
 101 # Libtool initialization
 102
 103 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 104 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 105 m4_ifset([LT_INIT],
 106          [LT_INIT([disable-static win32-dll])],
 107          [AC_DISABLE_STATIC
 108           AC_LIBTOOL_WIN32_DLL
 109           AC_PROG_LIBTOOL])
 110
 111
 112 # I18n
 113
 114 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
 115 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 116 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 117                    [Define to the domain used by gettext.])
 118 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 119 IT_PROG_INTLTOOL([0.35.0])
 120 AM_GLIB_GNU_GETTEXT
 121 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 122 AC_CONFIG_COMMANDS([default],
 123                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 124         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 125     esac],
 126                    [SED="${SED}"])
 127
 128
 129 # Check for required packages
 130
 131 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 132
 133 AC_MSG_CHECKING([if glib-genmarshal supports --internal])
 134 AS_IF([$PKG_CONFIG --atleast-version 2.13.0 glib-2.0],
 135       [AC_MSG_RESULT([yes])
 136        GLIB_GENMARSHAL="$GLIB_GENMARSHAL --internal"],
 137       [AC_MSG_RESULT([no])])
 138
 139 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 140 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 141 PKG_CHECK_MODULES([CAIRO_GOBJECT],[cairo-gobject],
 142                   [AC_DEFINE_UNQUOTED([CAIRO_GOBJECT_ENABLED],[1],
 143                                       [Defined if GObject support in cairo is present.])],
 144                   [:])
 145
 146
 147 # Check for optional packages
 148
 149 dnl PangoCairo
 150 AC_ARG_ENABLE([pango],
 151               [AS_HELP_STRING([--enable-pango],
 152                               [use pango for rendering text @<:@default=check@:>@])],
 153               [],[enable_pango=check])
 154 AS_IF([test "x${enable_pango}" != "xno"],
 155       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 156                          [enable_pango=yes
 157                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 158                                              [Defined if the pango support is enabled.])],
 159                          [AS_IF([test "x${enable_pango}" = "xyes"],
 160                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 161                                 [enable_pango=no])])])
 162 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 163
 164 dnl GTK+ support
 165 AC_ARG_WITH(gtk,
 166             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 167                             [include GTK+ specific widgets @<:@default=check@:>@])],
 168             [],[with_gtk=check])
 169 AS_CASE(["${with_gtk}"],
 170         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 171         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 172         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 173         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 174         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 175
 176 # GTK+ autodetection, giving precedence to GTK+3
 177 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 178       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,[gtk_pkg=gtk3],[:])])
 179 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 180       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,[gtk_pkg=gtk2],[:])])
 181 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 182
 183
 184 # Handle "check" graceful degradation
 185 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 186
 187 # Handle failures
 188 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 189       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 190
 191 AS_IF([test "x${with_gtk}" = "xgtk3"],
 192       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 193                           [Defined if the GTK+3 support is enabled.])])
 194 AS_IF([test "x${with_gtk}" = "xgtk2"],
 195       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 196                           [Defined if the GTK+2 support is enabled.])])
 197
 198 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 199 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 200 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 201
 202 dnl Glade catalog dir
 203 AC_ARG_WITH(glade_catalogdir,
 204             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 205                             [where to install the glade catalogs @<:@default=check@:>@])],
 206             [],[with_glade_catalogdir=check])
 207
 208 # Both "check" and "yes" mean gladeui autodetection,
 209 # but "yes" will fail on gladeui not found
 210 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 211       [glade_pkg=check])
 212
 213 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 214 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 215       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 216 AS_IF([test "x${glade_pkg}" = "xcheck"],
 217       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 218 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 219       [NTD_UNEXPAND([${glade_pkg}],
 220                     [catalogdir],
 221                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 222                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 223
 224 # Handle "yes" failure
 225 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 226       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 227
 228 # Handle "check" graceful degradation
 229 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 230       [with_glade_catalogdir=no])
 231
 232 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 233 AM_COND_IF([HAVE_GLADE],
 234            [enable_glade=yes
 235             report_glade="
 236                   Glade catalog dir: ${with_glade_catalogdir}"],
 237            [enable_glade=no
 238             report_glade=""])
 239 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 240
 241 dnl gtk-doc
 242 GTK_DOC_CHECK(gtkdoc_prereq)
 243
 244 dnl GObject introspection
 245 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 246 AC_ARG_WITH(girdir,
 247             [AS_HELP_STRING([--with-girdir=DIR],
 248                             [where the gir files are installed @<:@default=check@:>@])],
 249             [],[with_girdir=check])
 250 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_girdir}" = "xcheck"],
 251       [NTD_UNEXPAND([gobject-introspection-1.0],
 252                     [girdir],
 253                     [with_girdir="${NTD_UNEXPANDED}"])])
 254 AC_SUBST([GIRDIR],${with_girdir})
 255 AC_ARG_WITH(typelibdir,
 256             [AS_HELP_STRING([--with-typelibdir=DIR],
 257                             [where the typelib files are installed @<:@default=check@:>@])],
 258             [],[with_typelibdir=check])
 259 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_typelibdir}" = "xcheck"],
 260       [NTD_UNEXPAND([gobject-introspection-1.0],
 261                     [typelibdir],
 262                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 263 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 264 AM_COND_IF([HAVE_INTROSPECTION],
 265            [report_introspection="
 266          Where to install gir files: ${with_girdir}
 267  Where to install the typelib files: ${with_typelibdir}"],
 268            [report_introspection=""])
 269
 270 dnl GLib test framework
 271 AC_ARG_ENABLE([test_framework],
 272               [AS_HELP_STRING([--enable-test-framework],
 273                               [enable GLib test framework @<:@default=check@:>@])],
 274               [],[enable_test_framework=check])
 275 AS_IF([test "x${enable_test_framework}" != "xno"],
 276       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 277                         [enable_test_framework=yes],
 278                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 279                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 280                                [enable_test_framework=no])])])
 281 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 282
 283
 284 # Check for compiler characteristics
 285
 286 AC_C_CONST
 287
 288
 289 # Windows substitutions for NSis installer
 290
 291 dnl By default DLLDIR is set to "$prefix/bin", with "$prefix" got from
 292 dnl gobject-2.0.pc: all the DLLs *must* be under the same directory.
 293 AC_ARG_VAR([DLLDIR], Place where Windows DLLs must be picked from)
 294 AS_IF([test -z "$DLLDIR"],
 295       [DLLDIR="$($PKG_CONFIG --variable=prefix gobject-2.0)/bin"])
 296 AM_SUBST_NOTMAKE([DLLDIR])
 297
 298 dnl -win$ARCH will be appended to the installer file name
 299 AS_IF([test "x${host_cpu}" = "xx86_64"],[ARCH=64],[ARCH=32])
 300 AC_SUBST([ARCH])
 301 AM_SUBST_NOTMAKE([ARCH])
 302
 303
 304 # Additional substitutions
 305
 306 dnl The GObject dependency can be made optional by skipping
 307 dnl the building of the GObject wrappers.
 308 CPML_REQUIRES='cairo >= cairo_prereq gobject-2.0 >= gobject_prereq'
 309 AM_COND_IF([HAVE_PANGO],
 310       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 311        ADG_H_ADDITIONAL='
 312 #include <pango/pango.h>
 313 #include "adg/adg-text.h"
 314 #include "adg/adg-pango-style.h"
 315 '],
 316       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 317        ADG_H_ADDITIONAL=''])
 318 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 319 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 320 AM_COND_IF([HAVE_GTK],
 321            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 322 #include <gtk/gtk.h>
 323 #include \"adg/adg-gtk-utils.h\"
 324 #include \"adg/adg-gtk-area.h\"
 325 #include \"adg/adg-gtk-layout.h\"
 326 "
 327             ADG_CANVAS_H_ADDITIONAL='
 328 #include <gtk/gtk.h>
 329
 330 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 331                                                  const gchar    *paper_name,
 332                                                  GtkPageOrientation orientation);
 333 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 334                                                  GtkPageSetup   *page_setup);
 335 GtkPageSetup *  adg_canvas_get_page_setup       (AdgCanvas      *canvas);
 336 '],
 337            [ADG_CANVAS_H_ADDITIONAL=''])
 338
 339 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 340 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 341 AC_SUBST([CPML_REQUIRES])
 342 AC_SUBST([ADG_API_VERSION],adg_api_version)
 343 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 344 AC_SUBST([ADG_REQUIRES])
 345 AC_SUBST([ADG_H_ADDITIONAL])
 346 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 347
 348 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 349 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 350 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 351 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 352
 353 dnl CPML compiler flags and library dependencies
 354 CPML_CFLAGS="$CAIRO_CFLAGS $GOBJECT_CFLAGS"
 355 CPML_LIBS="$CAIRO_LIBS $GOBJECT_LIBS"
 356 AC_SUBST([CPML_CFLAGS])
 357 AC_SUBST([CPML_LIBS])
 358
 359 dnl ADG compiler flags and library dependencies
 360 ADG_CFLAGS="$CAIRO_GOBJECT_CFLAGS"
 361 ADG_LIBS="$CAIRO_GOBJECT_LIBS"
 362 AM_COND_IF([HAVE_PANGO],
 363            [ADG_CFLAGS="$PANGO_CFLAGS $ADG_CFLAGS"
 364             ADG_LIBS="$PANGO_LIBS $ADG_LIBS"])
 365 AM_COND_IF([HAVE_GTK2],
 366            [ADG_CFLAGS="$GTK2_CFLAGS $ADG_CFLAGS"
 367             ADG_LIBS="$GTK2_LIBS $ADG_LIBS"])
 368 AM_COND_IF([HAVE_GTK3],
 369            [ADG_CFLAGS="$GTK3_CFLAGS $ADG_CFLAGS"
 370             ADG_LIBS="$GTK3_LIBS $ADG_LIBS"])
 371 AC_SUBST([ADG_CFLAGS])
 372 AC_SUBST([ADG_LIBS])
 373
 374
 375 # Generation
 376
 377 AC_CONFIG_FILES([build/adg.nsi
 378                  Makefile
 379                  src/Makefile
 380                  src/cpml/cpml-1.pc
 381                  src/cpml/Makefile
 382                  src/cpml/tests/Makefile
 383                  src/adg/adg-1.pc
 384                  src/adg.h
 385                  src/adg/Makefile
 386                  src/adg/adg-canvas.h
 387                  src/adg/tests/Makefile
 388                  demo/Makefile
 389                  demo/cpml-demo.ui
 390                  demo/adg-demo.ui
 391                  po/Makefile.in
 392                  po-properties/Makefile.in
 393                  docs/Makefile
 394                  docs/cpml/Makefile
 395                  docs/cpml/bookinfo.xml
 396                  docs/adg/Makefile
 397                  docs/adg/bookinfo.xml])
 398 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 399 AC_OUTPUT
 400
 401
 402 # Report
 403
 404 AC_MSG_NOTICE([generating report
 405
 406 AC_PACKAGE_NAME adg_version will be built with the following options:
 407 ----------------------------------------------------------
 408                   API compatibility: adg_api_version
 409                 CPML library to use: internal (cpml-adg_version)
 410          Build pango based entities: ${enable_pango}
 411                        GTK+ support: ${with_gtk}
 412              Install glade catalogs: ${enable_glade}${report_glade}
 413                 Build API reference: ${enable_gtk_doc}
 414              GObject instrospection: ${enable_introspection}${report_introspection}
 415              Test framework support: ${enable_test_framework}
 416 ])