| blob | 6d808cb47857a39cf47d8c889f9230715d89a5ee |
1 .file "sinhf.s"
4 // Copyright (c) 2000 - 2005, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
40 // History
41 //*********************************************************************
42 // 02/02/00 Initial version
43 // 04/04/00 Unwind support added
44 // 08/15/00 Bundle added after call to __libm_error_support to properly
45 // set [the previously overwritten] GR_Parameter_RESULT.
46 // 10/12/00 Update to set denormal operand and underflow flags
47 // 01/22/01 Fixed to set inexact flag for small args.
48 // 05/02/01 Reworked to improve speed of all paths
49 // 05/20/02 Cleaned up namespace and sf0 syntax
50 // 11/20/02 Improved algorithm based on expf
51 // 03/31/05 Reformatted delimiters between data tables
52 //
53 // API
54 //*********************************************************************
55 // float sinhf(float)
56 //
57 // Overview of operation
58 //*********************************************************************
59 // Case 1: 0 < |x| < 2^-60
60 // Result = x, computed by x+sgn(x)*x^2) to handle flags and rounding
61 //
62 // Case 2: 2^-60 < |x| < 0.25
63 // Evaluate sinh(x) by a 9th order polynomial
64 // Care is take for the order of multiplication; and A2 is not exactly 1/5!,
65 // A3 is not exactly 1/7!, etc.
66 // sinh(x) = x + (A1*x^3 + A2*x^5 + A3*x^7 + A4*x^9)
67 //
68 // Case 3: 0.25 < |x| < 89.41598
69 // Algorithm is based on the identity sinh(x) = ( exp(x) - exp(-x) ) / 2.
70 // The algorithm for exp is described as below. There are a number of
71 // economies from evaluating both exp(x) and exp(-x). Although we
72 // are evaluating both quantities, only where the quantities diverge do we
73 // duplicate the computations. The basic algorithm for exp(x) is described
74 // below.
75 //
76 // Take the input x. w is "how many log2/128 in x?"
77 // w = x * 64/log2
78 // NJ = int(w)
79 // x = NJ*log2/64 + R
81 // NJ = 64*n + j
82 // x = n*log2 + (log2/64)*j + R
83 //
84 // So, exp(x) = 2^n * 2^(j/64)* exp(R)
85 //
86 // T = 2^n * 2^(j/64)
87 // Construct 2^n
88 // Get 2^(j/64) table
89 // actually all the entries of 2^(j/64) table are stored in DP and
90 // with exponent bits set to 0 -> multiplication on 2^n can be
91 // performed by doing logical "or" operation with bits presenting 2^n
93 // exp(R) = 1 + (exp(R) - 1)
94 // P = exp(R) - 1 approximated by Taylor series of 3rd degree
95 // P = A3*R^3 + A2*R^2 + R, A3 = 1/6, A2 = 1/2
96 //
98 // The final result is reconstructed as follows
99 // exp(x) = T + T*P
101 // Special values
102 //*********************************************************************
103 // sinhf(+0) = +0
104 // sinhf(-0) = -0
106 // sinhf(+qnan) = +qnan
107 // sinhf(-qnan) = -qnan
108 // sinhf(+snan) = +qnan
109 // sinhf(-snan) = -qnan
111 // sinhf(-inf) = -inf
112 // sinhf(+inf) = +inf
114 // Overflow and Underflow
115 //*********************************************************************
116 // sinhf(x) = largest single normal when
117 // x = 89.41598 = 0x42b2d4fc
118 //
119 // Underflow is handled as described in case 1 above
121 // Registers used
122 //*********************************************************************
123 // Floating Point registers used:
124 // f8 input, output
125 // f6,f7, f9 -> f15, f32 -> f45
127 // General registers used:
128 // r2, r3, r16 -> r38
130 // Predicate registers used:
131 // p6 -> p15
133 // Assembly macros
134 //*********************************************************************
135 // integer registers used
136 // scratch
137 rNJ = r2
138 rNJ_neg = r3
140 rJ_neg = r16
141 rN_neg = r17
142 rSignexp_x = r18
143 rExp_x = r18
144 rExp_mask = r19
145 rExp_bias = r20
146 rAd1 = r21
147 rAd2 = r22
148 rJ = r23
149 rN = r24
150 rTblAddr = r25
151 rA3 = r26
152 rExpHalf = r27
153 rLn2Div64 = r28
154 rGt_ln = r29
155 r17ones_m1 = r29
156 rRightShifter = r30
157 rJ_mask = r30
158 r64DivLn2 = r31
159 rN_mask = r31
160 // stacked
161 GR_SAVE_PFS = r32
162 GR_SAVE_B0 = r33
163 GR_SAVE_GP = r34
164 GR_Parameter_X = r35
165 GR_Parameter_Y = r36
166 GR_Parameter_RESULT = r37
167 GR_Parameter_TAG = r38
169 // floating point registers used
170 FR_X = f10
171 FR_Y = f1
172 FR_RESULT = f8
173 // scratch
174 fRightShifter = f6
175 f64DivLn2 = f7
176 fNormX = f9
177 fNint = f10
178 fN = f11
179 fR = f12
180 fLn2Div64 = f13
181 fA2 = f14
182 fA3 = f15
183 // stacked
184 fP = f32
185 fT = f33
186 fMIN_SGL_OFLOW_ARG = f34
187 fMAX_SGL_NORM_ARG = f35
188 fRSqr = f36
189 fA1 = f37
190 fA21 = f37
191 fA4 = f38
192 fA43 = f38
193 fA4321 = f38
194 fX4 = f39
195 fTmp = f39
196 fGt_pln = f39
197 fWre_urm_f8 = f40
198 fXsq = f40
199 fP_neg = f41
200 fX3 = f41
201 fT_neg = f42
202 fExp = f43
203 fExp_neg = f44
204 fAbsX = f45
207 RODATA
208 .align 16
210 LOCAL_OBJECT_START(_sinhf_table)
211 data4 0x42b2d4fd // Smallest single arg to overflow single result
212 data4 0x42b2d4fc // Largest single arg to give normal single result
213 data4 0x00000000 // pad
214 data4 0x00000000 // pad
215 //
216 // 2^(j/64) table, j goes from 0 to 63
217 data8 0x0000000000000000 // 2^(0/64)
218 data8 0x00002C9A3E778061 // 2^(1/64)
219 data8 0x000059B0D3158574 // 2^(2/64)
220 data8 0x0000874518759BC8 // 2^(3/64)
221 data8 0x0000B5586CF9890F // 2^(4/64)
222 data8 0x0000E3EC32D3D1A2 // 2^(5/64)
223 data8 0x00011301D0125B51 // 2^(6/64)
224 data8 0x0001429AAEA92DE0 // 2^(7/64)
225 data8 0x000172B83C7D517B // 2^(8/64)
226 data8 0x0001A35BEB6FCB75 // 2^(9/64)
227 data8 0x0001D4873168B9AA // 2^(10/64)
228 data8 0x0002063B88628CD6 // 2^(11/64)
229 data8 0x0002387A6E756238 // 2^(12/64)
230 data8 0x00026B4565E27CDD // 2^(13/64)
231 data8 0x00029E9DF51FDEE1 // 2^(14/64)
232 data8 0x0002D285A6E4030B // 2^(15/64)
233 data8 0x000306FE0A31B715 // 2^(16/64)
234 data8 0x00033C08B26416FF // 2^(17/64)
235 data8 0x000371A7373AA9CB // 2^(18/64)
236 data8 0x0003A7DB34E59FF7 // 2^(19/64)
237 data8 0x0003DEA64C123422 // 2^(20/64)
238 data8 0x0004160A21F72E2A // 2^(21/64)
239 data8 0x00044E086061892D // 2^(22/64)
240 data8 0x000486A2B5C13CD0 // 2^(23/64)
241 data8 0x0004BFDAD5362A27 // 2^(24/64)
242 data8 0x0004F9B2769D2CA7 // 2^(25/64)
243 data8 0x0005342B569D4F82 // 2^(26/64)
244 data8 0x00056F4736B527DA // 2^(27/64)
245 data8 0x0005AB07DD485429 // 2^(28/64)
246 data8 0x0005E76F15AD2148 // 2^(29/64)
247 data8 0x0006247EB03A5585 // 2^(30/64)
248 data8 0x0006623882552225 // 2^(31/64)
249 data8 0x0006A09E667F3BCD // 2^(32/64)
250 data8 0x0006DFB23C651A2F // 2^(33/64)
251 data8 0x00071F75E8EC5F74 // 2^(34/64)
252 data8 0x00075FEB564267C9 // 2^(35/64)
253 data8 0x0007A11473EB0187 // 2^(36/64)
254 data8 0x0007E2F336CF4E62 // 2^(37/64)
255 data8 0x00082589994CCE13 // 2^(38/64)
256 data8 0x000868D99B4492ED // 2^(39/64)
257 data8 0x0008ACE5422AA0DB // 2^(40/64)
258 data8 0x0008F1AE99157736 // 2^(41/64)
259 data8 0x00093737B0CDC5E5 // 2^(42/64)
260 data8 0x00097D829FDE4E50 // 2^(43/64)
261 data8 0x0009C49182A3F090 // 2^(44/64)
262 data8 0x000A0C667B5DE565 // 2^(45/64)
263 data8 0x000A5503B23E255D // 2^(46/64)
264 data8 0x000A9E6B5579FDBF // 2^(47/64)
265 data8 0x000AE89F995AD3AD // 2^(48/64)
266 data8 0x000B33A2B84F15FB // 2^(49/64)
267 data8 0x000B7F76F2FB5E47 // 2^(50/64)
268 data8 0x000BCC1E904BC1D2 // 2^(51/64)
269 data8 0x000C199BDD85529C // 2^(52/64)
270 data8 0x000C67F12E57D14B // 2^(53/64)
271 data8 0x000CB720DCEF9069 // 2^(54/64)
272 data8 0x000D072D4A07897C // 2^(55/64)
273 data8 0x000D5818DCFBA487 // 2^(56/64)
274 data8 0x000DA9E603DB3285 // 2^(57/64)
275 data8 0x000DFC97337B9B5F // 2^(58/64)
276 data8 0x000E502EE78B3FF6 // 2^(59/64)
277 data8 0x000EA4AFA2A490DA // 2^(60/64)
278 data8 0x000EFA1BEE615A27 // 2^(61/64)
279 data8 0x000F50765B6E4540 // 2^(62/64)
280 data8 0x000FA7C1819E90D8 // 2^(63/64)
281 LOCAL_OBJECT_END(_sinhf_table)
283 LOCAL_OBJECT_START(sinh_p_table)
284 data8 0x3ec749d84bc96d7d // A4
285 data8 0x3f2a0168d09557cf // A3
286 data8 0x3f811111326ed15a // A2
287 data8 0x3fc55555552ed1e2 // A1
288 LOCAL_OBJECT_END(sinh_p_table)
291 .section .text
292 GLOBAL_IEEE754_ENTRY(sinhf)
294 { .mlx
295 getf.exp rSignexp_x = f8 // Must recompute if x unorm
296 movl r64DivLn2 = 0x40571547652B82FE // 64/ln(2)
297 }
298 { .mlx
299 addl rTblAddr = @ltoff(_sinhf_table),gp
300 movl rRightShifter = 0x43E8000000000000 // DP Right Shifter
301 }
302 ;;
304 { .mfi
305 // point to the beginning of the table
306 ld8 rTblAddr = [rTblAddr]
307 fclass.m p6, p0 = f8, 0x0b // Test for x=unorm
308 addl rA3 = 0x3E2AA, r0 // high bits of 1.0/6.0 rounded to SP
309 }
310 { .mfi
311 nop.m 0
312 fnorm.s1 fNormX = f8 // normalized x
313 addl rExpHalf = 0xFFFE, r0 // exponent of 1/2
314 }
315 ;;
317 { .mfi
318 setf.d f64DivLn2 = r64DivLn2 // load 64/ln(2) to FP reg
319 fclass.m p15, p0 = f8, 0x1e3 // test for NaT,NaN,Inf
320 nop.i 0
321 }
322 { .mlx
323 // load Right Shifter to FP reg
324 setf.d fRightShifter = rRightShifter
325 movl rLn2Div64 = 0x3F862E42FEFA39EF // DP ln(2)/64 in GR
326 }
327 ;;
329 { .mfi
330 mov rExp_mask = 0x1ffff
331 fcmp.eq.s1 p13, p0 = f0, f8 // test for x = 0.0
332 shl rA3 = rA3, 12 // 0x3E2AA000, approx to 1.0/6.0 in SP
333 }
334 { .mfb
335 nop.m 0
336 nop.f 0
337 (p6) br.cond.spnt SINH_UNORM // Branch if x=unorm
338 }
339 ;;
341 SINH_COMMON:
342 { .mfi
343 setf.exp fA2 = rExpHalf // load A2 to FP reg
344 nop.f 0
345 mov rExp_bias = 0xffff
346 }
347 { .mfb
348 setf.d fLn2Div64 = rLn2Div64 // load ln(2)/64 to FP reg
349 (p15) fma.s.s0 f8 = f8, f1, f0 // result if x = NaT,NaN,Inf
350 (p15) br.ret.spnt b0 // exit here if x = NaT,NaN,Inf
351 }
352 ;;
354 { .mfi
355 // min overflow and max normal threshold
356 ldfps fMIN_SGL_OFLOW_ARG, fMAX_SGL_NORM_ARG = [rTblAddr], 8
357 nop.f 0
358 and rExp_x = rExp_mask, rSignexp_x // Biased exponent of x
359 }
360 { .mfb
361 setf.s fA3 = rA3 // load A3 to FP reg
362 nop.f 0
363 (p13) br.ret.spnt b0 // exit here if x=0.0, return x
364 }
365 ;;
367 { .mfi
368 sub rExp_x = rExp_x, rExp_bias // True exponent of x
369 fmerge.s fAbsX = f0, fNormX // Form |x|
370 nop.i 0
371 }
372 ;;
374 { .mfi
375 nop.m 0
376 // x*(64/ln(2)) + Right Shifter
377 fma.s1 fNint = fNormX, f64DivLn2, fRightShifter
378 add rTblAddr = 8, rTblAddr
379 }
380 { .mfb
381 cmp.gt p7, p0 = -2, rExp_x // Test |x| < 2^(-2)
382 fma.s1 fXsq = fNormX, fNormX, f0 // x*x for small path
383 (p7) br.cond.spnt SINH_SMALL // Branch if 0 < |x| < 2^-2
384 }
385 ;;
387 { .mfi
388 nop.m 0
389 // check for overflow
390 fcmp.ge.s1 p12, p13 = fAbsX, fMIN_SGL_OFLOW_ARG
391 mov rJ_mask = 0x3f // 6-bit mask for J
392 }
393 ;;
395 { .mfb
396 nop.m 0
397 fms.s1 fN = fNint, f1, fRightShifter // n in FP register
398 // branch out if overflow
399 (p12) br.cond.spnt SINH_CERTAIN_OVERFLOW
400 }
401 ;;
403 { .mfi
404 getf.sig rNJ = fNint // bits of n, j
405 // check for possible overflow
406 fcmp.gt.s1 p13, p0 = fAbsX, fMAX_SGL_NORM_ARG
407 nop.i 0
408 }
409 ;;
411 { .mfi
412 addl rN = 0xFFBF - 63, rNJ // biased and shifted n-1,j
413 fnma.s1 fR = fLn2Div64, fN, fNormX // R = x - N*ln(2)/64
414 and rJ = rJ_mask, rNJ // bits of j
415 }
416 { .mfi
417 sub rNJ_neg = r0, rNJ // bits of n, j for -x
418 nop.f 0
419 andcm rN_mask = -1, rJ_mask // 0xff...fc0 to mask N
420 }
421 ;;
423 { .mfi
424 shladd rJ = rJ, 3, rTblAddr // address in the 2^(j/64) table
425 nop.f 0
426 and rN = rN_mask, rN // biased, shifted n-1
427 }
428 { .mfi
429 addl rN_neg = 0xFFBF - 63, rNJ_neg // -x biased, shifted n-1,j
430 nop.f 0
431 and rJ_neg = rJ_mask, rNJ_neg // bits of j for -x
432 }
433 ;;
435 { .mfi
436 ld8 rJ = [rJ] // Table value
437 nop.f 0
438 shl rN = rN, 46 // 2^(n-1) bits in DP format
439 }
440 { .mfi
441 shladd rJ_neg = rJ_neg, 3, rTblAddr // addr in 2^(j/64) table -x
442 nop.f 0
443 and rN_neg = rN_mask, rN_neg // biased, shifted n-1 for -x
444 }
445 ;;
447 { .mfi
448 ld8 rJ_neg = [rJ_neg] // Table value for -x
449 nop.f 0
450 shl rN_neg = rN_neg, 46 // 2^(n-1) bits in DP format for -x
451 }
452 ;;
454 { .mfi
455 or rN = rN, rJ // bits of 2^n * 2^(j/64) in DP format
456 nop.f 0
457 nop.i 0
458 }
459 ;;
461 { .mmf
462 setf.d fT = rN // 2^(n-1) * 2^(j/64)
463 or rN_neg = rN_neg, rJ_neg // -x bits of 2^n * 2^(j/64) in DP
464 fma.s1 fRSqr = fR, fR, f0 // R^2
465 }
466 ;;
468 { .mfi
469 setf.d fT_neg = rN_neg // 2^(n-1) * 2^(j/64) for -x
470 fma.s1 fP = fA3, fR, fA2 // A3*R + A2
471 nop.i 0
472 }
473 { .mfi
474 nop.m 0
475 fnma.s1 fP_neg = fA3, fR, fA2 // A3*R + A2 for -x
476 nop.i 0
477 }
478 ;;
480 { .mfi
481 nop.m 0
482 fma.s1 fP = fP, fRSqr, fR // P = (A3*R + A2)*R^2 + R
483 nop.i 0
484 }
485 { .mfi
486 nop.m 0
487 fms.s1 fP_neg = fP_neg, fRSqr, fR // P = (A3*R + A2)*R^2 + R, -x
488 nop.i 0
489 }
490 ;;
492 { .mfi
493 nop.m 0
494 fmpy.s0 fTmp = fLn2Div64, fLn2Div64 // Force inexact
495 nop.i 0
496 }
497 ;;
499 { .mfi
500 nop.m 0
501 fma.s1 fExp = fP, fT, fT // exp(x)/2
502 nop.i 0
503 }
504 { .mfb
505 nop.m 0
506 fma.s1 fExp_neg = fP_neg, fT_neg, fT_neg // exp(-x)/2
507 // branch out if possible overflow result
508 (p13) br.cond.spnt SINH_POSSIBLE_OVERFLOW
509 }
510 ;;
512 { .mfb
513 nop.m 0
514 // final result in the absence of overflow
515 fms.s.s0 f8 = fExp, f1, fExp_neg // result = (exp(x)-exp(-x))/2
516 // exit here in the absence of overflow
517 br.ret.sptk b0 // Exit main path, 0.25 <= |x| < 89.41598
518 }
519 ;;
521 // Here if 0 < |x| < 0.25. Evaluate 9th order polynomial.
522 SINH_SMALL:
523 { .mfi
524 add rAd1 = 0x200, rTblAddr
525 fcmp.lt.s1 p7, p8 = fNormX, f0 // Test sign of x
526 cmp.gt p6, p0 = -60, rExp_x // Test |x| < 2^(-60)
527 }
528 { .mfi
529 add rAd2 = 0x210, rTblAddr
530 nop.f 0
531 nop.i 0
532 }
533 ;;
535 { .mmb
536 ldfpd fA4, fA3 = [rAd1]
537 ldfpd fA2, fA1 = [rAd2]
538 (p6) br.cond.spnt SINH_VERY_SMALL // Branch if |x| < 2^(-60)
539 }
540 ;;
542 { .mfi
543 nop.m 0
544 fma.s1 fX3 = fXsq, fNormX, f0
545 nop.i 0
546 }
547 { .mfi
548 nop.m 0
549 fma.s1 fX4 = fXsq, fXsq, f0
550 nop.i 0
551 }
552 ;;
554 { .mfi
555 nop.m 0
556 fma.s1 fA43 = fXsq, fA4, fA3
557 nop.i 0
558 }
559 { .mfi
560 nop.m 0
561 fma.s1 fA21 = fXsq, fA2, fA1
562 nop.i 0
563 }
564 ;;
566 { .mfi
567 nop.m 0
568 fma.s1 fA4321 = fX4, fA43, fA21
569 nop.i 0
570 }
571 ;;
573 // Dummy multiply to generate inexact
574 { .mfi
575 nop.m 0
576 fmpy.s0 fTmp = fA4, fA4
577 nop.i 0
578 }
579 { .mfb
580 nop.m 0
581 fma.s.s0 f8 = fA4321, fX3, fNormX
582 br.ret.sptk b0 // Exit if 2^-60 < |x| < 0.25
583 }
584 ;;
586 SINH_VERY_SMALL:
587 // Here if 0 < |x| < 2^-60
588 // Compute result by x + sgn(x)*x^2 to get properly rounded result
589 .pred.rel "mutex",p7,p8
590 { .mfi
591 nop.m 0
592 (p7) fnma.s.s0 f8 = fNormX, fNormX, fNormX // If x<0 result ~ x-x^2
593 nop.i 0
594 }
595 { .mfb
596 nop.m 0
597 (p8) fma.s.s0 f8 = fNormX, fNormX, fNormX // If x>0 result ~ x+x^2
598 br.ret.sptk b0 // Exit if |x| < 2^-60
599 }
600 ;;
602 SINH_POSSIBLE_OVERFLOW:
604 // Here if fMAX_SGL_NORM_ARG < x < fMIN_SGL_OFLOW_ARG
605 // This cannot happen if input is a single, only if input higher precision.
606 // Overflow is a possibility, not a certainty.
608 // Recompute result using status field 2 with user's rounding mode,
609 // and wre set. If result is larger than largest single, then we have
610 // overflow
612 { .mfi
613 mov rGt_ln = 0x1007f // Exponent for largest single + 1 ulp
614 fsetc.s2 0x7F,0x42 // Get user's round mode, set wre
615 nop.i 0
616 }
617 ;;
619 { .mfi
620 setf.exp fGt_pln = rGt_ln // Create largest single + 1 ulp
621 fma.s.s2 fWre_urm_f8 = fP, fT, fT // Result with wre set
622 nop.i 0
623 }
624 ;;
626 { .mfi
627 nop.m 0
628 fsetc.s2 0x7F,0x40 // Turn off wre in sf2
629 nop.i 0
630 }
631 ;;
633 { .mfi
634 nop.m 0
635 fcmp.ge.s1 p6, p0 = fWre_urm_f8, fGt_pln // Test for overflow
636 nop.i 0
637 }
638 ;;
640 { .mfb
641 nop.m 0
642 nop.f 0
643 (p6) br.cond.spnt SINH_CERTAIN_OVERFLOW // Branch if overflow
644 }
645 ;;
647 { .mfb
648 nop.m 0
649 fma.s.s0 f8 = fP, fT, fT
650 br.ret.sptk b0 // Exit if really no overflow
651 }
652 ;;
654 // here if overflow
655 SINH_CERTAIN_OVERFLOW:
656 { .mfi
657 addl r17ones_m1 = 0x1FFFE, r0
658 fcmp.lt.s1 p6, p7 = fNormX, f0 // Test for x < 0
659 nop.i 0
660 }
661 ;;
663 { .mmf
664 alloc r32 = ar.pfs, 0, 3, 4, 0 // get some registers
665 setf.exp fTmp = r17ones_m1
666 fmerge.s FR_X = f8,f8
667 }
668 ;;
670 { .mfi
671 mov GR_Parameter_TAG = 128
672 (p6) fnma.s.s0 FR_RESULT = fTmp, fTmp, f0 // Set I,O and -INF result
673 nop.i 0
674 }
675 { .mfb
676 nop.m 0
677 (p7) fma.s.s0 FR_RESULT = fTmp, fTmp, f0 // Set I,O and +INF result
678 br.cond.sptk __libm_error_region
679 }
680 ;;
682 // Here if x unorm
683 SINH_UNORM:
684 { .mfb
685 getf.exp rSignexp_x = fNormX // Must recompute if x unorm
686 fcmp.eq.s0 p6, p0 = f8, f0 // Set D flag
687 br.cond.sptk SINH_COMMON // Return to main path
688 }
689 ;;
691 GLOBAL_IEEE754_END(sinhf)
694 LOCAL_LIBM_ENTRY(__libm_error_region)
695 .prologue
696 { .mfi
697 add GR_Parameter_Y=-32,sp // Parameter 2 value
698 nop.f 0
699 .save ar.pfs,GR_SAVE_PFS
700 mov GR_SAVE_PFS=ar.pfs // Save ar.pfs
701 }
702 { .mfi
703 .fframe 64
704 add sp=-64,sp // Create new stack
705 nop.f 0
706 mov GR_SAVE_GP=gp // Save gp
707 };;
708 { .mmi
709 stfs [GR_Parameter_Y] = FR_Y,16 // Store Parameter 2 on stack
710 add GR_Parameter_X = 16,sp // Parameter 1 address
711 .save b0, GR_SAVE_B0
712 mov GR_SAVE_B0=b0 // Save b0
713 };;
714 .body
715 { .mfi
716 stfs [GR_Parameter_X] = FR_X // Store Parameter 1 on stack
717 nop.f 0
718 add GR_Parameter_RESULT = 0,GR_Parameter_Y // Parameter 3 address
719 }
720 { .mib
721 stfs [GR_Parameter_Y] = FR_RESULT // Store Parameter 3 on stack
722 add GR_Parameter_Y = -16,GR_Parameter_Y
723 br.call.sptk b0=__libm_error_support# // Call error handling function
724 };;
726 { .mmi
727 add GR_Parameter_RESULT = 48,sp
728 nop.m 0
729 nop.i 0
730 };;
732 { .mmi
733 ldfs f8 = [GR_Parameter_RESULT] // Get return result off stack
734 .restore sp
735 add sp = 64,sp // Restore stack pointer
736 mov b0 = GR_SAVE_B0 // Restore return address
737 };;
738 { .mib
739 mov gp = GR_SAVE_GP // Restore gp
740 mov ar.pfs = GR_SAVE_PFS // Restore ar.pfs
741 br.ret.sptk b0 // Return
742 };;
744 LOCAL_LIBM_END(__libm_error_region)
747 .type __libm_error_support#,@function
748 .global __libm_error_support#