git2svn

   1 #!/usr/bin/perl
   2 #
   3 # git2svn, converts a git branch to a svn ditto
   4 #
   5 # Copyright (c) 2008 Love Hörnquist Åstrand
   6 # All rights reserved.
   7 #
   8 # Redistribution and use in source and binary forms, with or without
   9 # modification, are permitted provided that the following conditions
  10 # are met:
  11 #
  12 # 1. Redistributions of source code must retain the above copyright
  13 #    notice, this list of conditions and the following disclaimer.
  14 #
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 #
  19 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  20 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  21 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  22 # ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  23 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  24 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  25 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  26 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  27 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  28 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  29 # SUCH DAMAGE.
  30
  31 use strict;
  32 use POSIX qw(strftime);
  33 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  34 use Pod::Usage;
  35
  36 my $IN;
  37 my $OUT;
  38
  39 my ($help, $verbose, $keeplogs, $no_load);
  40
  41 # svn
  42 my $svntree = "repro";
  43 my $basedir = "trunk";
  44 my $revision = 1;
  45
  46 # git
  47 my $branch = "master";
  48 my $syncname;
  49 my $masterrev;
  50 my $fexport;
  51
  52 my %blob;
  53 my %paths;
  54
  55 sub read_data
  56 {
  57     my ($IN, $next, $length, $data, $l) = (shift, shift);
  58     unless($next =~ m/^data (\d+)/) { die "missing data: $next" ; }
  59     $length = $1;
  60
  61     $l = read(IN, $data, $length);
  62     unless ($l == $length) { die "failed to read data $l != $length"; }
  63     $data = "" if ($length == 0);
  64     return $data;
  65 }
  66
  67 sub prop
  68 {
  69     my ($key, $value) = (shift, shift);
  70     "K " . length($key) . "\n$key\nV " . length($value) . "\n$value\n";
  71 }
  72
  73 sub parse_svn_tree
  74 {
  75     my $url = shift;
  76     my ($SVN, $type, $name);
  77
  78     open(SVN, "svn ls -R $url|") or die "failed to open svn ls -R $url";
  79     while (<SVN>) {
  80         chomp;
  81         if (m@/?(.*)/$@) {
  82             $type = 1;
  83             $name = "$1";
  84         } else {
  85             $type = 2;
  86             $name = "$_";
  87         }
  88         $paths{$name} = $type;
  89     }
  90     close SVN;
  91
  92     open(SVN, "svn info $url|") or die "failed to open svn info $url";
  93     while (<SVN>) {
  94         chomp;
  95         if ($revision eq 1 && /^Revision: (\d+)/) {
  96             $revision = $1 + 1;
  97         }
  98     }
  99     close SVN;
 100 }
 101
 102 sub find_branch_id
 103 {
 104     my ($gittree, $name) = (shift, shift);
 105
 106     my $GIT;
 107
 108     open FOO, "cd $gittree ".
 109         "&& git rev-parse $name 2>/dev/null|" or
 110         die "git rev-parse $name failed";
 111
 112     my $id = <FOO>;
 113     close GIT;
 114     chomp($id);
 115     $id = "" if ($id eq $name);
 116     return $id;
 117 }
 118
 119 sub parse_git_tree
 120 {
 121     my ($gittree, $branch, $shortbranch) = (shift, shift, shift);
 122
 123     $syncname = "git2svn-syncpoint-${shortbranch}";
 124     print STDERR "syncname tag: $syncname\n" if ($verbose);
 125
 126     $masterrev = find_branch_id($gittree, $branch);
 127     die "No head found for ${branch}" if ($masterrev eq "");
 128
 129     my $oldmasterrev = find_branch_id($gittree, $syncname);
 130
 131     if ($oldmasterrev ne "") {
 132
 133         die "no $svntree, but incremental (have synctag) ?\n".
 134             "(\"cd $gittree && git tag -d $syncname\" to remove)"
 135             unless ( -d $svntree);
 136
 137         if (${oldmasterrev} eq $masterrev) {
 138             print STDERR "nothing to sync, $syncname matches $branch\n"
 139                 if ($verbose);
 140             exit 0;
 141         }
 142
 143         $fexport = "$oldmasterrev..$masterrev";
 144     } else {
 145         $fexport="$masterrev";
 146
 147         system("svnadmin create ./$svntree") unless (-d $svntree);
 148     }
 149 }
 150
 151
 152 sub checkdirs
 153 {
 154     my $path = shift;
 155     my $base = "";
 156
 157     # pick first dir, create, take next dir, continue until we reached basename
 158     while ($path =~ m@^([^/]+)/(.*)$@) {
 159         my $first = $base . $1;
 160         $path = $2;
 161         $base = $first . "/";
 162         next if ($paths{$first});
 163
 164         $paths{$first} = 1;
 165
 166         printf OUT "Node-path: $first\n";
 167         printf OUT "Node-kind: dir\n";
 168         printf OUT "Node-action: add\n";
 169         printf OUT "Prop-content-length: 0\n";
 170         printf OUT "Content-length: 0\n";
 171         printf OUT "\n";
 172     }
 173 }
 174
 175 sub next_line
 176 {
 177     my $IN = shift;
 178     my $next = <IN>;
 179     chomp $next;
 180     return $next;
 181 }
 182
 183 #
 184 # This is to allow setting props for a path, XXX add configuration
 185 # file/options for this.
 186 #
 187
 188 sub auto_props
 189 {
 190     my $path = shift;
 191     ### given path, return prop("prop", "value")
 192     return "";
 193 }
 194
 195
 196 $|= 1;
 197
 198 my $result;
 199 $result = GetOptions ("git-branch=s" => \$branch,
 200                       "svn-prefix=s" => \$basedir,
 201                       "keep-logs" => \$keeplogs,
 202                       "no-load" => \$no_load,
 203                       "verbose+" => \$verbose,
 204                       "help" => \$help) or pod2usage(2);
 205
 206 pod2usage(0) if ($help);
 207
 208 die "to few arguments" if ($#ARGV < 1);
 209
 210 mkdir ".data" unless (-d ".data");
 211
 212 die "cant find branch name" unless ($branch =~ m@/?([^/]+)$@);
 213 my $shortbranch = $1;
 214
 215 my $gittree = $ARGV[0];
 216 $svntree = $ARGV[1];
 217
 218 # create an identifier by replacing path separators
 219 # (i.e. "/", ":" and "\") with underscores
 220 my $svntree_id = $svntree;
 221 $svntree_id =~ s/[\/:\\]/_/g;
 222
 223 my $gitdump = ".data/git.dump-${svntree_id}-${shortbranch}";
 224 my $svndump = ".data/svn.dump-${svntree_id}-${shortbranch}";
 225 my $log = ".data/log-${svntree_id}-${shortbranch}";
 226
 227 parse_git_tree($gittree, $branch, $shortbranch);
 228
 229 my $cwd = `pwd`;
 230 chomp($cwd);
 231 parse_svn_tree("file://" . $cwd ."/". $svntree);
 232
 233 system(">$log");
 234
 235 print STDERR "git fast-export $branch ($fexport)\n" if ($verbose);
 236
 237 system("(cd $gittree && git fast-export $fexport) > $gitdump 2>$log") == 0 or
 238     die "git fast-export: $!";
 239
 240 open IN, "$gitdump" or
 241     die "failed to open $gitdump";
 242
 243 open OUT, ">$svndump" or
 244     die "failed to open $svndump";
 245
 246 print STDERR "creating svn dump from revision $revision...\n" if ($verbose);
 247
 248 print OUT "SVN-fs-dump-format-version: 3\n";
 249
 250 my $next = next_line();
 251 COMMAND: while (!eof(IN)) {
 252     if ($next eq "") {
 253         $next = next_line($IN);
 254         next COMMAND;
 255     } elsif ($next =~ /^commit (.*)/) {
 256
 257         my %commit;
 258
 259         $next = next_line($IN);
 260         if ($next =~ m/mark +(.*)/) {
 261             $commit{Mark} = $1;
 262             $next = next_line($IN);
 263         }
 264         if ($next =~ m/author +(.*)/) {
 265             $commit{Author} = $1;
 266             $next = next_line($IN);
 267         }
 268         unless ($next =~ m/committer +(.+) +<([^>]+)> +(\d+) +[+-](\d+)$/) {
 269             die "missing comitter: $_";
 270         }
 271
 272         $commit{CommitterName} = $1;
 273         $commit{CommitterEmail} = $2;
 274         $commit{CommitterWhen} = $3;
 275         $commit{CommitterTZ} = $4;
 276
 277         $next = next_line($IN);
 278         my $log = read_data($IN, $next);
 279
 280         $next = next_line($IN);
 281         if ($next =~ m/from (.*)/) {
 282             $commit{From} = $1;
 283             $next = next_line($IN);
 284         }
 285         if ($next =~ m/merge (.*)/) {
 286             $commit{Merge} = $1;
 287             $next = next_line($IN);
 288         }
 289
 290         my $date =
 291             strftime("%Y-%m-%dT%H:%M:%S.000000Z",
 292                      gmtime($commit{CommitterWhen}));
 293
 294         my $author = "(no author)";
 295         if ($commit{CommitterEmail} =~ m/([^@]+)/) {
 296             $author = $1;
 297         }
 298         $author = "git2svn-dump" if ($author eq "(no author)");
 299
 300         my $props = "";
 301         $props .= prop("svn:author", $author);
 302         $props .= prop("svn:log", $log);
 303         $props .= prop("svn:date", $date);
 304         $props .= "PROPS-END";
 305
 306         # push out svn info
 307
 308         printf OUT "Revision-number: $revision\n"; $revision++;
 309         printf OUT "Prop-content-length: ". length($props) . "\n";
 310         printf OUT "Content-length: " . length($props) . "\n";
 311         printf OUT "\n";
 312         print OUT "$props\n";
 313
 314         while (1) {
 315             if ($next =~ m/M (\d+) (\S+) (.*)$/) {
 316                 my ($mode, $dataref, $path) = (oct $1, $2, $3);
 317                 my $content;
 318                 if ($dataref eq "inline") {
 319                     $next = next_line($IN);
 320                     $content = read_data($IN, $next);
 321                 } else {
 322                     if (defined $blob{$dataref}) {
 323                         $content = $blob{$dataref};
 324                     } else {
 325                                 # Submodules cannot be converted
 326                                 print STDERR "Ignored line, please check if this is a submodule: $next\n" if ($verbose);
 327                                 $next = next_line($IN);
 328                                 next;
 329                     }
 330                     # here we really want to delete $blob{$dataref},
 331                     # but it might be referenced in the future. To
 332                     # avoid keepig everything in memory for larger
 333                     # repositories this must be written out to disk
 334                     # and removed when done.
 335                 }
 336
 337                 $path = "$basedir/$path";
 338                 checkdirs($path);
 339
 340                 my $action = "add";
 341
 342                 my $type = $mode & 0777000;
 343
 344                 if ($paths{$path}) {
 345                     if (($paths{$path} != 2) && ($type != 0120000)) {
 346                                 die "file was a dir";
 347                     } elsif (($paths{$path} != 2) && ($type == 0120000)) {
 348                                 print STDERR "Dir is now a symlink, deleting: $path\n" if ($verbose);
 349                             foreach ( keys( %paths ) ) {
 350                         delete $paths{$_} if ( /^$path/ );
 351                                 }
 352                                 # This is now a file and not a path anymore
 353                                 $paths{$path} = 2;
 354                                 printf OUT "Node-path: $path\nNode-action: delete\n\n";
 355                     } else {
 356                       $action = "change";
 357                     }
 358                 } else {
 359                     $paths{$path} = 2;
 360                 }
 361
 362
 363                 my $kind = "";
 364                 $kind = "file" if ($type == 0100000);
 365                 $kind = "symlink" if ($type == 0120000);
 366                 die "$type unknown" if ($kind eq "");
 367
 368                 $props = "";
 369                 $props .= prop("svn:executable", "on") if ($mode & 0111);
 370                 $props .= prop("svn:special", "*") if ($kind eq "symlink");
 371                 $props .= auto_props($path);
 372                 $props .= "PROPS-END\n" if ($props ne "");
 373
 374                 $content = "link $content\n" if ($kind eq "symlink");
 375
 376                 my $plen = length($props);
 377                 my $clen = length($content);
 378
 379                 printf OUT "Node-path: $path\n";
 380                 printf OUT "Node-kind: file\n";
 381                 printf OUT "Node-action: $action\n";
 382                 printf OUT "Text-content-length: $clen\n";
 383                 printf OUT "Content-length: " . ($clen + $plen) . "\n";
 384                 printf OUT "Prop-content-length: $plen\n" if ($plen);
 385                 printf OUT "\n";
 386
 387                 print OUT "$props" if ($plen);
 388
 389                 print OUT $content;
 390                 printf OUT "\n";
 391             } elsif ($next =~ m/D (.*)/) {
 392                 my $path = $basedir . "/". $1;
 393
 394                 if ($paths{$path}) {
 395                     foreach ( keys( %paths ) ) {
 396                 delete $paths{$_} if ( /^$path/ );
 397                         }
 398
 399                     printf OUT "Node-path: $path\n";
 400                     printf OUT "Node-action: delete\n";
 401                     printf OUT "\n";
 402                 } elsif ($verbose) {
 403                     print STDERR "deleting non existing object: $path\n";
 404                 }
 405
 406             } elsif ($next =~ m/^C (.*)/) {
 407                 die "file copy ?";
 408             } elsif ($next =~ m/^R (.*)/) {
 409                 die "file rename ?";
 410             } elsif ($next =~ m/^filedeleteall$/) {
 411                 die "file delete all ?";
 412             } else {
 413                 next COMMAND;
 414             }
 415             $next = next_line($IN);
 416         }
 417
 418     } elsif ($next =~ /^tag .*/) {
 419     } elsif ($next =~ /^reset .*/) {
 420     } elsif ($next =~ /^blob/) {
 421         my $mark = undef;
 422         $next = next_line($IN);
 423         if ($next =~ m/mark (.*)/) {
 424             $mark = $1;
 425             $next = next_line($IN);
 426         }
 427         my $data = read_data($IN, $next);
 428         $blob{$mark} = $data if (defined $mark);
 429     } elsif ($next =~ /^checkpoint .*/) {
 430     } elsif ($next =~ /^progress (.*)/) {
 431         print STDERR "progress: $1\n" if ($verbose);
 432     } else {
 433         die "unknown command $next";
 434     }
 435     $next = next_line($IN);
 436 }
 437
 438 close IN;
 439 close OUT;
 440
 441 print STDERR "...dumped to revision $revision\n" if ($verbose);
 442 print STDERR "(re-)setting sync-tag to new master\n" if ($verbose);
 443
 444 unless ($no_load) {
 445     system("cd $gittree && ".
 446            "git tag -m \"sync $(date)\" -a -f ${syncname} ${masterrev}");
 447 }
 448
 449 print STDERR "loading dump into svn\n" if ($verbose);
 450
 451 unless ($no_load) {
 452     system("svnadmin load $svntree < $svndump >>$log 2>&1") == 0 or
 453         die "svnadmin load";
 454 }
 455
 456 unlink $svndump, $gitdump, $log unless ($keeplogs);
 457
 458 exit 0;
 459
 460
 461 __END__
 462
 463 =head1 NAME
 464
 465 B<git2svn> - converts a git branch to a svn ditto
 466
 467 =head1 SYNOPSIS
 468
 469 B<git2svn> [options] git-repro svn-repro
 470
 471 =head1 OPTIONS
 472
 473 =over 8
 474
 475 =item B<--git-branch>
 476
 477 The git branch to export. The default is branch is master.
 478
 479 =item B<--svn-prefix>
 480
 481 The svn prefix where the branch is import. The default is trunk to
 482 match the default GIT branch (master).
 483
 484 =item B<--no-load>
 485
 486 Don't load the svn repository or update the syncpoint tagname.
 487
 488 =item B<--keep-logs>
 489
 490 Don't delete the logs in $CWD/.data on success.
 491
 492 =item B<--verbose>
 493
 494 More verbose output, can be give more then once to increase the verbosity.
 495
 496 =item B<--help>
 497
 498 Print a brief help message and exits.
 499
 500 =back
 501
 502 =head1 DESCRIPTION
 503
 504 B<git2svn> will convert a git branch to a svn ditto, it also
 505 support incremantal updates.
 506
 507 B<git2svn> takes a git fast-export dump and converts it into a
 508 svn dump that is feed into svnadmin load.
 509
 510 B<git2svn> assumes its the only process that writes into the svn
 511 repository. This is because of the race between getting the to svn
 512 Revsion number from the svn, creating the dump with correct Revsions,
 513 and do the svnadmin load.
 514
 515 B<git2svn> also support incremental updates from a git branch to
 516 a svn reprositry. Its does this by setting a git tag
 517 (git2svn-syncpoint-<branchname>) where the last update was pulled
 518 from.
 519
 520 B<git2svn> was created as a hack over a weekend to support a
 521 smoother migration away from svn and allow users access to tools to
 522 browse and search code (fisheye) and use anonymouns svn servers.
 523
 524 =head1 EXAMPLES
 525
 526         B<git2svn> ~/src/heimdal svn-repro
 527
 528         B<git2svn> --git-branch heimdal-1-0-branch \
 529              --svn-prefix branches/heimdal-1-0-branch \
 530              ~/src/heimdal svn-repro
 531
 532 =head1 DOWNLOAD
 533
 534 B<git2svn> is avaible from repo.or.cz
 535
 536         git clone git://repo.or.cz/git2svn.git
 537
 538 =head1 AUTHORS
 539
 540         Love Hörnquist Åstrand <lha@kth.se>
 541
 542 =head1 BUGS
 543
 544         Send bug reports to lha@kth.se
 545
 546 =cut