configure.ac

   1 m4_define([adg_version],[0.6.3])
   2 m4_define([adg_api_version],[1.0])
   3
   4 m4_define([gtkdoc_prereq],[1.9])
   5 m4_define([gobject_prereq],[2.10.1])
   6 m4_define([cairo_prereq],[1.7.4])
   7 m4_define([gtk_prereq],[2.12.0])
   8 m4_define([pangocairo_prereq],[1.18.0])
   9
  10
  11 # Initialization
  12
  13 dnl autoconf 2.60 implements datarootdir, required by ADG
  14 dnl to help overcoming the hardcoded glade catalogdir
  15 AC_PREREQ([2.60])
  16 AC_INIT([adg-1.0],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  17 AC_CONFIG_SRCDIR([configure.ac])
  18 AC_CONFIG_HEADERS([src/config.h])
  19 AC_CONFIG_AUX_DIR([build])
  20 AC_CONFIG_MACRO_DIR([build])
  21 AM_INIT_AUTOMAKE([1.6 gnits no-dist-gzip dist-bzip2 -Wall])
  22 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
  23
  24
  25 # Check for host information
  26
  27 AC_CANONICAL_HOST
  28 case "${host}" in
  29   *-*-linux*)
  30     guessed_host=linux
  31     ;;
  32   *-*-freebsd*)
  33     guessed_host=freebsd
  34     ;;
  35   *-*-mingw*)
  36     guessed_host=mingw
  37     ;;
  38   *-*-solaris*)
  39     guessed_host=solaris
  40     ;;
  41   *-*-darwin*)
  42     guessed_host=darwin
  43     ;;
  44   *-*-beos*)
  45     guessed_host=beos
  46     ;;
  47   *-*-cygwin*)
  48     guessed_host=cygwin
  49     ;;
  50   *-*-minix)
  51     guessed_host=minix
  52     ;;
  53   *-*-aix*)
  54     guessed_host=aix
  55     ;;
  56   *)
  57     guessed_host=unknown
  58     ;;
  59 esac
  60 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  61 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" == "mingw" -o "${guessed_host}" == "cygwin"])
  62
  63
  64 # Check for programs
  65
  66 AC_PROG_CC
  67 AC_PROG_SED
  68 PKG_PROG_PKG_CONFIG
  69 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  70 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  71 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  72 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  73 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  74 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  75
  76
  77 # Check for libraries
  78
  79 AC_CHECK_LIB([m],[cos])
  80
  81
  82 # Libtool initialization
  83
  84 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
  85 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
  86 m4_ifset([LT_INIT],
  87          [LT_INIT([disable-static win32-dll])],
  88          [AC_DISABLE_STATIC
  89           AC_LIBTOOL_WIN32_DLL
  90           AC_PROG_LIBTOOL])
  91
  92
  93 # I18n
  94
  95 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
  96 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
  97                    [Define to the domain used by gettext.])
  98 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
  99 IT_PROG_INTLTOOL(0.40.1)
 100 AM_GLIB_GNU_GETTEXT
 101 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 102 AC_CONFIG_COMMANDS([default],
 103                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 104         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 105     esac],
 106                    [SED="${SED}"])
 107
 108
 109 # Check for required packages
 110
 111 GTK_DOC_CHECK(gtkdoc_prereq)
 112 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 113 PKG_CHECK_MODULES([GOBJECT2],[gobject-2.0 >= ]gobject_prereq)
 114 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 115
 116
 117 # Check for optional pango support
 118
 119 AC_ARG_ENABLE([pango],
 120               [AS_HELP_STRING([--enable-pango],
 121                               [use pango for rendering text @<:@default=check@:>@])],
 122               [],[enable_pango=check])
 123 AS_IF([test "x${enable_pango}" != "xno"],
 124       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 125                          [enable_pango=yes
 126                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 127                                              [Defined if the pango support is enabled.])],
 128                          [AS_IF([test "x${enable_pango}" = "xyes"],
 129                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 130                                 [enable_pango=no])])])
 131 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 132
 133
 134 # Check for optional GTK+2 support
 135
 136 AC_ARG_ENABLE([gtk2],
 137               [AS_HELP_STRING([--enable-gtk2],
 138                               [include GKT+2 specific widgets @<:@default=check@:>@])],
 139               [],[enable_gtk2=check])
 140 AS_IF([test "x${enable_gtk2}" != "xno"],
 141       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk_prereq,
 142                          [enable_gtk2=yes],
 143                          [AS_IF([test "x${enable_gtk2}" = "xyes"],
 144                                 [AC_MSG_ERROR([${GTK2_PKG_ERRORS} and GTK+2 support requested])],
 145                                 [enable_gtk2=no])])])
 146 AM_CONDITIONAL([HAVE_GTK2],[test "x${enable_gtk2}" = "xyes"])
 147
 148
 149 # Check for optional glade support
 150
 151 AC_ARG_ENABLE([glade],
 152               [AS_HELP_STRING([--enable-glade],
 153                               [install glade catalog file @<:@default=check@:>@])],
 154               [],[enable_glade=check])
 155 AS_IF([test "x${enable_glade}" != "xno"],
 156       [PKG_CHECK_MODULES([GLADE],[gladeui-1.0],
 157                          [enable_glade=yes],
 158                          [AS_IF([test "x${enable_glade}" = "xyes"],
 159                                 [AC_MSG_ERROR([${GLADE_PKG_ERRORS} and glade support requested])],
 160                                 [enable_glade=no])])])
 161 AM_CONDITIONAL([HAVE_GLADE],[test "x${enable_glade}" = "xyes"])
 162 AS_IF([test "x${enable_glade}" == "xyes"],
 163       [AC_MSG_CHECKING([for the glade catalog path])
 164        gladeroot=`${PKG_CONFIG} --variable=datarootdir gladeui-1.0`
 165        AS_IF([test "x${gladeroot}" == "x"],
 166              [GLADE_CATALOGDIR="\${datarootdir}/glade3/catalogs}"],
 167              [gladecatalog=`${PKG_CONFIG} --variable=catalogdir gladeui-1.0`
 168               GLADE_CATALOGDIR=`echo "${gladecatalog}" | ${SED} -e "s|^${gladeroot}|"'${datarootdir}|'`])
 169        AC_SUBST([GLADE_CATALOGDIR])
 170        AC_MSG_RESULT(${GLADE_CATALOGDIR})])
 171
 172
 173
 174 # Check for optional GLib test framework
 175
 176 AC_ARG_ENABLE([test_framework],
 177               [AS_HELP_STRING([--enable-test-framework],
 178                               [enable GLib test framework @<:@default=check@:>@])],
 179               [],[enable_test_framework=check])
 180 AS_IF([test "x${enable_test_framework}" != "xno"],
 181       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 182                         [enable_test_framework=yes],
 183                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 184                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 185                                [enable_test_framework=no])])])
 186 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 187
 188
 189 # Check for compiler characteristics
 190
 191 AC_C_CONST
 192
 193
 194 # Final step
 195
 196 AC_SUBST([CPML_REQUIRES],'cairo >= cairo_prereq')
 197 AC_SUBST([ADG_REQUIRES],'gobject-2.0 >= gobject_prereq')
 198 AC_SUBST([ADG_GTK_REQUIRES],'gtk+-2.0 >= gtk_prereq')
 199 AC_SUBST([DLLDIR],"$(${PKG_CONFIG} --variable=prefix gobject-2.0)/bin")
 200
 201 SHAVE_INIT([build],[enable])
 202 AC_CONFIG_FILES([build/shave
 203                  build/shave-libtool
 204                  build/adg.nsi
 205                  Makefile
 206                  src/Makefile
 207                  src/cpml-1.pc
 208                  src/cpml/Makefile
 209                  src/cpml/tests/Makefile
 210                  src/adg-1.pc
 211                  src/adg/Makefile
 212                  src/adg/tests/Makefile
 213                  src/adg-gtk-1.pc
 214                  src/adg-gtk/Makefile
 215                  src/adg-gtk/tests/Makefile
 216                  demo/Makefile
 217                  demo/cpml-demo.ui
 218                  demo/adg-demo.ui
 219                  po/Makefile.in
 220                  po-properties/Makefile.in
 221                  docs/Makefile
 222                  docs/cpml/Makefile
 223                  docs/cpml/bookinfo.xml
 224                  docs/adg/Makefile
 225                  docs/adg/bookinfo.xml])
 226 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 227 AC_OUTPUT
 228
 229
 230 # Report
 231
 232 AS_IF([test "x${enable_glade}" != "xno"],
 233       [report_glade_catalogdir="
 234                   Glade catalog dir: ${GLADE_CATALOGDIR}"],
 235       [report_glade_catalogdir=''])
 236
 237
 238 AC_MSG_NOTICE([generating report
 239
 240 AC_PACKAGE_NAME adg_version will be built with the following options:
 241 ----------------------------------------------------------
 242                   API compatibility: adg_api_version
 243                 CPML library to use: internal (cpml-adg_version)
 244          Build pango based entities: ${enable_pango}
 245            GTK+2 additional widgets: ${enable_gtk2}
 246              Install glade catalogs: ${enable_glade}${report_glade_catalogdir}
 247                 Build API reference: ${enable_gtk_doc}
 248              Test framework support: ${enable_test_framework}
 249 ])