arch/arm/mm/tlb-fa.S

   1 /*
   2  *  linux/arch/arm/mm/tlb-fa.S
   3  *
   4  *  Copyright (C) 2005 Faraday Corp.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  ARM architecture version 4, Faraday variation.
  11  *  This assume an unified TLBs, with a write buffer, and branch target buffer (BTB)
  12  *
  13  *  Processors: FA520 FA526 FA626
  14  *  03/31/2005 : Created by Luke Lee, modified from tlb-v4wbi.S
  15  *  05/06/2005 : Fixed buggy CPU versions that did not invalidate the associated
  16  *               data cache entries when invalidating TLB entries.
  17  */
  18 #include <linux/linkage.h>
  19 #include <linux/init.h>
  20 #include <asm/constants.h>
  21 #include <asm/tlbflush.h>
  22 #include "proc-macros.S"
  23
  24
  25 /*
  26  *      flush_user_tlb_range(start, end, mm)
  27  *
  28  *      Invalidate a range of TLB entries in the specified address space.
  29  *
  30  *      - start - range start address
  31  *      - end   - range end address
  32  *      - mm    - mm_struct describing address space
  33  */
  34         .align  4
  35 ENTRY(fa_flush_user_tlb_range)
  36
  37         vma_vm_mm ip, r2
  38         act_mm  r3                              @ get current->active_mm
  39         eors    r3, ip, r3                      @ == mm ?
  40         movne   pc, lr                          @ no, we dont do anything
  41         mov     r3, #0
  42
  43 #ifndef CONFIG_CPU_FA_WB_DISABLE
  44         mcr     p15, 0, r3, c7, c10, 4          @ drain WB
  45 #endif
  46
  47         vma_vm_flags r2, r2
  48         bic     r0, r0, #0x0ff
  49         bic     r0, r0, #0xf00
  50
  51 1:      mcr     p15, 0, r0, c8, c7, 1           @ invalidate UTLB entry
  52         add     r0, r0, #PAGE_SZ
  53         cmp     r0, r1
  54         bls     1b                              @ Luke Lee 05/19/2005 blo -> bls
  55
  56 #ifdef CONFIG_CPU_FA_BTB
  57         mcr     p15, 0, r3, c7, c5, 6           @ invalidate BTB
  58         nop
  59         nop
  60 #endif
  61         mov     pc, lr
  62
  63
  64 ENTRY(fa_flush_kern_tlb_range)
  65         mov     r3, #0
  66
  67         mcr     p15, 0, r3, c7, c10, 0          @ clean Dcache all 06/03/2005
  68
  69 #ifndef CONFIG_CPU_FA_WB_DISABLE
  70         mcr     p15, 0, r3, c7, c10, 4          @ drain WB
  71 #endif
  72
  73         bic     r0, r0, #0x0ff
  74         bic     r0, r0, #0xf00
  75 1:
  76         mcr     p15, 0, r0, c8, c7, 1           @ invalidate UTLB entry
  77         add     r0, r0, #PAGE_SZ
  78         cmp     r0, r1
  79         bls     1b                              @ Luke Lee 05/19/2005 blo -> bls
  80
  81 #ifdef CONFIG_CPU_FA_BTB
  82         mcr     p15, 0, r3, c7, c5, 6           @ invalidate BTB
  83         nop
  84         nop
  85 #endif
  86         mov     pc, lr
  87
  88
  89         __INITDATA
  90
  91         .type   fa_tlb_fns, #object
  92 ENTRY(fa_tlb_fns)
  93         .long   fa_flush_user_tlb_range
  94         .long   fa_flush_kern_tlb_range
  95         .long   fa_tlb_flags
  96         .size   fa_tlb_fns, . - fa_tlb_fns