configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.22)
   3 AC_PROG_CXX
   4 AM_PROG_LEX
   5 AC_PROG_YACC
   6 AC_SUBST(versioninfo)
   7 versioninfo=12:0:0
   8
   9 AC_CANONICAL_HOST
  10 AC_LIBTOOL_WIN32_DLL
  11 AC_SUBST(BV_LDFLAGS)
  12 case $host in
  13         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  14         if test "$enable_shared" = yes; then
  15                 BV_LDFLAGS="-no-undefined"
  16         fi
  17         ;;
  18 esac
  19
  20 AC_DISABLE_SHARED
  21 AC_PROG_LIBTOOL
  22
  23 AC_CHECK_HEADERS(getopt.h)
  24 AC_CHECK_HEADERS(sys/times.h)
  25
  26 dnl Check for GMP library
  27 AC_MSG_CHECKING(whether to use GMP)
  28 AC_ARG_WITH(libgmp,
  29         [  --with-libgmp           DIR Location of the GMP Distribution],
  30         gmp_package=$withval, gmp_package=yes)
  31 if test "x$gmp_package" = "xno"; then
  32         AC_MSG_RESULT(no)
  33         AC_MSG_ERROR(Need gmp)
  34 else
  35         AC_MSG_RESULT(yes)
  36         if test "x$gmp_package" != "xyes"; then
  37             GMP_DIR=$gmp_package
  38             if test ! -d "$GMP_DIR"; then
  39                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  40             fi
  41             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  42             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  43         fi
  44         poly_cv_gmpfatal="no"
  45         AC_CHECK_HEADER(gmp.h,
  46                 [AC_CHECK_LIB(gmp,main,
  47                     [],
  48                     [poly_cv_gmpfatal="yes"])],
  49                 [poly_cv_gmpfatal="yes"])
  50         if test "$poly_cv_gmpfatal" = "yes"; then
  51                 AC_MSG_ERROR([GMP not found])
  52         fi
  53 fi
  54 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
  55
  56 AC_ARG_WITH(polylib,
  57             [  --with-polylib=DIR      DIR Location of PolyLib],
  58             [ echo "Package polylib : $withval" && polylib_package=$withval],
  59             [ polylib_package=yes ])
  60
  61 if test "$polylib_package" = "no"; then
  62     AC_MSG_ERROR(Need polylib)
  63 fi
  64
  65 if test "$polylib_package" != "yes"; then
  66     CPPFLAGS="-I$polylib_package/include $CPPFLAGS"
  67     LDFLAGS="-L$polylib_package/lib $LDFLAGS"
  68     LD_LIBRARY_PATH="$polylib_package/lib:$LD_LIBRARY_PATH"
  69     export LD_LIBRARY_PATH
  70 fi
  71
  72 AC_CHECK_LIB(polylibgmp, PolyhedronTSort,[],[
  73     AC_MSG_ERROR(Need polylib)
  74 ])
  75 AC_CHECK_FUNCS(Enumeration_Free)
  76 AC_CHECK_FUNCS(compress_parms)
  77 AC_SUBST(bv_extra_programs)
  78 AC_CHECK_FUNCS(LexSmaller,[
  79         bv_extra_programs="verify_lexsmaller $bv_extra_programs"
  80     ])
  81 AC_REPLACE_FUNCS(DomainConstraintSimplify)
  82 AC_TRY_RUN([
  83 #include <polylib/polylibgmp.h>
  84
  85 int main()
  86 {
  87     int i, j;
  88     Polyhedron *P;
  89     Matrix *M = Matrix_Alloc(6,5);
  90     for (i = 0; i < 6; ++i) {
  91         value_set_si(M->p[i][0], 1);
  92         for (j = 1; j < 4; ++j)
  93             value_set_si(M->p[i][j], (j-1 == i/2) * (1-2*(i%2)));
  94         value_set_si(M->p[i][4], i%2);
  95     }
  96     P = Constraints2Polyhedron(M, 6);
  97     return !(P->NbRays == 8);
  98 }
  99 ],
 100 [AC_DEFINE(HAVE_GROWING_CHERNIKOVA,[],
 101           [PolyLib automatically grows the Chernikova table space])],
 102 AC_MSG_WARN([This version of PolyLib does not automatically])
 103 AC_MSG_WARN([enlarge the Chernikova table space]),
 104 AC_MSG_WARN([Unable to determine whether PolyLib automatically])
 105 AC_MSG_WARN([grows the Chernikova table space]))
 106
 107 AC_TRY_RUN([
 108 #include <polylib/polylibgmp.h>
 109
 110 int main()
 111 {
 112     enode *en = new_enode(polynomial, 1, 1);
 113     return !(en->arr[0].x.p == NULL);
 114 }
 115 ],,
 116 AC_MSG_WARN([This version of polylib leaks]),[true])
 117
 118 AC_TRY_RUN([
 119 #include <stdio.h>
 120 #include <polylib/polylibgmp.h>
 121
 122 int main()
 123 {
 124     Matrix *M;
 125     Polyhedron *P, *C;
 126     Param_Polyhedron *PP;
 127     int i;
 128     Param_Vertices *V;
 129
 130     freopen("$srcdir/tests/ehrhart/t12.in", "r", stdin);
 131     M = Matrix_Read();
 132     P = Constraints2Polyhedron(M, 1024);
 133     M = Matrix_Read();
 134     C = Constraints2Polyhedron(M, 1024);
 135     PP = Polyhedron2Param_Domain(P, C, 1024);
 136     for (i = 0, V = PP->V; V; ++i, V = V->next)
 137         ;
 138     return !(i == 10);
 139 }
 140 ],
 141 [AC_DEFINE(HAVE_CORRECT_VERTICES,[],
 142           [PolyLib computes correct vertices])],
 143 AC_MSG_WARN([This version of polylib produces incorrect vertices.]),
 144 AC_MSG_WARN([Unable to determine whether PolyLib computes correct vertices]))
 145
 146 AC_MSG_CHECKING([number of arguments of Polyhedron_Enumerate])
 147 AC_TRY_COMPILE([#include <polylib/polylibgmp.h>],
 148                [Polyhedron_Enumerate(NULL,NULL,0,NULL)],
 149                [AC_MSG_RESULT(4)
 150                 AC_DEFINE(HAVE_ENUMERATE4,[],
 151                           [Polyhedron_Enumerate takes four arguments])],
 152                [AC_MSG_RESULT(3)])
 153
 154 AC_MSG_CHECKING([number of arguments of count_points])
 155 AC_TRY_COMPILE([#include <polylib/polylibgmp.h>],
 156                [count_points(0,NULL,NULL,NULL)],
 157                [AC_MSG_RESULT(4)
 158                 AC_DEFINE(HAVE_COUNT_POINTS4,[],
 159                           [count_points takes four arguments])],
 160                [AC_MSG_RESULT(3)])
 161
 162 AC_MSG_CHECKING([for value_subtract macro])
 163 AC_EGREP_CPP(yes, [
 164     #include <polylib/polylibgmp.h>
 165     #ifdef value_subtract
 166     yes
 167     #endif
 168     ],[AC_MSG_RESULT(yes)],
 169     [AC_MSG_RESULT(no)
 170      AC_DEFINE(value_subtract,value_substract,
 171                 [define to value_substract if missing from PolyLib])])
 172
 173 AC_ARG_WITH(piplib,
 174             [  --with-piplib=DIR       DIR Location of PIP],
 175             [ echo "Package piplib : $withval" && piplib_package=$withval],
 176             [ piplib_package=yes ])
 177
 178 have_piplib=false
 179 if test "$piplib_package" != "no"; then
 180     SAVE_CPPFLAGS="$CPPFLAGS"
 181     SAVE_LDFLAGS="$LDFLAGS"
 182     if test "$piplib_package" != "yes"; then
 183         CPPFLAGS="-I$piplib_package/include $CPPFLAGS"
 184         LDFLAGS="-L$piplib_package/lib $LDFLAGS"
 185     fi
 186
 187     bv_cv_piplibfatal="no"
 188     AC_CHECK_LIB(piplibMP, pip_solve,[
 189         AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 190             AC_MSG_WARN([Piplib too old; please install version 1.3.6 or newer])
 191             bv_cv_piplibfatal="yes"
 192         ],[#include <stdio.h>
 193            #include <piplib/piplibMP.h>])
 194     ],[
 195         AC_MSG_WARN([Piplib not found])
 196         bv_cv_piplibfatal="yes"
 197     ])
 198     if test "$bv_cv_piplibfatal" = "no"; then
 199         AC_DEFINE(HAVE_PIPLIB,[],[use piplib])
 200         LIBS="-lpiplibMP $LIBS"
 201         AC_LIBOBJ(piputil)
 202         bv_extra_programs="piptest $bv_extra_programs"
 203         have_piplib=true
 204     else
 205         CPPFLAGS="$SAVE_CPPFLAGS"
 206         LDFLAGS="$SAVE_LDFLAGS"
 207     fi
 208 fi
 209 AM_CONDITIONAL(HAVE_PIPLIB, test x$have_piplib = xtrue)
 210
 211 AC_MSG_CHECKING(if the fractional representation should be used)
 212 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 213                                           [Don't use fractional representation])],
 214             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 215 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 216                                       [Don't use fractional representation])],
 217             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 218 AC_MSG_RESULT($bv_cv_modulo)
 219 if test "x$bv_cv_modulo" != "xno" ; then
 220         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 221 fi
 222
 223 AC_MSG_CHECKING(whether to use incremental algorithm)
 224 AC_ARG_ENABLE(incremental,
 225         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 226                         [Enable incremental algorithm [bf]])],
 227         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 228 AC_MSG_RESULT($bv_cv_incremental)
 229 case $bv_cv_incremental in
 230         yes | bf)
 231                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 232                           [Use breadth-first incremental algorithm])
 233         ;;
 234         df)
 235                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 236                           [Use depth-first incremental algorithm])
 237         ;;
 238 esac
 239
 240 AC_ARG_WITH(ntl,
 241             [  --with-ntl=DIR          DIR Location of NTL],
 242             [ echo "Package ntl : $withval" && ntl_package=$withval],
 243             [ ntl_package=yes ])
 244
 245 if test "$ntl_package" = "no"; then
 246     AC_MSG_ERROR(Need ntl)
 247 fi
 248
 249 if test "$ntl_package" != "yes"; then
 250     CPPFLAGS="-I$ntl_package/include $CPPFLAGS"
 251     LDFLAGS="-L$ntl_package/lib $LDFLAGS"
 252 fi
 253
 254 AC_EGREP_CPP(yes, [
 255     #include <NTL/ZZ.h>
 256     #ifdef NTL_GMP_LIP
 257     yes
 258     #endif
 259     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 260
 261 AC_CHECK_LIB(ntl, main,[],[
 262     AC_MSG_ERROR(Need ntl)
 263 ])
 264
 265 AC_LANG_PUSH(C++)
 266 have_ginac=false
 267 AM_PATH_GINAC(1.3.3, [
 268         have_ginac=true
 269         AC_DEFINE(HAVE_GINAC,[],[use GiNaC])])
 270 AC_LANG_POP
 271 AM_CONDITIONAL(HAVE_GINAC, test x$have_ginac = xtrue)
 272
 273 AC_MSG_CHECKING(whether to use Omega)
 274 AC_ARG_WITH(omega, [AS_HELP_STRING([--with-omega=DIR],[DIR Location of Omega])],
 275             [ omega_package=$withval],  [ omega_package=yes ])
 276 AC_MSG_RESULT($omega_package)
 277
 278 AC_SUBST(OMEGA_CPPFLAGS)
 279 AC_SUBST(OMEGA_LDFLAGS)
 280 AC_SUBST(OMEGA_LIBS)
 281 AC_SUBST(bv_omega_programs)
 282 have_omega=false
 283 if test "$omega_package" != "no"; then
 284     if test "x$omega_package" != "xyes"; then
 285         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 286         OMEGA_LDFLAGS="-L$omega_package/lib"
 287     else
 288         for i in /usr/include /usr/local/include; do
 289             if test -f $i/omega/omega.h; then
 290                 OMEGA_CPPFLAGS="-I$i/omega"
 291             fi
 292         done
 293     fi
 294
 295     AC_LANG_PUSH(C++)
 296     SAVE_CPPFLAGS="$CPPFLAGS"
 297     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 298     AC_CHECK_HEADERS([omega.h],[
 299         if test x$have_ginac = xtrue; then
 300             bv_omega_programs="occ $bv_omega_programs"
 301         fi
 302         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 303         OMEGA_LIBS="-lcode_gen -lomega"
 304         have_omega=true
 305     ],[AC_MSG_WARN(Omega not found)])
 306     CPPFLAGS="$SAVE_CPPFLAGS"
 307     AC_LANG_POP
 308 fi
 309 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 310
 311 AC_MSG_CHECKING(whether to use GLPK)
 312 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 313             [ glpk_package=$withval],  [ glpk_package=yes ])
 314 AC_MSG_RESULT($glpk_package)
 315
 316 have_glpk=false
 317 if test "$glpk_package" != "no"; then
 318     if test "x$glpk_package" != "xyes"; then
 319         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 320         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 321     fi
 322     AC_CHECK_HEADERS([glpk.h],[
 323         have_glpk=true
 324         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 325     ])
 326 fi
 327 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 328
 329 if test "$have_glpk" = "true"; then
 330     AC_LIBOBJ(basis_reduction)
 331     AC_LIBOBJ(sample)
 332     bv_extra_programs="polyhedron_sample 4coins lexmin $bv_extra_programs"
 333     bv_extra_programs="polytope_scan $bv_extra_programs"
 334 fi
 335
 336 AC_SUBST(GIT_HEAD_ID)
 337 AC_SUBST(GIT_HEAD)
 338 AC_SUBST(GIT_HEAD_VERSION)
 339 if test -f $srcdir/.git/HEAD; then
 340     GIT_HEAD="$srcdir/.git/index"
 341     GIT_REPO="$srcdir/.git"
 342     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 343 elif test -f $srcdir/GIT_HEAD_ID; then
 344     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 345 else
 346     mysrcdir=`(cd $srcdir; pwd)`
 347     head=`basename $mysrcdir | sed -e 's/.*-//'`
 348     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 349     head3=`echo $head2 | sed -e 's/........................................//'`
 350     base=`basename $mysrcdir | sed -e 's/-.*//'`
 351     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 352         GIT_HEAD_ID="barvinok-$VERSION-$head
 353     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 354         GIT_HEAD_ID="barvinok-$VERSION-$head
 355     else
 356         GIT_HEAD_ID="UNKNOWN"
 357     fi
 358 fi
 359 if test -z "$GIT_REPO" ; then
 360     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 361 else
 362     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 363 fi
 364 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 365
 366 AX_CREATE_PKGCONFIG_INFO
 367
 368 AC_CONFIG_HEADERS(config.h)
 369 AC_CONFIG_FILES(Makefile doc/Makefile omega/Makefile)
 370 AC_CONFIG_SUBDIRS(bernstein)
 371 AC_OUTPUT