readme: update FAQ link
[siplcs.git] / configure.ac
blobe9cb26b829f2cfedf6686120c39062367757f62a
1 dnl ensure recent enough version of Autoconf
2 AC_PREREQ([2.50])
4 dnl Use 'VERSION' files to get version.
5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
7 dnl Strip off newline characters.
8 m4_define([SIPE_VERSION],
9         m4_substr(SIPE_VERSION_DATA,
10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
12 dnl homepage
13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
15 dnl initialize package name, version, bugtracker & homepage
16 AC_INIT([pidgin-sipe], SIPE_VERSION,
17         [https://sourceforge.net/p/sipe/bugs/], [],
18         SIPE_HOMEPAGE)
20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
22         [URL for submitting translations.])
24 dnl define optional git commit ID generated by autogen.sh
25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
27         [AC_MSG_NOTICE([set git commit])
28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
31 dnl setup automake and require recent enough version
32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
34 AC_CANONICAL_HOST
36 dnl set PACKAGE_URL for autoconf < 2.64
37 AS_IF([test "x${PACKAGE_URL}" = x],
38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
42 dnl set programming language
43 AC_LANG(C)
44 AM_PROG_CC_C_O
45 AC_HEADER_STDC
47 dnl setup shared library generation
48 LT_INIT([disable-static])
50 dnl checks for tools
51 IT_PROG_INTLTOOL([0.35.0])
52 AC_PROG_INSTALL
53 AC_PROG_RANLIB
55 dnl ******************************
56 dnl Win32
57 dnl ******************************
58 AC_MSG_CHECKING([for Win32])
59 AS_CASE(["$host"],
60                 [*-mingw*], [os_win32=yes],
61                 [os_win32=no])
62 AC_MSG_RESULT([$os_win32])
63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
65 dnl checks for header files
66 AC_CHECK_HEADERS([])
68 dnl checks for library functions
69 AC_CHECK_FUNCS([])
71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
72 dnl as that is likely where libpurple will be found if it is not in the default
73 dnl pkgconfig path
74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
75 export PKG_CONFIG_PATH
77 dnl debug mode
78 AC_ARG_ENABLE(debug,
79         [AS_HELP_STRING([--enable-debug],
80                         [compile with debugging support @<:@default=no@:>@])],
81         [],
82         [enable_debug=no])
84 AS_IF([test "x$enable_debug" = xyes],
85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
86 AC_SUBST(DEBUG_CFLAGS)
88 dnl quality check mode
89 dnl For people who are interested in finding bugs and not hiding them
90 AC_ARG_ENABLE(quality-check,
91         [AS_HELP_STRING([--enable-quality-check],
92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
93         [],
94         [enable_quality_check=yes])
96 AS_IF([test "x$enable_quality_check" = xyes],
97         [dnl default quality configuration
98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
100          dnl enable warnings supported by the GCC on the build system
101          for newflag in \
102                         "-Wextra" \
103                         "-Waggregate-return" \
104                         "-Wcast-align" \
105                         "-Wcast-function-type" \
106                         "-Wdeclaration-after-statement" \
107                         "-Wdeprecated-declarations" \
108                         "-Wduplicate-decl-specifier" \
109                         "-Winit-self" \
110                         "-Wmaybe-uninitialized" \
111                         "-Wmissing-declarations" \
112                         "-Wmissing-prototypes" \
113                         "-Wnested-externs" \
114                         "-Wpointer-arith" \
115                         "-Wundef" \
116                         "-Wunused-but-set-variable" \
117          ; do
118                  ac_save_CFLAGS="$CFLAGS"
119                  AC_MSG_CHECKING([if $CC supports $newflag])
120                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
121                  AC_COMPILE_IFELSE(
122                         [AC_LANG_SOURCE([[]])],
123                         [AC_MSG_RESULT(yes)
124                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
125                         [AC_MSG_RESULT(no)]
126                  )
127                  CFLAGS="$ac_save_CFLAGS"
128          done
129         ])
130 AC_SUBST(QUALITY_CFLAGS)
132 dnl check for availability of addition linker flags
133 for newflag in \
134         "-Wl,-Bsymbolic-functions" \
135 ; do
136         ac_save_LDFLAGS="$LDFLAGS"
137         AC_MSG_CHECKING([if $CC supports $newflag])
138         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
139         AC_LINK_IFELSE(
140                 [AC_LANG_SOURCE([[
141 int main(int argc, char *argv[])
143         return(0);
145                  ]])],
146                 [AC_MSG_RESULT(yes)
147                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
148                 [AC_MSG_RESULT(no)]
149         )
150         LDFLAGS="$ac_save_LDFLAGS"
151 done
152 AC_SUBST(ADDITIONAL_LDFLAGS)
154 dnl Check for pkg-config before using it
155 PKG_PROG_PKG_CONFIG
157 dnl check for valgrind (optional, only needed for debugging)
158 PKG_CHECK_MODULES(VALGRIND, [valgrind],
159         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
160         [AC_MSG_RESULT(no)])
162 dnl build option: with AppStream support
163 AC_ARG_WITH(appstream,
164         [AC_HELP_STRING([--with-appstream],
165                 [install AppStream XML file @<:@default=yes@:>@])],
166         [AS_IF([test "x$withval" = xno], [with_appstream=no])],
167         [with_appstream=yes])
168 AM_CONDITIONAL(SIPE_WITH_APPSTREAM, [test "x$with_appstream" != xno])
170 dnl build option: with voice & video support (for all backends)
171 AC_ARG_WITH(vv,
172         [AC_HELP_STRING([--with-vv],
173                 [compile with voice and video support @<:@default=check@:>@])],
174         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
175         [with_vv=check])
177 dnl check for Kerberos 5 support
178 AC_ARG_WITH([krb5],
179         [AC_HELP_STRING([--with-krb5],
180                 [compile with Kerberos 5 support @<:@default=check@:>@])],
181         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
182         [with_krb5=check])
184 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
185       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
186         [AC_MSG_CHECKING(if Kerberos 5 is available)
187          AS_IF([AC_RUN_LOG([krb5-config --version])],
188                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
189                  KRB5_LDFLAGS=""
191                  dnl same as AC_CHECK_LIB()
192                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
193                 [AC_MSG_RESULT(no)
194                  with_krb5=no])],
195       [                               dnl path specified by user
196         KRB5_CFLAGS="-I${with_krb5}/include"
197         KRB5_LDFLAGS="-L${with_krb5}/lib"
198       ])
199 AS_IF([test "x$with_krb5" != xno],
200       [ac_save_CFLAGS="$CFLAGS"
201        ac_save_LDFLAGS="$LDFLAGS"
202        CFLAGS="$CFLAGS $KRB5_CFLAGS"
203        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
204        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
205                         [],
206                         [AC_ERROR([GSSAPI headers not found])])
207        AC_CHECK_FUNC([gss_init_sec_context],
208                      [],
209                      [AC_ERROR([GSSAPI libraries not found])])
211        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
212        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
213                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
214                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
215                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
216                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
218        CFLAGS="$ac_save_CFLAGS"
219        LDFLAGS="$ac_save_LDFLAGS"
220       ])
222 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
223 AC_SUBST(KRB5_CFLAGS)
224 AC_SUBST(KRB5_LDFLAGS)
226 dnl check for DBUS support
227 AC_ARG_WITH([dbus],
228         [AC_HELP_STRING([--with-dbus],
229                 [compile with D-BUS support @<:@default=check@:>@])],
230         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
231         [with_dbus=check])
233 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
234       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
235         [PKG_CHECK_MODULES(DBUS, [dbus-1],
236                 [with_dbus=yes],
237                 [with_dbus=no])
238         ])
239 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
240 AS_IF([test "x$with_dbus" = xyes],
241         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
243 AC_ARG_ENABLE(gssapi_only,
244         [AS_HELP_STRING([--enable-gssapi-only],
245                         [disable all internal authentication code and only use
246                          GSSAPI for authentication @<:@default=yes@:>@])],
247         [],
248         dnl requires Kerberos which provides GSSAPI
249         [enable_gssapi_only=$with_krb5])
250 AS_IF([test "x$enable_gssapi_only" != xno],
251         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
252                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
253                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
254                         enable_gssapi_only=no])
255         ])
256 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
258 dnl check for glib
259 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
260 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
262 dnl check for gmime
263 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
264         [ac_have_gmime=yes],
265         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
266                 [ac_have_gmime=yes],
267                 [ac_have_gmime=no])
268         ])
269 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
270 AS_IF([test "x$ac_have_gmime" = xyes],
271         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
273 dnl check for NSS
274 AC_ARG_ENABLE(nss,
275         [AS_HELP_STRING([--enable-nss],
276                         [use NSS as crypto backend @<:@default=yes@:>@])],
277         [],
278         [enable_nss=yes])
279 AS_IF([test "x$enable_nss" != xno],
280         [PKG_CHECK_MODULES(NSS, [nss],
281                 [],
282                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
283                         [],
284                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
285                                 [],
286                                 [enable_nss=no])
287                         ])
288                 ])
289         ])
291 dnl check for OpenSSL
292 AC_ARG_ENABLE(openssl,
293         [AS_HELP_STRING([--enable-openssl],
294                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
295         [],
296         [enable_openssl=yes])
297 AS_IF([test "x$enable_openssl" != xno],
298         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
299                    [],
300                    [enable_openssl=no])
301         ])
302 AS_IF(
303         [test "x$enable_nss" != xno],
304                 [ dnl NSS has priority over OpenSSL
305                   enable_openssl=no
306                   AC_MSG_NOTICE([using NSS as crypto backend.])],
307         [test "x$enable_openssl" != xno],
308                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
309         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
310 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
312 dnl check for libxml2
313 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
315 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
316 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
317 ac_save_CFLAGS="$CFLAGS"
318 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
319 dnl note the [[[ quoting: our code contains []!
320 AC_RUN_IFELSE(
321         [AC_LANG_PROGRAM(
322                 [[
323 #include <glib.h>
324 #include <stdio.h>
326 /* Copied from uuid.c */
327 typedef struct {
328    guint32 time_low;
329    guint16 time_mid;
330    guint16 time_hi_and_version;
331    guint8  clock_seq_hi_and_reserved;
332    guint8  clock_seq_low;
333    guint8  node[6];
334 } uuid_t;
335                 ]],
336                 [[if (sizeof(uuid_t) == 16) {
337                         return(0);
338                  } else {
339                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
340                         return(1);
341                  }]])],
342         [AC_MSG_RESULT(yes)],
343         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
345 Please notify the SIPE developers.
347 Copy & paste all lines starting with the line
349   checking that sizeof(uuid_t) is 16...
351 to the report and attach the file "config.log".
353 Compiler information:
355  host:     $host
356  build:    $build
357  compiler: $CC
358 ])],
359         [AC_MSG_WARN([cross compiling: not checking])])
360 CFLAGS="$ac_save_CFLAGS"
362 dnl build option: OCS2005 client hack
363 AC_ARG_ENABLE([ocs2005-message-hack],
364         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
365                                                           which causes "false" not delivered error messages
366                                                           @<:@default=no@:>@])],
367         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
368                    [Define to 1 to disable SIP MESSAGE timeout feature.
369                     OCS2005 clients don't seem to acknowledge MESSAGEs and
370                     disabling the timeout suppresses "false" error messages])])
372 dnl build option: purple backend
373 AC_ARG_ENABLE([purple],
374         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
375         [],
376         [enable_purple=yes])
377 ac_have_appshare=no
378 ac_have_xdata=no
379 with_purple_vv=no
380 AS_IF([test "x$enable_purple" != xno],
381         [PKG_CHECK_MODULES(PURPLE, [purple-3],
382                 [purple_pkgconfig=purple-3],
383                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
384                         [purple_pkgconfig=purple],
385                         [enable_purple=no])])
387          AS_IF([test "x$enable_purple" != xno],
388                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
390                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
391                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
392                  AC_SUBST(PURPLE_MAJOR_VERSION)
394                  ac_save_CFLAGS="$CFLAGS"
395                  ac_save_LIBS="$LIBS"
396                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
397                  LIBS="$LIBS $PURPLE_LIBS"
399                  dnl check whether enable voice and video support
400                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
401                        [AC_MSG_CHECKING(for purple voice and video support)
402                         purple_has_media=no
403                         AC_RUN_IFELSE(
404                                 [AC_LANG_PROGRAM([[
405 #include <media.h>
406                                         ]],
407                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
408                                 )],
409                                 [purple_has_media=yes
410                                  AC_MSG_RESULT(ok)
411                                 ],
412                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
413                                 [AS_IF([test "x$with_vv" = xyes],
414                                        [purple_has_media=yes
415                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
416                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
417                                 ]
418                         )
419                         AS_IF([test "x$purple_has_media" = xyes],
420                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
421                                         dnl sipe-media.c uses g_slist_free_full()
422                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
423                                                 dnl check purple pkgconfig for gstreamer version
424                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
425                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
426                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
427                                                                 [gstreamer_pkgconfig=1.0])])
428                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
429                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
431                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
432                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
433                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
434                                                                         [with_purple_vv=yes
436                                                                          AC_COMPILE_IFELSE(
437                                                                                  [AC_LANG_PROGRAM([[
438 #include <media.h>
439                                                                                         ]],
440                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
441                                                                                  )],
442                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
443                                                                         )],
444                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
445                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
446                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
447                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
448                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
449                                 ])
450                        ])
452                  dnl SRTP and XDATA require media backend
453                  AS_IF([test "x$with_purple_vv" != xno],
454                         [AC_LINK_IFELSE(
455                                 [AC_LANG_PROGRAM([[
456 #include <media.h>
457                                         ]],
458                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
459                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
460                                  )],
461                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
462                          )
464                          AC_COMPILE_IFELSE(
465                                 [AC_LANG_PROGRAM([[
466 #include <media.h>
467                                         ]],
468                                         [[return (PURPLE_MEDIA_APPLICATION);]]
469                                  )],
470                                  [dnl libpurple supports raw data RTP connections
471                                   ac_have_xdata=yes
473                                   dnl gio-2.0 is mandatory for application sharing support
474                                   PKG_CHECK_MODULES(GIO, [gio-2.0], [ac_have_appshare=yes])
475                                  ]
476                          )
477                         ],
478                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
479                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
480                          )]
481                  )
483                  CFLAGS="$ac_save_CFLAGS"
484                  LIBS="$ac_save_LIBS"])])
485 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
486 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
488 dnl build option: telepathy backend
489 AC_ARG_ENABLE([telepathy],
490         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
491         [],
492         [enable_telepathy=yes])
493 AS_IF([test "x$enable_telepathy" != xno],
494         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
495                 [dnl GMIME is a build requirement
496                  AS_IF([test "x$ac_have_gmime" = xyes],
497                         [],
498                         [AC_ERROR(GMIME package is required for telepathy plugin)])
500                  dnl telepathy is based on GObject & D-Bus GLib
501                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
502                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
504                  dnl telepathy uses from gio:
505                  dnl  - GIOStream      (>= 2.22.0)
506                  dnl  - GResolver      (>= 2.22.0)
507                  dnl  - GSocketClient  (>= 2.32.0)
508                  dnl  - GTlsConnection (>= 2.28.0)
509                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
511                 ],
512                 [enable_telepathy=no])])
513 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
515 dnl sanity check
516 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
517         [AC_ERROR(at least one plugin must be selected
519 If you didn't use a --enable option then please check that you have
520 the headers for the packages "purple" or "telepathy-glib" installed.
522         [])
524 dnl enable voice & video support if any backend supports it
525 AS_IF([test "x$with_purple_vv" != xno],
526         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
527 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
529 dnl raw data RTP streams enable Lync file transfer
530 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
531 AS_IF([test "x$ac_have_xdata" == xyes],
532         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
534 dnl enable appshare support
535 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
536 AS_IF([test "x$ac_have_appshare" == xyes],
537         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
539 dnl telepathy code parts rely on interfaces that require GValueArray. This
540 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
541 dnl is no backward compatible replacement implementation possible
542 AS_IF([test "x$enable_telepathy" != xno],
543         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
544                    [We need GValueArray for which no replacement is available])])
546 dnl i18n
547 AC_MSG_CHECKING([locale_CPPFLAGS])
548 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
549 AC_SUBST([LOCALE_CPPFLAGS])
550 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
551 AM_GLIB_GNU_GETTEXT
552 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
554 dnl codeset
555 AM_LANGINFO_CODESET
557 dnl substitutions and generated files
558 AC_CONFIG_HEADERS([config.h])
559 AC_CONFIG_FILES([
560         Makefile
561         pixmaps/Makefile
562         m4macros/Makefile
563         po/Makefile.in
564         pixmaps/16/Makefile
565         pixmaps/22/Makefile
566         pixmaps/24/Makefile
567         pixmaps/32/Makefile
568         pixmaps/48/Makefile
569         pixmaps/scalable/Makefile
570         src/Makefile
571         src/core/Makefile
572         src/api/Makefile
573         src/purple/Makefile
574         src/telepathy/Makefile
575         src/telepathy/data/Makefile
576         ])
578 dnl generate files
579 AC_OUTPUT()
581 dnl additional info for the user
582 AS_ECHO()
583 AS_IF([test "x$enable_purple" = xno],
584         [AS_ECHO("Not building purple plugin")],
585         [AS_ECHO("Build purple plugin")
586          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
587          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
588          AS_ECHO_N("Voice and video: ")
589          AS_IF([test "x$with_purple_vv" = xno],
590           [AS_ECHO("disabled")],
591           [AS_ECHO("enabled")])
592         ])
593 AS_ECHO()
594 AS_IF([test "x$enable_telepathy" = xno],
595         [AS_ECHO("Not building telepathy plugin")],
596         [AS_ECHO("Build telepathy plugin")
597          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
598          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
599 AS_ECHO()
600 AS_IF([test "x$with_krb5" = xno],
601         [AS_ECHO("Not building with Kerberos 5 support")],
602         [AS_ECHO("Build with Kerberos 5 support")
603          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
604          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
605 AS_ECHO()
606 AS_IF([test "x$enable_gssapi_only" = xno],
607         [AS_ECHO("Using internal authentication implementation")],
608         [AS_ECHO("Using only GSSAPI for authentication")])
609 AS_ECHO()
610 AS_IF([test "x$enable_debug" = xno],
611         [AS_ECHO("Debugging not enabled")],
612         [AS_ECHO("Build with debugging enabled")
613          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
614 AS_ECHO()
615 AS_IF([test "x$QUALITY_CFLAGS" = x],
616         [AS_ECHO("Compiler checks disabled")],
617         [AS_ECHO("Build with compiler checks enabled")
618          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
619 AS_ECHO()
620 AS_ECHO("configure complete. Now run 'make'")
621 AS_ECHO()
623 dnl The End.