zeromq-api.lisp

   1 ;; Copyright (c) 2009, 2010 Vitaly Mayatskikh <v.mayatskih@gmail.com>
   2 ;;
   3 ;; This file is part of CL-ZMQ.
   4 ;;
   5 ;; Vitaly Mayatskikh grants you the rights to distribute
   6 ;; and use this software as governed by the terms
   7 ;; of the Lisp Lesser GNU Public License
   8 ;; (http://opensource.franz.com/preamble.html),
   9 ;; known as the LLGPL.
  10
  11 (in-package :zeromq)
  12
  13 (defcfun ("memcpy" memcpy) :pointer
  14   (dst  :pointer)
  15   (src  :pointer)
  16   (len  :long))
  17
  18 ;; Stolen from CFFI. Uses custom allocator (alloc-fn) instead of foreign-alloc
  19 (defun copy-lisp-string-octets (string alloc-fn &key (encoding cffi::*default-foreign-encoding*)
  20                                 (null-terminated-p t) (start 0) end)
  21   "Allocate a foreign string containing Lisp string STRING.
  22 The string must be freed with FOREIGN-STRING-FREE."
  23   (check-type string string)
  24   (cffi::with-checked-simple-vector ((string (coerce string 'babel:unicode-string))
  25                                      (start start) (end end))
  26     (declare (type simple-string string))
  27     (let* ((mapping (cffi::lookup-mapping cffi::*foreign-string-mappings* encoding))
  28            (count (funcall (cffi::octet-counter mapping) string start end 0))
  29            (length (if null-terminated-p
  30                        (+ count (cffi::null-terminator-len encoding))
  31                        count))
  32            (ptr (funcall alloc-fn length)))
  33       (funcall (cffi::encoder mapping) string start end ptr 0)
  34       (when null-terminated-p
  35         (dotimes (i (cffi::null-terminator-len encoding))
  36           (setf (mem-ref ptr :char (+ count i)) 0)))
  37       (values ptr length))))
  38
  39 (defclass msg ()
  40   ((raw         :accessor msg-raw :initform nil)))
  41
  42 (defmethod initialize-instance :after ((inst msg) &key size data)
  43   (let ((obj (foreign-alloc 'msg)))
  44     (tg:finalize inst (lambda ()
  45                         (%msg-close obj)
  46                         (foreign-free obj)))
  47     (cond (size (%msg-init-size obj size))
  48           (data
  49            (etypecase data
  50              (string (copy-lisp-string-octets
  51                       data (lambda (sz)
  52                              (%msg-init-size obj sz)
  53                              (%msg-data obj))))
  54              ((simple-array (unsigned-byte 8))
  55               (let ((len (length data)))
  56                 (%msg-init-size obj len)
  57                 (with-pointer-to-vector-data (ptr data)
  58                   (memcpy (%msg-data obj) ptr len))))
  59              (array (progn
  60                       (%msg-init-size obj (length data))
  61                       (let ((ptr (%msg-data obj))
  62                             (i -1))
  63                         (map nil (lambda (x)
  64                                    (setf (mem-aref ptr :uchar (incf i)) x))
  65                              data))))))
  66           (t (msg-init obj)))
  67     (setf (msg-raw inst) obj)))
  68
  69 (defclass pollitem ()
  70   ((raw         :accessor pollitem-raw :initform nil)
  71    (socket      :accessor pollitem-socket :initform nil :initarg :socket)
  72    (fd          :accessor pollitem-fd :initform -1 :initarg :fd)
  73    (events      :accessor pollitem-events :initform 0 :initarg :events)
  74    (revents     :accessor pollitem-revents :initform 0)))
  75
  76 (defmethod initialize-instance :after ((inst pollitem) &key)
  77   (let ((obj (foreign-alloc 'pollitem)))
  78     (setf (pollitem-raw inst) obj)
  79     (tg:finalize inst (lambda () (foreign-free obj)))))
  80
  81 (defun bind (s address)
  82   (with-foreign-string (addr address)
  83     (%bind s addr)))
  84
  85 (defun connect (s address)
  86   (with-foreign-string (addr address)
  87     (%connect s addr)))
  88
  89 (defmacro with-context ((context io-threads) &body body)
  90   `(let ((,context (init ,io-threads)))
  91      (unwind-protect
  92           (progn ,@body)
  93        (term ,context))))
  94
  95 (defmacro with-socket ((socket context type) &body body)
  96   `(let ((,socket (socket ,context ,type)))
  97      (unwind-protect
  98           (progn ,@body)
  99        (close ,socket))))
 100
 101 (defun msg-data-as-is (msg)
 102   (%msg-data (msg-raw msg)))
 103
 104 (defun msg-data-as-string (msg)
 105   (let ((data (%msg-data (msg-raw msg)))
 106         (size (%msg-size (msg-raw msg))))
 107     (unless (zerop (pointer-address data))
 108       (foreign-string-to-lisp data :count size))))
 109
 110 (defun msg-data-as-array (msg)
 111   (let ((data (%msg-data (msg-raw msg))))
 112     (unless (zerop (pointer-address data))
 113       (let* ((len (msg-size msg))
 114              (arr (#+lispworks sys:in-static-area
 115                                #-lispworks cl:identity
 116                                (make-array len :element-type '(unsigned-byte 8)))))
 117         (declare (type (simple-array (unsigned-byte 8)) arr))
 118         (with-pointer-to-vector-data (ptr arr)
 119           (memcpy ptr data len))
 120         arr))))
 121
 122 (defun send (s msg &optional flags)
 123   (%send s (msg-raw msg) (or flags 0)))
 124
 125 (defun recv (s msg &optional flags)
 126   (%recv s (msg-raw msg) (or flags 0)))
 127
 128 (defun msg-init-size (msg size)
 129   (%msg-init-size (msg-raw msg) size))
 130
 131 (defun msg-close (msg)
 132   (%msg-close (msg-raw msg)))
 133
 134 (defun msg-size (msg)
 135   (%msg-size (msg-raw msg)))
 136
 137 (defun msg-move (dst src)
 138   (%msg-move (msg-raw dst) (msg-raw src)))
 139
 140 (defun msg-copy (dst src)
 141   (%msg-copy (msg-raw dst) (msg-raw src)))
 142
 143 (defun setsockopt (socket option value)
 144   (etypecase value
 145     (string (with-foreign-string (string value)
 146               (%setsockopt socket option string (length value))))
 147     (integer (with-foreign-object (int :int64)
 148                (setf (mem-aref int :int64) value)
 149                (%setsockopt socket option int (foreign-type-size :int64))))))
 150
 151 (defun getsockopt (socket option)
 152   (with-foreign-objects ((opt :int64)
 153                          (len :long))
 154     (setf (mem-aref opt :int64) 0
 155           (mem-aref len :long) (foreign-type-size :int64))
 156     (%getsockopt socket option opt len)
 157     (mem-aref opt :int64)))
 158
 159 (defun poll (items &optional (timeout -1))
 160   (let ((len (length items)))
 161     (with-foreign-object (%items 'pollitem len)
 162       (dotimes (i len)
 163         (let ((item (nth i items))
 164               (%item (mem-aref %items 'pollitem i)))
 165           (with-foreign-slots ((socket fd events revents) %item pollitem)
 166             (setf socket (pollitem-socket item)
 167                   fd (pollitem-fd item)
 168                   events (pollitem-events item)))))
 169       (let ((ret (%poll %items len timeout)))
 170         (cond
 171           ((zerop ret) nil)
 172           ((plusp ret)
 173            (loop for i below len
 174               for revent = (foreign-slot-value (mem-aref %items 'pollitem i)
 175                                                'pollitem
 176                                                'revents)
 177               collect (setf (pollitem-revents (nth i items)) revent)))
 178           (t (error (convert-from-foreign (%strerror (errno)) :string))))))))
 179
 180 (defmacro with-polls (list &body body)
 181   `(let ,(loop for (name . polls) in list
 182             collect `(,name
 183                       (list
 184                        ,@(loop for (socket . events) in polls
 185                             collect `(make-instance 'pollitem
 186                                                     :socket ,socket
 187                                                     :events ,events)))))
 188      ,@body))
 189
 190 (defun version ()
 191   (with-foreign-objects ((major :int)
 192                          (minor :int)
 193                          (patch :int))
 194     (%version major minor patch)
 195     (format nil "~d.~d.~d"
 196             (mem-ref major :int)
 197             (mem-ref minor :int)
 198             (mem-ref patch :int))))
 199
 200 (defun device (device insocket outsocket)
 201   (%device device insocket outsocket))