lisp/ob-js.el

   1 ;;; ob-js.el --- org-babel functions for Javascript
   2
   3 ;; Copyright (C) 2010-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research, js
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Now working with SBCL for both session and external evaluation.
  27 ;;
  28 ;; This certainly isn't optimally robust, but it seems to be working
  29 ;; for the basic use cases.
  30
  31 ;;; Requirements:
  32
  33 ;; - a non-browser javascript engine such as node.js http://nodejs.org/
  34 ;;   or mozrepl http://wiki.github.com/bard/mozrepl/
  35 ;;
  36 ;; - for session based evaluation mozrepl and moz.el are required see
  37 ;;   http://wiki.github.com/bard/mozrepl/emacs-integration for
  38 ;;   configuration instructions
  39
  40 ;;; Code:
  41 (require 'ob)
  42 (eval-when-compile (require 'cl))
  43
  44 (declare-function run-mozilla "ext:moz" (arg))
  45
  46 (defvar org-babel-default-header-args:js '()
  47   "Default header arguments for js code blocks.")
  48
  49 (defvar org-babel-js-eoe "org-babel-js-eoe"
  50   "String to indicate that evaluation has completed.")
  51
  52 (defcustom org-babel-js-cmd "node"
  53   "Name of command used to evaluate js blocks."
  54   :group 'org-babel
  55   :version "24.1"
  56   :type 'string)
  57
  58 (defvar org-babel-js-function-wrapper
  59   "require('sys').print(require('sys').inspect(function(){%s}()));"
  60   "Javascript code to print value of body.")
  61
  62 (defun org-babel-execute:js (body params)
  63   "Execute a block of Javascript code with org-babel.
  64 This function is called by `org-babel-execute-src-block'"
  65   (let* ((org-babel-js-cmd (or (cdr (assoc :cmd params)) org-babel-js-cmd))
  66          (result-type (cdr (assoc :result-type params)))
  67          (full-body (org-babel-expand-body:generic
  68                      body params (org-babel-variable-assignments:js params))))
  69     (org-babel-js-read
  70      (if (not (string= (cdr (assoc :session params)) "none"))
  71          ;; session evaluation
  72          (let ((session (org-babel-prep-session:js
  73                          (cdr (assoc :session params)) params)))
  74            (nth 1
  75                 (org-babel-comint-with-output
  76                     (session (format "%S" org-babel-js-eoe) t body)
  77                   (mapc
  78                    (lambda (line)
  79                      (insert (org-babel-chomp line)) (comint-send-input nil t))
  80                    (list body (format "%S" org-babel-js-eoe))))))
  81        ;; external evaluation
  82        (let ((script-file (org-babel-temp-file "js-script-")))
  83          (with-temp-file script-file
  84            (insert
  85             ;; return the value or the output
  86             (if (string= result-type "value")
  87                 (format org-babel-js-function-wrapper full-body)
  88               full-body)))
  89          (org-babel-eval
  90           (format "%s %s" org-babel-js-cmd
  91                   (org-babel-process-file-name script-file)) ""))))))
  92
  93 (defun org-babel-js-read (results)
  94   "Convert RESULTS into an appropriate elisp value.
  95 If RESULTS look like a table, then convert them into an
  96 Emacs-lisp table, otherwise return the results as a string."
  97   (org-babel-read
  98    (if (and (stringp results) (string-match "^\\[.+\\]$" results))
  99        (org-babel-read
 100         (concat "'"
 101                 (replace-regexp-in-string
 102                  "\\[" "(" (replace-regexp-in-string
 103                             "\\]" ")" (replace-regexp-in-string
 104                                        ", " " " (replace-regexp-in-string
 105                                                  "'" "\"" results))))))
 106      results)))
 107
 108 (defun org-babel-js-var-to-js (var)
 109   "Convert VAR into a js variable.
 110 Convert an elisp value into a string of js source code
 111 specifying a variable of the same value."
 112   (if (listp var)
 113       (concat "[" (mapconcat #'org-babel-js-var-to-js var ", ") "]")
 114     (format "%S" var)))
 115
 116 (defun org-babel-prep-session:js (session params)
 117   "Prepare SESSION according to the header arguments specified in PARAMS."
 118   (let* ((session (org-babel-js-initiate-session session))
 119          (var-lines (org-babel-variable-assignments:js params)))
 120     (when session
 121       (org-babel-comint-in-buffer session
 122         (sit-for .5) (goto-char (point-max))
 123         (mapc (lambda (var)
 124                 (insert var) (comint-send-input nil t)
 125                 (org-babel-comint-wait-for-output session)
 126                 (sit-for .1) (goto-char (point-max))) var-lines)))
 127     session))
 128
 129 (defun org-babel-variable-assignments:js (params)
 130   "Return list of Javascript statements assigning the block's variables."
 131   (mapcar
 132    (lambda (pair) (format "var %s=%s;"
 133                           (car pair) (org-babel-js-var-to-js (cdr pair))))
 134    (mapcar #'cdr (org-babel-get-header params :var))))
 135
 136 (defun org-babel-js-initiate-session (&optional session)
 137   "If there is not a current inferior-process-buffer in SESSION
 138 then create.  Return the initialized session."
 139   (unless (string= session "none")
 140     (cond
 141      ((string= "mozrepl" org-babel-js-cmd)
 142       (require 'moz)
 143       (let ((session-buffer (save-window-excursion
 144                               (run-mozilla nil)
 145                               (rename-buffer session)
 146                               (current-buffer))))
 147         (if (org-babel-comint-buffer-livep session-buffer)
 148             (progn (sit-for .25) session-buffer)
 149           (sit-for .5)
 150           (org-babel-js-initiate-session session))))
 151      ((string= "node" org-babel-js-cmd )
 152       (error "Session evaluation with node.js is not supported"))
 153      (t
 154       (error "Sessions are only supported with mozrepl add \":cmd mozrepl\"")))))
 155
 156 (provide 'ob-js)
 157
 158
 159
 160 ;;; ob-js.el ends here