games-engines/qtads/qtads-9999.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="4"
   6
   7 EGIT_REPO_URI="git://${PN}.git.sourceforge.net/gitroot/${PN}/${PN}"
   8 inherit eutils gnome2-utils fdo-mime games qt4-r2 git-2
   9
  10 DESCRIPTION="Multimedia interpreter for TADS text adventures"
  11 HOMEPAGE="http://qtads.sourceforge.net"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS=""
  16 IUSE=""
  17
  18 # Note that for sdl-sound, we need the "mp3", not the "mpeg" USE flag. "mpeg"
  19 # uses the SMPEG lib for decoding, which plays some MP3s at double speed. "mp3"
  20 # uses SDL_sound's internal MPGLIB, which doesn't have that problem. It's OK
  21 # if both "mp3" as well as "mpeg" are enabled, because SDL_sound tries MPGLIB
  22 # first, and only if that fails will it use SMPEG.
  23 DEPEND="x11-libs/qt-gui:4
  24         media-libs/libsdl[audio]
  25         media-libs/sdl-mixer[midi,vorbis]
  26         media-libs/sdl-sound[mp3]"
  27 RDEPEND="${DEPEND}"
  28
  29 DOCS="AUTHORS BUGS NEWS HTML_TADS_LICENSE README"
  30
  31 src_install() {
  32         dogamesbin qtads || die
  33         doman qtads.6 || die
  34         dodoc ${DOCS} || die
  35         newicon -s 256 qtads_256x256.png ${PN}.png
  36         insinto /usr/share/icons
  37         doins -r "icons/hicolor"
  38         insinto /usr/share/mime/packages
  39         doins "icons/qtads.xml"
  40         make_desktop_entry qtads QTads ${PN} Game "GenericName=TADS Multimedia Interpreter\nMimeType=application/x-tads;application/x-t3vm-image;"
  41         prepgamesdirs
  42 }
  43
  44 pkg_preinst() {
  45         games_pkg_preinst
  46         gnome2_icon_savelist
  47 }
  48
  49 pkg_postinst() {
  50         games_pkg_postinst
  51         fdo-mime_desktop_database_update
  52         fdo-mime_mime_database_update
  53         gnome2_icon_cache_update
  54 }
  55
  56 pkg_postrm() {
  57         fdo-mime_desktop_database_update
  58         fdo-mime_mime_database_update
  59         gnome2_icon_cache_update
  60 }