src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46
  47 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  48   (let ((change nil))
  49     (labels ((has-x (mask) (= 1 (logand mask 1)))
  50              (has-y (mask) (= 2 (logand mask 2)))
  51              (has-w (mask) (= 4 (logand mask 4)))
  52              (has-h (mask) (= 8 (logand mask 8)))
  53              (has-bw (mask) (= 16 (logand mask 16)))
  54              (has-stackmode (mask) (= 64 (logand mask 64)))
  55              (adjust-from-request ()
  56                (when (has-x value-mask) (setf (x-drawable-x window) x
  57                                               change :moved))
  58                (when (has-y value-mask) (setf (x-drawable-y window) y
  59                                               change :moved))
  60                (when (has-h value-mask) (setf (x-drawable-height window) height
  61                                               change :resized))
  62                (when (has-w value-mask) (setf (x-drawable-width window) width
  63                                               change :resized))))
  64       (when window
  65         (xlib:with-state (window)
  66           (let ((current-root (find-current-root)))
  67             (if (find-child window current-root)
  68                 (let ((parent (find-parent-frame window current-root)))
  69                   (if (and parent (managed-window-p window parent))
  70                       (setf change (adapt-child-to-parent window parent))
  71                       (adjust-from-request)))
  72                 (adjust-from-request)))
  73           (when (has-bw value-mask)
  74             (setf (x-drawable-border-width window) border-width
  75                   change :resized))
  76           (when (has-stackmode value-mask)
  77             (case stack-mode
  78               (:above
  79                (unless (null-size-window-p window)
  80                  (when (or (child-equal-p window (current-child))
  81                            (is-in-current-child-p window))
  82                    (setf change (or change :moved))
  83                    (raise-window window)
  84                    (focus-window window)
  85                    (focus-all-children window (find-parent-frame window (find-current-root)))))))))
  86         (unless (eq change :resized)
  87           ;; To be ICCCM compliant, send a fake configuration notify event only when
  88           ;; the window has moved and not when it has been resized or the border width has changed.
  89           (send-configuration-notify window (x-drawable-x window) (x-drawable-y window)
  90                                      (x-drawable-width window) (x-drawable-height window)
  91                                      (x-drawable-border-width window)))))))
  92
  93
  94 (define-handler main-mode :map-request (window send-event-p)
  95   (unless send-event-p
  96     (unless (find-child window *root-frame*)
  97       (unhide-window window)
  98       (process-new-window window)
  99       (map-window window)
 100       (unless (null-size-window-p window)
 101         (multiple-value-bind (never-managed raise)
 102             (never-managed-window-p window)
 103           (unless (and never-managed raise)
 104             (show-all-children)))))))
 105
 106
 107
 108 (define-handler main-mode :unmap-notify (send-event-p event-window window)
 109   (unless (and (not send-event-p)
 110                (not (xlib:window-equal window event-window)))
 111     (when (find-child window *root-frame*)
 112       (setf (window-state window) +withdrawn-state+)
 113       (xlib:unmap-window window)
 114       (delete-child-in-all-frames window)
 115       (show-all-children))))
 116
 117
 118
 119
 120
 121 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 122   (unless (or send-event-p
 123               (xlib:window-equal window event-window))
 124     (when (find-child window *root-frame*)
 125       (delete-child-in-all-frames window)
 126       (show-all-children)
 127       (xlib:destroy-window window))))
 128
 129 (define-handler main-mode :enter-notify  (window root-x root-y)
 130   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 131                (> root-y (- (xlib:screen-height *screen*) 3)))
 132     (case (if (frame-p (current-child))
 133               (frame-focus-policy (current-child))
 134               *default-focus-policy*)
 135       (:sloppy (focus-window window))
 136       (:sloppy-strict (when (and (frame-p (current-child))
 137                                  (child-member window (frame-child (current-child))))
 138                         (focus-window window)))
 139       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 140                              (parent (find-parent-frame child)))
 141                         (unless (or (child-root-p child)
 142                                     (equal (typecase child
 143                                              (xlib:window parent)
 144                                              (t child))
 145                                            (current-child)))
 146                             (focus-all-children child parent)
 147                             (show-all-children)))))))
 148
 149 (define-handler main-mode :exposure (window)
 150   (awhen (find-frame-window window)
 151     (display-frame-info it)))
 152
 153 (define-handler main-mode :configure-notify (window)
 154   (when (child-equal-p window *root*)
 155     (place-frames-from-xinerama-infos)
 156     (finish-configuring-root)
 157     (show-all-children)
 158     (call-hook *root-size-change*)))
 159
 160
 161 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 162   "Handle X errors"
 163   (cond
 164     ;; ignore asynchronous window errors
 165     ((and asynchronous
 166           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 167      #+:xlib-debug (format t "~&Ignoring XLib asynchronous error: ~s~%" error-key))
 168     ((eq error-key 'xlib:access-error)
 169      (write-line "~&Another window manager is running.")
 170      (throw 'exit-clfswm nil))
 171     ;; all other asynchronous errors are printed.
 172     (asynchronous
 173      #+:xlib-debug (format t "~&Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 174     ;;((find error-key '(xlib:window-error xlib:drawable-error xlib:match-error))
 175     ;; (format t "~&Ignoring Xlib error: ~S ~S~%" error-key key-vals))
 176     (t
 177      (apply 'error error-key :display display :error-key error-key key-vals))))
 178
 179
 180 (defun main-loop ()
 181   (loop
 182      (with-xlib-protect (:main-loop nil)
 183        (call-hook *loop-hook*)
 184        (process-timers)
 185        (when (xlib:event-listen *display* *loop-timeout*)
 186          (xlib:process-event *display* :handler #'handle-event))
 187        (xlib:display-finish-output *display*)
 188        (setf *x-error-count* 0))))
 189
 190
 191
 192
 193 (defun open-display (display-str protocol)
 194   (multiple-value-bind (host display-num) (parse-display-string display-str)
 195     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 196           (xlib:display-error-handler *display*) 'error-handler
 197           (getenv "DISPLAY") display-str)))
 198
 199
 200
 201 (defun default-init-hook ()
 202   (place-frames-from-xinerama-infos)
 203   (finish-configuring-root))
 204
 205
 206 (defun init-display ()
 207   (reset-root-list)
 208   (reset-bind-or-jump-slots)
 209   (reset-open-menu)
 210   (fill-handle-event-fun-symbols)
 211   (assoc-keyword-handle-event 'main-mode)
 212   (setf *screen* (first (xlib:display-roots *display*))
 213         *root* (xlib:screen-root *screen*)
 214         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 215         *default-font* (xlib:open-font *display* *default-font-string*)
 216         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 217                                             :height (xlib:screen-height *screen*)
 218                                             :depth (xlib:screen-root-depth *screen*)
 219                                             :drawable *root*)
 220         *in-second-mode* nil
 221         *x-error-count* 0)
 222   (store-root-background)
 223   (init-modifier-list)
 224   (xgrab-init-pointer)
 225   (xgrab-init-keyboard)
 226   (init-last-child)
 227   (call-hook *binding-hook*)
 228   (clear-timers)
 229   (map-window *no-focus-window*)
 230   (dbg *display*)
 231   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 232                                                               :substructure-notify
 233                                                               :structure-notify
 234                                                               :property-change
 235                                                               ;;:resize-redirect
 236                                                               :exposure
 237                                                               :button-press
 238                                                               :button-release
 239                                                               :pointer-motion))
 240   (xlib:display-finish-output *display*)
 241   ;;(intern-atoms *display*)
 242   (netwm-set-properties)
 243   (xlib:display-force-output *display*)
 244   (setf *child-selection* nil)
 245   (setf *root-frame* (create-frame :name "Root" :number 0)
 246         (current-child) *root-frame*)
 247   (call-hook *init-hook*)
 248   (process-existing-windows *screen*)
 249   (show-all-children)
 250   (grab-main-keys)
 251   (xlib:display-finish-output *display*)
 252   (optimize-event-hook))
 253
 254
 255
 256
 257 (defun read-conf-file ()
 258   (let* ((conf (conf-file-name)))
 259     (if conf
 260         (handler-case (load conf)
 261           (error (c)
 262             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 263             (values nil (format nil "~s" c) conf))
 264           (:no-error (&rest args)
 265             (declare (ignore args))
 266             (values t nil conf)))
 267         (values t nil nil))))
 268
 269
 270
 271
 272
 273
 274 (defun exit-clfswm ()
 275   "Exit clfswm"
 276   (throw 'exit-clfswm nil))
 277
 278 (defun reset-clfswm ()
 279   "Reset clfswm"
 280   (throw 'exit-main-loop nil))
 281
 282
 283
 284
 285 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 286                          (read-conf-file-p t) (alternate-conf nil)
 287                          error-msg)
 288   (conf-file-name alternate-conf)
 289   (when read-conf-file-p
 290     (read-conf-file))
 291   (create-configuration-menu :clear t)
 292   (call-hook *main-entrance-hook*)
 293   (handler-case
 294       (open-display display protocol)
 295     (xlib:access-error (c)
 296       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 297       (force-output)
 298       (exit-clfswm)))
 299   (handler-case
 300       (init-display)
 301     (xlib:access-error (c)
 302       (ungrab-main-keys)
 303       (xlib:destroy-window *no-focus-window*)
 304       (xlib:close-display *display*)
 305       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 306       (force-output)
 307       (exit-clfswm)))
 308   (when error-msg
 309     (info-mode error-msg))
 310   (catch 'exit-main-loop
 311       (unwind-protect
 312            (main-loop)
 313         (progn
 314           (ungrab-main-keys)
 315           (xlib:destroy-window *no-focus-window*)
 316           (xlib:free-pixmap *pixmap-buffer*)
 317           (destroy-all-frames-window)
 318           (call-hook *close-hook*)
 319           (clear-event-hooks)
 320           (xlib:close-display *display*)
 321           #+:event-debug
 322           (format t "~2&Unhandled events: ~A~%" *unhandled-events*)))))
 323
 324
 325
 326 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 327              (read-conf-file-p t)
 328              (alternate-conf nil))
 329   (let (error-msg)
 330     (catch 'exit-clfswm
 331       (loop
 332          (handler-case
 333              (if *other-window-manager*
 334                  (run-other-window-manager)
 335                  (main-unprotected :display display :protocol protocol
 336                                    :read-conf-file-p read-conf-file-p
 337                                    :alternate-conf alternate-conf
 338                                    :error-msg error-msg))
 339            (error (c)
 340              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 341                (format t "~&~A~%Reinitializing...~%" msg)
 342                (setf error-msg (list (list msg *info-color-title*)
 343                                      "Reinitializing...")))))))))
 344
 345
 346