src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq *boot-state* 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when *boot-state*
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 #-sb-fluid (declaim (inline gdefinition))
  42 (defun gdefinition (spec)
  43   ;; This is null layer right now, but once FDEFINITION stops bypasssing
  44   ;; fwrappers/encapsulations we can do that here.
  45   (fdefinition spec))
  46
  47 (defun (setf gdefinition) (new-value spec)
  48   ;; This is almost a null layer right now, but once (SETF
  49   ;; FDEFINITION) stops bypasssing fwrappers/encapsulations we can do
  50   ;; that here.
  51   (sb-c::note-name-defined spec :function) ; FIXME: do we need this? Why?
  52   (setf (fdefinition spec) new-value))
  53 \f
  54 ;;;; type specifier hackery
  55
  56 ;;; internal to this file
  57 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
  58   (if (symbolp class)
  59       (or (find-class class (not make-forward-referenced-class-p))
  60           (ensure-class class))
  61       class))
  62
  63 ;;; interface
  64 (defun specializer-from-type (type &aux args)
  65   (when (symbolp type)
  66     (return-from specializer-from-type (find-class type)))
  67   (when (consp type)
  68     (setq args (cdr type) type (car type)))
  69   (cond ((symbolp type)
  70          (or (ecase type
  71                (class    (coerce-to-class (car args)))
  72                (prototype (make-instance 'class-prototype-specializer
  73                                          :object (coerce-to-class (car args))))
  74                (class-eq (class-eq-specializer (coerce-to-class (car args))))
  75                (eql      (intern-eql-specializer (car args))))))
  76         ;; FIXME: do we still need this?
  77         ((and (null args) (typep type 'classoid))
  78          (or (classoid-pcl-class type)
  79              (ensure-non-standard-class (classoid-name type))))
  80         ((specializerp type) type)))
  81
  82 ;;; interface
  83 (defun type-from-specializer (specl)
  84   (cond ((eq specl t)
  85          t)
  86         ((consp specl)
  87          (unless (member (car specl) '(class prototype class-eq eql))
  88            (error "~S is not a legal specializer type." specl))
  89          specl)
  90         ((progn
  91            (when (symbolp specl)
  92              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
  93              (setq specl (find-class specl)))
  94            (or (not (eq *boot-state* 'complete))
  95                (specializerp specl)))
  96          (specializer-type specl))
  97         (t
  98          (error "~S is neither a type nor a specializer." specl))))
  99
 100 (defun type-class (type)
 101   (declare (special *the-class-t*))
 102   (setq type (type-from-specializer type))
 103   (if (atom type)
 104       (if (eq type t)
 105           *the-class-t*
 106           (error "bad argument to TYPE-CLASS"))
 107       (case (car type)
 108         (eql (class-of (cadr type)))
 109         (prototype (class-of (cadr type))) ;?
 110         (class-eq (cadr type))
 111         (class (cadr type)))))
 112
 113 (defun class-eq-type (class)
 114   (specializer-type (class-eq-specializer class)))
 115
 116 ;;; internal to this file..
 117 ;;;
 118 ;;; These functions are a pale imitation of their namesake. They accept
 119 ;;; class objects or types where they should.
 120 (defun *normalize-type (type)
 121   (cond ((consp type)
 122          (if (member (car type) '(not and or))
 123              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 124              (if (null (cdr type))
 125                  (*normalize-type (car type))
 126                  type)))
 127         ((symbolp type)
 128          (let ((class (find-class type nil)))
 129            (if class
 130                (let ((type (specializer-type class)))
 131                  (if (listp type) type `(,type)))
 132                `(,type))))
 133         ((or (not (eq *boot-state* 'complete))
 134              (specializerp type))
 135          (specializer-type type))
 136         (t
 137          (error "~S is not a type." type))))
 138
 139 ;;; internal to this file...
 140 (defun convert-to-system-type (type)
 141   (case (car type)
 142     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 143                                           (cdr type))))
 144     ((class class-eq) ; class-eq is impossible to do right
 145      (layout-classoid (class-wrapper (cadr type))))
 146     (eql type)
 147     (t (if (null (cdr type))
 148            (car type)
 149            type))))
 150
 151 ;;; Writing the missing NOT and AND clauses will improve the quality
 152 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 153 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 154 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 155 ;;;
 156 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 157 ;;; in the compiler. Could we share some of it here?
 158 (defun *subtypep (type1 type2)
 159   (if (equal type1 type2)
 160       (values t t)
 161       (if (eq *boot-state* 'early)
 162           (values (eq type1 type2) t)
 163           (let ((*in-precompute-effective-methods-p* t))
 164             (declare (special *in-precompute-effective-methods-p*))
 165             ;; FIXME: *IN-PRECOMPUTE-EFFECTIVE-METHODS-P* is not a
 166             ;; good name. It changes the way
 167             ;; CLASS-APPLICABLE-USING-CLASS-P works.
 168             (setq type1 (*normalize-type type1))
 169             (setq type2 (*normalize-type type2))
 170             (case (car type2)
 171               (not
 172                (values nil nil)) ; XXX We should improve this.
 173               (and
 174                (values nil nil)) ; XXX We should improve this.
 175               ((eql wrapper-eq class-eq class)
 176                (multiple-value-bind (app-p maybe-app-p)
 177                    (specializer-applicable-using-type-p type2 type1)
 178                  (values app-p (or app-p (not maybe-app-p)))))
 179               (t
 180                (subtypep (convert-to-system-type type1)
 181                          (convert-to-system-type type2))))))))
 182 \f
 183 (defvar *built-in-class-symbols* ())
 184 (defvar *built-in-wrapper-symbols* ())
 185
 186 (defun get-built-in-class-symbol (class-name)
 187   (or (cadr (assq class-name *built-in-class-symbols*))
 188       (let ((symbol (make-class-symbol class-name)))
 189         (push (list class-name symbol) *built-in-class-symbols*)
 190         symbol)))
 191
 192 (defun get-built-in-wrapper-symbol (class-name)
 193   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 194       (let ((symbol (make-wrapper-symbol class-name)))
 195         (push (list class-name symbol) *built-in-wrapper-symbols*)
 196         symbol)))
 197 \f
 198 (defvar *standard-method-combination*)
 199 \f
 200 (defun plist-value (object name)
 201   (getf (object-plist object) name))
 202
 203 (defun (setf plist-value) (new-value object name)
 204   (if new-value
 205       (setf (getf (object-plist object) name) new-value)
 206       (progn
 207         (remf (object-plist object) name)
 208         nil)))
 209 \f
 210 ;;;; built-in classes
 211
 212 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 213 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 214 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 215 (defvar *built-in-classes*
 216   (labels ((direct-supers (class)
 217              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 218              (if (typep class 'built-in-classoid)
 219                  (built-in-classoid-direct-superclasses class)
 220                  (let ((inherits (layout-inherits
 221                                   (classoid-layout class))))
 222                    (/noshow inherits)
 223                    (list (svref inherits (1- (length inherits)))))))
 224            (direct-subs (class)
 225              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 226              (collect ((res))
 227                (let ((subs (classoid-subclasses class)))
 228                  (/noshow subs)
 229                  (when subs
 230                    (dohash ((sub v) subs)
 231                      (declare (ignore v))
 232                      (/noshow sub)
 233                      (when (member class (direct-supers sub))
 234                        (res sub)))))
 235                (res))))
 236     (mapcar (lambda (kernel-bic-entry)
 237               (/noshow "setting up" kernel-bic-entry)
 238               (let* ((name (car kernel-bic-entry))
 239                      (class (find-classoid name))
 240                      (prototype-form
 241                       (getf (cdr kernel-bic-entry) :prototype-form)))
 242                 (/noshow name class)
 243                 `(,name
 244                   ,(mapcar #'classoid-name (direct-supers class))
 245                   ,(mapcar #'classoid-name (direct-subs class))
 246                   ,(map 'list
 247                         (lambda (x)
 248                           (classoid-name
 249                            (layout-classoid x)))
 250                         (reverse
 251                          (layout-inherits
 252                           (classoid-layout class))))
 253                   ,(if prototype-form
 254                        (eval prototype-form)
 255                        ;; This is the default prototype value which
 256                        ;; was used, without explanation, by the CMU CL
 257                        ;; code we're derived from. Evidently it's safe
 258                        ;; in all relevant cases.
 259                        42))))
 260             (remove-if (lambda (kernel-bic-entry)
 261                          (member (first kernel-bic-entry)
 262                                  ;; I'm not sure why these are removed from
 263                                  ;; the list, but that's what the original
 264                                  ;; CMU CL code did. -- WHN 20000715
 265                                  '(t function stream
 266                                      file-stream string-stream)))
 267                        sb-kernel::*built-in-classes*))))
 268 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 269 \f
 270 ;;;; the classes that define the kernel of the metabraid
 271
 272 (defclass t () ()
 273   (:metaclass built-in-class))
 274
 275 (defclass function (t) ()
 276   (:metaclass built-in-class))
 277
 278 (defclass stream (t) ()
 279   (:metaclass built-in-class))
 280
 281 (defclass file-stream (stream) ()
 282   (:metaclass built-in-class))
 283
 284 (defclass string-stream (stream) ()
 285   (:metaclass built-in-class))
 286
 287 (defclass slot-object (t) ()
 288   (:metaclass slot-class))
 289
 290 (defclass condition (slot-object) ()
 291   (:metaclass condition-class))
 292
 293 (defclass structure-object (slot-object) ()
 294   (:metaclass structure-class))
 295
 296 (defstruct (dead-beef-structure-object
 297             (:constructor |STRUCTURE-OBJECT class constructor|)
 298             (:copier nil)))
 299
 300 (defclass standard-object (slot-object) ())
 301
 302 (defclass funcallable-standard-object (function standard-object)
 303   ()
 304   (:metaclass funcallable-standard-class))
 305
 306 (defclass metaobject (standard-object) ())
 307
 308 (defclass generic-function (dependent-update-mixin
 309                             definition-source-mixin
 310                             metaobject
 311                             funcallable-standard-object)
 312   ((%documentation
 313     :initform nil
 314     :initarg :documentation)
 315    ;; We need to make a distinction between the methods initially set
 316    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 317    ;; DEFMETHOD, because ANSI specifies that executing DEFGENERIC on
 318    ;; an already-DEFGENERICed function clears the methods set by the
 319    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 320    ;; this distinction seems a little kludgy, but it has the positive
 321    ;; effect of making it so that loading a file a.lisp containing
 322    ;; DEFGENERIC, then loading a second file b.lisp containing
 323    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 324    ;; tends to leave the generic function in a state consistent with
 325    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 326    (initial-methods
 327     :initform ()
 328     :accessor generic-function-initial-methods))
 329   (:metaclass funcallable-standard-class))
 330
 331 (defclass standard-generic-function (generic-function)
 332   ((name
 333     :initform nil
 334     :initarg :name
 335     :reader generic-function-name)
 336    (methods
 337     :initform ()
 338     :accessor generic-function-methods
 339     :type list)
 340    (method-class
 341     :initarg :method-class
 342     :accessor generic-function-method-class)
 343    (%method-combination
 344     :initarg :method-combination
 345     :accessor generic-function-method-combination)
 346    (declarations
 347     ;; KLUDGE: AMOP specifies :DECLARATIONS, while ANSI specifies
 348     ;; :DECLARE.  Allow either (but FIXME: maybe a note or a warning
 349     ;; might be appropriate).
 350     :initarg :declarations
 351     :initarg :declare
 352     :initform ()
 353     :accessor generic-function-declarations)
 354    (arg-info
 355     :initform (make-arg-info)
 356     :reader gf-arg-info)
 357    (dfun-state
 358     :initform ()
 359     :accessor gf-dfun-state)
 360    ;; Used to make DFUN-STATE & FIN-FUNCTION updates atomic.
 361    (%lock
 362     :initform (sb-thread::make-spinlock :name "GF lock")
 363     :reader gf-lock))
 364   (:metaclass funcallable-standard-class)
 365   (:default-initargs :method-class *the-class-standard-method*
 366                      :method-combination *standard-method-combination*))
 367
 368 (defclass method (metaobject) ())
 369
 370 (defclass standard-method (plist-mixin definition-source-mixin method)
 371   ((%generic-function :initform nil :accessor method-generic-function)
 372    (qualifiers :initform () :initarg :qualifiers :reader method-qualifiers)
 373    (specializers :initform () :initarg :specializers
 374                  :reader method-specializers)
 375    (lambda-list :initform () :initarg :lambda-list :reader method-lambda-list)
 376    (%function :initform nil :initarg :function :reader method-function)
 377    (%documentation :initform nil :initarg :documentation)))
 378
 379 (defclass accessor-method (standard-method)
 380   ((slot-name :initform nil :initarg :slot-name
 381               :reader accessor-method-slot-name)))
 382
 383 (defclass standard-accessor-method (accessor-method)
 384   ((%slot-definition :initform nil :initarg :slot-definition
 385                      :reader accessor-method-slot-definition)))
 386
 387 (defclass standard-reader-method (standard-accessor-method) ())
 388 (defclass standard-writer-method (standard-accessor-method) ())
 389 ;;; an extension, apparently.
 390 (defclass standard-boundp-method (standard-accessor-method) ())
 391
 392 ;;; for (SLOT-VALUE X 'FOO) / ACCESSOR-SLOT-VALUE optimization, which
 393 ;;; can't be STANDARD-READER-METHOD because there is no associated
 394 ;;; slot definition.
 395 (defclass global-reader-method (accessor-method) ())
 396 (defclass global-writer-method (accessor-method) ())
 397 (defclass global-boundp-method (accessor-method) ())
 398
 399 (defclass method-combination (metaobject)
 400   ((%documentation :initform nil :initarg :documentation)))
 401
 402 (defclass standard-method-combination (definition-source-mixin
 403                                        method-combination)
 404   ((type-name
 405     :reader method-combination-type-name
 406     :initarg :type-name)
 407    (options
 408     :reader method-combination-options
 409     :initarg :options)))
 410
 411 (defclass long-method-combination (standard-method-combination)
 412   ((function
 413     :initarg :function
 414     :reader long-method-combination-function)
 415    (args-lambda-list
 416     :initarg :args-lambda-list
 417     :reader long-method-combination-args-lambda-list)))
 418
 419 (defclass short-method-combination (standard-method-combination)
 420   ((operator
 421     :reader short-combination-operator
 422     :initarg :operator)
 423    (identity-with-one-argument
 424     :reader short-combination-identity-with-one-argument
 425     :initarg :identity-with-one-argument)))
 426
 427 (defclass slot-definition (metaobject)
 428   ((name
 429     :initform nil
 430     :initarg :name
 431     :accessor slot-definition-name)
 432    (initform
 433     :initform nil
 434     :initarg :initform
 435     :accessor slot-definition-initform)
 436    (initfunction
 437     :initform nil
 438     :initarg :initfunction
 439     :accessor slot-definition-initfunction)
 440    (readers
 441     :initform nil
 442     :initarg :readers
 443     :accessor slot-definition-readers)
 444    (writers
 445     :initform nil
 446     :initarg :writers
 447     :accessor slot-definition-writers)
 448    (initargs
 449     :initform nil
 450     :initarg :initargs
 451     :accessor slot-definition-initargs)
 452    (%type :initform t :initarg :type :accessor slot-definition-type)
 453    (%type-check-function :initform nil
 454                          :initarg type-check-function
 455                          :accessor slot-definition-type-check-function)
 456    (%documentation
 457     :initform nil :initarg :documentation
 458     ;; KLUDGE: we need a reader for bootstrapping purposes, in
 459     ;; COMPUTE-EFFECTIVE-SLOT-DEFINITION-INITARGS.
 460     :reader %slot-definition-documentation)
 461    (%class :initform nil :initarg :class :accessor slot-definition-class)))
 462
 463 (defclass standard-slot-definition (slot-definition)
 464   ((allocation
 465     :initform :instance
 466     :initarg :allocation
 467     :accessor slot-definition-allocation)
 468    (allocation-class
 469     :initform nil
 470     :initarg :allocation-class
 471     :accessor slot-definition-allocation-class)))
 472
 473 (defclass condition-slot-definition (slot-definition)
 474   ((allocation
 475     :initform :instance
 476     :initarg :allocation
 477     :accessor slot-definition-allocation)
 478    (allocation-class
 479     :initform nil
 480     :initarg :allocation-class
 481     :accessor slot-definition-allocation-class)))
 482
 483 (defclass structure-slot-definition (slot-definition)
 484   ((defstruct-accessor-symbol
 485      :initform nil
 486      :initarg :defstruct-accessor-symbol
 487      :accessor slot-definition-defstruct-accessor-symbol)
 488    (internal-reader-function
 489      :initform nil
 490      :initarg :internal-reader-function
 491      :accessor slot-definition-internal-reader-function)
 492    (internal-writer-function
 493      :initform nil
 494      :initarg :internal-writer-function
 495      :accessor slot-definition-internal-writer-function)))
 496
 497 (defclass direct-slot-definition (slot-definition)
 498   ())
 499
 500 (defclass effective-slot-definition (slot-definition)
 501   ((reader-function ; (lambda (object) ...)
 502     :accessor slot-definition-reader-function)
 503    (writer-function ; (lambda (new-value object) ...)
 504     :accessor slot-definition-writer-function)
 505    (boundp-function ; (lambda (object) ...)
 506     :accessor slot-definition-boundp-function)
 507    (accessor-flags
 508     :initform 0)))
 509
 510 (defclass standard-direct-slot-definition (standard-slot-definition
 511                                            direct-slot-definition)
 512   ())
 513
 514 (defclass standard-effective-slot-definition (standard-slot-definition
 515                                               effective-slot-definition)
 516   ((location ; nil, a fixnum, a cons: (slot-name . value)
 517     :initform nil
 518     :accessor slot-definition-location)))
 519
 520 (defclass condition-direct-slot-definition (condition-slot-definition
 521                                             direct-slot-definition)
 522   ())
 523
 524 (defclass condition-effective-slot-definition (condition-slot-definition
 525                                                effective-slot-definition)
 526   ())
 527
 528 (defclass structure-direct-slot-definition (structure-slot-definition
 529                                             direct-slot-definition)
 530   ())
 531
 532 (defclass structure-effective-slot-definition (structure-slot-definition
 533                                                effective-slot-definition)
 534   ())
 535
 536 (defclass specializer (metaobject)
 537   ;; KLUDGE: in sbcl-0.9.10.2 this was renamed from TYPE, which was an
 538   ;; external symbol of the CL package and hence potentially collides
 539   ;; with user code.  Renaming this to %TYPE, however, is the coward's
 540   ;; way out, because the objects that PCL puts in this slot aren't
 541   ;; (quite) types: they are closer to kinds of specializer.  However,
 542   ;; the wholesale renaming and disentangling of specializers didn't
 543   ;; appeal.  (See also message <sqd5hrclb2.fsf@cam.ac.uk> and
 544   ;; responses in comp.lang.lisp).  -- CSR, 2006-02-27
 545   ((%type :initform nil :reader specializer-type)))
 546
 547 ;;; STANDARD in this name doesn't mean "blessed by a standard" but
 548 ;;; "comes as standard with PCL"; that is, it includes CLASS-EQ
 549 ;;; and vestiges of PROTOTYPE specializers
 550 (defclass standard-specializer (specializer) ())
 551
 552 (defclass specializer-with-object (specializer) ())
 553
 554 (defclass exact-class-specializer (specializer) ())
 555
 556 (defclass class-eq-specializer (standard-specializer
 557                                 exact-class-specializer
 558                                 specializer-with-object)
 559   ((object :initarg :class
 560            :reader specializer-class
 561            :reader specializer-object)))
 562
 563 (defclass class-prototype-specializer (standard-specializer specializer-with-object)
 564   ((object :initarg :class
 565            :reader specializer-class
 566            :reader specializer-object)))
 567
 568 (defclass eql-specializer (standard-specializer exact-class-specializer specializer-with-object)
 569   ((object :initarg :object :reader specializer-object
 570            :reader eql-specializer-object)))
 571
 572 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 573
 574 (defvar *eql-specializer-table-lock*
 575   (sb-thread::make-spinlock :name "EQL-specializer table lock"))
 576
 577 (defun intern-eql-specializer (object)
 578   ;; Need to lock, so that two threads don't get non-EQ specializers
 579   ;; for an EQL object.
 580   (sb-thread::with-spinlock (*eql-specializer-table-lock*)
 581     (or (gethash object *eql-specializer-table*)
 582         (setf (gethash object *eql-specializer-table*)
 583               (make-instance 'eql-specializer :object object)))))
 584
 585 (defclass class (dependent-update-mixin
 586                  definition-source-mixin
 587                  standard-specializer)
 588   ((name
 589     :initform nil
 590     :initarg :name
 591     :reader class-name)
 592    (class-eq-specializer
 593     :initform nil
 594     :reader class-eq-specializer)
 595    (direct-superclasses
 596     :initform ()
 597     :reader class-direct-superclasses)
 598    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 599    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 600    ;; becomes available, i.e. when the PCL class is created.
 601    (direct-subclasses
 602     :initform ()
 603     :reader class-direct-subclasses)
 604    (direct-methods
 605     :initform (cons nil nil))
 606    (%documentation
 607     :initform nil
 608     :initarg :documentation)
 609    ;; True if the class definition was compiled with a (SAFETY 3)
 610    ;; optimization policy.
 611    (safe-p
 612     :initform nil
 613     :initarg safe-p
 614     :accessor safe-p)
 615    (finalized-p
 616     :initform nil
 617     :reader class-finalized-p)))
 618
 619 (def!method make-load-form ((class class) &optional env)
 620   ;; FIXME: should we not instead pass ENV to FIND-CLASS?  Probably
 621   ;; doesn't matter while all our environments are the same...
 622   (declare (ignore env))
 623   (let ((name (class-name class)))
 624     (unless (and name (eq (find-class name nil) class))
 625       (error "~@<Can't use anonymous or undefined class as constant: ~S~:@>"
 626              class))
 627     `(find-class ',name)))
 628
 629 ;;; The class PCL-CLASS is an implementation-specific common
 630 ;;; superclass of all specified subclasses of the class CLASS.
 631 (defclass pcl-class (class)
 632   ((%class-precedence-list
 633     :reader class-precedence-list)
 634    ;; KLUDGE: see note in CPL-OR-NIL
 635    (cpl-available-p
 636     :reader cpl-available-p
 637     :initform nil)
 638    (can-precede-list
 639     :initform ()
 640     :reader class-can-precede-list)
 641    (incompatible-superclass-list
 642     :initform ()
 643     :accessor class-incompatible-superclass-list)
 644    (wrapper
 645     :initform nil
 646     :reader class-wrapper)
 647    (prototype
 648     :initform nil
 649     :reader class-prototype)))
 650
 651 (defclass slot-class (pcl-class)
 652   ((direct-slots
 653     :initform ()
 654     :reader class-direct-slots)
 655    (slots
 656     :initform ()
 657     :reader class-slots)))
 658
 659 ;;; The class STD-CLASS is an implementation-specific common
 660 ;;; superclass of the classes STANDARD-CLASS and
 661 ;;; FUNCALLABLE-STANDARD-CLASS.
 662 (defclass std-class (slot-class)
 663   ())
 664
 665 (defclass standard-class (std-class)
 666   ())
 667
 668 (defclass funcallable-standard-class (std-class)
 669   ())
 670
 671 (defclass forward-referenced-class (pcl-class) ())
 672
 673 (defclass built-in-class (pcl-class) ())
 674
 675 (defclass condition-class (slot-class) ())
 676
 677 (defclass structure-class (slot-class)
 678   ((defstruct-form
 679      :initform ()
 680      :accessor class-defstruct-form)
 681    (defstruct-constructor
 682      :initform nil
 683      :accessor class-defstruct-constructor)
 684    (from-defclass-p
 685     :initform nil
 686     :initarg :from-defclass-p)))
 687
 688 (defclass definition-source-mixin (standard-object)
 689   ((source
 690     :initform nil
 691     :reader definition-source
 692     :initarg :definition-source)))
 693
 694 (defclass plist-mixin (standard-object)
 695   ((plist :initform () :accessor object-plist :initarg plist)))
 696
 697 (defclass dependent-update-mixin (plist-mixin) ())
 698
 699 (defparameter *early-class-predicates*
 700   '((specializer specializerp)
 701     (standard-specializer standard-specializer-p)
 702     (exact-class-specializer exact-class-specializer-p)
 703     (class-eq-specializer class-eq-specializer-p)
 704     (eql-specializer eql-specializer-p)
 705     (class classp)
 706     (slot-class slot-class-p)
 707     (std-class std-class-p)
 708     (standard-class standard-class-p)
 709     (funcallable-standard-class funcallable-standard-class-p)
 710     (condition-class condition-class-p)
 711     (structure-class structure-class-p)
 712     (forward-referenced-class forward-referenced-class-p)
 713     (method method-p)
 714     (standard-method standard-method-p)
 715     (accessor-method accessor-method-p)
 716     (standard-accessor-method standard-accessor-method-p)
 717     (standard-reader-method standard-reader-method-p)
 718     (standard-writer-method standard-writer-method-p)
 719     (standard-boundp-method standard-boundp-method-p)
 720     (global-reader-method global-reader-method-p)
 721     (global-writer-method global-writer-method-p)
 722     (global-boundp-method global-boundp-method-p)
 723     (generic-function generic-function-p)
 724     (standard-generic-function standard-generic-function-p)
 725     (method-combination method-combination-p)
 726     (long-method-combination long-method-combination-p)
 727     (short-method-combination short-method-combination-p)))