src/parse/unparse.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs: nil -*-
   2 ;;; ---------------------------------------------------------------------------
   3 ;;;     Title: Unparse HTML
   4 ;;;   Created: 2007-10-14
   5 ;;;    Author: David Lichteblau <david@lichteblau.com>
   6 ;;;   License: BSD-style
   7 ;;; ---------------------------------------------------------------------------
   8 ;;;  (c) copyright 2005-2007 David Lichteblau
   9
  10
  11 (in-package :closure-html)
  12
  13
  14 ;;; SINK: an HTML output sink
  15
  16 (defclass sink (hax:abstract-handler)
  17     ((ystream :initarg :ystream :accessor sink-ystream)
  18      (stack :initform nil :accessor stack)))
  19
  20 #-rune-is-character
  21 (defmethod hax:%want-strings-p ((handler sink))
  22   nil)
  23
  24 ;; bisschen unschoen hier SCHON WIEDER die ganze api zu duplizieren, aber die
  25 ;; ystreams sind noch undokumentiert
  26 (macrolet ((define-maker (make-sink make-ystream &rest args)
  27              `(defun ,make-sink (,@args &rest initargs)
  28                 (apply #'make-instance
  29                        'sink
  30                        :ystream (,make-ystream ,@args)
  31                        initargs))))
  32   (define-maker make-octet-vector-sink make-octet-vector-ystream)
  33   (define-maker make-octet-stream-sink make-octet-stream-ystream stream)
  34   (define-maker make-rod-sink make-rod-ystream)
  35
  36   #+rune-is-character
  37   (define-maker make-character-stream-sink make-character-stream-ystream stream)
  38
  39   #-rune-is-character
  40   (define-maker make-string-sink/utf8 make-string-ystream/utf8)
  41
  42   #-rune-is-character
  43   (define-maker make-character-stream-sink/utf8
  44       make-character-stream-ystream/utf8
  45     stream))
  46
  47 #+rune-is-character
  48 (defun make-string-sink (&rest args) (apply #'make-rod-sink args))
  49
  50
  51 ;;;; Events
  52
  53 (defmethod hax:start-document ((sink sink) name public-id system-id)
  54   (when (plusp (length system-id))
  55     (%write-rod #"<!DOCTYPE " sink)
  56     (%write-rod name sink)
  57     (cond
  58       ((plusp (length public-id))
  59        (%write-rod #" PUBLIC \"" sink)
  60        (unparse-string public-id sink)
  61        (%write-rod #"\" \"" sink)
  62        (unparse-string system-id sink)
  63        (%write-rod #"\"" sink))
  64       (t
  65        (%write-rod #" SYSTEM \"" sink)
  66        (unparse-string system-id sink)
  67        (%write-rod #"\"" sink)))
  68     (%write-rod #">" sink)
  69     (%write-rune #/U+000A sink)))
  70
  71 (defmethod hax:end-document ((sink sink))
  72   (close-ystream (sink-ystream sink)))
  73
  74 (defmethod hax:start-element ((sink sink) name attributes)
  75   (let* ((key (find-symbol (string-upcase (rod-string name)) :keyword))
  76          (elt
  77           (and key (sgml::find-element closure-html::*html-dtd* key nil nil)))
  78          (attlist (and elt (sgml::element-attlist elt))))
  79     (push (cons name elt) (stack sink))
  80     (%write-rune #/< sink)
  81     (%write-rod name sink)
  82     (dolist (a attributes)
  83       (let* ((aname (hax:attribute-name a))
  84              (akey (find-symbol (string-upcase (string-rod aname)) :keyword))
  85              (att (and akey (assoc akey attlist)))
  86              (values (second att)))
  87         (%write-rune #/space sink)
  88         (%write-rod aname sink)
  89         (unless (and att (listp values) (eq (car att) (car values)))
  90           (%write-rune #/= sink)
  91           (%write-rune #/\" sink)
  92           (unparse-string (hax:attribute-value a) sink)
  93           (%write-rune #/\" sink))))
  94     (%write-rune #/> sink)))
  95
  96 (defmethod hax:end-element
  97     ((sink sink) name)
  98   (let* ((prev (pop (stack sink)))
  99          (prev-name (car prev))
 100          (elt (cdr prev)))
 101     (unless (rod= prev-name name)
 102       (error "output does not nest: expected ~A but got ~A"
 103              name prev-name))
 104     (unless (and elt (null (sgml::element-include elt)))
 105       (%write-rod '#.(string-rod "</") sink)
 106       (%write-rod name sink)
 107       (%write-rod '#.(string-rod ">") sink))))
 108
 109 (defmethod hax:characters ((sink sink) data)
 110   (let ((y (sink-ystream sink)))
 111     (loop for c across data do (unparse-datachar-readable c y))))
 112
 113 (defmethod hax:comment ((sink sink) data)
 114   ;; XXX signal error if body is unprintable?
 115   (%write-rod #"<!--" sink)
 116   (map nil (lambda (c) (%write-rune c sink)) data)
 117   (%write-rod #"-->" sink))
 118
 119 (defun unparse-string (str sink)
 120   (let ((y (sink-ystream sink)))
 121     (loop for rune across str do (unparse-datachar rune y))))
 122
 123 (defun unparse-datachar (c ystream)
 124   (cond ((rune= c #/&) (write-rod '#.(string-rod "&amp;") ystream))
 125         ((rune= c #/<) (write-rod '#.(string-rod "&lt;") ystream))
 126         ((rune= c #/>) (write-rod '#.(string-rod "&gt;") ystream))
 127         ((rune= c #/\") (write-rod '#.(string-rod "&quot;") ystream))
 128         ((rune= c #/U+0009) (write-rod '#.(string-rod "&#9;") ystream))
 129         ((rune= c #/U+000A) (write-rod '#.(string-rod "&#10;") ystream))
 130         ((rune= c #/U+000D) (write-rod '#.(string-rod "&#13;") ystream))
 131         (t
 132          (write-rune c ystream))))
 133
 134 (defun unparse-datachar-readable (c ystream)
 135   (cond ((rune= c #/&) (write-rod '#.(string-rod "&amp;") ystream))
 136         ((rune= c #/<) (write-rod '#.(string-rod "&lt;") ystream))
 137         ((rune= c #/>) (write-rod '#.(string-rod "&gt;") ystream))
 138         ((rune= c #/\") (write-rod '#.(string-rod "&quot;") ystream))
 139         ((rune= c #/U+000D) (write-rod '#.(string-rod "&#13;") ystream))
 140         (t
 141           (write-rune c ystream))))
 142
 143 (defun unparse-dtd-string (str sink)
 144   (let ((y (sink-ystream sink)))
 145     (loop for rune across str do (unparse-dtd-char rune y))))
 146
 147 (defun unparse-dtd-char (c ystream)
 148   (cond ((rune= c #/%) (write-rod '#.(string-rod "&#37;") ystream))
 149         ((rune= c #/&) (write-rod '#.(string-rod "&amp;") ystream))
 150         ((rune= c #/<) (write-rod '#.(string-rod "&lt;") ystream))
 151         ((rune= c #/>) (write-rod '#.(string-rod "&gt;") ystream))
 152         ((rune= c #/\") (write-rod '#.(string-rod "&quot;") ystream))
 153         ((rune= c #/U+0009) (write-rod '#.(string-rod "&#9;") ystream))
 154         ((rune= c #/U+000A) (write-rod '#.(string-rod "&#10;") ystream))
 155         ((rune= c #/U+000D) (write-rod '#.(string-rod "&#13;") ystream))
 156         (t
 157          (write-rune c ystream))))
 158
 159 (defun %write-rune (c sink)
 160   (write-rune c (sink-ystream sink)))
 161
 162 (defun %write-rod (r sink)
 163   (write-rod r (sink-ystream sink)))
 164
 165
 166 ;;;; convenience functions for PTless HTML serialization
 167
 168 (defvar *current-element*)
 169 (defvar *sink*)
 170
 171 (defmacro with-html-output
 172     ((sink &key (name "HTML") public-id system-id) &body body)
 173   `(invoke-with-html-output (lambda () ,@body)
 174                             ,sink
 175                             ,name
 176                             ,public-id
 177                             ,system-id))
 178
 179 (defun invoke-with-html-output (fn sink name pubid sysid)
 180   (let ((*sink* sink)
 181         (*current-element* nil))
 182     (hax:start-document *sink* name pubid sysid)
 183     (funcall fn)
 184     (hax:end-document *sink*)))
 185
 186 ;; fuer XML ist hier mehr zu tun, also gehen wir vorsichtshalber fuer HTML
 187 ;; erstmal auch diesen Weg
 188 (defmacro with-output-sink ((var) &body body)
 189   `(invoke-with-output-sink (lambda (,var) ,@body)))
 190 (defun invoke-with-output-sink (fn)
 191   (funcall fn *sink*))
 192
 193 (defmacro with-element (name &body body)
 194   `(invoke-with-element (lambda () ,@body) ,name))
 195
 196 (defun maybe-emit-start-tag ()
 197   (when *current-element*
 198     ;; starting child node, need to emit opening tag of parent first:
 199     (destructuring-bind (name &rest attributes) *current-element*
 200       (hax:start-element *sink* name (reverse attributes)))
 201     (setf *current-element* nil)))
 202
 203 (defun invoke-with-element (fn name)
 204   (setf name (rod name))
 205   (maybe-emit-start-tag)
 206   (let ((*current-element* (list name)))
 207     (multiple-value-prog1
 208         (funcall fn)
 209       (maybe-emit-start-tag)
 210       (hax:end-element *sink* name))))
 211
 212 (defgeneric unparse-attribute (value))
 213 (defmethod unparse-attribute ((value string)) value)
 214 (defmethod unparse-attribute ((value null)) nil)
 215 (defmethod unparse-attribute ((value integer)) (write-to-string value))
 216
 217 (defun attribute (name value)
 218   (setf name (rod name))
 219   (setf value (unparse-attribute value))
 220   (push (hax:make-attribute name value t)
 221         (cdr *current-element*)))
 222
 223 (defun text (data)
 224   (maybe-emit-start-tag)
 225   (hax:characters *sink* (rod data))
 226   data)
 227
 228 (defun comment (data)
 229   (maybe-emit-start-tag)
 230   (hax:comment *sink* (rod data))
 231   data)