configure.ac

   1 m4_define([adg_version],[0.7.0])
   2 m4_define([adg_api_version],[1.0])
   3 m4_define([adg_lt_version],[2:0:0])
   4
   5 m4_define([cpml_version],adg_version)
   6 m4_define([cpml_api_version],adg_api_version)
   7 m4_define([cpml_lt_version],[1:1:0])
   8
   9 m4_define([gtkdoc_prereq],[1.12])dnl Support introspection annotations
  10 m4_define([gobject_prereq],[2.10.1])
  11 m4_define([cairo_prereq],[1.7.4])
  12 m4_define([cairo_gobject_prereq],cairo_prereq)
  13 m4_define([gtk2_prereq],[2.12.0])
  14 m4_define([gtk3_prereq],[3.0.0])
  15 m4_define([pangocairo_prereq],[1.18.0])
  16 m4_define([gi_prereq],[0.9.5])dnl Picked up from clutter
  17
  18
  19 # Initialization
  20
  21 dnl autoconf 2.62 is required by GObject introspection:
  22 dnl http://live.gnome.org/GObjectIntrospection/AutotoolsIntegration
  23 AC_PREREQ([2.62])
  24 AC_INIT([adg-1],adg_version,[http://dev.entidi.com/p/adg/],[adg],[http://adg.entidi.com/])
  25 AC_CONFIG_SRCDIR([configure.ac])
  26 AC_CONFIG_HEADERS([src/config.h])
  27 AC_CONFIG_AUX_DIR([build])
  28 AC_CONFIG_MACRO_DIR([build])
  29 AM_INIT_AUTOMAKE([1.10 gnits no-dist-gzip dist-bzip2 -Wall -Wno-portability])
  30
  31 dnl m4 backward compatibility stuff
  32 m4_ifdef([AM_SILENT_RULES],
  33          [AM_SILENT_RULES([yes])],
  34          [AC_SUBST([AM_V_GEN],[])])
  35 m4_ifdef([AM_SUBST_NOTMAKE],[],
  36          [AC_DEFUN([AM_SUBST_NOTMAKE],[_AM_SUBST_NOTMAKE($@)])])
  37 m4_ifdef([AM_COND_IF],[],
  38          [AC_DEFUN([AM_COND_IF],
  39                    [AS_IF([test -z "$$1_TRUE"],[$2],[$3])])])
  40
  41
  42 # Check for host information
  43
  44 AC_CANONICAL_HOST
  45 case "${host}" in
  46   *-*-linux*)
  47     guessed_host=linux
  48     ;;
  49   *-*-freebsd*)
  50     guessed_host=freebsd
  51     ;;
  52   *-*-mingw*)
  53     guessed_host=mingw
  54     ;;
  55   *-*-solaris*)
  56     guessed_host=solaris
  57     ;;
  58   *-*-darwin*)
  59     guessed_host=darwin
  60     ;;
  61   *-*-beos*)
  62     guessed_host=beos
  63     ;;
  64   *-*-cygwin*)
  65     guessed_host=cygwin
  66     ;;
  67   *-*-minix*)
  68     guessed_host=minix
  69     ;;
  70   *-*-aix*)
  71     guessed_host=aix
  72     ;;
  73   *)
  74     guessed_host=unknown
  75     ;;
  76 esac
  77 AM_CONDITIONAL([OS_UNIX],[test "${guessed_host}" != "mingw"])
  78 AM_CONDITIONAL([OS_WINDOWS],[test "${guessed_host}" = "mingw" -o "${guessed_host}" = "cygwin"])
  79
  80
  81 # Check for programs
  82
  83 AC_PROG_CC
  84 AC_PROG_SED
  85 PKG_PROG_PKG_CONFIG
  86 AC_PATH_PROG([XSLTPROC],[xsltproc],[/usr/bin/xsltproc])
  87 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums],[/usr/bin/glib-mkenums])
  88 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal],[/usr/bin/glib-genmarshal])
  89 AC_PATH_PROG([GTESTER],[gtester],[/usr/bin/gtester])
  90 AC_PATH_PROG([GTESTER_REPORT],[gtester-report],[/usr/bin/gtester-report])
  91 AC_PATH_PROG([GLADE3],[glade-3],[/usr/bin/glade-3])
  92 AM_COND_IF([OS_WINDOWS],
  93            [AC_PATH_PROG([MAKENSIS],[makensis],[/usr/bin/makensis])
  94             AC_PATH_PROG([WINE],[wine])])
  95
  96
  97 # Check for libraries
  98
  99 AC_CHECK_LIB([m],[cos])
 100
 101
 102 # Libtool initialization
 103
 104 AC_MSG_CHECKING([which libtool initialization strategy to adopt])
 105 AC_MSG_RESULT([m4_ifset([LT_INIT],[LT-INIT],[AC-PROG-LIBTOOL])])
 106 m4_ifset([LT_INIT],
 107          [LT_INIT([disable-static win32-dll])],
 108          [AC_DISABLE_STATIC
 109           AC_LIBTOOL_WIN32_DLL
 110           AC_PROG_LIBTOOL])
 111
 112
 113 # I18n
 114
 115 AC_SUBST([ADG_API_PACKAGE],AC_PACKAGE_TARNAME-adg_api_version)
 116 AC_SUBST([GETTEXT_PACKAGE],[${ADG_API_PACKAGE}])
 117 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${ADG_API_PACKAGE}"],
 118                    [Define to the domain used by gettext.])
 119 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 120 IT_PROG_INTLTOOL(0.40.1)
 121 AM_GLIB_GNU_GETTEXT
 122 GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 123 AC_CONFIG_COMMANDS([default],
 124                    [case "${CONFIG_FILES}" in *po-properties/Makefile.in*)
 125         ${SED} -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 126     esac],
 127                    [SED="${SED}"])
 128
 129
 130 # Check for required packages
 131
 132 PKG_CHECK_MODULES([GLIB],[glib-2.0])
 133 PKG_CHECK_MODULES([GOBJECT],[gobject-2.0 >= ]gobject_prereq)
 134 PKG_CHECK_MODULES([CAIRO],[cairo >= ]cairo_prereq)
 135 PKG_CHECK_MODULES([CAIRO_GOBJECT],[cairo-gobject >= ]cairo_gobject_prereq)
 136
 137
 138 # Check for optional packages
 139
 140 dnl PangoCairo
 141 AC_ARG_ENABLE([pango],
 142               [AS_HELP_STRING([--enable-pango],
 143                               [use pango for rendering text @<:@default=check@:>@])],
 144               [],[enable_pango=check])
 145 AS_IF([test "x${enable_pango}" != "xno"],
 146       [PKG_CHECK_MODULES([PANGO],[pangocairo >= ]pangocairo_prereq,
 147                          [enable_pango=yes
 148                           AC_DEFINE_UNQUOTED([PANGO_ENABLED],[1],
 149                                              [Defined if the pango support is enabled.])],
 150                          [AS_IF([test "x${enable_pango}" = "xyes"],
 151                                 [AC_MSG_ERROR([${PANGO_PKG_ERRORS} and pango support requested])],
 152                                 [enable_pango=no])])])
 153 AM_CONDITIONAL([HAVE_PANGO],[test "x${enable_pango}" = "xyes"])
 154
 155 dnl GTK+ support
 156 AC_ARG_WITH(gtk,
 157             [AS_HELP_STRING([--with-gtk@<:@=gtk2/gtk3@:>@],
 158                             [include GTK+ specific widgets @<:@default=check@:>@])],
 159             [],[with_gtk=check])
 160 AS_CASE(["${with_gtk}"],
 161         [gtk2],      [gtk2_pkg=yes; gtk3_pkg=no],
 162         [gtk3],      [gtk2_pkg=no;  gtk3_pkg=yes],
 163         [check|yes], [gtk2_pkg=yes; gtk3_pkg=yes],
 164         [no],        [gtk2_pkg=no;  gtk3_pkg=no],
 165         [AC_MSG_ERROR([Invalid option passed to --with-gtk])])
 166
 167 # GTK+ autodetection, giving precedence to GTK+3
 168 AS_IF([test "x${gtk3_pkg}" = "xyes"],
 169       [PKG_CHECK_MODULES([GTK3],[gtk+-3.0 >= ]gtk3_prereq,[gtk_pkg=gtk3],[:])])
 170 AS_IF([test "x${gtk2_pkg}" = "xyes" -a "x${gtk_pkg}" = "x"],
 171       [PKG_CHECK_MODULES([GTK2],[gtk+-2.0 >= ]gtk2_prereq,[gtk_pkg=gtk2],[:])])
 172 AS_IF([test "x${gtk_pkg}" != "x"],[with_gtk=${gtk_pkg}])
 173
 174
 175 # Handle "check" graceful degradation
 176 AS_IF([test "x${with_gtk}" = "xcheck"],[with_gtk=no])
 177
 178 # Handle failures
 179 AS_IF([test "x${with_gtk}" != "xno" -a "x${gtk_pkg}" = "x"],
 180       [AC_MSG_ERROR([GTK+ support explicitely required but no valid GTK+ found])])
 181
 182 AS_IF([test "x${with_gtk}" = "xgtk3"],
 183       [AC_DEFINE_UNQUOTED([GTK3_ENABLED],[1],
 184                           [Defined if the GTK+3 support is enabled.])])
 185 AS_IF([test "x${with_gtk}" = "xgtk2"],
 186       [AC_DEFINE_UNQUOTED([GTK2_ENABLED],[1],
 187                           [Defined if the GTK+2 support is enabled.])])
 188
 189 AM_CONDITIONAL([HAVE_GTK], [test "x${with_gtk}" != "xno"])
 190 AM_CONDITIONAL([HAVE_GTK2],[test "x${with_gtk}" = "xgtk2"])
 191 AM_CONDITIONAL([HAVE_GTK3],[test "x${with_gtk}" = "xgtk3"])
 192
 193 dnl Glade catalog dir
 194 AC_ARG_WITH(glade_catalogdir,
 195             [AS_HELP_STRING([--with-glade-catalogdir@<:@=DIR@:>@],
 196                             [where to install the glade catalogs @<:@default=check@:>@])],
 197             [],[with_glade_catalogdir=check])
 198
 199 # Both "check" and "yes" mean gladeui autodetection,
 200 # but "yes" will fail on gladeui not found
 201 AS_IF([test "x${with_glade_catalogdir}" = "xcheck" -o "x${with_glade_catalogdir}" = "xyes"],
 202       [glade_pkg=check])
 203
 204 # gladeui autodetection, giving precedence to gladeui-2.0 if possible
 205 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_gtk}" != "xgtk2"],
 206       [PKG_CHECK_MODULES([GLADEUI2],[gladeui-2.0],[glade_pkg=gladeui-2.0],[:])])
 207 AS_IF([test "x${glade_pkg}" = "xcheck"],
 208       [PKG_CHECK_MODULES([GLADEUI1],[gladeui-1.0],[glade_pkg=gladeui-1.0],[:])])
 209 AS_IF([test "x${glade_pkg}" != "x" -a "x${glade_pkg}" != "xcheck"],
 210       [NTD_UNEXPAND([${glade_pkg}],
 211                     [catalogdir],
 212                     [with_glade_catalogdir="${NTD_UNEXPANDED}"],
 213                     [AC_MSG_ERROR([${glade_pkg} found but pkg-config file invalid])])])
 214
 215 # Handle "yes" failure
 216 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xyes"],
 217       [AC_MSG_ERROR([Glade support explicitely required but no valid gladeui found])])
 218
 219 # Handle "check" graceful degradation
 220 AS_IF([test "x${glade_pkg}" = "xcheck" -a "x${with_glade_catalogdir}" = "xcheck"],
 221       [with_glade_catalogdir=no])
 222
 223 AM_CONDITIONAL([HAVE_GLADE],[test "x${with_glade_catalogdir}" != "xno"])
 224 AM_COND_IF([HAVE_GLADE],
 225            [enable_glade=yes
 226             report_glade="
 227                   Glade catalog dir: ${with_glade_catalogdir}"],
 228            [enable_glade=no
 229             report_glade=""])
 230 AC_SUBST([GLADE_CATALOGDIR],${with_glade_catalogdir})
 231
 232 dnl gtk-doc
 233 GTK_DOC_CHECK(gtkdoc_prereq)
 234
 235 dnl GObject introspection
 236 GOBJECT_INTROSPECTION_CHECK(gi_prereq)
 237 AC_ARG_WITH(girdir,
 238             [AS_HELP_STRING([--with-girdir=DIR],
 239                             [where the gir files are installed @<:@default=check@:>@])],
 240             [],[with_girdir=check])
 241 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_girdir}" = "xcheck"],
 242       [NTD_UNEXPAND([gobject-introspection-1.0],
 243                     [girdir],
 244                     [with_girdir="${NTD_UNEXPANDED}"])])
 245 AC_SUBST([GIRDIR],${with_girdir})
 246 AC_ARG_WITH(typelibdir,
 247             [AS_HELP_STRING([--with-typelibdir=DIR],
 248                             [where the typelib files are installed @<:@default=check@:>@])],
 249             [],[with_typelibdir=check])
 250 AS_IF([test "x${enable_introspection}" = "xyes" -a "x${with_typelibdir}" = "xcheck"],
 251       [NTD_UNEXPAND([gobject-introspection-1.0],
 252                     [typelibdir],
 253                     [with_typelibdir="${NTD_UNEXPANDED}"])])
 254 AC_SUBST([TYPELIBDIR],${with_typelibdir})
 255 AM_COND_IF([HAVE_INTROSPECTION],
 256            [report_introspection="
 257          Where to install gir files: ${with_girdir}
 258  Where to install the typelib files: ${with_typelibdir}"],
 259            [report_introspection=""])
 260
 261 dnl GLib test framework
 262 AC_ARG_ENABLE([test_framework],
 263               [AS_HELP_STRING([--enable-test-framework],
 264                               [enable GLib test framework @<:@default=check@:>@])],
 265               [],[enable_test_framework=check])
 266 AS_IF([test "x${enable_test_framework}" != "xno"],
 267       [PKG_CHECK_EXISTS([glib-2.0 >= 2.16.0],
 268                         [enable_test_framework=yes],
 269                         [AS_IF([test "x${enable_test_framework}" = "xyes"],
 270                                [AC_MSG_ERROR([The test framework needs glib2-2.16.0 or later])],
 271                                [enable_test_framework=no])])])
 272 AM_CONDITIONAL([HAVE_TEST_FRAMEWORK],[test "x${enable_test_framework}" = "xyes"])
 273
 274
 275 # Check for compiler characteristics
 276
 277 AC_C_CONST
 278
 279
 280 # Windows substitutions for NSis installer
 281
 282 dnl By default DLLDIR is set to "$prefix/bin", with "$prefix" got from
 283 dnl gobject-2.0.pc: all the DLLs *must* be under the same directory.
 284 AC_ARG_VAR([DLLDIR], Place where Windows DLLs must be picked from)
 285 AS_IF([test -z "$DLLDIR"],
 286       [DLLDIR="$($PKG_CONFIG --variable=prefix gobject-2.0)/bin"])
 287 AM_SUBST_NOTMAKE([DLLDIR])
 288
 289 dnl -win$ARCH will be appended to the installer file name
 290 AS_IF([test "x${host_cpu}" = "xx86_64"],[ARCH=64],[ARCH=32])
 291 AC_SUBST([ARCH])
 292 AM_SUBST_NOTMAKE([ARCH])
 293
 294
 295 # Additional substitutions
 296
 297 dnl The GObject dependency can be made optional by skipping
 298 dnl the building of the GObject wrappers.
 299 CPML_REQUIRES='cairo >= cairo_prereq gobject >= gobject_prereq'
 300 AM_COND_IF([HAVE_PANGO],
 301       [ADG_REQUIRES='pangocairo >= pangocairo_prereq'
 302        ADG_H_ADDITIONAL='
 303 #include <pango/pango.h>
 304 #include "adg/adg-text.h"
 305 #include "adg/adg-pango-style.h"
 306 '],
 307       [ADG_REQUIRES='gobject-2.0 >= gobject_prereq'
 308        ADG_H_ADDITIONAL=''])
 309 AM_COND_IF([HAVE_GTK3],[ADG_REQUIRES='gtk+-3.0 >= gtk3_prereq'])
 310 AM_COND_IF([HAVE_GTK2],[ADG_REQUIRES='gtk+-2.0 >= gtk2_prereq'])
 311 AM_COND_IF([HAVE_GTK],
 312            [ADG_H_ADDITIONAL="${ADG_H_ADDITIONAL}
 313 #include <gtk/gtk.h>
 314 #include \"adg/adg-gtk-utils.h\"
 315 #include \"adg/adg-gtk-area.h\"
 316 #include \"adg/adg-gtk-layout.h\"
 317 "
 318             ADG_CANVAS_H_ADDITIONAL='
 319 #include <gtk/gtk.h>
 320
 321 void            adg_canvas_set_paper            (AdgCanvas      *canvas,
 322                                                  const gchar    *paper_name,
 323                                                  GtkPageOrientation orientation);
 324 void            adg_canvas_set_page_setup       (AdgCanvas      *canvas,
 325                                                  GtkPageSetup   *page_setup);
 326 '],
 327            [ADG_CANVAS_H_ADDITIONAL=''])
 328
 329 AC_SUBST([CPML_API_VERSION],cpml_api_version)
 330 AC_SUBST([CPML_LT_VERSION],cpml_lt_version)
 331 AC_SUBST([CPML_REQUIRES])
 332 AC_SUBST([ADG_API_VERSION],adg_api_version)
 333 AC_SUBST([ADG_LT_VERSION],adg_lt_version)
 334 AC_SUBST([ADG_REQUIRES])
 335 AC_SUBST([ADG_H_ADDITIONAL])
 336 AC_SUBST([ADG_CANVAS_H_ADDITIONAL])
 337
 338 AM_SUBST_NOTMAKE([CPML_REQUIRES])
 339 AM_SUBST_NOTMAKE([ADG_REQUIRES])
 340 AM_SUBST_NOTMAKE([ADG_H_ADDITIONAL])
 341 AM_SUBST_NOTMAKE([ADG_CANVAS_H_ADDITIONAL])
 342
 343 dnl CPML compiler flags and library dependencies
 344 CPML_CFLAGS="$CAIRO_CFLAGS $GOBJECT_CFLAGS"
 345 CPML_LIBS="$CAIRO_LIBS $GOBJECT_LIBS"
 346 AC_SUBST([CPML_CFLAGS])
 347 AC_SUBST([CPML_LIBS])
 348
 349 dnl ADG compiler flags and library dependencies
 350 ADG_CFLAGS="$CAIRO_GOBJECT_CFLAGS"
 351 ADG_LIBS="$CAIRO_GOBJECT_LIBS"
 352 AM_COND_IF([HAVE_PANGO],
 353            [ADG_CFLAGS="$PANGO_CFLAGS $ADG_CFLAGS"
 354             ADG_LIBS="$PANGO_LIBS $ADG_LIBS"])
 355 AM_COND_IF([HAVE_GTK2],
 356            [ADG_CFLAGS="$GTK2_CFLAGS $ADG_CFLAGS"
 357             ADG_LIBS="$GTK2_LIBS $ADG_LIBS"])
 358 AM_COND_IF([HAVE_GTK3],
 359            [ADG_CFLAGS="$GTK3_CFLAGS $ADG_CFLAGS"
 360             ADG_LIBS="$GTK3_LIBS $ADG_LIBS"])
 361 AC_SUBST([ADG_CFLAGS])
 362 AC_SUBST([ADG_LIBS])
 363
 364
 365 # Generation
 366
 367 AC_CONFIG_FILES([build/adg.nsi
 368                  Makefile
 369                  src/Makefile
 370                  src/cpml/cpml-1.pc
 371                  src/cpml/Makefile
 372                  src/cpml/tests/Makefile
 373                  src/adg/adg-1.pc
 374                  src/adg.h
 375                  src/adg/Makefile
 376                  src/adg/adg-canvas.h
 377                  src/adg/tests/Makefile
 378                  demo/Makefile
 379                  demo/cpml-demo.ui
 380                  demo/adg-demo.ui
 381                  po/Makefile.in
 382                  po-properties/Makefile.in
 383                  docs/Makefile
 384                  docs/cpml/Makefile
 385                  docs/cpml/bookinfo.xml
 386                  docs/adg/Makefile
 387                  docs/adg/bookinfo.xml])
 388 AC_CONFIG_FILES([demo/adg-glade],[chmod +x demo/adg-glade])
 389 AC_OUTPUT
 390
 391
 392 # Report
 393
 394 AC_MSG_NOTICE([generating report
 395
 396 AC_PACKAGE_NAME adg_version will be built with the following options:
 397 ----------------------------------------------------------
 398                   API compatibility: adg_api_version
 399                 CPML library to use: internal (cpml-adg_version)
 400          Build pango based entities: ${enable_pango}
 401                        GTK+ support: ${with_gtk}
 402              Install glade catalogs: ${enable_glade}${report_glade}
 403                 Build API reference: ${enable_gtk_doc}
 404              GObject instrospection: ${enable_introspection}${report_introspection}
 405              Test framework support: ${enable_test_framework}
 406 ])