configure.ac

   1 m4_define([adg_version],[0.6.5])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[1:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[1:0:0])
   8
   9 m4_define([gtkdoc_prereq],[1.9])
  10 m4_define([gobject_prereq],[2.10.1])
  11 m4_define([cairo_prereq],[1.7.4])
  12 m4_define([gtk2_prereq],[2.12.0])
  13 m4_define([gtk3_prereq],[3.0.0])
  14 m4_define([pangocairo_prereq],[1.18.0])
  15 m4_define([gi_prereq],[0.9.5])dnl Picked up from clutter
  16
  17
  18 # Initialization
  19
  20 dnl autoconf 2.62 is required by GObject introspection:
  21 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  22 AC_PREREQ([2.62])
  23 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_HEADERS([src/config.h])
  26 AC_CONFIG_AUX_DIR([build])
  27 AC_CONFIG_MACRO_DIR([build])
  28 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  29
  30 dnl m4 backward compatibility stuff
  31 m4_ifdef([AM_SILENT_RULES],
  32          [AM_SILENT_RULES([yes])],
  33          [AC_SUBST([AM_V_GEN],[])])
  34 m4_ifdef([AM_SUBST_NOTMAKE],[],
  35          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  36 m4_ifdef([AM_COND_IF],[],
  37          [AC_DEFUN([AM_COND_IF],
  38                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  39
  40
  41 # Check for host information
  42
  43 AC_CANONICAL_HOST
  44 case "${host}" in
  45   *-*-linux*)
  46     guessed_host=linux
  47     ;;
  48   *-*-freebsd*)
  49     guessed_host=freebsd
  50     ;;
  51   *-*-mingw*)
  52     guessed_host=mingw
  53     ;;
  54   *-*-solaris*)
  55     guessed_host=solaris
  56     ;;
  57   *-*-darwin*)
  58     guessed_host=darwin
  59     ;;
  60   *-*-beos*)
  61     guessed_host=beos
  62     ;;
  63   *-*-cygwin*)
  64     guessed_host=cygwin
  65     ;;
  66   *-*-minix)
  67     guessed_host=minix
  68     ;;
  69   *-*-aix*)
  70     guessed_host=aix
  71     ;;
  72   *)
  73     guessed_host=unknown
  74     ;;
  75 esac
  76 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  77 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  78
  79
  80 # Check for programs
  81
  82 AC_PROG_CC
  83 AC_PROG_SED
  84 PKG_PROG_PKG_CONFIG
  85 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  86 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  87 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  88 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  89 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  90 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  91
  92
  93 # Check for libraries
  94
  95 AC_CHECK_LIB([m],[cos])
  96
  97
  98 # Libtool initialization
  99
 100 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 101 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 102 m4_ifset([LT_INIT],
 103          [LT_INIT([disable-static win32-dll])],
 104          [AC_DISABLE_STATIC
 105           AC_LIBTOOL_WIN32_DLL
 106           AC_PROG_LIBTOOL])
 107
 108
 109 # I18n
 110
 111 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
 112 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 113 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 114                    [Define to the domain used by gettext.])
 115 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 116 IT_PROG_INTLTOOL(0.40.1)
 117 AM_GLIB_GNU_GETTEXT
 118 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 119 AC_CONFIG_COMMANDS([default],
 120                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 121         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 122     esac],
 123                    [SED="${SED}"])
 124
 125
 126 # Check for required packages
 127
 128 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 129 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 130 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 131
 132
 133 # Check for optional packages
 134
 135 dnl PangoCairo
 136 AC_ARG_ENABLE([pango],
 137               [AS_HELP_STRING([--enable-pango],
 138                               [use pango for rendering text @<:@default=check@:>@])],
 139               [],[enable_pango=check])
 140 AS_IF([test "x${enable_pango}" != "xno"],
 141       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 142                          [enable_pango=yes
 143                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 144                                              [Defined if the pango support is enabled.])],
 145                          [AS_IF([test "x${enable_pango}" = "xyes"],
 146                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 147                                 [enable_pango=no])])])
 148 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 149
 150 dnl GTK+ support
 151 AC_ARG_WITH(gtk,
 152             [AC_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 153                             [include GTK+ specific widgets @<:@default=check@:>@])],
 154             [],[with_gtk=check])
 155 AS_CASE(["${with_gtk}"],
 156         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 157         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 158         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 159         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 160         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 161
 162 # GTK+ autodetection, giving precedence to GTK+3
 163 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 164       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,[gtk_pkg=gtk3],[:])])
 165 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 166       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,[gtk_pkg=gtk2],[:])])
 167 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 168
 169
 170 # Handle "check" graceful degradation
 171 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 172
 173 # Handle failures
 174 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 175       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 176
 177 AS_IF([test "x${with_gtk}" = "xgtk3"],
 178       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 179                           [Defined if the GTK+3 support is enabled.])])
 180 AS_IF([test "x${with_gtk}" = "xgtk2"],
 181       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 182                           [Defined if the GTK+2 support is enabled.])])
 183
 184 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 185 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 186 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 187
 188 dnl Glade catalog dir
 189 AC_ARG_WITH(glade_catalogdir,
 190             [AC_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 191                             [where to install the glade catalogs @<:@default=check@:>@])],
 192             [],[with_glade_catalogdir=check])
 193
 194 # Both "check" and "yes" mean gladeui autodetection,
 195 # but "yes" will fail on gladeui not found
 196 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 197       [glade_pkg=check])
 198
 199 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 200 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 201       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 202 AS_IF([test "x${glade_pkg}" = "xcheck"],
 203       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 204 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 205       [NTD_UNEXPAND([${glade_pkg}],
 206                     [catalogdir],
 207                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 208                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 209
 210 # Handle "yes" failure
 211 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 212       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 213
 214 # Handle "check" graceful degradation
 215 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 216       [with_glade_catalogdir=no])
 217
 218 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 219 AM_COND_IF([HAVE_GLADE],
 220            [enable_glade=yes
 221             report_glade="
 222                   Glade catalog dir: ${with_glade_catalogdir}"],
 223            [enable_glade=no
 224             report_glade=""])
 225 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 226
 227 dnl gtk-doc
 228 GTK_DOC_CHECK(gtkdoc_prereq)
 229
 230 dnl GObject introspection
 231 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 232 AC_ARG_WITH(girdir,
 233             [AC_HELP_STRING([--with-girdir=DIR],
 234                             [where the gir files are installed @<:@default=check@:>@])],
 235             [],[with_girdir=check])
 236 AS_IF([test "x${with_girdir}" = "xcheck"],
 237       [NTD_UNEXPAND([gobject-introspection-1.0],
 238                     [girdir],
 239                     [with_girdir="${NTD_UNEXPANDED}"])])
 240 AC_SUBST([GIRDIR],${with_girdir})
 241 AC_ARG_WITH(typelibdir,
 242             [AC_HELP_STRING([--with-typelibdir=DIR],
 243                             [where the typelib files are installed @<:@default=check@:>@])],
 244             [],[with_typelibdir=check])
 245 AS_IF([test "x${with_typelibdir}" = "xcheck"],
 246       [NTD_UNEXPAND([gobject-introspection-1.0],
 247                     [typelibdir],
 248                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 249 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 250 AM_COND_IF([HAVE_INTROSPECTION],
 251            [enable_introspection='yes'
 252             report_introspection="
 253          Where to install gir files: ${with_girdir}
 254  Where to install the typelib files: ${with_typelibdir}"],
 255            [enable_introspection='no'
 256             report_introspection=""])
 257
 258 dnl GLib test framework
 259 AC_ARG_ENABLE([test_framework],
 260               [AS_HELP_STRING([--enable-test-framework],
 261                               [enable GLib test framework @<:@default=check@:>@])],
 262               [],[enable_test_framework=check])
 263 AS_IF([test "x${enable_test_framework}" != "xno"],
 264       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 265                         [enable_test_framework=yes],
 266                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 267                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 268                                [enable_test_framework=no])])])
 269 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 270
 271
 272 # Check for compiler characteristics
 273
 274 AC_C_CONST
 275
 276
 277 # Additional substitutions
 278
 279 DLLDIR="$(${PKG_CONFIG} --variable=prefix gobject-2.0)/bin"
 280 CPML_REQUIRES='cairo >= cairo_prereq'
 281 AM_COND_IF([HAVE_PANGO],
 282       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 283        ADG_H_ADDITIONAL='
 284 #include <pango/pango.h>
 285 #include "adg/adg-text.h"
 286 #include "adg/adg-pango-style.h"
 287 '],
 288       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 289        ADG_H_ADDITIONAL=''])
 290 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 291 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 292 AM_COND_IF([HAVE_GTK],
 293            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 294 #include <gtk/gtk.h>
 295 #include \"adg/adg-gtk-utils.h\"
 296 #include \"adg/adg-gtk-area.h\"
 297 #include \"adg/adg-gtk-layout.h\"
 298 "
 299             ADG_CANVAS_H_ADDITIONAL='
 300 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 301                                                  const gchar    *paper_name,
 302                                                  GtkPageOrientation orientation);
 303 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 304                                                  GtkPageSetup   *page_setup);
 305 '],
 306            [ADG_CANVAS_H_ADDITIONAL=''])
 307
 308 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 309 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 310 AC_SUBST([CPML_REQUIRES])
 311 AC_SUBST([ADG_API_VERSION],adg_api_version)
 312 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 313 AC_SUBST([ADG_REQUIRES])
 314 AC_SUBST([ADG_H_ADDITIONAL])
 315 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 316 AC_SUBST([DLLDIR])
 317
 318 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 319 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 320 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 321 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 322 AM_SUBST_NOTMAKE([DLLDIR])
 323
 324
 325 # Generation
 326
 327 AC_CONFIG_FILES([build/adg.nsi
 328                  Makefile
 329                  src/Makefile
 330                  src/cpml/cpml-1.pc
 331                  src/cpml/Makefile
 332                  src/cpml/tests/Makefile
 333                  src/adg/adg-1.pc
 334                  src/adg.h
 335                  src/adg/Makefile
 336                  src/adg/adg-canvas.h
 337                  src/adg/tests/Makefile
 338                  demo/Makefile
 339                  demo/cpml-demo.ui
 340                  demo/adg-demo.ui
 341                  po/Makefile.in
 342                  po-properties/Makefile.in
 343                  docs/Makefile
 344                  docs/cpml/Makefile
 345                  docs/cpml/bookinfo.xml
 346                  docs/adg/Makefile
 347                  docs/adg/bookinfo.xml])
 348 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 349 AC_OUTPUT
 350
 351
 352 # Report
 353
 354 AC_MSG_NOTICE([generating report
 355
 356 AC_PACKAGE_NAME adg_version will be built with the following options:
 357 ----------------------------------------------------------
 358                   API compatibility: adg_api_version
 359                 CPML library to use: internal (cpml-adg_version)
 360          Build pango based entities: ${enable_pango}
 361                        GTK+ support: ${with_gtk}
 362              Install glade catalogs: ${enable_glade}${report_glade}
 363                 Build API reference: ${enable_gtk_doc}
 364              GObject instrospection: ${enable_introspection}${report_introspection}
 365              Test framework support: ${enable_test_framework}
 366 ])