bin/wtscript2json.pl

   1 #! perl
   2
   3 use strict;
   4 use warnings;
   5
   6 # PODNAME: wtscript2json
   7 # ABSTRACT: convert read configuration into JSON
   8
   9 use v5.10.1;
  10
  11 use File::Slurp qw(write_file);
  12 use Getopt::Long;
  13 use JSON ();
  14 use List::MoreUtils qw(zip);
  15 use Params::Util qw(_ARRAY);
  16 use Pod::Usage;
  17
  18 use WWW::Mechanize::Script::Util qw(:ALL);
  19 use WWW::Mechanize::Script;
  20
  21 our $VERSION = '0.001_003';
  22 my %opts = (
  23              "input-files"    => [],
  24              "output-files"   => [],
  25              "output-pattern" => []
  26            );
  27 my @options = (
  28                 "input-files=s@"      => $opts{"input-files"},
  29                 "output-files=s@"     => $opts{"output-files"},
  30                 "output-pattern=s{2}" => $opts{"output-pattern"},
  31                 "help|h", "usage|?"
  32               );
  33
  34 GetOptions( \%opts, @options ) or pod2usage(2);
  35
  36 # clean-up defaults
  37 @{ $opts{"input-files"} }    or delete $opts{"input-files"};
  38 @{ $opts{"output-files"} }   or delete $opts{"output-files"};
  39 @{ $opts{"output-pattern"} } or delete $opts{"output-pattern"};
  40
  41 # check ...
  42 defined( $opts{help} )
  43   and $opts{help}
  44   and pod2usage(
  45                  {
  46                    -verbose => 2,
  47                    -exitval => 0
  48                  }
  49                );
  50 defined( $opts{usage} ) and $opts{usage} and pod2usage(1);
  51 opt_required_all( \%opts, qw(input-files) );
  52 opt_exclusive( \%opts, qw(output-files output-pattern) );
  53 opt_required_one( \%opts, qw(output-files output-pattern) );
  54 _ARRAY( $opts{"input-files"} )
  55   and _ARRAY( $opts{"output-files"} )
  56   and scalar( @{ $opts{"input-files"} } ) != scalar( @{ $opts{"output-files"} } )
  57   and pod2usage(
  58                  {
  59                    -message => "Count of --input-files and --output-files doesn't match",
  60                    -exitval => 1
  61                  }
  62                );
  63
  64 my %in2out =
  65     _ARRAY( $opts{"output-files"} )
  66   ? zip( @{ $opts{"input-files"} }, @{ $opts{"output-files"} } )
  67   : ();
  68 my %cfg = load_config();
  69
  70 my $coder = JSON->new();
  71 _ARRAY( $cfg{wtscript_extensions} )
  72   and Config::Any::WTScript->extensions( @{ $cfg{wtscript_extensions} } );
  73 foreach my $filename ( @{ $opts{"input-files"} } )
  74 {
  75     my @script_files = find_scripts( \%cfg, $filename );
  76     my $scripts = Config::Any->load_files(
  77                                            {
  78                                              files           => [@script_files],
  79                                              use_ext         => 1,
  80                                              flatten_to_hash => 1,
  81                                            }
  82                                          );
  83     if ( $opts{"output-files"} )
  84     {
  85         @script_files = keys %{$scripts};
  86         scalar(@script_files) > 1
  87           and pod2usage(
  88                    {
  89                      -message => "filename $filename is ambigious: " . join( ", ", @script_files ),
  90                      -exitval => 1
  91                    }
  92           );
  93         scalar(@script_files) < 1
  94           and next;    # file not found or not parsable ...
  95                        # merge into default and previous loaded config ...
  96         my $json = $coder->pretty->encode( $scripts->{ $script_files[0] } );
  97         write_file( $in2out{$filename}, $json );
  98     }
  99     else
 100     {
 101         while ( my ( $script_file, $script ) = each(%$scripts) )
 102         {
 103             my $json = $coder->pretty->encode($script);
 104             ( my $target = $script_file ) =~
 105               s/$opts{"output-pattern"}->[0]/$opts{"output-pattern"}->[1]/;
 106             write_file( $target, $json );
 107         }
 108     }
 109 }
 110
 111 __END__
 112