games-engines/qtads/qtads-1.9.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6 inherit flag-o-matic qt3 games
   7
   8 DESCRIPTION="Qt3-based GUI interpreter for TADS 2 and TADS 3 text adventures"
   9 HOMEPAGE="http://qtads.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~x86"
  15
  16 DEPEND="x11-libs/qt:3"
  17 RDEPEND="${DEPEND}"
  18
  19 LANGUAGES="de"
  20 for i in ${LANGUAGES}; do
  21         IUSE="${IUSE} linguas_${i}"
  22 done
  23
  24 src_unpack() {
  25         unpack ${A}
  26         cd "${S}"
  27         gunzip qtads.6.gz || die "gunzip qtads.6.gz failed"
  28 }
  29
  30 src_configure() {
  31         # Work-around for a bug when compiling with some versions of g++;
  32         # strict-aliasing will break the Tads 3 VM.
  33         append-cxxflags -fno-strict-aliasing
  34         eqmake3 qtads.pro \
  35                 BIN_INSTALL="${GAMES_BINDIR}" DATA_INSTALL="${GAMES_DATADIR}"
  36 }
  37
  38 src_install() {
  39         # Install everything except documentation and i18n.
  40         emake INSTALL_ROOT="${D}" \
  41                 install_target install_charmaps \
  42         || die "make install failed"
  43         # We install documentation manually to comply with Gentoo guidelines.
  44         dodoc \
  45                 AUTHORS BUGS CREDITS INSTALL NEWS PORTABILITY README \
  46                 SOURCE_README TIPS TODO
  47         # Same for i18n.
  48         insinto "${GAMES_DATADIR}/${PN}/i18n"
  49         for i in ${LANGUAGES}; do
  50                 if has ${i} ${LINGUAS}; then
  51                         doins "${PN}_${i}.qm" || die "doins ${PN}_${i}.qm failed"
  52                 fi
  53         done
  54         doman qtads.6
  55         make_desktop_entry qtads QTads
  56         prepgamesdirs
  57 }