configure.ac

   1 nl Initialize autoconf and automake
   2 AC_INIT
   3 AC_CONFIG_SRCDIR(src/main.c)
   4 AC_PREREQ(2.52)
   5 AM_INIT_AUTOMAKE(adesklets,0.6.2)
   6 AM_MAINTAINER_MODE
   7
   8 dnl Language selection
   9 AC_LANG(C)
  10
  11 dnl Locate required external software
  12 AC_PROG_CPP
  13 if test "x$CPP" != 'x'; then
  14 :
  15 AC_SUBST(CPP)
  16 fi
  17 AC_PROG_CC
  18 AM_PROG_LEX
  19 if test "x$LEX" != 'xflex'; then
  20 AC_MSG_WARN([
  21 -----------------------------------------------------
  22 `flex' was not found on your system. If you encounter
  23 problems recompiling a `l' file, please try `flex'
  24 first. You can get it from any GNU archive site.
  25 You will not need `flex' as long as you do not
  26 modify `l' files.
  27 ----------------------------------------------------])
  28 fi
  29 AC_PROG_YACC
  30 if test "x$YACC" != "xbison -y"; then
  31 AC_MSG_WARN([
  32 -----------------------------------------------------
  33 Nor `byacc' or `yacc' parsers had been used
  34 for developing adesklets. If you encounter problems
  35 recompiling a `y' file, please try `bison' instead.
  36 You can get it from any GNU archive site. You will
  37 not need `bison' as long as you do not modify
  38 `y' files.
  39 -----------------------------------------------------])
  40 fi
  41 AC_PROG_INSTALL
  42
  43 dnl Check for python support
  44 withval=
  45 AC_ARG_WITH(python-support,
  46 [  --without-python-support
  47                           do not install adesklets python package
  48                           Do not set this option unless you have
  49                           good reasons])
  50 : ${withval:=yes}
  51 if test x$withval = "xyes"; then
  52 withval=
  53 AC_ARG_WITH(python-force-detection,
  54 [  --with-python-force-detection
  55                           bypass all the python version check mechanism.
  56                           When using this, make sure you have a version
  57                           greater or egal to python 2.3 installed
  58                           as 'python' in your path [default=no]])
  59 : ${withval:=no}
  60 if test x$withval = "xno"; then
  61 AM_PATH_PYTHON([2.3])
  62 else
  63 AM_PATH_PYTHON()
  64 fi
  65 AC_PYTHON_DEVEL
  66 withval=
  67 AC_ARG_WITH(python-install-submission-scripts,
  68 [  --with-python-install-submission-scripts
  69                           install in the path the submission-related scripts
  70                           from submit/ in the $PREFIX/bin program path.
  71                           Useful for desklets author [default=no]])
  72 : ${withval:=no}
  73 if test x$withval = "xyes"; then
  74 AM_CONDITIONAL(PYTHON_INSTALL_SUBMISSION_SCRIPTS, true)
  75 else
  76 AM_CONDITIONAL(PYTHON_INSTALL_SUBMISSION_SCRIPTS, false)
  77 fi
  78 AC_CHECK_FUNCS(sigprocmask,
  79 [HAVE_SIGPROCMASK="#define HAVE_SIGPROCMASK 1", SIGPROC=yes],
  80 [HAVE_SIGPROCMASK="#undef HAVE_SIGPROCMASK"])
  81 else
  82 HAVE_SIGPROCMASK="#undef HAVE_SIGPROCMASK"
  83 fi
  84 AC_SUBST(HAVE_SIGPROCMASK)
  85 AM_CONDITIONAL(PYTHON_SUPPORT, test "x$PYTHON" != "x")
  86 AM_CONDITIONAL(PYTHON_INSTALL_SUBMISSION_SCRIPTS, true)
  87
  88 dnl Check for Perl support
  89 withval=
  90 AC_ARG_WITH(perl-support,
  91 [  --without-perl-support  do not install adesklets Perl package
  92                           Do not set this option unless you have
  93                           good reasons])
  94 : ${withval:=yes}
  95 perl_ok=false
  96 if test x$withval = "xyes"; then
  97 AC_PATH_PROG(PERL, perl)
  98 AC_PROG_PERL_VERSION(5.8.2,
  99         AC_PROG_PERL_MODULES(IPC::Open3, perl_ok=true),
 100         AC_MSG_WARN(['Perl >= 5.8.2 could not be found']))
 101 fi
 102 AM_CONDITIONAL(PERL_SUPPORT,$perl_ok)
 103
 104 dnl help2man presence
 105 AC_PATH_PROG(HELP2MAN, help2man)
 106 AM_CONDITIONAL(HELP2MAN_SUPPORT, test "x$HELP2MAN" != "x")
 107
 108 dnl htmltidy presence
 109 AC_PATH_PROG(TIDY,tidy)
 110
 111 dnl doxygen presence
 112 AC_PATH_PROG(DOXYGEN,doxygen)
 113 AM_CONDITIONAL(DOXYGEN_SUPPORT, test "x$DOXYGEN" != "x")
 114
 115 dnl makeinfo support:
 116 dnl Also test the presence of the full documentation package
 117 AM_CONDITIONAL(MAKEINFO_SUPPORT,
 118 test "x$MAKEINFO:" != "x" && test -f doc/Makefile.am)
 119
 120 dnl Try to enforce ISO C (iso9899 1999)
 121 dnl This will more likely work
 122 dnl only with gcc. In fact,
 123 dnl expect for variadic macros, this program
 124 dnl should be ansi C (ISO C90).
 125 TMP_CFLAGS="$CFLAGS"
 126 CFLAGS="$CFLAGS -std=c99 -pedantic -Wall"
 127 AC_MSG_CHECKING([for ISO C99 warnings generation])
 128 AC_TRY_COMPILE(
 129 ,
 130 int
 131 main(void)
 132 {
 133    return 0L;
 134 },
 135 AC_MSG_RESULT([yes]),
 136 AC_MSG_RESULT([no])
 137 CFLAGS="$TMP_CFLAGS"
 138 )
 139
 140 dnl Define source to be BSD compliant (ISO C, POSIX, and 4.3BSD)
 141 AC_DEFINE(_BSD_SOURCE,1,[Source is BSD compliant (ISO C, POSIX and 4.3BSD)])
 142 if test "x`uname`" = xNetBSD; then
 143 dnl NetBSD (at least version 1.6.1) is following the standard less closely than
 144 dnl the other... Hence, we declare the source specifically as _POSIX_SOURCE
 145 dnl instead of the newer _POSIX_C_SOURCE 199309
 146 AC_DEFINE(_POSIX_SOURCE,1,[Source is POSIX 1 compliant (IEEE Std 1003.1)])
 147 else
 148 dnl For some unspecified reason, it as been reported than FreeBSD [5|6|7].x
 149 dnl doesn't like those POSIX keywords either
 150 UNAME_REDUX=`uname -r -s | sed 's/\..*//' 2> /dev/null`
 151 if test "$UNAME_REDUX" != 'FreeBSD 5' && \
 152    test "$UNAME_REDUX" != 'FreeBSD 6' && \
 153    test "$UNAME_REDUX" != 'FreeBSD 7'
 154 then
 155 AC_DEFINE(_POSIX_C_SOURCE,199309,[Source is POSIX 4 compliant (IEEE Std 1003.1b)])
 156 fi
 157 fi
 158
 159 dnl Check for system header files
 160 AC_HEADER_STDC
 161 AC_CHECK_HEADERS(stdio.h stdarg.h errno.h fcntl.h signal.h time.h math.h sys/time.h sys/types.h sys/stat.h grp.h pwd.h libgen.h dirent.h iconv.h)
 162
 163 dnl Enable debugging
 164 dnl This will filter out optimisation switch (-O[s0-9])
 165 dnl for gcc compiler
 166 AC_ARG_ENABLE(
 167   debug, [  --enable-debug        enable debugging symbols and supplementary
 168                           messages generation in final binary])
 169
 170 : ${enableval="no"}
 171 AC_MSG_CHECKING([for debugging symbols generation])
 172 if test x$enableval = "xyes"; then
 173    AC_MSG_RESULT([yes])
 174    AC_DEFINE(DEBUG, 1, [Debug mode is on if defined.])
 175    CFLAGS="$CFLAGS -g"
 176    DEBUG=yes
 177 else
 178    AC_MSG_RESULT([no])
 179    CFLAGS=`echo "$CFLAGS" | sed 's/^-g$//; s/^-g@<:@@<:@:space:@:>@@:>@\+// ; s/@<:@@<:@:space:@:>@@:>@\+-g$//; s/@<:@@<:@:space:@:>@@:>@\+-g@<:@@<:@:space:@:>@@:>@\+/ /'`
 180 fi
 181
 182 dnl SIGKILL timeout setting
 183 enableval=
 184 AC_MSG_CHECKING([for sigkill timeout])
 185 AC_ARG_ENABLE(sigkill-timeout,
 186 [  --enable-sigkill-timeout=SEC
 187                           timeout (in seconds) before sending `kill'
 188                           signal to parent process in case of restart
 189                           if `term' has no effect [default=5]])
 190 : ${enableval:=5}
 191 test $enableval -gt 0 2> /dev/null || {
 192 AC_MSG_RESULT([no])
 193 AC_MSG_ERROR([Given sigkill timeout was not understood])
 194 }
 195 AC_MSG_RESULT([yes])
 196 AC_DEFINE_UNQUOTED(SIGKILL_TIMEOUT,$enableval,
 197 [Delay between SIGTERM ans SIGKILL to parent process in case of restart.])
 198
 199 dnl X polling frequency setting
 200 enableval=
 201 period=
 202 AC_MSG_CHECKING([for polling frequency])
 203 AC_ARG_ENABLE(x-polling-frequency,
 204 [  --enable-x-polling-frequency=FREQ
 205                           frequency (in hertz) for polling the X server
 206                           for events. Lower values leads to less responsive,
 207                           but less CPU hungry desklets [default=50]])
 208 : ${enableval:=50}
 209 test $enableval -gt 0 2> /dev/null || {
 210 AC_MSG_RESULT([no])
 211 AC_MSG_ERROR([Positive, integer value is required as x-polling-frequency])
 212 }
 213
 214 AC_CHECK_PROG(EXISTS,bc,yes,no)
 215 if test $enableval -ne 50; then
 216 if test x$EXISTS = "xyes"; then
 217    period=`echo "1000000 / $enableval" | bc`
 218 else
 219    AC_MSG_WARN([Could not find the `bc' calculator to perform arithmetic
 220 computation of X server polling period value. Default 50 Hz is assumed.])
 221 fi
 222 fi
 223 : ${period:=20000}
 224 AC_DEFINE_UNQUOTED(X_POLLING_PERIOD,$period,
 225 [Polling period (in 10e-6 seconds) of stdin between two cycles of events loop.])
 226
 227 dnl Lock files directory setting
 228 enableval=
 229 AC_MSG_CHECKING([for lock files directory setting])
 230 AC_ARG_ENABLE(lockfiles-dir,
 231 [  --enable-lockfiles-dir=DIR
 232                           directory to put lock files in [default=/tmp]])
 233 : ${enableval:=/tmp}
 234 test -d $enableval || {
 235 AC_MSG_RESULT([no])
 236 AC_MSG_ERROR([Given lock files directory does not exist on your system])
 237 }
 238 AC_MSG_RESULT([yes])
 239 AC_DEFINE_UNQUOTED(LOCKFILES_DIR,"$enableval",
 240 [Directory to put lock files in.])
 241 LOCKFILES_DIR=$enableval
 242 AC_SUBST(LOCKFILES_DIR)
 243
 244 dnl Control modifier on context menu
 245 enableval=
 246 AC_MSG_CHECKING([for control modifier on context menu])
 247 AC_ARG_ENABLE(control-on-context-menu,
 248 [  --enable-control-on-context-menu
 249                           force CTRL to be pressed to fire context menu
 250                           [default=no]])
 251 : ${enableval:=no}
 252 if test x$enableval != "xno" ; then
 253 AC_MSG_RESULT([yes])
 254 AC_DEFINE(CONTROL_ON_CONTEXT_MENU, 1,
 255 [Force CTRL to be pressed to fire context menu])
 256 else
 257 AC_MSG_RESULT([no])
 258 fi
 259
 260 dnl Legacy Window Manager detection code
 261 enableval=
 262 AC_MSG_CHECKING([for legacy fake root window detection code])
 263 AC_ARG_ENABLE(legacy-fake-root-window-detection,
 264 [  --enable-legacy-fake-root-window-detection
 265                           Use the old code to detect fake root windows
 266                           [default=no]])
 267 : ${enableval:=no}
 268 if test x$enableval != "xno" ; then
 269 AC_MSG_RESULT([yes])
 270 AC_DEFINE(WM_DETECTION_OLD_STYLE, 1,
 271 [Use former fake root window detection code])
 272 else
 273 AC_MSG_RESULT([no])
 274 fi
 275
 276 dnl New frontend driver
 277 enableval=
 278 AC_MSG_CHECKING([for frontend shell driver])
 279 AC_ARG_ENABLE(frontend-shell-driver,
 280 [  --disable-frontend-shell-driver
 281                           Do not invoke the frontend shell-based driver
 282                           for adesklets [default=no]])
 283 : ${enableval:=yes}
 284 if test x$enableval != "xyes" ; then
 285 AM_CONDITIONAL(FRONTEND_SHELL_SUPPORT, test 1 -eq 0)
 286 AC_MSG_RESULT([no])
 287 else
 288 AC_DEFINE(FRONTEND_SHELL_DRIVER, 1,
 289 [Enable the frontend shell driver mecanism])
 290 AM_CONDITIONAL(FRONTEND_SHELL_SUPPORT, test 1 -eq 1)
 291 AC_MSG_RESULT([yes])
 292 fi
 293
 294 dnl Collect various system informations strings,
 295 dnl for embedding into final executable
 296 EXISTS=
 297 WELCOME1="\"$PACKAGE $VERSION"
 298 AC_CHECK_PROG(EXISTS,date,yes)
 299 if test x$EXISTS = "xyes"; then
 300    WELCOME1="$WELCOME1 ("`date | sed 's/@<:@@<:@:space:@:>@@:>@\+/ /g'`")"
 301 else
 302    WELCOME1="$WELCOME1 (unknown time)"
 303 fi
 304 EXISTS=
 305 AC_CHECK_PROG(EXISTS,uname,yes)
 306 if test x$EXISTS = "xyes"; then
 307    if uname -rs &> /dev/null; then
 308       WELCOME1="$WELCOME1, on "`uname -rs`"\""
 309    else
 310       WELCOME1="$WELCOME1, on an unknown OS\""
 311    fi
 312 else
 313    WELCOME1="$WELCOME1, on an unknown OS\""
 314 fi
 315 AC_DEFINE_UNQUOTED(WELCOME_LINE_1, $WELCOME1, [Welcome message, first line.])
 316 dnl Note: @<:@ and @:>@ are respective quadrigraphs for `[' and `]'
 317 ${CC} --version &> /dev/null && \
 318       WELCOME2="\"${CC} "`${CC} --version | sed -n '1 s/^@<:@^0-9@:>@*//p'`"\""
 319 : ${WELCOME2:=\"${CC} unknown version\"}
 320 AC_DEFINE_UNQUOTED(WELCOME_LINE_2, $WELCOME2, [Welcome message, second line.])
 321
 322 dnl Variables save: all changes to CFLAGS, LIBS and LDFLAGS beyond
 323 dnl this point will be wiped
 324 TMP_CFLAGS="$CFLAGS"
 325 TMP_LIBS="$LIBS"
 326 TMP_LDFLAGS="$LDFLAGS"
 327
 328 dnl Check for readline
 329 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=yes; LibTermcap=ncurses,
 330    AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=yes; LibTermcap=termcap,
 331       AC_CHECK_LIB(curses, tputs, HaveLibTermcap=yes; LibTermcap=curses,
 332                    HaveLibTermcap=no)))
 333 if test $HaveLibTermcap = "yes" ; then
 334    LIBS="$LIBS -l$LibTermcap"
 335 else
 336    AC_MSG_ERROR([Could not find terminal management library for readline
 337 (either ncurses, termcap or curses).])
 338 fi
 339 AC_CHECK_LIB(readline,readline,
 340   READLINE_LIBS="-l$LibTermcap -lreadline",
 341   AC_MSG_ERROR([Could not find the readline library]),
 342   $LFLAGS)
 343 LIBS="$TMP_LIBS"
 344
 345 dnl Check for libhistory support
 346 withval=
 347 AC_ARG_WITH(history,
 348 [  --without-history       remove history support in interactive use
 349                           of the interpreter])
 350 : ${withval:=yes}
 351 if test x$withval = "xyes"; then
 352 AC_CHECK_LIB(history,add_history,
 353         READLINE_LIBS="$READLINE_LIBS -lhistory";
 354         HaveLibHistory=history,
 355         AC_CHECK_LIB(readline,add_history,
 356         HaveLibHistory=readline,
 357         HaveLibHistory=no,
 358         $READLINE_LIBS),
 359         $READLINE_LIBS)
 360
 361 if test $HaveLibHistory = "no"; then
 362 AC_MSG_WARN([Could not find GNU history library in the system])
 363 else
 364 AC_DEFINE(HAVE_READLINE_HISTORY_H,1,
 365         [Define to 1 if you have the <readline/history.h> header file.])
 366 AC_CHECK_LIB($HaveLibHistory,free_history_entry,
 367         AC_DEFINE(HAVE_FREE_HISTORY_ENTRY,1,
 368         [Define to 1 if you have the `free_history_entry' function.]),,
 369         $READLINE_LIBS)
 370 fi
 371
 372 AC_MSG_CHECKING([for history max command lenght])
 373 enableval=
 374 AC_ARG_ENABLE(history-max-command-lenght,
 375 [  --enable-history-max-command-lenght=LEN
 376                           maximum string lenght (in characters) that a single
 377                           command can have and still be kept in history
 378                           (a lenght of zero meaning no limits) [default=256]])
 379 : ${enableval:=256}
 380
 381 if test $enableval -ge 0 ; then
 382 AC_MSG_RESULT([yes])
 383 AC_DEFINE_UNQUOTED(HISTORY_MAX_COMMAND_LENGHT,$enableval,
 384 [maximum history string lenght.])
 385 else
 386 AC_MSG_RESULT([no])
 387 AC_MSG_ERROR([history max command lenght must be positive or null])
 388 fi
 389
 390 fi
 391 AC_SUBST(READLINE_LIBS)
 392
 393 dnl Check for 8 bit characters support forcing
 394 enableval=
 395 AC_ARG_ENABLE(force-extended-characters-input,
 396 [  --enable-force-extended-characters-input
 397                           force input and ouput of unescaped
 398                           height bits characters through GNU readline,
 399                           regardless of the inputrc settings [default=no]])
 400 : ${enableval:=no}
 401 if ! test x$enableval = "xno" ; then
 402 AC_DEFINE(FORCE_EXTENDED_CHARACTERS_INPUT,1,
 403 [force 8 bit characters support in GNU readline])
 404 fi
 405
 406 dnl Check for fontconfig
 407 withval=
 408 AC_ARG_WITH(fontconfig,
 409 [  --without-fontconfig    remove fontconfig support enabling automatic
 410                           detection of all truetype fonts already available
 411                           on the machine])
 412 : ${withval:=yes}
 413 if test x$withval = "xyes"; then
 414 AC_PATH_PROG(PKG_CONFIG, pkg-config)
 415 if ! test x$PKG_CONFIG = "x" ; then
 416    if $PKG_CONFIG --exists fontconfig 2> /dev/null; then
 417       FONTCONFIG_LIBS=`pkg-config --libs fontconfig`
 418       FONTCONFIG_CFLAGS=`pkg-config --cflags fontconfig`
 419    fi
 420 fi
 421 if test x$FONTCONFIG_LIBS = "x"; then
 422    FONTCONFIG_LIBS=-lfontconfig
 423 fi
 424 LIBS="$LIBS $FONTCONFIG_LIBS"
 425 CFLAGS="$CFLAGS $FONTCONFIG_CFLAGS"
 426 AC_MSG_CHECKING([for fontconfig])
 427 AC_TRY_LINK(
 428 #include <fontconfig/fontconfig.h>
 429 , FcInit(),
 430 AC_MSG_RESULT([yes])
 431 AC_DEFINE(HAVE_FONTCONFIG_FONTCONFIG_H,1,[Define to 1 if you have the <fontconfig/fontconfig.h> header file.])
 432
 433 AC_MSG_CHECKING([For fontconfig FcFini()])
 434 AC_TRY_LINK(
 435 #include <fontconfig/fontconfig.h>
 436 , FcFini(),
 437 AC_MSG_RESULT([yes])
 438 AC_DEFINE(HAVE_FONTCONFIG_FCFINI,1,[Define to 1 if FcFini() call exists])
 439 ,
 440 AC_MSG_RESULT([no]))
 441
 442 ,
 443 AC_MSG_RESULT([no])
 444 FONTCONFIG_LIBS=
 445 FONTCONFIG_CFLAGS=
 446 AC_MSG_WARN([
 447 -----------------------------------------------------
 448 `fontconfig' was not found on your system.
 449 Although `adesklets' will work anyway system-wide
 450 automatic font detection will not occur:
 451 it is therefore quite possible that only the
 452 default font provided with the package will display.
 453 -----------------------------------------------------]))
 454 AC_SUBST(FONTCONFIG_LIBS)
 455 AC_SUBST(FONTCONFIG_CFLAGS)
 456 LIBS="$TMP_LIBS"
 457 CFLAGS="$TMP_CFLAGS"
 458 fi
 459
 460 dnl Check for fork() system call
 461 AC_CHECK_FUNCS(fork,,
 462 AC_MSG_ERROR([Could not find the fork() system call]))
 463
 464 dnl Check for X headers and libraries
 465 AC_PATH_X
 466
 467 if test x$no_x != "xyes"; then
 468
 469 if test x$x_includes != "x" ; then
 470    X_CFLAGS="-I$x_includes"
 471    CFLAGS="$CFLAGS $X_CFLAGS"
 472 fi
 473
 474 if test x$x_libraries != "x" ; then
 475    X_LIBS="-L$x_libraries"
 476    LDFLAGS="$LDFLAGS $X_LIBS"
 477 fi
 478
 479 dnl Check for required functions in -lX11
 480 AC_CHECK_LIB(X11, XOpenDisplay,
 481   X_LIBS="$X_LIBS -lX11"
 482   LIBS="$LIBS -lX11",
 483   AC_MSG_ERROR([Could not find XOpenDisplay in -lX11.])
 484 )
 485 AC_DEFINE(X_DISPLAY_SUPPORT,1,[Define to 1 if the X Window System is supported, 0 otherwise.])
 486 else
 487 AC_DEFINE(X_DISPLAY_SUPPORT,0,[Define to 1 if the X Window System is supported, 0 otherwise.])
 488    X_CFLAGS=
 489    X_LIBS=
 490 AC_DEFINE(X_DISPLAY_MISSING,,[Defined if the X headers were not found])
 491 fi
 492 AC_SUBST(X_CFLAGS)
 493 AC_SUBST(X_LIBS)
 494
 495 dnl Imlib2 detection
 496 withval=
 497 AC_ARG_WITH(imlib2,
 498         [  --with-imlib2=DIR       use imlib2 in <DIR>],
 499         [CFLAGS="$CFLAGS -I$withval/include"
 500         LIBS="-L$withval/lib $LIBS"])
 501
 502 AC_PATH_GENERIC_MODIFIED(imlib2, 1.1.2,,
 503   AC_MSG_ERROR([Cannot find imlib2: Is imlib2-config in the path?]),
 504   1.2.0,,
 505   AC_MSG_WARN([
 506 -----------------------------------------------------
 507 $PACKAGE should work with your version of imlib2...
 508 But for better results you are _warmly_ encouraged
 509 to try out version 1.2.0 or above;
 510 known bugs are still lurking in dark corners
 511 with what you have installed: beware strange problems
 512 with dynamic image filters for instance!
 513 -----------------------------------------------------]))
 514
 515 LIBS="$LIBS -lImlib2"
 516 dnl CFLAGS="$CFLAGS $IMLIB2_CFLAGS"
 517
 518 AC_MSG_CHECKING([for imlib2 program linking with ad-hoc flags])
 519 AC_TRY_LINK(
 520 #ifndef X_DISPLAY_MISSING
 521         #include <X11/Xlib.h>
 522         #include <X11/Xutil.h>
 523         #include <X11/Xos.h>
 524         #include <X11/Xatom.h>
 525 #endif
 526         #include <Imlib2.h>
 527 ,       Imlib_Image image;
 528         image = imlib_load_image("toto.png");
 529 #ifndef X_DISPLAY_MISSING
 530         imlib_context_set_display(NULL);
 531 #endif
 532 ,
 533         AC_MSG_RESULT([yes])
 534         IMLIB2_CFLAGS=""
 535         IMLIB2_LIBS="-lImlib2",
 536         AC_MSG_RESULT([no])
 537         CFLAGS="$TMP_CFLAGS $IMLIB2_CFLAGS"
 538         LIBS="$TMP_LIBS $IMLIB2_LIBS"
 539         AC_MSG_CHECKING([for imlib2 program linking])
 540         AC_TRY_LINK(
 541 #ifndef X_DISPLAY_MISSING
 542         #include <X11/Xlib.h>
 543         #include <X11/Xutil.h>
 544         #include <X11/Xos.h>
 545         #include <X11/Xatom.h>
 546 #endif
 547         #include <Imlib2.h>
 548 ,       Imlib_Image image;
 549         image = imlib_load_image("toto.png");
 550 #ifndef X_DISPLAY_MISSING
 551         imlib_context_set_display(NULL);
 552 #endif
 553 ,
 554         AC_MSG_RESULT([yes]),
 555         AC_MSG_RESULT([no])
 556         AC_MSG_ERROR([Cannot link Imlib2 program.
 557 If you specified you did not want X support this can be caused
 558 by your Imlib2 installment being configured so it needs it
 559 or conversely. In that case reinstall Imlib2 with proper
 560 --enable-x11-support parameter (as from enlightement CVS)
 561 before retrying to configure this package.])))
 562
 563 AC_SUBST(IMLIB2_CFLAGS)
 564 AC_SUBST(IMLIB2_LIBS)
 565
 566
 567 dnl Test for uint typedef
 568 AC_MSG_CHECKING([for uint typedef in standard library])
 569 AC_TRY_COMPILE(
 570 #ifdef HAVE_SYS_TYPES_H
 571         #include <sys/types.h>
 572 #endif
 573 #ifdef HAVE_UNISTD_H
 574         #include <unistd.h>
 575 #endif
 576 ,       uint i,
 577         AC_MSG_RESULT([yes]),
 578         AC_MSG_RESULT([no])
 579         AC_DEFINE(UINT_NOT_DEFINED,1,
 580                   [Define to 1 if compability type uint is not detected.])
 581 )
 582
 583 dnl Important variables reset
 584 CFLAGS="$TMP_CFLAGS"
 585 LIBS="$TMP_LIBS"
 586 LDFLAGS="$TMP_LDFLAGS"
 587
 588 dnl PKGDATADIR definition
 589 dnl PKGDATADIR is only well constructed in make context,
 590 dnl so let's put this AFTER all tests.
 591 CFLAGS="$CFLAGS"' -DPKGDATADIR=\"$(pkgdatadir)\"'
 592
 593 dnl Output files
 594 AM_CONFIG_HEADER(src/config.h)
 595 AC_OUTPUT(Makefile
 596 src/Makefile
 597 data/Makefile
 598 utils/Makefile
 599 doc/Makefile
 600 doc/adesklets_checkin.1
 601 doc/adesklets_submit.1
 602 doc/htmldoc.sh
 603 doc/imlib2/Makefile
 604 scripting/Makefile
 605 scripting/protoize.sh
 606 scripting/python/Makefile
 607 scripting/python/config.h
 608 scripting/python/setup.py
 609 scripting/perl/Makefile
 610 scripting/perl/Makefile.PL
 611 scripting/perl/updateproto.pl
 612 utils/adesklets_frontend.sh
 613 )
 614
 615 dnl Change script(s) permissions
 616 chmod +x scripting/protoize.sh scripting/perl/updateproto.pl \
 617       doc/htmldoc.sh utils/adesklets_frontend.sh
 618
 619 dnl Final warning, if needed
 620 if test x$DEBUG = "xyes"; then
 621 AC_MSG_WARN([
 622 -----------------------------------------------------
 623 you choosed to make a `debug' compilation: this will
 624 generate a significantly bigger executable
 625 that produces on stderr (by default) a lot of outputs
 626 unwanted during normal use; set up the ADESKLETS_LOG
 627 environment variable to a filename the interpreter
 628 can safely suffix with a pid related extension
 629 than truncate to collect all debug outputs
 630 there instead. Be also aware that all optimisation
 631 settings (-O flags in CFLAGS) are discarded when
 632 enabling this.
 633 -----------------------------------------------------])
 634 fi
 635 if test x$no_x = "xyes"; then
 636 AC_MSG_WARN([
 637 -----------------------------------------------------
 638 you choosed to perform an `X Window less' build -
 639 which means you will eventually end up with
 640 a strictly command line program free of all
 641 dependencies on xlib. If it is not what you intended
 642 please reconfigure. For this to work you do need first
 643 to configure your Imlib2 incantation for not using
 644 X Window itself.
 645 -----------------------------------------------------
 646 ])
 647 fi
 648
 649 if test x$PYTHON != "x" ; then
 650 if test x$SIGPROC != "xyes" ; then
 651 AC_MSG_WARN([
 652 -----------------------------------------------------
 653 your system does not seem to support reliable POSIX
 654 signal calls such as `sigprocmask', `sigpending' or
 655 `sigsuspend'. Although this does not affect $PACKAGE
 656 directly, it seriously impedes python ability
 657 to handle things well through its package.
 658 To our knowledge, no modern UNIX platforms lack
 659 those system calls...
 660 -----------------------------------------------------
 661 ])
 662 fi
 663 fi