contrib/lisp/ox-groff.el

   1 ;;; ox-groff.el --- Groff Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2011-2017  Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou at gmail dot com>
   6 ;; Author: Luis R Anaya <papoanaya aroba hot mail punto com>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8
   9 ;; This file is not part of GNU Emacs.
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;; Commentary:
  24 ;;
  25 ;; This library implements a Groff Memorandum Macro back-end for Org
  26 ;; generic exporter.
  27 ;;
  28 ;; To test it, run
  29 ;;
  30 ;;   M-: (org-export-to-buffer 'groff "*Test Groff*") RET
  31 ;;
  32 ;; in an org-mode buffer then switch to the buffer to see the Groff
  33 ;; export.  See ox.el for more details on how this exporter works.
  34 ;;
  35 ;; It introduces two new buffer keywords: "GROFF_CLASS" and
  36 ;; "GROFF_CLASS_OPTIONS".
  37
  38 ;;; Code:
  39
  40 (eval-when-compile (require 'cl))
  41 (require 'ox)
  42
  43 (defvar orgtbl-exp-regexp)
  44
  45 \f
  46 ;;; Define Back-End
  47
  48 (org-export-define-backend 'groff
  49   '((bold . org-groff-bold)
  50     (center-block . org-groff-center-block)
  51     (clock . org-groff-clock)
  52     (code . org-groff-code)
  53     (drawer . org-groff-drawer)
  54     (dynamic-block . org-groff-dynamic-block)
  55     (entity . org-groff-entity)
  56     (example-block . org-groff-example-block)
  57     (export-block . org-groff-export-block)
  58     (export-snippet . org-groff-export-snippet)
  59     (fixed-width . org-groff-fixed-width)
  60     (footnote-definition . org-groff-footnote-definition)
  61     (footnote-reference . org-groff-footnote-reference)
  62     (headline . org-groff-headline)
  63     (horizontal-rule . org-groff-horizontal-rule)
  64     (inline-src-block . org-groff-inline-src-block)
  65     (inlinetask . org-groff-inlinetask)
  66     (italic . org-groff-italic)
  67     (item . org-groff-item)
  68     (keyword . org-groff-keyword)
  69     (line-break . org-groff-line-break)
  70     (link . org-groff-link)
  71     (node-property . org-groff-node-property)
  72     (paragraph . org-groff-paragraph)
  73     (plain-list . org-groff-plain-list)
  74     (plain-text . org-groff-plain-text)
  75     (planning . org-groff-planning)
  76     (property-drawer . org-groff-property-drawer)
  77     (quote-block . org-groff-quote-block)
  78     (radio-target . org-groff-radio-target)
  79     (section . org-groff-section)
  80     (special-block . org-groff-special-block)
  81     (src-block . org-groff-src-block)
  82     (statistics-cookie . org-groff-statistics-cookie)
  83     (strike-through . org-groff-strike-through)
  84     (subscript . org-groff-subscript)
  85     (superscript . org-groff-superscript)
  86     (table . org-groff-table)
  87     (table-cell . org-groff-table-cell)
  88     (table-row . org-groff-table-row)
  89     (target . org-groff-target)
  90     (template . org-groff-template)
  91     (timestamp . org-groff-timestamp)
  92     (underline . org-groff-underline)
  93     (verbatim . org-groff-verbatim)
  94     (verse-block . org-groff-verse-block))
  95   :menu-entry
  96   '(?g "Export to GROFF"
  97        ((?g "As GROFF file" org-groff-export-to-groff)
  98         (?p "As PDF file" org-groff-export-to-pdf)
  99         (?o "As PDF file and open"
 100             (lambda (a s v b)
 101               (if a (org-groff-export-to-pdf t s v b)
 102                 (org-open-file (org-groff-export-to-pdf nil s v b)))))))
 103   :options-alist
 104   '((:groff-class "GROFF_CLASS" nil org-groff-default-class t)
 105     (:groff-class-options "GROFF_CLASS_OPTIONS" nil nil t)
 106     (:groff-header-extra "GROFF_HEADER" nil nil newline)))
 107
 108
 109 \f
 110 ;;; User Configurable Variables
 111
 112 (defgroup org-export-groff nil
 113   "Options for exporting Org mode files to Groff."
 114   :tag "Org Export Groff"
 115   :group 'org-export)
 116
 117 ;;; Preamble
 118
 119 (defcustom org-groff-default-class "internal"
 120   "The default Groff class."
 121   :group 'org-export-groff
 122   :type '(string :tag "Groff class"))
 123
 124 (defcustom org-groff-classes
 125   '(("file" ".MT 1"
 126      (:heading 'default :type "memo" :last-section "toc"))
 127     ("internal" ".MT 0"
 128      (:heading 'default :type "memo" :last-section "toc"))
 129     ("programmer" ".MT 2"
 130      (:heading 'default :type "memo" :last-section "toc"))
 131     ("engineer" ".MT 3"
 132      (:heading 'default :type "memo" :last-section "toc"))
 133     ("external" ".MT 4"
 134      (:heading 'default :type "memo" :last-section "toc"))
 135     ("letter" ".MT 5"
 136      (:heading 'default :type "memo" :last-section "sign"))
 137     ("custom" ".so file"
 138      (:heading custom-function :type "custom" :last-section "toc"))
 139     ("dummy" ""
 140      (:heading 'default :type "memo"))
 141     ("ms" "ms"
 142      (:heading 'default :type "cover" :last-section "toc"))
 143     ("se_ms" "se_ms"
 144      (:heading 'default :type "cover" :last-section "toc"))
 145     ("block" "BL"
 146      (:heading 'default :type "letter" :last-section "sign"))
 147     ("semiblock" "SB"
 148      (:heading 'default :type "letter" :last-section "sign"))
 149     ("fullblock" "FB"
 150      (:heading 'default :type "letter" :last-section "sign"))
 151     ("simplified" "SP"
 152      (:heading 'default :type "letter" :last-section "sign"))
 153     ("none" "" (:heading 'default :type "custom")))
 154
 155   ;; none means, no Cover or Memorandum Type and no calls to AU, AT, ND and TL
 156   ;; This is to facilitate the creation of custom pages.
 157
 158   ;; dummy means, no Cover or Memorandum Type but calls to AU, AT, ND and TL
 159   ;; are made. This is to facilitate Abstract Insertion.
 160
 161   "This list describes the attributes for the documents being created.
 162    It allows for the creation of new "
 163   :group 'org-export-groff
 164   :type '(repeat
 165           (list (string :tag "Document Type")
 166                 (string :tag "Header")
 167                 (repeat :tag "Options" :inline t
 168                         (choice
 169                          (list :tag "Heading")
 170                          (function :tag "Hook computing sectioning"))))))
 171
 172 ;;; Headline
 173
 174 (defconst org-groff-special-tags
 175   '("FROM" "TO" "ABSTRACT" "APPENDIX" "BODY" "NS"))
 176
 177 (defcustom org-groff-format-headline-function nil
 178   "Function to format headline text.
 179
 180 This function will be called with 5 arguments:
 181 TODO      the todo keyword (string or nil).
 182 TODO-TYPE the type of todo (symbol: `todo', `done', nil)
 183 PRIORITY  the priority of the headline (integer or nil)
 184 TEXT      the main headline text (string).
 185 TAGS      the tags as a list of strings (list of strings or nil).
 186
 187 The function result will be used in the section format string.
 188
 189 As an example, one could set the variable to the following, in
 190 order to reproduce the default set-up:
 191
 192 \(defun org-groff-format-headline (todo todo-type priority text tags)
 193   \"Default format function for a headline.\"
 194   \(concat (when todo
 195             \(format \"\\fB%s\\fP \" todo))
 196           \(when priority
 197             \(format \"[\\#%c] \" priority))
 198           text
 199           \(when tags
 200             \(format \" %s \"
 201               \(mapconcat 'identity tags \":\"))))"
 202   :group 'org-export-groff
 203   :type 'function)
 204
 205 ;;; Timestamps
 206
 207 (defcustom org-groff-active-timestamp-format "\\fI%s\\fP"
 208   "A printf format string to be applied to active timestamps."
 209   :group 'org-export-groff
 210   :type 'string)
 211
 212 (defcustom org-groff-inactive-timestamp-format "\\fI%s\\fP"
 213   "A printf format string to be applied to inactive timestamps."
 214   :group 'org-export-groff
 215   :type 'string)
 216
 217 (defcustom org-groff-diary-timestamp-format "\\fI%s\\fP"
 218   "A printf format string to be applied to diary timestamps."
 219   :group 'org-export-groff
 220   :type 'string)
 221
 222 ;;; Links
 223
 224 (defcustom org-groff-inline-image-rules
 225   '(("file" . "\\.\\(jpg\\|png\\|pdf\\|ps\\|eps\\|pic\\)\\'")
 226     ("fuzzy" . "\\.\\(jpg\\|png\\|pdf\\|ps\\|eps\\|pic\\)\\'"))
 227   "Rules characterizing image files that can be inlined into Groff.
 228
 229 A rule consists in an association whose key is the type of link
 230 to consider, and value is a regexp that will be matched against
 231 link's path.
 232
 233 Note that, by default, the image extensions actually allowed
 234 depend on the way the Groff file is processed.  When used with
 235 pdfgroff, pdf, jpg and png images are OK.  When processing
 236 through dvi to Postscript, only ps and eps are allowed.  The
 237 default we use here encompasses both."
 238   :group 'org-export-groff
 239   :type '(alist :key-type (string :tag "Type")
 240                 :value-type (regexp :tag "Path")))
 241
 242 (defcustom org-groff-link-with-unknown-path-format "\\fI%s\\fP"
 243   "Format string for links with unknown path type."
 244   :group 'org-export-groff
 245   :type 'string)
 246
 247 ;;; Tables
 248
 249 (defcustom org-groff-tables-centered t
 250   "When non-nil, tables are exported in a center environment."
 251   :group 'org-export-groff
 252   :type 'boolean)
 253
 254 (defcustom org-groff-tables-verbatim nil
 255   "When non-nil, tables are exported verbatim."
 256   :group 'org-export-groff
 257   :type 'boolean)
 258
 259 (defcustom org-groff-table-scientific-notation "%sE%s"
 260   "Format string to display numbers in scientific notation.
 261 The format should have \"%s\" twice, for mantissa and exponent
 262 \(i.e. \"%s\\\\times10^{%s}\").
 263
 264 When nil, no transformation is made."
 265   :group 'org-export-groff
 266   :type '(choice
 267           (string :tag "Format string")
 268           (const :tag "No formatting")))
 269
 270 ;;; Text markup
 271
 272 (defcustom org-groff-text-markup-alist
 273    '((bold . "\\fB%s\\fP")
 274     (code . "\\fC%s\\fP")
 275     (italic . "\\fI%s\\fP")
 276     (strike-through . "\\fC%s\\fP")  ; Strike through and underline
 277     (underline . "\\fI%s\\fP")       ; need to be revised.
 278     (verbatim .   "protectedtexttt"))
 279   "Alist of Groff expressions to convert text markup.
 280
 281 The key must be a symbol among `bold', `code', `italic',
 282 `strike-through', `underline' and `verbatim'.  The value is
 283 a formatting string to wrap fontified text with it.
 284
 285 If no association can be found for a given markup, text will be
 286 returned as-is."
 287   :group 'org-export-groff
 288   :type 'alist
 289   :options '(bold code italic strike-through underline verbatim))
 290
 291 ;;; Drawers
 292
 293 (defcustom org-groff-format-drawer-function nil
 294   "Function called to format a drawer in Groff code.
 295
 296 The function must accept two parameters:
 297   NAME      the drawer name, like \"LOGBOOK\"
 298   CONTENTS  the contents of the drawer.
 299
 300 The function should return the string to be exported.
 301
 302 For example, the variable could be set to the following function
 303 in order to mimic default behaviour:
 304
 305 \(defun org-groff-format-drawer-default \(name contents\)
 306   \"Format a drawer element for Groff export.\"
 307   contents\)"
 308   :group 'org-export-groff
 309   :type 'function)
 310
 311 ;;; Inlinetasks
 312
 313 (defcustom org-groff-format-inlinetask-function nil
 314   "Function called to format an inlinetask in Groff code.
 315
 316 The function must accept six parameters:
 317   TODO      the todo keyword, as a string
 318   TODO-TYPE the todo type, a symbol among `todo', `done' and nil.
 319   PRIORITY  the inlinetask priority, as a string
 320   NAME      the inlinetask name, as a string.
 321   TAGS      the inlinetask tags, as a list of strings.
 322   CONTENTS  the contents of the inlinetask, as a string.
 323
 324 The function should return the string to be exported.
 325
 326 For example, the variable could be set to the following function
 327 in order to mimic default behaviour:
 328
 329 \(defun org-groff-format-inlinetask \(todo type priority name tags contents\)
 330 \"Format an inline task element for Groff export.\"
 331   \(let ((full-title
 332          \(concat
 333           \(when todo
 334             \(format \"\\fB%s\\fP \" todo))
 335           \(when priority (format \"[\\#%c] \" priority))
 336           title
 337           \(when tags
 338             \(format \":%s:\"
 339                     \(mapconcat 'identity tags \":\")))))
 340     \(format (concat \".DS L\\n\"
 341                     \"%s\\n\\n\"
 342                     \"%s\"
 343                     \".DE\")
 344             full-title contents))"
 345   :group 'org-export-groff
 346   :type 'function)
 347
 348 ;; Src blocks
 349
 350 (defcustom org-groff-source-highlight nil
 351   "Use GNU source highlight to embellish source blocks "
 352   :group 'org-export-groff
 353   :type 'boolean)
 354
 355 (defcustom org-groff-source-highlight-langs
 356   '((emacs-lisp "lisp") (lisp "lisp") (clojure "lisp")
 357     (scheme "scheme")
 358     (c "c") (cc "cpp") (csharp "csharp") (d "d")
 359     (fortran "fortran") (cobol "cobol") (pascal "pascal")
 360     (ada "ada") (asm "asm")
 361     (perl "perl") (cperl "perl")
 362     (python "python") (ruby "ruby") (tcl "tcl") (lua "lua")
 363     (java "java") (javascript "javascript")
 364     (tex "latex")
 365     (shell-script "sh") (awk "awk") (diff "diff") (m4 "m4")
 366     (ocaml "caml") (caml "caml")
 367     (sql "sql") (sqlite "sql")
 368     (html "html") (css "css") (xml "xml")
 369     (bat "bat") (bison "bison") (clipper "clipper")
 370     (ldap "ldap") (opa "opa")
 371     (php "php") (postscript "postscript") (prolog "prolog")
 372     (properties "properties") (makefile "makefile")
 373     (tml "tml") (vala "vala") (vbscript "vbscript") (xorg "xorg"))
 374   "Alist mapping languages to their listing language counterpart.
 375 The key is a symbol, the major mode symbol without the \"-mode\".
 376 The value is the string that should be inserted as the language
 377 parameter for the listings package.  If the mode name and the
 378 listings name are the same, the language does not need an entry
 379 in this list - but it does not hurt if it is present."
 380   :group 'org-export-groff
 381   :type '(repeat
 382           (list
 383            (symbol :tag "Major mode       ")
 384            (string :tag "Listings language"))))
 385
 386 (defcustom org-groff-source-highlight-options nil
 387   "Association list of options for the groff listings package.
 388
 389 These options are supplied as a comma-separated list to the
 390 \\lstset command.  Each element of the association list should be
 391 a list containing two strings: the name of the option, and the
 392 value.  For example,
 393
 394   (setq org-groff-source-highlight-options
 395     '((\"basicstyle\" \"\\small\")
 396       (\"keywordstyle\" \"\\color{black}\\bfseries\\underbar\")))
 397
 398 will typeset the code in a small size font with underlined, bold
 399 black keywords.
 400
 401 Note that the same options will be applied to blocks of all
 402 languages."
 403   :group 'org-export-groff
 404   :type '(repeat
 405           (list
 406            (string :tag "Listings option name ")
 407            (string :tag "Listings option value"))))
 408
 409 (defvar org-groff-custom-lang-environments nil
 410   "Alist mapping languages to language-specific Groff environments.
 411
 412 It is used during export of src blocks by the listings and
 413 groff packages.  For example,
 414
 415   \(setq org-groff-custom-lang-environments
 416      '\(\(python \"pythoncode\"\)\)\)
 417
 418 would have the effect that if org encounters begin_src python
 419 during groff export it will use pythoncode as the source-highlight
 420 language.")
 421
 422 ;;; Plain text
 423
 424 (defcustom org-groff-special-char
 425   '(("(c)" . "\\\\(co")
 426     ("(tm)" . "\\\\(tm")
 427     ("(rg)" . "\\\\(rg"))
 428   "CONS list in which the value of the car
 429   is replace on the value of the CDR. "
 430   :group 'org-export-groff
 431   :type '(list
 432           (cons :tag "Character Subtitute"
 433                 (string :tag "Original Character Group")
 434                 (string :tag "Replacement Character"))))
 435
 436 ;;; Compilation
 437
 438 (defcustom org-groff-pdf-process
 439   '("pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf"
 440     "pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf"
 441     "pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf")
 442
 443   "Commands to process a Groff file to a PDF file.
 444 This is a list of strings, each of them will be given to the
 445 shell as a command.  %f in the command will be replaced by the
 446 full file name, %b by the file base name \(i.e. without
 447 extension) and %o by the base directory of the file."
 448   :group 'org-export-pdf
 449   :type '(choice
 450           (repeat :tag "Shell command sequence"
 451                   (string :tag "Shell command"))
 452           (const :tag "2 runs of pdfgroff"
 453                  ("pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf"
 454                   "pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf"))
 455           (const :tag "3 runs of pdfgroff"
 456                  ("pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf"
 457                   "pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf"
 458                   "pic %f | tbl | eqn | groff -mm | ps2pdf - > %b.pdf"))
 459           (function)))
 460
 461 (defcustom org-groff-logfiles-extensions
 462   '("aux" "idx" "log" "out" "toc" "nav" "snm" "vrb")
 463   "The list of file extensions to consider as Groff logfiles."
 464   :group 'org-export-groff
 465   :type '(repeat (string :tag "Extension")))
 466
 467 (defcustom org-groff-remove-logfiles t
 468   "Non-nil means remove the logfiles produced by PDF production.
 469 These are the .aux, .log, .out, and .toc files."
 470   :group 'org-export-groff
 471   :type 'boolean)
 472
 473 (defcustom org-groff-organization "Org User"
 474   "Name of the organization used to populate the .AF command."
 475   :group 'org-export-groff
 476   :type 'string)
 477
 478 (defcustom org-groff-raster-to-ps nil
 479   "Command used to convert raster to EPS. Nil for no conversion. Make sure that
 480    `org-groff-inline-image-rules' is adjusted accordingly if not conversion is being
 481    done. In this case, remove the entries for jpg and png in the file and fuzzy lists."
 482   :group 'org-export-groff
 483   :type '(choice
 484          (repeat :tag "Shell Command Sequence" (string :tag "Shell Command"))
 485          (const :tag "sam2p" "a=%s;b=%s;sam2p ${a} ${b} ;grep -v BeginData ${b} > b_${b};mv b_${b} ${b}" )
 486          (const :tag "NetPNM"  "a=%s;b=%s;pngtopnm ${a} | pnmtops -noturn > ${b}" )
 487          (const :tag "None" nil)))
 488
 489 (defvar org-groff-registered-references nil)
 490 (defvar org-groff-special-content nil)
 491
 492
 493 \f
 494 ;;; Internal Functions
 495
 496 (defun org-groff--caption/label-string (element info)
 497   "Return caption and label Groff string for ELEMENT.
 498
 499 INFO is a plist holding contextual information.  If there's no
 500 caption nor label, return the empty string.
 501
 502 For non-floats, see `org-groff--wrap-label'."
 503   (let ((main (org-export-get-caption element))
 504         (short (org-export-get-caption element t))
 505         (label (org-element-property :name element)))
 506     (cond ((and (not main) (not label)) "")
 507           ((not main) (format "\\fI%s\\fP" label))
 508           ;; Option caption format with short name.
 509           (short (format "%s\n.br\n - %s\n"
 510                          (org-export-data short info)
 511                          (org-export-data main info)))
 512           ;; Standard caption format.
 513           (t (format "\\fR%s\\fP" (org-export-data main info))))))
 514
 515 (defun org-groff--wrap-label (element output)
 516   "Wrap label associated to ELEMENT around OUTPUT, if appropriate.
 517 This function shouldn't be used for floats.  See
 518 `org-groff--caption/label-string'."
 519   (let ((label (org-element-property :name element)))
 520     (if (or (not output) (not label) (string= output "") (string= label ""))
 521         output
 522       (concat (format "%s\n.br\n" label) output))))
 523
 524 (defun org-groff--text-markup (text markup)
 525   "Format TEXT depending on MARKUP text markup.
 526 See `org-groff-text-markup-alist' for details."
 527   (let ((fmt (cdr (assq markup org-groff-text-markup-alist))))
 528     (cond
 529      ;; No format string: Return raw text.
 530      ((not fmt) text)
 531      ((string= "protectedtexttt" fmt)
 532       (let ((start 0)
 533             (trans '(("\\" . "\\")))
 534             (rtn "")
 535             char)
 536         (while (string-match "[\\{}$%&_#~^]" text)
 537           (setq char (match-string 0 text))
 538           (if (> (match-beginning 0) 0)
 539               (setq rtn (concat rtn (substring text 0 (match-beginning 0)))))
 540           (setq text (substring text (1+ (match-beginning 0))))
 541           (setq char (or (cdr (assoc char trans)) (concat "\\" char))
 542                 rtn (concat rtn char)))
 543         (setq text (concat rtn text))
 544         (format "\\fC%s\\fP" text)))
 545      ;; Else use format string.
 546      (t (format fmt text)))))
 547
 548
 549 (defun org-groff--get-tagged-content  (tag info)
 550   (cdr  (assoc tag org-groff-special-content)))
 551
 552 (defun org-groff--mt-head (title contents attr info)
 553   (concat
 554
 555    ;; 1. Insert Organization
 556    (let ((firm-option (plist-get attr :firm)))
 557      (cond
 558       ((stringp firm-option)
 559        (format ".AF \"%s\" \n" firm-option))
 560       (t (format ".AF \"%s\" \n" (or org-groff-organization "")))))
 561
 562    ;; 2. Title
 563    (let ((title (if (plist-get info :with-title) title ""))
 564          (subtitle1 (plist-get attr :subtitle1))
 565          (subtitle2 (plist-get attr :subtitle2)))
 566
 567      (cond
 568       ((string= "" title)
 569        (format ".TL \"%s\" \"%s\" \n%s\n"
 570                (or subtitle1 "")
 571                (or subtitle2 "") " "))
 572
 573       ((not (or subtitle1 subtitle2))
 574        (format ".TL\n%s\n"
 575                (or title "")))
 576       (t
 577        (format ".TL \"%s\" \"%s \" \n%s\n"
 578                (or subtitle1 "")
 579                (or subtitle2 "") title))))
 580
 581    ;; 3. Author.
 582    ;; In Groff, .AU *MUST* be placed after .TL
 583    ;; If From, populate with data from From else
 584    ;;
 585    (let ((author (and (plist-get info :with-author)
 586                       (let ((auth (plist-get info :author)))
 587                         (and auth (org-export-data auth info)))))
 588          (email (and (plist-get info :with-email)
 589                      (org-export-data (plist-get info :email) info)))
 590          (from-data  (org-groff--get-tagged-content "FROM" info))
 591
 592          (to-data  (org-groff--get-tagged-content "TO" info)))
 593
 594      (cond
 595       ((and author from-data)
 596        (let ((au-line
 597               (mapconcat
 598                (lambda (from-line)
 599                  (format " \"%s\" " from-line))
 600                (split-string
 601                 (setq from-data
 602                       (replace-regexp-in-string "\\.P\n" "" from-data)) "\n") "")))
 603
 604          (concat
 605           (format ".AU \"%s\" " author) au-line "\n")))
 606
 607       ((and author email (not (string= "" email)))
 608        (format ".AU \"%s\" \"%s\"\n" author email))
 609
 610       (author (format ".AU \"%s\"\n" author))
 611
 612       (t ".AU \"\" \n")))
 613
 614
 615    ;; 4. Author Title, if present
 616    (let ((at-item (plist-get attr :author-title)))
 617      (if (and at-item (stringp at-item))
 618          (format ".AT \"%s\" \n" at-item)
 619        ""))
 620
 621    ;; 5. Date.
 622    (when (plist-get info :with-date)
 623      (let ((date (org-export-data (org-export-get-date info) info)))
 624        (and (org-string-nw-p date) (format ".ND \"%s\"\n" date))))
 625
 626    ;;
 627    ;; If Abstract, then Populate Abstract
 628    ;;
 629
 630    (let ((abstract-data (org-groff--get-tagged-content "ABSTRACT" info))
 631          (to-data (org-groff--get-tagged-content "TO" info)))
 632      (cond
 633       (abstract-data
 634        (format ".AS\n%s\n.AE\n" abstract-data))
 635       (to-data
 636        (format ".AS\n%s\n.AE\n" to-data))))))
 637
 638 (defun org-groff--letter-head (title contents attr info)
 639   (let ((author (and (plist-get info :with-author)
 640                      (let ((auth (plist-get info :author)))
 641                        (and auth (org-export-data auth info)))))
 642         (email (and (plist-get info :with-email)
 643                     (org-export-data (plist-get info :email) info)))
 644         (from-data  (org-groff--get-tagged-content "FROM" info))
 645         (at-item (plist-get attr :author-title))
 646         (to-data  (org-groff--get-tagged-content "TO" info)))
 647
 648
 649     ;; If FROM then get data from FROM
 650     (if from-data
 651         (setq from-data
 652               (replace-regexp-in-string "\\.P\n" "" from-data))
 653       (setq from-data ""))
 654
 655     (if to-data
 656         (setq to-data
 657               (replace-regexp-in-string "\\.P\n" "" to-data))
 658       (setq from-data ""))
 659
 660     (concat
 661      (cond
 662       (from-data
 663        (format ".WA \"%s\" \"%s\" \n%s\n.WE\n" author (or at-item "") from-data))
 664       ((and author email (not (string= "" email)))
 665        (format ".WA \"%s\"\n \"%s\"\n.WE\n" author email))
 666       (author (format ".WA \"%s\"\n.WE\n" author))
 667       (t ".WA \"\" \n.WE\n"))
 668
 669      ;; If TO then get data from TO
 670
 671      (when to-data
 672        (format ".IA \n%s\n.IE\n" to-data)))))
 673
 674 \f
 675 ;;; Template
 676
 677 (defun org-groff-template (contents info)
 678   "Return complete document string after Groff conversion.
 679 CONTENTS is the transcoded contents string.  INFO is a plist
 680 holding export options."
 681   (let* ((title (org-export-data (plist-get info :title) info))
 682          (attr (read
 683                 (format "(%s)"
 684                         (mapconcat
 685                          #'identity
 686                          (list (plist-get info :groff-class-options))
 687                          " "))))
 688          (class (plist-get info :groff-class))
 689          (class-options (plist-get info :groff-class-options))
 690          (classes (assoc class org-groff-classes))
 691          (classes-options (car (last classes)))
 692          (heading-option (plist-get classes-options :heading))
 693          (type-option (plist-get classes-options :type))
 694          (last-option (plist-get classes-options :last-section))
 695          (hyphenate (plist-get attr :hyphenate))
 696          (justify-right (plist-get attr :justify-right))
 697
 698          (document-class-string
 699           (progn
 700             (org-element-normalize-string
 701              (let* ((header (nth 1 (assoc class org-groff-classes)))
 702                     (document-class-item (if (stringp header) header "")))
 703                document-class-item)))))
 704
 705
 706     (concat
 707      (if justify-right
 708          (case justify-right
 709            ('yes ".SA 1 \n")
 710            ('no ".SA 0 \n")
 711            (t ""))
 712        "")
 713
 714      (if hyphenate
 715          (case hyphenate
 716            ('yes ".nr Hy 1 \n")
 717            ('no ".nr Hy 0 \n")
 718            (t ""))
 719        "")
 720
 721      (cond
 722       ((string= type-option "custom") "")
 723
 724       ((and (stringp document-class-string)
 725             (string= type-option "cover"))
 726
 727        (concat
 728         (format ".COVER %s\n" document-class-string)
 729         (org-groff--mt-head title contents attr info)
 730         ".COVEND\n"))
 731
 732       ((string= type-option "memo")
 733        (concat
 734         (org-groff--mt-head title contents attr info)
 735         document-class-string))
 736       ((string= type-option "letter")
 737        (concat
 738         (org-groff--letter-head title contents attr info)
 739         (let ((sa-item (plist-get attr :salutation))
 740               (cn-item (plist-get attr :confidential))
 741               (sj-item (plist-get attr :subject))
 742               (rn-item (plist-get attr :reference))
 743               (at-item (plist-get attr :attention)))
 744
 745           (concat
 746
 747            (if (stringp sa-item)
 748                (format ".LO SA \"%s\" \n"  sa-item)
 749              ".LO SA\n")
 750
 751            (when cn-item
 752              (if (stringp cn-item)
 753                  (format ".LO CN \"%s\"\n" cn-item)
 754                ".LO CN\n"))
 755
 756            (when (and at-item (stringp at-item))
 757              (format ".LO AT \"%s\" \n"  at-item))
 758            (when (and title rn-item)
 759              (format ".LO RN \"%s\"\n" title))
 760
 761            (when (and sj-item (stringp sj-item))
 762              (format ".LO SJ \"%s\" \n"  sj-item))
 763
 764
 765            ".LT " document-class-string  "\n"))))
 766
 767       (t ""))
 768
 769      contents
 770
 771      (cond
 772       ((string= last-option "toc")
 773        ".TC")
 774       ((string= last-option "sign")
 775        (let ((fc-item (plist-get attr :closing)))
 776          (concat (if (stringp fc-item)
 777                      (format ".FC \"%s\" \n" fc-item)
 778                    ".FC\n")
 779                  ".SG\n")))
 780       (t ""))
 781
 782      (progn
 783        (mapconcat
 784         (lambda (item)
 785           (when (string= (car item) "NS")
 786             (replace-regexp-in-string
 787                     "\\.P\n" "" (cdr item))))
 788         (reverse org-groff-special-content) "\n")))))
 789
 790
 791 \f
 792 ;;; Transcode Functions
 793
 794 ;;; Babel Call
 795 ;;
 796 ;; Babel Calls are ignored.
 797
 798
 799 ;;; Bold
 800
 801 (defun org-groff-bold (bold contents info)
 802   "Transcode BOLD from Org to Groff.
 803 CONTENTS is the text with bold markup.  INFO is a plist holding
 804 contextual information."
 805   (org-groff--text-markup contents 'bold))
 806
 807 ;;; Center Block
 808
 809 (defun org-groff-center-block (center-block contents info)
 810   "Transcode a CENTER-BLOCK element from Org to Groff.
 811 CONTENTS holds the contents of the center block.  INFO is a plist
 812 holding contextual information."
 813   (org-groff--wrap-label
 814    center-block
 815    (format ".DS C \n%s\n.DE" contents)))
 816
 817 ;;; Clock
 818
 819 (defun org-groff-clock (clock contents info)
 820   "Transcode a CLOCK element from Org to Groff.
 821 CONTENTS is nil.  INFO is a plist holding contextual
 822 information."
 823   (concat
 824    (format "\\fB%s\\fP " org-clock-string)
 825    (format org-groff-inactive-timestamp-format
 826            (concat (org-timestamp-translate (org-element-property :value clock))
 827                    (let ((time (org-element-property :duration clock)))
 828                      (and time (format " (%s)" time)))))))
 829
 830 ;;; Code
 831
 832 (defun org-groff-code (code contents info)
 833   "Transcode a CODE object from Org to Groff.
 834 CONTENTS is nil.  INFO is a plist used as a communication
 835 channel."
 836   (org-groff--text-markup (org-element-property :value code) 'code))
 837
 838 ;;; Comments and Comment Blocks are ignored.
 839
 840 ;;; Drawer
 841
 842 (defun org-groff-drawer (drawer contents info)
 843   "Transcode a DRAWER element from Org to Groff.
 844 CONTENTS holds the contents of the block.  INFO is a plist
 845 holding contextual information."
 846   (let* ((name (org-element-property :drawer-name drawer))
 847          (output (if (functionp org-groff-format-drawer-function)
 848                      (funcall org-groff-format-drawer-function
 849                               name contents)
 850                    ;; If there's no user defined function: simply
 851                    ;; display contents of the drawer.
 852                    contents)))
 853     (org-groff--wrap-label drawer output)))
 854
 855 ;;; Dynamic Block
 856
 857 (defun org-groff-dynamic-block (dynamic-block contents info)
 858   "Transcode a DYNAMIC-BLOCK element from Org to Groff.
 859 CONTENTS holds the contents of the block.  INFO is a plist
 860 holding contextual information.  See `org-export-data'."
 861   (org-groff--wrap-label dynamic-block contents))
 862
 863 ;;; Entity
 864
 865 (defun org-groff-entity (entity contents info)
 866   "Transcode an ENTITY object from Org to Groff.
 867 CONTENTS are the definition itself.  INFO is a plist holding
 868 contextual information."
 869   (org-element-property :utf-8 entity))
 870
 871 ;;; Example Block
 872
 873 (defun org-groff-example-block (example-block contents info)
 874   "Transcode an EXAMPLE-BLOCK element from Org to Groff.
 875 CONTENTS is nil.  INFO is a plist holding contextual
 876 information."
 877   (org-groff--wrap-label
 878    example-block
 879    (format ".DS L\n%s\n.DE"
 880            (org-export-format-code-default example-block info))))
 881
 882 ;;; Export Block
 883
 884 (defun org-groff-export-block (export-block contents info)
 885   "Transcode a EXPORT-BLOCK element from Org to Groff.
 886 CONTENTS is nil.  INFO is a plist holding contextual information."
 887   (when (string= (org-element-property :type export-block) "GROFF")
 888     (org-remove-indentation (org-element-property :value export-block))))
 889
 890 ;;; Export Snippet
 891
 892 (defun org-groff-export-snippet (export-snippet contents info)
 893   "Transcode a EXPORT-SNIPPET object from Org to Groff.
 894 CONTENTS is nil.  INFO is a plist holding contextual information."
 895   (when (eq (org-export-snippet-backend export-snippet) 'groff)
 896     (org-element-property :value export-snippet)))
 897
 898 ;;; Fixed Width
 899
 900 (defun org-groff-fixed-width (fixed-width contents info)
 901   "Transcode a FIXED-WIDTH element from Org to Groff.
 902 CONTENTS is nil.  INFO is a plist holding contextual information."
 903   (org-groff--wrap-label
 904    fixed-width
 905    (format "\\fC\n%s\\fP"
 906            (org-remove-indentation
 907             (org-element-property :value fixed-width)))))
 908
 909 ;;; Footnote Definition
 910 ;;
 911 ;; Footnote Definitions are ignored.
 912 ;;
 913 ;; Footnotes are handled automatically in GROFF.  Although manual
 914 ;; references can be added, not really required.
 915
 916 (defun org-groff-footnote-reference (footnote-reference contents info)
 917   ;; Changing from info to footnote-reference
 918   (let* ((raw (org-export-get-footnote-definition footnote-reference info))
 919                  (n (org-export-get-footnote-number footnote-reference info))
 920                  (data (org-trim (org-export-data raw info)))
 921          (ref-id (plist-get (nth 1 footnote-reference) :label)))
 922     ;; It is a reference
 923     (if (string-match "fn:rl" ref-id)
 924         (if (member ref-id org-groff-registered-references)
 925             (format "\\*[%s]" ref-id)
 926           (progn
 927             (push ref-id org-groff-registered-references)
 928             (format "\\*(Rf\n.RS \"%s\" \n%s\n.RF\n" ref-id  data)))
 929       ;; else it is a footnote
 930       (format "\\u\\s-2%s\\d\\s+2\n.FS %s\n%s\n.FE\n" n n data))))
 931
 932 ;;; Headline
 933
 934 (defun org-groff-headline (headline contents info)
 935   "Transcode a HEADLINE element from Org to Groff.
 936 CONTENTS holds the contents of the headline.  INFO is a plist
 937 holding contextual information."
 938   (let* ((class (plist-get info :groff-class))
 939          (level (org-export-get-relative-level headline info))
 940          (numberedp (org-export-numbered-headline-p headline info))
 941          ;; Section formatting will set two placeholders: one for the
 942          ;; title and the other for the contents.
 943          (classes (assoc class org-groff-classes))
 944          (classes-options (car (last classes)))
 945          (heading-option (plist-get classes-options :heading))
 946          (section-fmt
 947           (progn
 948             (cond
 949              ((and (symbolp heading-option)
 950                    (fboundp heading-option))
 951               (funcall heading-option level numberedp))
 952              ((> level 7) nil)
 953              (t (if numberedp
 954                     (concat ".H " (number-to-string level) " \"%s\"\n%s")
 955                   ".HU \"%s\"\n%s")))))
 956          ;; End of section-fmt
 957          (text (org-export-data (org-element-property :title headline) info))
 958          (todo
 959           (and (plist-get info :with-todo-keywords)
 960                (let ((todo (org-element-property :todo-keyword headline)))
 961                  (and todo (org-export-data todo info)))))
 962          (todo-type (and todo (org-element-property :todo-type headline)))
 963          (tags (and (plist-get info :with-tags)
 964                     (org-export-get-tags headline info)))
 965          (priority (and (plist-get info :with-priority)
 966                         (org-element-property :priority headline)))
 967          ;; Create the headline text along with a no-tag version.  The
 968          ;; latter is required to remove tags from table of contents.
 969          (full-text (if (functionp org-groff-format-headline-function)
 970                         ;; User-defined formatting function.
 971                         (funcall org-groff-format-headline-function
 972                                  todo todo-type priority text tags)
 973                       ;; Default formatting.
 974                       (concat
 975                        (when todo
 976                          (format "\\fB%s\\fP " todo))
 977                        (when priority (format " [\\#%c] " priority))
 978                        text
 979                        (when tags
 980                          (format " \\fC:%s:\\fP "
 981                                  (mapconcat 'identity tags ":"))))))
 982          (full-text-no-tag
 983           (if (functionp org-groff-format-headline-function)
 984               ;; User-defined formatting function.
 985               (funcall org-groff-format-headline-function
 986                        todo todo-type priority text nil)
 987             ;; Default formatting.
 988             (concat
 989              (when todo (format "\\fB%s\\fP " todo))
 990              (when priority (format " [\\#%c] " priority))
 991              text)))
 992          ;; Associate some \label to the headline for internal links.
 993          ;;      (headline-label
 994          ;;       (format "\\label{sec-%s}\n"
 995          ;;               (mapconcat 'number-to-string
 996          ;;                          (org-export-get-headline-number headline info)
 997          ;;                          "-")))
 998          (headline-label "")
 999          (pre-blanks
1000           (make-string (org-element-property :pre-blank headline) 10)))
1001
1002     (cond
1003      ;; Case 1: Special Tag
1004      ((member (car  tags)  org-groff-special-tags)
1005       (cond
1006        ((string= (car tags) "BODY") contents)
1007
1008        ((string= (car tags) "NS")
1009         (progn
1010           (push (cons (car tags)
1011                       (format ".NS \"%s\" 1 \n%s"
1012                               (car (org-element-property :title headline))
1013                               (or contents " ")))
1014                 org-groff-special-content) nil))
1015
1016        (t
1017         (progn
1018           (push (cons  (car tags) contents) org-groff-special-content)
1019           nil))))
1020
1021      ;; Case 2: This is a footnote section: ignore it.
1022      ((org-element-property :footnote-section-p headline) nil)
1023
1024      ;; Case 3: This is a deep sub-tree: export it as a list item.
1025      ;;         Also export as items headlines for which no section
1026      ;;         format has been found.
1027      ((or (not section-fmt) (org-export-low-level-p headline info))
1028       ;; Build the real contents of the sub-tree.
1029       (let ((low-level-body
1030              (concat
1031               ;; If the headline is the first sibling, start a list.
1032               (when (org-export-first-sibling-p headline info)
1033                 (format "%s\n" (if numberedp ".AL 1\n" ".DL \n")))
1034               ;; Itemize headline
1035               ".LI\n" full-text "\n" headline-label pre-blanks contents)))
1036         ;; If headline is not the last sibling simply return
1037         ;; LOW-LEVEL-BODY.  Otherwise, also close the list, before any
1038         ;; blank line.
1039         (if (not (org-export-last-sibling-p headline info)) low-level-body
1040           (replace-regexp-in-string
1041            "[ \t\n]*\\'"
1042            (concat "\n.LE")
1043            low-level-body))))
1044
1045      ;; Case 4. Standard headline.  Export it as a section.
1046      (t
1047       (format section-fmt full-text
1048               (concat headline-label pre-blanks contents))))))
1049
1050 ;;; Horizontal Rule
1051 ;; Not supported
1052
1053 ;;; Inline Babel Call
1054 ;;
1055 ;; Inline Babel Calls are ignored.
1056
1057 ;;; Inline Src Block
1058
1059 (defun org-groff-inline-src-block (inline-src-block contents info)
1060   "Transcode an INLINE-SRC-BLOCK element from Org to Groff.
1061 CONTENTS holds the contents of the item.  INFO is a plist holding
1062 contextual information."
1063   (let* ((code (org-element-property :value inline-src-block)))
1064     (cond
1065      (org-groff-source-highlight
1066       (let* ((tmpdir temporary-file-directory)
1067              (in-file  (make-temp-name
1068                         (expand-file-name "srchilite" tmpdir)))
1069              (out-file (make-temp-name
1070                         (expand-file-name "reshilite" tmpdir)))
1071              (org-lang (org-element-property :language inline-src-block))
1072              (lst-lang (cadr (assq (intern org-lang)
1073                                    org-groff-source-highlight-langs)))
1074
1075              (cmd (concat (expand-file-name "source-highlight")
1076                           " -s " lst-lang
1077                           " -f groff_mm_color "
1078                           " -i " in-file
1079                           " -o " out-file)))
1080         (if lst-lang
1081             (let ((code-block ""))
1082               (with-temp-file in-file (insert code))
1083               (shell-command cmd)
1084               (setq code-block  (org-file-contents out-file))
1085               (delete-file in-file)
1086               (delete-file out-file)
1087               code-block)
1088           (format ".DS I\n\\fC\\m[black]%s\\m[]\\fP\n.DE\n"
1089                   code))))
1090
1091      ;; Do not use a special package: transcode it verbatim.
1092      (t
1093       (concat ".DS I\n" "\\fC" code "\\fP\n.DE\n")))))
1094
1095 ;;; Inlinetask
1096
1097 (defun org-groff-inlinetask (inlinetask contents info)
1098   "Transcode an INLINETASK element from Org to Groff.
1099 CONTENTS holds the contents of the block.  INFO is a plist
1100 holding contextual information."
1101   (let ((title (org-export-data (org-element-property :title inlinetask) info))
1102         (todo (and (plist-get info :with-todo-keywords)
1103                    (let ((todo (org-element-property :todo-keyword inlinetask)))
1104                      (and todo (org-export-data todo info)))))
1105         (todo-type (org-element-property :todo-type inlinetask))
1106         (tags (and (plist-get info :with-tags)
1107                    (org-export-get-tags inlinetask info)))
1108         (priority (and (plist-get info :with-priority)
1109                        (org-element-property :priority inlinetask))))
1110     ;; If `org-groff-format-inlinetask-function' is provided, call it
1111     ;; with appropriate arguments.
1112     (if (functionp org-groff-format-inlinetask-function)
1113         (funcall org-groff-format-inlinetask-function
1114                  todo todo-type priority title tags contents)
1115       ;; Otherwise, use a default template.
1116       (org-groff--wrap-label
1117        inlinetask
1118        (let ((full-title
1119               (concat
1120                (when todo (format "\\fB%s\\fP " todo))
1121                (when priority (format " [\\#%c] " priority))
1122                title
1123                (when tags (format " \\fC:%s:\\fP "
1124                                   (mapconcat 'identity tags ":"))))))
1125          (format (concat "\n.DS I\n"
1126                          "%s\n"
1127                          ".sp"
1128                          "%s\n"
1129                          ".DE")
1130                  full-title contents))))))
1131
1132 ;;; Italic
1133
1134 (defun org-groff-italic (italic contents info)
1135   "Transcode ITALIC from Org to Groff.
1136 CONTENTS is the text with italic markup.  INFO is a plist holding
1137 contextual information."
1138   (org-groff--text-markup contents 'italic))
1139
1140 ;;; Item
1141
1142 (defun org-groff-item (item contents info)
1143   "Transcode an ITEM element from Org to Groff.
1144 CONTENTS holds the contents of the item.  INFO is a plist holding
1145 contextual information."
1146   (let* ((bullet (org-element-property :bullet item))
1147          (type (org-element-property
1148                 :type (org-element-property :parent item)))
1149          (checkbox (case (org-element-property :checkbox item)
1150                      (on "\\o'\\(sq\\(mu'")
1151                      (off "\\(sq")
1152                      (trans "\\o'\\(sq\\(mi'")))
1153          (tag (let ((tag (org-element-property :tag item)))
1154                 ;; Check-boxes must belong to the tag.
1155                 (and tag (format "%s"
1156                                  (concat checkbox
1157                                          (org-export-data tag info)))))))
1158
1159         (cond
1160          ((or checkbox tag)
1161           (concat ".LI ""\"" (or tag (concat "\\ " checkbox)) "\""
1162               "\n"
1163               (org-trim (or contents " "))))
1164      ((eq type 'ordered)
1165       (concat ".LI"
1166               "\n"
1167               (org-trim (or contents " "))))
1168      (t
1169       (let* ((bullet (org-trim bullet))
1170              (marker (cond  ((string= "-" bullet) "\\(em")
1171                             ((string= "*" bullet) "\\(bu")
1172                             (t "\\(dg"))))
1173         (concat ".LI " marker "\n"
1174                 (org-trim (or contents " "))))))))
1175
1176 ;;; Keyword
1177
1178 (defun org-groff-keyword (keyword contents info)
1179   "Transcode a KEYWORD element from Org to Groff.
1180 CONTENTS is nil.  INFO is a plist holding contextual information."
1181   (let ((key (org-element-property :key keyword))
1182         (value (org-element-property :value keyword)))
1183     (cond
1184      ((string= key "GROFF") value)
1185      (t nil))))
1186
1187 ;;; Line Break
1188
1189 (defun org-groff-line-break (line-break contents info)
1190   "Transcode a LINE-BREAK object from Org to Groff.
1191 CONTENTS is nil.  INFO is a plist holding contextual information."
1192   ".br\n")
1193
1194 ;;; Link
1195 ;; Inline images just place a call to .PSPIC or .PS/.PE
1196 ;;  and load the graph.
1197
1198 (defun org-groff-link--inline-image (link info)
1199   "Return Groff code for an inline image.
1200 LINK is the link pointing to the inline image.  INFO is a plist
1201 used as a communication channel."
1202   (let* ((parent (org-export-get-parent-element link))
1203          (path (let ((raw-path (org-element-property :path link)))
1204                  (if (not (file-name-absolute-p raw-path)) raw-path
1205                    (expand-file-name raw-path))))
1206          (attr (org-export-read-attribute :attr_groff link))
1207          (placement
1208           (let ((pos (plist-get attr :position)))
1209             (cond ((string= pos 'center) "")
1210                   ((string= pos 'left) "-L")
1211                   ((string= pos 'right) "-R")
1212                   (t ""))))
1213          (width  (or (plist-get attr :width) ""))
1214          (height (or (plist-get attr :height) ""))
1215          (caption (and (not (plist-get attr :disable-caption))
1216                        (org-groff--caption/label-string parent info))))
1217     ;; Now clear ATTR from any special keyword and set a default value
1218     ;; if nothing is left.  Return proper string.
1219     (concat
1220      (cond
1221       ((and org-groff-raster-to-ps
1222             (or  (string-match ".\.png$" path)
1223                  (string-match ".\.jpg$" path)))
1224        (let ((eps-path (concat path ".eps")))
1225          (shell-command (format org-groff-raster-to-ps path eps-path))
1226          (format "\n.DS L F\n.PSPIC %s \"%s\" %s %s\n.DE "
1227                  placement eps-path width height)))
1228       ((string-match ".\.pic$" path)
1229        (format "\n.PS\ncopy \"%s\"\n.PE" path))
1230       (t (format "\n.DS L F\n.PSPIC %s \"%s\" %s %s\n.DE "
1231                  placement path width height)))
1232      (and caption (format "\n.FG \"%s\"" caption)))))
1233
1234 (defun org-groff-link (link desc info)
1235   "Transcode a LINK object from Org to Groff.
1236
1237 DESC is the description part of the link, or the empty string.
1238 INFO is a plist holding contextual information.  See
1239 `org-export-data'."
1240
1241   (let* ((type (org-element-property :type link))
1242          (raw-path (org-element-property :path link))
1243          ;; Ensure DESC really exists, or set it to nil.
1244          (desc (and (not (string= desc "")) desc))
1245          (imagep (org-export-inline-image-p
1246                   link org-groff-inline-image-rules))
1247          (path (cond
1248                 ((member type '("http" "https" "ftp" "mailto"))
1249                  (concat type ":" raw-path))
1250                 ((string= type "file") (org-export-file-uri raw-path))
1251                 (t raw-path))))
1252     (cond
1253      ((org-export-custom-protocol-maybe link desc 'groff))
1254      ;; Image file.
1255      (imagep (org-groff-link--inline-image link info))
1256      ;; import groff files
1257      ((and (string= type "file")
1258            (string-match ".\.groff$" raw-path))
1259       (concat ".so " raw-path "\n"))
1260      ;; Radio link: transcode target's contents and use them as link's
1261      ;; description.
1262      ((string= type "radio")
1263       (let ((destination (org-export-resolve-radio-link link info)))
1264         (if (not destination) desc
1265           (format "\\fI [%s] \\fP"
1266                   (org-export-get-reference destination info)))))
1267
1268      ;; Links pointing to a headline: find destination and build
1269      ;; appropriate referencing command.
1270      ((member type '("custom-id" "fuzzy" "id"))
1271       (let ((destination (if (string= type "fuzzy")
1272                              (org-export-resolve-fuzzy-link link info)
1273                            (org-export-resolve-id-link link info))))
1274         (case (org-element-type destination)
1275           ;; Id link points to an external file.
1276           (plain-text
1277            (if desc (format "%s \\fBat\\fP \\fIfile://%s\\fP" desc destination)
1278              (format "\\fI file://%s \\fP" destination)))
1279           ;; Fuzzy link points nowhere.
1280           ('nil
1281            (format org-groff-link-with-unknown-path-format
1282                    (or desc
1283                        (org-export-data
1284                         (org-element-property :raw-link link) info))))
1285           ;; LINK points to a headline.  If headlines are numbered and
1286           ;; the link has no description, display headline's number.
1287           ;; Otherwise, display description or headline's title.
1288           (headline
1289            (let ((label ""))
1290              (if (and (plist-get info :section-numbers) (not desc))
1291                  (format "\\fI%s\\fP" label)
1292                (format "\\fI%s\\fP"
1293                        (or desc
1294                            (org-export-data
1295                             (org-element-property :title destination) info))))))
1296           ;; Fuzzy link points to a target.  Do as above.
1297           (otherwise
1298            (let ((ref (org-export-get-reference destination info)))
1299              (if (not desc) (format "\\fI%s\\fP" ref)
1300                (format "%s \\fBat\\fP \\fI%s\\fP" desc ref)))))))
1301      ;; External link with a description part.
1302      ((and path desc) (format "%s \\fBat\\fP \\fI%s\\fP" path desc))
1303      ;; External link without a description part.
1304      (path (format "\\fI%s\\fP" path))
1305      ;; No path, only description.  Try to do something useful.
1306      (t (format org-groff-link-with-unknown-path-format desc)))))
1307
1308 ;;; Node Property
1309
1310 (defun org-groff-node-property (node-property contents info)
1311   "Transcode a NODE-PROPERTY element from Org to Groff.
1312 CONTENTS is nil.  INFO is a plist holding contextual
1313 information."
1314   (format "%s:%s"
1315           (org-element-property :key node-property)
1316           (let ((value (org-element-property :value node-property)))
1317             (if value (concat " " value) ""))))
1318
1319 ;;; Paragraph
1320
1321 (defun org-groff-paragraph (paragraph contents info)
1322   "Transcode a PARAGRAPH element from Org to Groff.
1323 CONTENTS is the contents of the paragraph, as a string.  INFO is
1324 the plist used as a communication channel."
1325   (let ((parent (plist-get (nth 1 paragraph) :parent)))
1326     (when parent
1327       (let* ((parent-type (car parent))
1328              (fixed-paragraph "")
1329              (class (plist-get info :groff-class))
1330              (class-options (plist-get info :groff-class-options))
1331              (classes (assoc class org-groff-classes))
1332              (classes-options (car (last classes)))
1333              (paragraph-option (plist-get classes-options :paragraph)))
1334         (cond
1335          ((and (symbolp paragraph-option)
1336                (fboundp paragraph-option))
1337           (funcall paragraph-option parent-type parent contents))
1338          ((and (eq parent-type 'item)
1339                (plist-get (nth 1 parent) :bullet))
1340           (setq fixed-paragraph (concat "" contents)))
1341          ((eq parent-type 'section)
1342           (setq fixed-paragraph (concat ".P\n" contents)))
1343          ((eq parent-type 'footnote-definition)
1344           (setq fixed-paragraph (concat "" contents)))
1345          (t (setq fixed-paragraph (concat "" contents))))
1346         fixed-paragraph))))
1347
1348 ;;; Plain List
1349
1350 (defun org-groff-plain-list (plain-list contents info)
1351   "Transcode a PLAIN-LIST element from Org to Groff.
1352 CONTENTS is the contents of the list.  INFO is a plist holding
1353 contextual information."
1354   (let* ((type (org-element-property :type plain-list))
1355          (attr (mapconcat #'identity
1356                           (org-element-property :attr_groff plain-list)
1357                           " "))
1358          (groff-type (cond
1359                       ((eq type 'ordered) ".AL")
1360                       ((eq type 'unordered) ".BL")
1361                       ((eq type 'descriptive) ".VL 2.0i"))))
1362     (org-groff--wrap-label
1363      plain-list
1364      (format "%s\n%s\n.LE" groff-type contents))))
1365
1366 ;;; Plain Text
1367
1368 (defun org-groff-plain-text (text info)
1369   "Transcode a TEXT string from Org to Groff.
1370 TEXT is the string to transcode.  INFO is a plist holding
1371 contextual information."
1372 (let ((output text))
1373   ;; Protect various characters.
1374   (setq output (replace-regexp-in-string
1375                 "\\(?:[^\\]\\|^\\)\\(\\\\\\)\\(?:[^%$#&{}~^_\\]\\|$\\)"
1376                 "$\\" output nil t 1))
1377   ;; Activate smart quotes.  Be sure to provide original TEXT string
1378   ;; since OUTPUT may have been modified.
1379   (when (plist-get info :with-smart-quotes)
1380     (setq output (org-export-activate-smart-quotes output :utf-8 info text)))
1381   ;; Handle Special Characters
1382   (if org-groff-special-char
1383       (dolist (special-char-list org-groff-special-char)
1384         (setq output
1385               (replace-regexp-in-string (car special-char-list)
1386                                         (cdr special-char-list) output))))
1387   ;; Handle break preservation if required.
1388   (when (plist-get info :preserve-breaks)
1389     (setq output (replace-regexp-in-string
1390                   "\\(\\\\\\\\\\)?[ \t]*\n" ".br\n" output)))
1391   ;; Return value.
1392   output))
1393
1394 ;;; Planning
1395
1396 (defun org-groff-planning (planning contents info)
1397   "Transcode a PLANNING element from Org to Groff.
1398 CONTENTS is nil.  INFO is a plist holding contextual
1399 information."
1400   (concat
1401    (mapconcat
1402     'identity
1403     (delq nil
1404           (list
1405            (let ((closed (org-element-property :closed planning)))
1406              (when closed
1407                (concat
1408                 (format "\\fR %s \\fP" org-closed-string)
1409                 (format org-groff-inactive-timestamp-format
1410                         (org-timestamp-translate closed)))))
1411            (let ((deadline (org-element-property :deadline planning)))
1412              (when deadline
1413                (concat
1414                 (format "\\fB %s \\fP" org-deadline-string)
1415                 (format org-groff-active-timestamp-format
1416                         (org-timestamp-translate deadline)))))
1417            (let ((scheduled (org-element-property :scheduled planning)))
1418              (when scheduled
1419                (concat
1420                 (format "\\fR %s \\fP" org-scheduled-string)
1421                 (format org-groff-active-timestamp-format
1422                         (org-timestamp-translate scheduled)))))))
1423     "")
1424    ""))
1425
1426 ;;;; Property Drawer
1427
1428 (defun org-groff-property-drawer (property-drawer contents info)
1429   "Transcode a PROPERTY-DRAWER element from Org to Groff.
1430 CONTENTS holds the contents of the drawer.  INFO is a plist
1431 holding contextual information."
1432   (and (org-string-nw-p contents)
1433        (format "\\fC\n%s\\fP" contents)))
1434
1435 ;;; Quote Block
1436
1437 (defun org-groff-quote-block (quote-block contents info)
1438   "Transcode a QUOTE-BLOCK element from Org to Groff.
1439 CONTENTS holds the contents of the block.  INFO is a plist
1440 holding contextual information."
1441   (org-groff--wrap-label
1442    quote-block
1443    (format ".DS I\n.I\n%s\n.R\n.DE" contents)))
1444
1445 ;;; Radio Target
1446
1447 (defun org-groff-radio-target (radio-target text info)
1448   "Transcode a RADIO-TARGET object from Org to Groff.
1449 TEXT is the text of the target.  INFO is a plist holding
1450 contextual information."
1451   (format "%s - %s" (org-export-get-reference radio-target info) text))
1452
1453 ;;; Section
1454
1455 (defun org-groff-section (section contents info)
1456   "Transcode a SECTION element from Org to Groff.
1457 CONTENTS holds the contents of the section.  INFO is a plist
1458 holding contextual information."
1459   contents)
1460
1461 ;;; Special Block
1462
1463 (defun org-groff-special-block (special-block contents info)
1464   "Transcode a SPECIAL-BLOCK element from Org to Groff.
1465 CONTENTS holds the contents of the block.  INFO is a plist
1466 holding contextual information."
1467   (let ((type (org-element-property :type special-block)))
1468     (org-groff--wrap-label
1469      special-block
1470      (format "%s\n" contents))))
1471
1472 ;;; Src Block
1473
1474 (defun org-groff-src-block (src-block contents info)
1475   "Transcode a SRC-BLOCK element from Org to Groff.
1476 CONTENTS holds the contents of the item.  INFO is a plist holding
1477 contextual information."
1478   (let* ((lang (org-element-property :language src-block))
1479          (label (org-element-property :name src-block))
1480          (code (org-element-property :value src-block))
1481          (custom-env (and lang
1482                           (cadr (assq (intern lang)
1483                                       org-groff-custom-lang-environments))))
1484          (num-start (org-export-get-loc src-block info))
1485          (retain-labels (org-element-property :retain-labels src-block))
1486          (caption (and (not (org-export-read-attribute
1487                              :attr_groff src-block :disable-caption))
1488                        (org-groff--caption/label-string src-block info))))
1489
1490     (cond
1491      ;; Case 1.  No source fontification.
1492      ((not org-groff-source-highlight)
1493       (concat
1494        (format ".DS I\n\\fC%s\\fP\n.DE\n"
1495                (org-export-format-code-default src-block info))
1496        (and caption (format ".EX \"%s\" " caption))))
1497
1498      ;; Case 2.  Source fontification.
1499      (org-groff-source-highlight
1500       (let* ((tmpdir temporary-file-directory)
1501              (in-file  (make-temp-name
1502                         (expand-file-name "srchilite" tmpdir)))
1503              (out-file (make-temp-name
1504                         (expand-file-name "reshilite" tmpdir)))
1505
1506              (org-lang (org-element-property :language src-block))
1507              (lst-lang (cadr (assq (intern org-lang)
1508                                    org-groff-source-highlight-langs)))
1509
1510              (cmd (concat "source-highlight"
1511                           " -s " lst-lang
1512                           " -f groff_mm_color "
1513                           " -i " in-file
1514                           " -o " out-file)))
1515
1516         (concat
1517          (if lst-lang
1518              (let ((code-block ""))
1519                (with-temp-file in-file (insert code))
1520                (shell-command cmd)
1521                (setq code-block  (org-file-contents out-file))
1522                (delete-file in-file)
1523                (delete-file out-file)
1524                (format "%s\n"  code-block))
1525            (format ".DS I\n\\fC\\m[black]%s\\m[]\\fP\n.DE\n"
1526                    code))
1527          (and caption (format ".EX \"%s\" " caption))))))))
1528
1529
1530 ;;; Statistics Cookie
1531
1532 (defun org-groff-statistics-cookie (statistics-cookie contents info)
1533   "Transcode a STATISTICS-COOKIE object from Org to Groff.
1534 CONTENTS is nil.  INFO is a plist holding contextual information."
1535   (org-element-property :value statistics-cookie))
1536
1537
1538 ;;; Strike-Through
1539
1540 (defun org-groff-strike-through (strike-through contents info)
1541   "Transcode STRIKE-THROUGH from Org to Groff.
1542 CONTENTS is the text with strike-through markup.  INFO is a plist
1543 holding contextual information."
1544   (org-groff--text-markup contents 'strike-through))
1545
1546 ;;; Subscript
1547
1548 (defun org-groff-subscript (subscript contents info)
1549   "Transcode a SUBSCRIPT object from Org to Groff.
1550 CONTENTS is the contents of the object.  INFO is a plist holding
1551 contextual information."
1552   (format  "\\d\\s-2%s\\s+2\\u" contents))
1553
1554 ;;; Superscript "^_%s$
1555
1556 (defun org-groff-superscript (superscript contents info)
1557   "Transcode a SUPERSCRIPT object from Org to Groff.
1558 CONTENTS is the contents of the object.  INFO is a plist holding
1559 contextual information."
1560   (format  "\\u\\s-2%s\\s+2\\d" contents))
1561
1562
1563 ;;; Table
1564 ;;
1565 ;; `org-groff-table' is the entry point for table transcoding.  It
1566 ;; takes care of tables with a "verbatim" attribute.  Otherwise, it
1567 ;; delegates the job to  `org-groff-table--org-table' function,
1568 ;; depending of the type of the table.
1569 ;;
1570 ;; `org-groff-table--align-string' is a subroutine used to build
1571 ;; alignment string for Org tables.
1572
1573 (defun org-groff-table (table contents info)
1574   "Transcode a TABLE element from Org to Groff.
1575 CONTENTS is the contents of the table.  INFO is a plist holding
1576 contextual information."
1577   (cond
1578    ;; Case 1: verbatim table.
1579    ((or org-groff-tables-verbatim
1580         (let ((attr (read (format "(%s)"
1581                  (mapconcat
1582                   #'identity
1583                                    (org-element-property :attr_groff table) " ")))))
1584           (and attr (plist-get attr :verbatim))))
1585
1586     (format ".DS L\n\\fC%s\\fP\n.DE"
1587             ;; Re-create table, without affiliated keywords.
1588             (org-trim
1589              (org-element-interpret-data
1590               `(table nil ,@(org-element-contents table))))))
1591
1592    ;; Case 2: Standard table.
1593    (t (org-groff-table--org-table table contents info))))
1594
1595 (defun org-groff-table--align-string (divider table info)
1596   "Return an appropriate Groff alignment string.
1597 TABLE is the considered table.  INFO is a plist used as
1598 a communication channel."
1599   (let (alignment)
1600     ;; Extract column groups and alignment from first (non-rule) row.
1601     (org-element-map
1602         (org-element-map table 'table-row
1603           (lambda (row)
1604             (and (eq (org-element-property :type row) 'standard) row))
1605           info 'first-match)
1606         'table-cell
1607       (lambda (cell)
1608         (let* ((borders (org-export-table-cell-borders cell info))
1609                (raw-width (org-export-table-cell-width cell info))
1610                (width-cm (when raw-width (/ raw-width 5)))
1611                (width (if raw-width (format "w(%dc)"
1612                                             (if (< width-cm 1) 1 width-cm)) "")))
1613           ;; Check left border for the first cell only.
1614           ;; Alignment is nil on assignment
1615
1616           (when (and (memq 'left borders) (not alignment))
1617             (push "|" alignment))
1618           (push
1619            (case (org-export-table-cell-alignment cell info)
1620              (left (concat "l" width divider))
1621              (right (concat "r" width divider))
1622              (center (concat "c" width divider)))
1623            alignment)
1624           (when (memq 'right borders) (push "|" alignment))))
1625       info)
1626     (apply 'concat (reverse alignment))))
1627
1628 (defun org-groff-table--org-table (table contents info)
1629   "Return appropriate Groff code for an Org table.
1630
1631 TABLE is the table type element to transcode.  CONTENTS is its
1632 contents, as a string.  INFO is a plist used as a communication
1633 channel.
1634
1635 This function assumes TABLE has `org' as its `:type' attribute."
1636   (let* ((attr (org-export-read-attribute :attr_groff table))
1637          (label (org-element-property :name table))
1638          (caption (and (not (plist-get attr :disable-caption))
1639                        (org-groff--caption/label-string table info)))
1640          (divider (if (plist-get attr :divider) "|" " "))
1641
1642          ;; Determine alignment string.
1643          (alignment (org-groff-table--align-string divider table info))
1644
1645          ;; Extract others display options.
1646
1647          (lines (org-split-string contents "\n"))
1648
1649          (attr-list
1650           (delq nil
1651                 (list (and (plist-get attr :expand) "expand")
1652                       (let ((placement (plist-get attr :placement)))
1653                         (cond ((string= placement 'center) "center")
1654                               ((string= placement 'left) nil)
1655                               (t (if org-groff-tables-centered "center" ""))))
1656                       (or (plist-get attr :boxtype) "box"))))
1657
1658          (title-line  (plist-get attr :title-line))
1659          (long-cells (plist-get attr :long-cells))
1660
1661          (table-format
1662           (concat
1663            (or (car attr-list) "")
1664            (or
1665             (let (output-list)
1666               (when (cdr attr-list)
1667                 (dolist (attr-item (cdr attr-list))
1668                   (setq output-list (concat output-list
1669                                             (format ",%s" attr-item)))))
1670               output-list) "")))
1671          (first-line
1672           (when lines (org-split-string (car lines) "\t"))))
1673     ;; Prepare the final format string for the table.
1674
1675
1676     (cond
1677      ;; Others.
1678      (lines
1679       (concat ".TS\n " table-format ";\n"
1680               (format "%s.\n"
1681                       (let ((final-line ""))
1682                         (when title-line
1683                           (dotimes (i (length first-line))
1684                             (setq final-line (concat final-line "cb" divider))))
1685
1686                         (setq final-line (concat final-line "\n"))
1687
1688                         (if alignment
1689                             (setq final-line (concat final-line alignment))
1690                           (dotimes (i (length first-line))
1691                             (setq final-line (concat final-line "c" divider))))
1692                         final-line))
1693
1694               (format "%s.TE\n"
1695                       (let ((final-line "")
1696                             (long-line "")
1697                             (lines (org-split-string contents "\n")))
1698
1699                         (dolist (line-item lines)
1700                           (setq long-line "")
1701
1702                           (if long-cells
1703                               (progn
1704                                 (if (string= line-item "_")
1705                                     (setq long-line (format "%s\n" line-item))
1706                                   ;; else string =
1707                                   (let ((cell-item-list (org-split-string line-item "\t")))
1708                                     (dolist (cell-item cell-item-list)
1709
1710                                       (cond  ((eq cell-item (car (last cell-item-list)))
1711                                               (setq long-line (concat long-line
1712                                                                       (format "T{\n%s\nT}\t\n"  cell-item))))
1713                                              (t
1714                                               (setq long-line (concat long-line
1715                                                                       (format "T{\n%s\nT}\t"  cell-item))))))
1716                                     long-line))
1717                                 ;; else long cells
1718                                 (setq final-line (concat final-line long-line)))
1719
1720                             (setq final-line (concat final-line line-item "\n"))))
1721                         final-line))
1722
1723               (if caption (format ".TB \"%s\"" caption) ""))))))
1724
1725 ;;; Table Cell
1726
1727 (defun org-groff-table-cell (table-cell contents info)
1728   "Transcode a TABLE-CELL element from Org to Groff
1729 CONTENTS is the cell contents.  INFO is a plist used as
1730 a communication channel."
1731   (progn
1732     (concat (if (and contents
1733                      org-groff-table-scientific-notation
1734                      (string-match orgtbl-exp-regexp contents))
1735                 ;; Use appropriate format string for scientific
1736                 ;; notation.
1737                 (format org-groff-table-scientific-notation
1738                         (match-string 1 contents)
1739                         (match-string 2 contents))
1740               contents)
1741             (when (org-export-get-next-element table-cell info) "\t"))))
1742
1743
1744 ;;; Table Row
1745
1746 (defun org-groff-table-row (table-row contents info)
1747   "Transcode a TABLE-ROW element from Org to Groff
1748 CONTENTS is the contents of the row.  INFO is a plist used as
1749 a communication channel."
1750   ;; Rules are ignored since table separators are deduced from
1751   ;; borders of the current row.
1752   (when (eq (org-element-property :type table-row) 'standard)
1753     (let* ((attr (mapconcat 'identity
1754                             (org-element-property
1755                              :attr_groff (org-export-get-parent table-row))
1756                             " "))
1757            ;; TABLE-ROW's borders are extracted from its first cell.
1758            (borders
1759             (org-export-table-cell-borders
1760              (car (org-element-contents table-row)) info)))
1761       (concat
1762        ;; Mark horizontal lines
1763        (cond  ((and (memq 'top borders) (memq 'above borders)) "_\n"))
1764        contents
1765        (cond
1766         ;; When BOOKTABS are activated enforce bottom rule even when
1767         ;; no hline was specifically marked.
1768         ((and (memq 'bottom borders) (memq 'below borders)) "\n_")
1769         ((memq 'below borders) "\n_"))))))
1770
1771 ;;; Target
1772
1773 (defun org-groff-target (target contents info)
1774   "Transcode a TARGET object from Org to Groff.
1775 CONTENTS is nil.  INFO is a plist holding contextual
1776 information."
1777   (format "\\fI%s\\fP" (org-export-get-reference target info)))
1778
1779 ;;; Timestamp
1780
1781 (defun org-groff-timestamp (timestamp contents info)
1782   "Transcode a TIMESTAMP object from Org to Groff.
1783 CONTENTS is nil.  INFO is a plist holding contextual
1784 information."
1785   (let ((value (org-groff-plain-text
1786                 (org-timestamp-translate timestamp) info)))
1787     (case (org-element-property :type timestamp)
1788       ((active active-range)
1789        (format org-groff-active-timestamp-format value))
1790       ((inactive inactive-range)
1791        (format org-groff-inactive-timestamp-format value))
1792       (t (format org-groff-diary-timestamp-format value)))))
1793
1794 ;;; Underline
1795
1796 (defun org-groff-underline (underline contents info)
1797   "Transcode UNDERLINE from Org to Groff.
1798 CONTENTS is the text with underline markup.  INFO is a plist
1799 holding contextual information."
1800   (org-groff--text-markup contents 'underline))
1801
1802 ;;; Verbatim
1803
1804 (defun org-groff-verbatim (verbatim contents info)
1805   "Transcode a VERBATIM object from Org to Groff.
1806 CONTENTS is nil.  INFO is a plist used as a communication
1807 channel."
1808   (org-groff--text-markup (org-element-property :value verbatim) 'verbatim))
1809
1810 ;;; Verse Block
1811
1812 (defun org-groff-verse-block (verse-block contents info)
1813   "Transcode a VERSE-BLOCK element from Org to Groff.
1814 CONTENTS is verse block contents. INFO is a plist holding
1815 contextual information."
1816   (format ".DS C\n.ft HI\n%s\n.ft\n.DE" contents))
1817
1818 \f
1819 ;;; Interactive functions
1820
1821 (defun org-groff-export-to-groff
1822   (&optional async subtreep visible-only body-only ext-plist)
1823   "Export current buffer to a Groff file.
1824
1825 If narrowing is active in the current buffer, only export its
1826 narrowed part.
1827
1828 If a region is active, export that region.
1829
1830 A non-nil optional argument ASYNC means the process should happen
1831 asynchronously.  The resulting file should be accessible through
1832 the `org-export-stack' interface.
1833
1834 When optional argument SUBTREEP is non-nil, export the sub-tree
1835 at point, extracting information from the headline properties
1836 first.
1837
1838 When optional argument VISIBLE-ONLY is non-nil, don't export
1839 contents of hidden elements.
1840
1841 EXT-PLIST, when provided, is a property list with external
1842 parameters overriding Org default settings, but still inferior to
1843 file-local settings.
1844
1845 Return output file's name."
1846   (interactive)
1847   (let ((outfile (org-export-output-file-name ".groff" subtreep))
1848         (org-groff-registered-references nil)
1849         (org-groff-special-content nil))
1850     (org-export-to-file 'groff outfile
1851       async subtreep visible-only body-only ext-plist)))
1852
1853 (defun org-groff-export-to-pdf
1854   (&optional async subtreep visible-only body-only ext-plist)
1855   "Export current buffer to Groff then process through to PDF.
1856
1857 If narrowing is active in the current buffer, only export its
1858 narrowed part.
1859
1860 If a region is active, export that region.
1861
1862 A non-nil optional argument ASYNC means the process should happen
1863 asynchronously.  The resulting file should be accessible through
1864 the `org-export-stack' interface.
1865
1866 When optional argument SUBTREEP is non-nil, export the sub-tree
1867 at point, extracting information from the headline properties
1868 first.
1869
1870 When optional argument VISIBLE-ONLY is non-nil, don't export
1871 contents of hidden elements.
1872
1873 EXT-PLIST, when provided, is a property list with external
1874 parameters overriding Org default settings, but still inferior to
1875 file-local settings.
1876
1877 Return PDF file's name."
1878   (interactive)
1879   (let ((outfile (org-export-output-file-name ".groff" subtreep)))
1880     (org-export-to-file 'groff outfile
1881       async subtreep visible-only body-only ext-plist
1882       (lambda (file) (org-groff-compile file)))))
1883
1884 (defun org-groff-compile (file)
1885   "Compile a Groff file.
1886
1887 FILE is the name of the file being compiled.  Processing is done
1888 through the command specified in `org-groff-pdf-process'.
1889
1890 Return PDF file name or an error if it couldn't be produced."
1891   (let* ((base-name (file-name-sans-extension (file-name-nondirectory file)))
1892          (full-name (file-truename file))
1893          (out-dir (file-name-directory file))
1894          (time (current-time))
1895          ;; Properly set working directory for compilation.
1896          (default-directory (if (file-name-absolute-p file)
1897                                 (file-name-directory full-name)
1898                               default-directory))
1899          errors)
1900     (message (format "Processing Groff file %s ..." file))
1901     (save-window-excursion
1902       (cond
1903        ;; A function is provided: Apply it.
1904        ((functionp org-groff-pdf-process)
1905         (funcall org-groff-pdf-process (shell-quote-argument file)))
1906        ;; A list is provided: Replace %b, %f and %o with appropriate
1907        ;; values in each command before applying it.  Output is
1908        ;; redirected to "*Org PDF Groff Output*" buffer.
1909        ((consp org-groff-pdf-process)
1910         (let ((outbuf (get-buffer-create "*Org PDF Groff Output*")))
1911           (mapc
1912            (lambda (command)
1913              (shell-command
1914               (replace-regexp-in-string
1915                "%b" (shell-quote-argument base-name)
1916                (replace-regexp-in-string
1917                 "%f" (shell-quote-argument full-name)
1918                 (replace-regexp-in-string
1919                  "%o" (shell-quote-argument out-dir) command t t)
1920                 t t) t t)
1921               outbuf))
1922            org-groff-pdf-process)
1923           ;; Collect standard errors from output buffer.
1924           (setq errors (org-groff-collect-errors outbuf))))
1925        (t (error "No valid command to process to PDF")))
1926       (let ((pdffile (concat out-dir base-name ".pdf")))
1927         ;; Check for process failure.  Provide collected errors if
1928         ;; possible.
1929         (if (or (not (file-exists-p pdffile))
1930                 ;; Only compare times up to whole seconds as some
1931                 ;; filesystems (e.g. HFS+) do not retain any finer
1932                 ;; granularity.
1933                 (time-less-p (cl-subseq (nth 5 (file-attributes pdffile)) 0 2)
1934                              (cl-subseq time 0 2)))
1935             (error (concat (format "PDF file %s wasn't produced" pdffile)
1936                            (when errors (concat ": " errors))))
1937           ;; Else remove log files, when specified, and signal end of
1938           ;; process to user, along with any error encountered.
1939           (when org-groff-remove-logfiles
1940             (dolist (ext org-groff-logfiles-extensions)
1941               (let ((file (concat out-dir base-name "." ext)))
1942                 (when (file-exists-p file) (delete-file file)))))
1943           (message (concat "Process completed"
1944                            (if (not errors) "."
1945                              (concat " with errors: " errors)))))
1946         ;; Return output file name.
1947         pdffile))))
1948
1949 (defun org-groff-collect-errors (buffer)
1950   "Collect some kind of errors from \"groff\" output
1951 BUFFER is the buffer containing output.
1952 Return collected error types as a string, or nil if there was
1953 none."
1954   (with-current-buffer buffer
1955     (save-excursion
1956       (goto-char (point-max))
1957       ;; Find final run
1958       nil)))
1959
1960
1961 (provide 'ox-groff)
1962 ;;; ox-groff.el ends here