games-engines/qtads/qtads-2.1.5.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="4"
   6 inherit eutils gnome2-utils fdo-mime games qt4-r2
   7
   8 DESCRIPTION="Multimedia interpreter for TADS text adventures"
   9 HOMEPAGE="http://qtads.sourceforge.net"
  10 SRC_URI="mirror://sourceforge/qtads/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE=""
  16
  17 DEPEND="x11-libs/qt-gui:4
  18         media-libs/libsdl[audio]
  19         media-libs/sdl-mixer[midi,vorbis]
  20         media-libs/sdl-sound[mp3]"
  21
  22 src_install() {
  23         dogamesbin qtads || die
  24         doman qtads.6
  25         dodoc AUTHORS BUGS HTML_TADS_LICENSE NEWS README
  26         newicon -s 256 qtads_256x256.png ${PN}.png
  27         insinto /usr/share/icons
  28         doins -r "icons/hicolor"
  29         insinto /usr/share/mime/packages
  30         doins "icons/qtads.xml"
  31         make_desktop_entry qtads QTads qtads Game "GenericName=TADS Multimedia Interpreter\nMimeType=application/x-tads;application/x-t3vm-image;"
  32         prepgamesdirs
  33 }
  34
  35 pkg_preinst() {
  36         games_pkg_preinst
  37         gnome2_icon_savelist
  38 }
  39
  40 pkg_postinst() {
  41         games_pkg_postinst
  42         fdo-mime_desktop_database_update
  43         fdo-mime_mime_database_update
  44         gnome2_icon_cache_update
  45 }
  46
  47 pkg_postrm() {
  48         fdo-mime_desktop_database_update
  49         fdo-mime_mime_database_update
  50         gnome2_icon_cache_update
  51 }