nodist/symbols.mp

   1 % Miscellaneous symbols
   2
   3 linecap := rounded;
   4 linejoin := rounded;
   5
   6 pen thin, thick;
   7 thin := pencircle scaled 3;
   8 thick := pencircle scaled 5;
   9
  10
  11 beginfig(0) % Server
  12
  13 pickup thick;
  14 draw (300, 300) -- (180, 260) --
  15      (180,  50) .. controls (200, 30) and (250, 0) .. (280, 0) --
  16      (400, 100) -- (400, 280) -- cycle;
  17
  18 pickup thin;
  19 draw (280, 210) .. controls (250, 210) and (200, 230) .. (180, 260);
  20 draw fullcircle scaled 15 yscaled 1.4 shifted (260, 80);
  21 draw fullcircle scaled 15 yscaled 1.4 shifted (260, 50);
  22 draw (260, 185) .. controls (240, 190) and (220, 190) .. (190, 220);
  23 draw (260, 165) .. controls (240, 170) and (220, 170) .. (190, 200);
  24 draw (400, 280) -- (280, 210) -- (280, 0);
  25
  26 endfig;
  27
  28
  29 beginfig(1) % Database
  30
  31 pickup thick;
  32 draw halfcircle scaled 400 yscaled 0.2 shifted (200, 200) --
  33      halfcircle rotated 180 scaled 400 yscaled 0.2 shifted (200, 40) --
  34      cycle;
  35
  36 pickup thin;
  37 draw halfcircle rotated 180 scaled 400 yscaled 0.2 shifted (200, 200);
  38
  39 endfig;
  40
  41
  42 beginfig(2) % Printer
  43
  44 pickup thick;
  45 draw (100, 0) -- (300, 0) -- (300, 70) -- (100, 70) -- cycle;
  46 draw (300, 50) --
  47      quartercircle rotated -90 scaled 60 shifted (370, 80) ..
  48      quartercircle scaled 60 shifted (370, 200) ..
  49      quartercircle rotated 90 scaled 60 shifted (30, 200) ..
  50      quartercircle rotated 180 scaled 60 shifted (30, 80) .. (100, 50);
  51 draw (300, 230) -- (300, 330) -- (100, 330) -- (100, 230);
  52
  53 pickup thin;
  54 draw (120, 20) -- (280, 20);
  55 draw (120, 35) -- (280, 35);
  56 draw (120, 50) -- (280, 50);
  57 draw (40, 200) -- (360, 200) -- (360, 190) -- (40, 190) -- cycle;
  58
  59 endfig;
  60
  61
  62 beginfig(3) % Sheet
  63
  64 pickup thick;
  65 draw (50, 0) -- (350, 0) -- (350, 300) -- (250, 400) -- (50, 400) -- cycle;
  66 linecap := butt;
  67 draw (350, 300) -- (250, 300) -- (250, 400);
  68
  69 pickup thin;
  70 for n = 50 step 30 until 290:
  71     draw (100, n) -- (300, n);
  72 endfor
  73
  74 draw (100, 320) -- (250, 320);
  75 draw (100, 350) -- (250, 350);
  76
  77 endfig;
  78
  79
  80 beginfig(4) % Laptop
  81
  82 pickup thick;
  83 draw (50, 100) -- (350, 100) -- (350, 300) -- (50, 300) -- cycle;
  84 draw (50, 100) -- (0, 20) -- (10, 0) -- (390, 0) -- (400, 20) -- (350, 100);
  85 draw (0, 20) -- (400, 20);
  86
  87 pickup thin;
  88 draw quartercircle rotated -90 scaled 40 shifted (320, 130) ..
  89      quartercircle scaled 40 shifted (320, 270) ..
  90      quartercircle rotated 90 scaled 40 shifted (80, 270) ..
  91      quartercircle rotated 180 scaled 40 shifted (80, 130) .. cycle;
  92 draw (35, 55) -- (55, 92) -- (345, 92) -- (365, 55) -- cycle;
  93 draw (170, 50) -- (230, 50) -- (233, 28) -- (167, 28) -- cycle;
  94
  95 endfig;
  96
  97
  98 beginfig(5) % Cloud
  99
 100 pickup thick;
 101 draw (305,  25) .. controls (279,  20) and (253,  26) ..
 102      (235,  39) .. controls (225,  30) and (223,  24) ..
 103      (198,  20) .. controls (148,  12) and (118,  30) ..
 104      (107,  60) .. controls (106,  62) and (106,  65) ..
 105      (105,  67) .. controls ( 70,  64) and ( 35,  81) ..
 106      ( 25, 108) .. controls ( 15, 135) and ( 33, 162) ..
 107      ( 66, 174) .. controls ( 64, 177) and ( 63, 180) ..
 108      ( 61, 183) .. controls ( 50, 213) and ( 74, 244) ..
 109      (113, 252) .. controls (132, 256) and (152, 254) ..
 110      (168, 247) .. controls (177, 262) and (193, 273) ..
 111      (216, 278) .. controls (248, 284) and (280, 274) ..
 112      (297, 255) .. controls (304, 259) and (312, 262) ..
 113      (321, 264) .. controls (361, 272) and (402, 254) ..
 114      (412, 224) .. controls (417, 209) and (414, 194) ..
 115      (404, 181) .. controls (414, 174) and (421, 165) ..
 116      (425, 155) .. controls (436, 125) and (412,  94) ..
 117      (373,  85) .. controls (369,  84) and (365,  84) ..
 118      (360,  83) .. controls (362,  56) and (340,  31) .. cycle;
 119
 120 endfig;
 121
 122
 123 beginfig(6) % Tablet
 124
 125 pickup thick;
 126 draw quartercircle rotated -90 scaled 120 shifted (280, 60) ..
 127      quartercircle scaled 120 shifted (280, 340) ..
 128      quartercircle rotated 90 scaled 120 shifted (120, 340) ..
 129      quartercircle rotated 180 scaled 120 shifted (120, 60) .. cycle;
 130
 131 pickup thin;
 132 draw (90, 70) -- (90, 330) -- (310, 330) -- (310, 70) -- cycle;
 133 draw fullcircle scaled 50 shifted (200, 35);
 134 draw (150, 370) -- (250, 370) -- (240, 360) -- (160, 360) -- cycle;
 135
 136 endfig;
 137
 138
 139 beginfig(7) % Workstation
 140
 141 pickup thick;
 142 draw (0, 100) -- (300, 100) -- (300, 300) -- (0, 300) -- cycle;
 143 draw (130, 90) -- (170, 90){down} .. (180, 65) -- (120, 65) .. {up}cycle;
 144 draw (80, 50) -- (0, 10) -- (10, 0) -- (290, 0) -- (300, 10) -- (220, 50) -- cycle;
 145 draw (318, 28) .. controls (320, 33) and (335, 43) ..
 146      (350, 38) .. controls (367, 32) and (380, 15) ..
 147      (368,  4) .. controls (360, -5) and (344,  7) ..
 148      (339, 11) .. controls (334, 15) and (318, 23) .. (318, 28) .. cycle;
 149
 150 pickup thin;
 151 draw quartercircle rotated -90 scaled 40 shifted (270, 130) ..
 152      quartercircle scaled 40 shifted (270, 270) ..
 153      quartercircle rotated 90 scaled 40 shifted (30, 270) ..
 154      quartercircle rotated 180 scaled 40 shifted (30, 130) .. cycle;
 155 draw (0, 10) -- (300, 10);
 156 draw (370, 10) .. {dir 135}(340, 20) .. (320, 30);
 157
 158 draw (313, 35){dir 135} .. (280, 50) .. (290, 60) .. (250, 70) ..
 159      (220, 70) .. {dir 220}(185, 75);
 160
 161
 162 endfig;
 163
 164
 165 end.