src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2012 Philippe Brochard <pbrochard@common-lisp.net>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46
  47 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  48   (let ((change nil))
  49     (labels ((has-x (mask) (= 1 (logand mask 1)))
  50              (has-y (mask) (= 2 (logand mask 2)))
  51              (has-w (mask) (= 4 (logand mask 4)))
  52              (has-h (mask) (= 8 (logand mask 8)))
  53              (has-bw (mask) (= 16 (logand mask 16)))
  54              (has-stackmode (mask) (= 64 (logand mask 64)))
  55              (adjust-from-request ()
  56                (when (has-x value-mask) (setf (x-drawable-x window) x
  57                                               change :moved))
  58                (when (has-y value-mask) (setf (x-drawable-y window) y
  59                                               change :moved))
  60                (when (has-h value-mask) (setf (x-drawable-height window) height
  61                                               change :resized))
  62                (when (has-w value-mask) (setf (x-drawable-width window) width
  63                                               change :resized))))
  64       (when window
  65         (xlib:with-state (window)
  66           (let ((current-root (find-current-root)))
  67             (if (find-child window current-root)
  68                 (let ((parent (find-parent-frame window current-root)))
  69                   (if (and parent (managed-window-p window parent))
  70                       (setf change (adapt-child-to-parent window parent))
  71                       (adjust-from-request)))
  72                 (adjust-from-request)))
  73           (when (has-bw value-mask)
  74             (setf (x-drawable-border-width window) border-width
  75                   change :resized))
  76           (when (has-stackmode value-mask)
  77             (case stack-mode
  78               (:above
  79                (when (or (child-equal-p window (current-child))
  80                          (is-in-current-child-p window))
  81                  (setf change (or change :moved))
  82                  (focus-window window)
  83                  (focus-all-children window (find-parent-frame window (find-current-root)))
  84                  (show-all-children))))))
  85         (unless (eq change :resized)
  86           ;; To be ICCCM compliant, send a fake configuration notify event only when
  87           ;; the window has moved and not when it has been resized or the border width has changed.
  88           (send-configuration-notify window (x-drawable-x window) (x-drawable-y window)
  89                                      (x-drawable-width window) (x-drawable-height window)
  90                                      (x-drawable-border-width window)))))))
  91
  92
  93 (define-handler main-mode :map-request (window send-event-p)
  94   (unless send-event-p
  95     (unless (find-child window *root-frame*)
  96       (unhide-window window)
  97       (process-new-window window)
  98       (map-window window)
  99       (multiple-value-bind (never-managed raise)
 100           (never-managed-window-p window)
 101         (unless (and never-managed raise)
 102           (show-all-children))))))
 103
 104
 105
 106 (define-handler main-mode :unmap-notify (send-event-p event-window window)
 107   (unless (and (not send-event-p)
 108                (not (xlib:window-equal window event-window)))
 109     (when (find-child window *root-frame*)
 110       (setf (window-state window) +withdrawn-state+)
 111       (remove-child-in-all-frames window)
 112       (show-all-children))))
 113
 114
 115 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 116   (unless (or send-event-p
 117               (xlib:window-equal window event-window))
 118     (when (find-child window *root-frame*)
 119       (delete-child-in-all-frames window)
 120       (show-all-children)
 121       (xlib:destroy-window window))))
 122
 123
 124 (define-handler main-mode :enter-notify  (window root-x root-y)
 125   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 126                (> root-y (- (xlib:screen-height *screen*) 3)))
 127     (case (if (frame-p (current-child))
 128               (frame-focus-policy (current-child))
 129               *default-focus-policy*)
 130       (:sloppy (focus-window window))
 131       (:sloppy-strict (when (and (frame-p (current-child))
 132                                  (child-member window (frame-child (current-child))))
 133                         (focus-window window)))
 134       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 135                              (parent (find-parent-frame child)))
 136                         (unless (or (child-root-p child)
 137                                     (equal (typecase child
 138                                              (xlib:window parent)
 139                                              (t child))
 140                                            (current-child)))
 141                             (focus-all-children child parent)
 142                             (show-all-children)))))))
 143
 144 (define-handler main-mode :exposure (window)
 145   (awhen (find-frame-window window)
 146     (display-frame-info it)))
 147
 148
 149 (define-handler main-mode :configure-notify (window)
 150   (when (child-equal-p window *root*)
 151     (unless (eql (place-frames-from-xinerama-infos) :update)
 152       (finish-configuring-root))
 153     (show-all-children)
 154     (call-hook *root-size-change-hook*)))
 155
 156
 157 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 158   "Handle X errors"
 159   (cond
 160     ;; ignore asynchronous window errors
 161     ((and asynchronous
 162           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 163      #+:xlib-debug (format t "~&Ignoring XLib asynchronous error: ~s~%" error-key))
 164     ((eq error-key 'xlib:access-error)
 165      (write-line "~&Another window manager is running.")
 166      (throw 'exit-clfswm nil))
 167     ;; all other asynchronous errors are printed.
 168     (asynchronous
 169      #+:xlib-debug (format t "~&Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 170     ;;((find error-key '(xlib:window-error xlib:drawable-error xlib:match-error))
 171     ;; (format t "~&Ignoring Xlib error: ~S ~S~%" error-key key-vals))
 172     (t
 173      (apply 'error error-key :display display :error-key error-key key-vals))))
 174
 175
 176 (defun main-loop ()
 177   (loop
 178      (with-xlib-protect (:main-loop nil)
 179        (call-hook *loop-hook*)
 180        (process-timers)
 181        (when (xlib:event-listen *display* *loop-timeout*)
 182          (xlib:process-event *display* :handler #'handle-event))
 183        (xlib:display-finish-output *display*)
 184        (setf *x-error-count* 0))))
 185
 186
 187
 188
 189 (defun open-display (display-str protocol)
 190   (multiple-value-bind (host display-num) (parse-display-string display-str)
 191     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 192           (xlib:display-error-handler *display*) 'error-handler
 193           (getenv "DISPLAY") display-str)))
 194
 195
 196
 197 (defun default-init-hook ()
 198   (place-frames-from-xinerama-infos)
 199   (finish-configuring-root))
 200
 201
 202 (defun init-display ()
 203   (reset-root-list)
 204   (reset-last-head-size)
 205   (reset-bind-or-jump-slots)
 206   (reset-open-menu)
 207   (fill-handle-event-fun-symbols)
 208   (assoc-keyword-handle-event 'main-mode)
 209   (setf *screen* (first (xlib:display-roots *display*))
 210         *root* (xlib:screen-root *screen*)
 211         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 212         *default-font* (xlib:open-font *display* *default-font-string*)
 213         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 214                                             :height (xlib:screen-height *screen*)
 215                                             :depth (xlib:screen-root-depth *screen*)
 216                                             :drawable *root*)
 217         *in-second-mode* nil
 218         *x-error-count* 0)
 219   (store-root-background)
 220   (init-modifier-list)
 221   (xgrab-init-pointer)
 222   (xgrab-init-keyboard)
 223   (init-last-child)
 224   (call-hook *binding-hook*)
 225   (clear-timers)
 226   (map-window *no-focus-window*)
 227   (dbg *display*)
 228   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 229                                                               :substructure-notify
 230                                                               :structure-notify
 231                                                               :property-change
 232                                                               ;;:resize-redirect
 233                                                               :exposure
 234                                                               :button-press
 235                                                               :button-release
 236                                                               :pointer-motion))
 237   (xlib:display-finish-output *display*)
 238   ;;(intern-atoms *display*)
 239   (netwm-set-properties)
 240   (xlib:display-force-output *display*)
 241   (setf *child-selection* nil)
 242   (setf *root-frame* (create-frame :name "Root" :number 0)
 243         (current-child) *root-frame*)
 244   (call-hook *init-hook*)
 245   (process-existing-windows *screen*)
 246   (show-all-children)
 247   (grab-main-keys)
 248   (xlib:display-finish-output *display*)
 249   (optimize-event-hook))
 250
 251
 252
 253
 254 (defun read-conf-file ()
 255   (let* ((conf (conf-file-name)))
 256     (if conf
 257         (handler-case (load conf)
 258           (error (c)
 259             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 260             (values nil (format nil "~s" c) conf))
 261           (:no-error (&rest args)
 262             (declare (ignore args))
 263             (values t nil conf)))
 264         (values t nil nil))))
 265
 266
 267
 268
 269
 270
 271 (defun exit-clfswm ()
 272   "Exit clfswm"
 273   (throw 'exit-clfswm nil))
 274
 275 (defun reset-clfswm ()
 276   "Reset clfswm"
 277   (throw 'exit-main-loop nil))
 278
 279
 280
 281
 282 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 283                          (read-conf-file-p t) (alternate-conf nil)
 284                          error-msg)
 285   (conf-file-name alternate-conf)
 286   (when read-conf-file-p
 287     (read-conf-file))
 288   (create-configuration-menu :clear t)
 289   (call-hook *main-entrance-hook*)
 290   (handler-case
 291       (open-display display protocol)
 292     (xlib:access-error (c)
 293       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 294       (force-output)
 295       (exit-clfswm)))
 296   (handler-case
 297       (init-display)
 298     (xlib:access-error (c)
 299       (ungrab-main-keys)
 300       (xlib:destroy-window *no-focus-window*)
 301       (xlib:close-display *display*)
 302       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 303       (force-output)
 304       (exit-clfswm)))
 305   (when error-msg
 306     (info-mode error-msg))
 307   (catch 'exit-main-loop
 308       (unwind-protect
 309            (main-loop)
 310         (progn
 311           (ungrab-main-keys)
 312           (xlib:destroy-window *no-focus-window*)
 313           (xlib:free-pixmap *pixmap-buffer*)
 314           (destroy-all-frames-window)
 315           (call-hook *close-hook*)
 316           (clear-event-hooks)
 317           (xlib:close-display *display*)
 318           #+:event-debug
 319           (format t "~2&Unhandled events: ~A~%" *unhandled-events*)))))
 320
 321
 322
 323 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 324              (read-conf-file-p t)
 325              (alternate-conf nil))
 326   (let (error-msg)
 327     (catch 'exit-clfswm
 328       (loop
 329          (handler-case
 330              (if *other-window-manager*
 331                  (run-other-window-manager)
 332                  (main-unprotected :display display :protocol protocol
 333                                    :read-conf-file-p read-conf-file-p
 334                                    :alternate-conf alternate-conf
 335                                    :error-msg error-msg))
 336            (error (c)
 337              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 338                (format t "~&~A~%Reinitializing...~%" msg)
 339                (setf error-msg (list (list msg *info-color-title*)
 340                                      "Reinitializing...")))))))))
 341
 342
 343